lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 # check deps
   4 BEGIN {
   5   use Carp::Clan qw/^DBIx::Class/;
   6   use DBIx::Class;
   7   croak('The following modules are required for DBIx::Class::Admin ' . DBIx::Class::Optional::Dependencies->req_missing_for ('admin') )
   8     unless DBIx::Class::Optional::Dependencies->req_ok_for ('admin');
   9 }
  10
  11 use Moose;
  12 use MooseX::Types::Moose qw/Int Str Any Bool/;
  13 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  14 use MooseX::Types::JSON qw(JSON);
  15 use MooseX::Types::Path::Class qw(Dir File);
  16 use Try::Tiny;
  17 use JSON::Any qw(DWIW XS JSON);
  18 use namespace::autoclean;
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Admin - Administration object for schemas
  23
  24 =head1 SYNOPSIS
  25
  26   $ dbicadmin --help
  27
  28   $ dbicadmin --schema=MyApp::Schema \
  29     --connect='["dbi:SQLite:my.db", "", ""]' \
  30     --deploy
  31
  32   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  33     --connect='["dbi:SQLite:my.db", "", ""]' \
  34     --op=update --set='{ "name": "New_Employee" }'
  35
  36   use DBIx::Class::Admin;
  37
  38   # ddl manipulation
  39   my $admin = DBIx::Class::Admin->new(
  40     schema_class=> 'MY::Schema',
  41     sql_dir=> $sql_dir,
  42     connect_info => { dsn => $dsn, user => $user, password => $pass },
  43   );
  44
  45   # create SQLite sql
  46   $admin->create('SQLite');
  47
  48   # create SQL diff for an upgrade
  49   $admin->create('SQLite', {} , "1.0");
  50
  51   # upgrade a database
  52   $admin->upgrade();
  53
  54   # install a version for an unversioned schema
  55   $admin->install("3.0");
  56
  57 =head1 REQUIREMENTS
  58
  59 The Admin interface has additional requirements not currently part of
  60 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  61
  62 =head1 ATTRIBUTES
  63
  64 =head2 schema_class
  65
  66 the class of the schema to load
  67
  68 =cut
  69
  70 has 'schema_class' => (
  71   is  => 'ro',
  72   isa => Str,
  73 );
  74
  75
  76 =head2 schema
  77
  78 A pre-connected schema object can be provided for manipulation
  79
  80 =cut
  81
  82 has 'schema' => (
  83   is          => 'ro',
  84   isa         => 'DBIx::Class::Schema',
  85   lazy_build  => 1,
  86 );
  87
  88 sub _build_schema {
  89   my ($self)  = @_;
  90   require Class::MOP;
  91   {
  92     my @include_dirs = @{$self->include_dirs};
  93     local @INC = (@include_dirs, @INC);
  94     Class::MOP::load_class($self->schema_class);
  95   }
  96   $self->connect_info->[3]->{ignore_version} =1;
  97   return $self->schema_class->connect(@{$self->connect_info()} ); # ,  $self->connect_info->[3], { ignore_version => 1} );
  98 }
  99
 100 =head2 include_dirs
 101
 102 Extra include directories to look when loading C<schema_class>
 103
 104 =cut
 105
 106 has 'include_dirs' => (
 107     is => 'rw',
 108     isa => 'ArrayRef',
 109     default => sub {[]}
 110 );
 111
 112 =head2 resultset
 113
 114 a resultset from the schema to operate on
 115
 116 =cut
 117
 118 has 'resultset' => (
 119   is  => 'rw',
 120   isa => Str,
 121 );
 122
 123
 124 =head2 where
 125
 126 a hash ref or json string to be used for identifying data to manipulate
 127
 128 =cut
 129
 130 has 'where' => (
 131   is      => 'rw',
 132   isa     => DBICHashRef,
 133   coerce  => 1,
 134 );
 135
 136
 137 =head2 set
 138
 139 a hash ref or json string to be used for inserting or updating data
 140
 141 =cut
 142
 143 has 'set' => (
 144   is      => 'rw',
 145   isa     => DBICHashRef,
 146   coerce  => 1,
 147 );
 148
 149
 150 =head2 attrs
 151
 152 a hash ref or json string to be used for passing additonal info to the ->search call
 153
 154 =cut
 155
 156 has 'attrs' => (
 157   is      => 'rw',
 158   isa     => DBICHashRef,
 159   coerce  => 1,
 160 );
 161
 162
 163 =head2 connect_info
 164
 165 connect_info the arguments to provide to the connect call of the schema_class
 166
 167 =cut
 168
 169 has 'connect_info' => (
 170   is          => 'ro',
 171   isa         => DBICConnectInfo,
 172   lazy_build  => 1,
 173   coerce      => 1,
 174 );
 175
 176 sub _build_connect_info {
 177   my ($self) = @_;
 178   return $self->_find_stanza($self->config, $self->config_stanza);
 179 }
 180
 181
 182 =head2 config_file
 183
 184 config_file provide a config_file to read connect_info from, if this is provided
 185 config_stanze should also be provided to locate where the connect_info is in the config
 186 The config file should be in a format readable by Config::General
 187
 188 =cut
 189
 190 has config_file => (
 191   is      => 'ro',
 192   isa     => File,
 193   coerce  => 1,
 194 );
 195
 196
 197 =head2 config_stanza
 198
 199 config_stanza for use with config_file should be a '::' deliminated 'path' to the connection information
 200 designed for use with catalyst config files
 201
 202 =cut
 203
 204 has 'config_stanza' => (
 205   is  => 'ro',
 206   isa => Str,
 207 );
 208
 209
 210 =head2 config
 211
 212 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 213 config_stanza will still be required.
 214
 215 =cut
 216
 217 has config => (
 218   is          => 'ro',
 219   isa         => DBICHashRef,
 220   lazy_build  => 1,
 221 );
 222
 223 sub _build_config {
 224   my ($self) = @_;
 225
 226   try { require Config::Any }
 227     catch { die ("Config::Any is required to parse the config file.\n") };
 228
 229   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 230
 231   # just grab the config from the config file
 232   $cfg = $cfg->{$self->config_file};
 233   return $cfg;
 234 }
 235
 236
 237 =head2 sql_dir
 238
 239 The location where sql ddl files should be created or found for an upgrade.
 240
 241 =cut
 242
 243 has 'sql_dir' => (
 244   is      => 'ro',
 245   isa     => Dir,
 246   coerce  => 1,
 247 );
 248
 249
 250 =head2 version
 251
 252 Used for install, the version which will be 'installed' in the schema
 253
 254 =cut
 255
 256 has version => (
 257   is  => 'rw',
 258   isa => Str,
 259 );
 260
 261
 262 =head2 preversion
 263
 264 Previouse version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 265
 266 =cut
 267
 268 has preversion => (
 269   is  => 'rw',
 270   isa => Str,
 271 );
 272
 273
 274 =head2 force
 275
 276 Try and force certain operations.
 277
 278 =cut
 279
 280 has force => (
 281   is  => 'rw',
 282   isa => Bool,
 283 );
 284
 285
 286 =head2 quiet
 287
 288 Be less verbose about actions
 289
 290 =cut
 291
 292 has quiet => (
 293   is  => 'rw',
 294   isa => Bool,
 295 );
 296
 297 has '_confirm' => (
 298   is  => 'bare',
 299   isa => Bool,
 300 );
 301
 302
 303 =head1 METHODS
 304
 305 =head2 create
 306
 307 =over 4
 308
 309 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 310
 311 =back
 312
 313 L<create> will generate sql for the supplied schema_class in sql_dir.  The flavour of sql to
 314 generate can be controlled by suppling a sqlt_type which should be a L<SQL::Translator> name.
 315
 316 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 317
 318 Optional preversion can be supplied to generate a diff to be used by upgrade.
 319
 320 =cut
 321
 322 sub create {
 323   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 324
 325   $preversion ||= $self->preversion();
 326
 327   my $schema = $self->schema();
 328   # create the dir if does not exist
 329   $self->sql_dir->mkpath() if ( ! -d $self->sql_dir);
 330
 331   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 332 }
 333
 334
 335 =head2 upgrade
 336
 337 =over 4
 338
 339 =item Arguments: <none>
 340
 341 =back
 342
 343 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 344 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 345
 346 =cut
 347
 348 sub upgrade {
 349   my ($self) = @_;
 350   my $schema = $self->schema();
 351
 352   if (!$schema->get_db_version()) {
 353     # schema is unversioned
 354     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 355   } else {
 356     my $ret = $schema->upgrade();
 357     return $ret;
 358   }
 359 }
 360
 361
 362 =head2 install
 363
 364 =over 4
 365
 366 =item Arguments: $version
 367
 368 =back
 369
 370 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 371 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 372 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 373 already versioned databases.
 374
 375 =cut
 376
 377 sub install {
 378   my ($self, $version) = @_;
 379
 380   my $schema = $self->schema();
 381   $version ||= $self->version();
 382   if (!$schema->get_db_version() ) {
 383     # schema is unversioned
 384     print "Going to install schema version\n" if (!$self->quiet);
 385     my $ret = $schema->install($version);
 386     print "return is $ret\n" if (!$self->quiet);
 387   }
 388   elsif ($schema->get_db_version() and $self->force ) {
 389     carp "Forcing install may not be a good idea";
 390     if($self->_confirm() ) {
 391       $self->schema->_set_db_version({ version => $version});
 392     }
 393   }
 394   else {
 395     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 396   }
 397
 398 }
 399
 400
 401 =head2 deploy
 402
 403 =over 4
 404
 405 =item Arguments: $args
 406
 407 =back
 408
 409 deploy will create the schema at the connected database.  C<$args> are passed straight to
 410 L<DBIx::Class::Schema/deploy>.
 411
 412 =cut
 413
 414 sub deploy {
 415   my ($self, $args) = @_;
 416   my $schema = $self->schema();
 417   $schema->deploy( $args, $self->sql_dir );
 418 }
 419
 420 =head2 insert
 421
 422 =over 4
 423
 424 =item Arguments: $rs, $set
 425
 426 =back
 427
 428 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 429 into that resultset
 430
 431 =cut
 432
 433 sub insert {
 434   my ($self, $rs, $set) = @_;
 435
 436   $rs ||= $self->resultset();
 437   $set ||= $self->set();
 438   my $resultset = $self->schema->resultset($rs);
 439   my $obj = $resultset->create( $set );
 440   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 441 }
 442
 443
 444 =head2 update
 445
 446 =over 4
 447
 448 =item Arguments: $rs, $set, $where
 449
 450 =back
 451
 452 update takes the name of a resultset from the schema_class, a hashref of data to update and
 453 a where hash used to form the search for the rows to update.
 454
 455 =cut
 456
 457 sub update {
 458   my ($self, $rs, $set, $where) = @_;
 459
 460   $rs ||= $self->resultset();
 461   $where ||= $self->where();
 462   $set ||= $self->set();
 463   my $resultset = $self->schema->resultset($rs);
 464   $resultset = $resultset->search( ($where||{}) );
 465
 466   my $count = $resultset->count();
 467   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 468
 469   if ( $self->force || $self->_confirm() ) {
 470     $resultset->update_all( $set );
 471   }
 472 }
 473
 474
 475 =head2 delete
 476
 477 =over 4
 478
 479 =item Arguments: $rs, $where, $attrs
 480
 481 =back
 482
 483 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 484 The found data is deleted and cannot be recovered.
 485
 486 =cut
 487
 488 sub delete {
 489   my ($self, $rs, $where, $attrs) = @_;
 490
 491   $rs ||= $self->resultset();
 492   $where ||= $self->where();
 493   $attrs ||= $self->attrs();
 494   my $resultset = $self->schema->resultset($rs);
 495   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 496
 497   my $count = $resultset->count();
 498   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 499
 500   if ( $self->force || $self->_confirm() ) {
 501     $resultset->delete_all();
 502   }
 503 }
 504
 505
 506 =head2 select
 507
 508 =over 4
 509
 510 =item Arguments: $rs, $where, $attrs
 511
 512 =back
 513
 514 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 515 The found data is returned in a array ref where the first row will be the columns list.
 516
 517 =cut
 518
 519 sub select {
 520   my ($self, $rs, $where, $attrs) = @_;
 521
 522   $rs ||= $self->resultset();
 523   $where ||= $self->where();
 524   $attrs ||= $self->attrs();
 525   my $resultset = $self->schema->resultset($rs);
 526   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 527
 528   my @data;
 529   my @columns = $resultset->result_source->columns();
 530   push @data, [@columns];#
 531
 532   while (my $row = $resultset->next()) {
 533     my @fields;
 534     foreach my $column (@columns) {
 535       push( @fields, $row->get_column($column) );
 536     }
 537     push @data, [@fields];
 538   }
 539
 540   return \@data;
 541 }
 542
 543 sub _confirm {
 544   my ($self) = @_;
 545
 546   # mainly here for testing
 547   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 548
 549   print "Are you sure you want to do this? (type YES to confirm) \n";
 550   my $response = <STDIN>;
 551
 552   return ($response=~/^YES/);
 553 }
 554
 555 sub _find_stanza {
 556   my ($self, $cfg, $stanza) = @_;
 557   my @path = split /::/, $stanza;
 558   while (my $path = shift @path) {
 559     if (exists $cfg->{$path}) {
 560       $cfg = $cfg->{$path};
 561     }
 562     else {
 563       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 564     }
 565   }
 566   return $cfg;
 567 }
 568
 569 =head1 AUTHOR
 570
 571 See L<DBIx::Class/CONTRIBUTORS>.
 572
 573 =head1 LICENSE
 574
 575 You may distribute this code under the same terms as Perl itself
 576
 577 =cut
 578
 579 1;