lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 # check deps
   4 BEGIN {
   5   use Carp::Clan qw/^DBIx::Class/;
   6   use DBIx::Class;
   7   croak('The following modules are required for DBIx::Class::Admin ' . DBIx::Class::Optional::Dependencies->req_missing_for ('admin') )
   8     unless DBIx::Class::Optional::Dependencies->req_ok_for ('admin');
   9 }
  10
  11 use Moose;
  12 use MooseX::Types::Moose qw/Int Str Any Bool/;
  13 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  14 use MooseX::Types::JSON qw(JSON);
  15 use MooseX::Types::Path::Class qw(Dir File);
  16 use Try::Tiny;
  17 use JSON::Any qw(DWIW XS JSON);
  18 use namespace::autoclean;
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Admin - Administration object for schemas
  23
  24 =head1 SYNOPSIS
  25
  26   $ dbicadmin --help
  27
  28   $ dbicadmin --schema=MyApp::Schema \
  29     --connect='["dbi:SQLite:my.db", "", ""]' \
  30     --deploy
  31
  32   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  33     --connect='["dbi:SQLite:my.db", "", ""]' \
  34     --op=update --set='{ "name": "New_Employee" }'
  35
  36   use DBIx::Class::Admin;
  37
  38   # ddl manipulation
  39   my $admin = DBIx::Class::Admin->new(
  40     schema_class=> 'MY::Schema',
  41     sql_dir=> $sql_dir,
  42     connect_info => { dsn => $dsn, user => $user, password => $pass },
  43   );
  44
  45   # create SQLite sql
  46   $admin->create('SQLite');
  47
  48   # create SQL diff for an upgrade
  49   $admin->create('SQLite', {} , "1.0");
  50
  51   # upgrade a database
  52   $admin->upgrade();
  53
  54   # install a version for an unversioned schema
  55   $admin->install("3.0");
  56
  57 =head1 REQUIREMENTS
  58
  59 The Admin interface has additional requirements not currently part of
  60 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  61
  62 =head1 ATTRIBUTES
  63
  64 =head2 schema_class
  65
  66 the class of the schema to load
  67
  68 =cut
  69
  70 has 'schema_class' => (
  71   is  => 'ro',
  72   isa => Str,
  73 );
  74
  75
  76 =head2 schema
  77
  78 A pre-connected schema object can be provided for manipulation
  79
  80 =cut
  81
  82 has 'schema' => (
  83   is          => 'ro',
  84   isa         => 'DBIx::Class::Schema',
  85   lazy_build  => 1,
  86 );
  87
  88 sub BUILD {
  89    my $self = shift;
  90    require Class::MOP;
  91
  92    my @include_dirs = @{$self->include_dirs};
  93    @INC = (@include_dirs, @INC);
  94    Class::MOP::load_class($self->schema_class);
  95 }
  96
  97 sub _build_schema {
  98   my ($self)  = @_;
  99   $self->connect_info->[3]{ignore_version} = 1;
 100   return $self->schema_class->connect(@{$self->connect_info});
 101 }
 102
 103 =head2 include_dirs
 104
 105 Extra include directories to look when loading C<schema_class>
 106
 107 =cut
 108
 109 has 'include_dirs' => (
 110     is => 'rw',
 111     isa => 'ArrayRef',
 112     default => sub {[]}
 113 );
 114
 115 =head2 resultset
 116
 117 a resultset from the schema to operate on
 118
 119 =cut
 120
 121 has 'resultset' => (
 122   is  => 'rw',
 123   isa => Str,
 124 );
 125
 126
 127 =head2 where
 128
 129 a hash ref or json string to be used for identifying data to manipulate
 130
 131 =cut
 132
 133 has 'where' => (
 134   is      => 'rw',
 135   isa     => DBICHashRef,
 136   coerce  => 1,
 137 );
 138
 139
 140 =head2 set
 141
 142 a hash ref or json string to be used for inserting or updating data
 143
 144 =cut
 145
 146 has 'set' => (
 147   is      => 'rw',
 148   isa     => DBICHashRef,
 149   coerce  => 1,
 150 );
 151
 152
 153 =head2 attrs
 154
 155 a hash ref or json string to be used for passing additonal info to the ->search call
 156
 157 =cut
 158
 159 has 'attrs' => (
 160   is      => 'rw',
 161   isa     => DBICHashRef,
 162   coerce  => 1,
 163 );
 164
 165
 166 =head2 connect_info
 167
 168 connect_info the arguments to provide to the connect call of the schema_class
 169
 170 =cut
 171
 172 has 'connect_info' => (
 173   is          => 'ro',
 174   isa         => DBICConnectInfo,
 175   lazy_build  => 1,
 176   coerce      => 1,
 177 );
 178
 179 sub _build_connect_info {
 180   my ($self) = @_;
 181   return $self->_find_stanza($self->config, $self->config_stanza);
 182 }
 183
 184
 185 =head2 config_file
 186
 187 config_file provide a config_file to read connect_info from, if this is provided
 188 config_stanze should also be provided to locate where the connect_info is in the config
 189 The config file should be in a format readable by Config::General
 190
 191 =cut
 192
 193 has config_file => (
 194   is      => 'ro',
 195   isa     => File,
 196   coerce  => 1,
 197 );
 198
 199
 200 =head2 config_stanza
 201
 202 config_stanza for use with config_file should be a '::' deliminated 'path' to the connection information
 203 designed for use with catalyst config files
 204
 205 =cut
 206
 207 has 'config_stanza' => (
 208   is  => 'ro',
 209   isa => Str,
 210 );
 211
 212
 213 =head2 config
 214
 215 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 216 config_stanza will still be required.
 217
 218 =cut
 219
 220 has config => (
 221   is          => 'ro',
 222   isa         => DBICHashRef,
 223   lazy_build  => 1,
 224 );
 225
 226 sub _build_config {
 227   my ($self) = @_;
 228
 229   try { require Config::Any }
 230     catch { die ("Config::Any is required to parse the config file.\n") };
 231
 232   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 233
 234   # just grab the config from the config file
 235   $cfg = $cfg->{$self->config_file};
 236   return $cfg;
 237 }
 238
 239
 240 =head2 sql_dir
 241
 242 The location where sql ddl files should be created or found for an upgrade.
 243
 244 =cut
 245
 246 has 'sql_dir' => (
 247   is      => 'ro',
 248   isa     => Dir,
 249   coerce  => 1,
 250 );
 251
 252
 253 =head2 version
 254
 255 Used for install, the version which will be 'installed' in the schema
 256
 257 =cut
 258
 259 has version => (
 260   is  => 'rw',
 261   isa => Str,
 262 );
 263
 264
 265 =head2 preversion
 266
 267 Previouse version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 268
 269 =cut
 270
 271 has preversion => (
 272   is  => 'rw',
 273   isa => Str,
 274 );
 275
 276
 277 =head2 force
 278
 279 Try and force certain operations.
 280
 281 =cut
 282
 283 has force => (
 284   is  => 'rw',
 285   isa => Bool,
 286 );
 287
 288
 289 =head2 quiet
 290
 291 Be less verbose about actions
 292
 293 =cut
 294
 295 has quiet => (
 296   is  => 'rw',
 297   isa => Bool,
 298 );
 299
 300 has '_confirm' => (
 301   is  => 'bare',
 302   isa => Bool,
 303 );
 304
 305
 306 =head1 METHODS
 307
 308 =head2 create
 309
 310 =over 4
 311
 312 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 313
 314 =back
 315
 316 L<create> will generate sql for the supplied schema_class in sql_dir. The
 317 flavour of sql to generate can be controlled by supplying a sqlt_type which
 318 should be a L<SQL::Translator> name.
 319
 320 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 321
 322 Optional preversion can be supplied to generate a diff to be used by upgrade.
 323
 324 =cut
 325
 326 sub create {
 327   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 328
 329   $preversion ||= $self->preversion();
 330
 331   my $schema = $self->schema();
 332   # create the dir if does not exist
 333   $self->sql_dir->mkpath() if ( ! -d $self->sql_dir);
 334
 335   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 336 }
 337
 338
 339 =head2 upgrade
 340
 341 =over 4
 342
 343 =item Arguments: <none>
 344
 345 =back
 346
 347 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 348 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 349
 350 =cut
 351
 352 sub upgrade {
 353   my ($self) = @_;
 354   my $schema = $self->schema();
 355
 356   if (!$schema->get_db_version()) {
 357     # schema is unversioned
 358     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 359   } else {
 360     $schema->upgrade_directory ($self->sql_dir) if $self->sql_dir;  # this will override whatever default the schema has
 361     my $ret = $schema->upgrade();
 362     return $ret;
 363   }
 364 }
 365
 366
 367 =head2 install
 368
 369 =over 4
 370
 371 =item Arguments: $version
 372
 373 =back
 374
 375 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 376 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 377 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 378 already versioned databases.
 379
 380 =cut
 381
 382 sub install {
 383   my ($self, $version) = @_;
 384
 385   my $schema = $self->schema();
 386   $version ||= $self->version();
 387   if (!$schema->get_db_version() ) {
 388     # schema is unversioned
 389     print "Going to install schema version\n" if (!$self->quiet);
 390     my $ret = $schema->install($version);
 391     print "return is $ret\n" if (!$self->quiet);
 392   }
 393   elsif ($schema->get_db_version() and $self->force ) {
 394     carp "Forcing install may not be a good idea";
 395     if($self->_confirm() ) {
 396       $self->schema->_set_db_version({ version => $version});
 397     }
 398   }
 399   else {
 400     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 401   }
 402
 403 }
 404
 405
 406 =head2 deploy
 407
 408 =over 4
 409
 410 =item Arguments: $args
 411
 412 =back
 413
 414 deploy will create the schema at the connected database.  C<$args> are passed straight to
 415 L<DBIx::Class::Schema/deploy>.
 416
 417 =cut
 418
 419 sub deploy {
 420   my ($self, $args) = @_;
 421   my $schema = $self->schema();
 422   $schema->deploy( $args, $self->sql_dir );
 423 }
 424
 425 =head2 insert
 426
 427 =over 4
 428
 429 =item Arguments: $rs, $set
 430
 431 =back
 432
 433 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 434 into that resultset
 435
 436 =cut
 437
 438 sub insert {
 439   my ($self, $rs, $set) = @_;
 440
 441   $rs ||= $self->resultset();
 442   $set ||= $self->set();
 443   my $resultset = $self->schema->resultset($rs);
 444   my $obj = $resultset->create( $set );
 445   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 446 }
 447
 448
 449 =head2 update
 450
 451 =over 4
 452
 453 =item Arguments: $rs, $set, $where
 454
 455 =back
 456
 457 update takes the name of a resultset from the schema_class, a hashref of data to update and
 458 a where hash used to form the search for the rows to update.
 459
 460 =cut
 461
 462 sub update {
 463   my ($self, $rs, $set, $where) = @_;
 464
 465   $rs ||= $self->resultset();
 466   $where ||= $self->where();
 467   $set ||= $self->set();
 468   my $resultset = $self->schema->resultset($rs);
 469   $resultset = $resultset->search( ($where||{}) );
 470
 471   my $count = $resultset->count();
 472   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 473
 474   if ( $self->force || $self->_confirm() ) {
 475     $resultset->update_all( $set );
 476   }
 477 }
 478
 479
 480 =head2 delete
 481
 482 =over 4
 483
 484 =item Arguments: $rs, $where, $attrs
 485
 486 =back
 487
 488 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 489 The found data is deleted and cannot be recovered.
 490
 491 =cut
 492
 493 sub delete {
 494   my ($self, $rs, $where, $attrs) = @_;
 495
 496   $rs ||= $self->resultset();
 497   $where ||= $self->where();
 498   $attrs ||= $self->attrs();
 499   my $resultset = $self->schema->resultset($rs);
 500   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 501
 502   my $count = $resultset->count();
 503   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 504
 505   if ( $self->force || $self->_confirm() ) {
 506     $resultset->delete_all();
 507   }
 508 }
 509
 510
 511 =head2 select
 512
 513 =over 4
 514
 515 =item Arguments: $rs, $where, $attrs
 516
 517 =back
 518
 519 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 520 The found data is returned in a array ref where the first row will be the columns list.
 521
 522 =cut
 523
 524 sub select {
 525   my ($self, $rs, $where, $attrs) = @_;
 526
 527   $rs ||= $self->resultset();
 528   $where ||= $self->where();
 529   $attrs ||= $self->attrs();
 530   my $resultset = $self->schema->resultset($rs);
 531   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 532
 533   my @data;
 534   my @columns = $resultset->result_source->columns();
 535   push @data, [@columns];#
 536
 537   while (my $row = $resultset->next()) {
 538     my @fields;
 539     foreach my $column (@columns) {
 540       push( @fields, $row->get_column($column) );
 541     }
 542     push @data, [@fields];
 543   }
 544
 545   return \@data;
 546 }
 547
 548 sub _confirm {
 549   my ($self) = @_;
 550
 551   # mainly here for testing
 552   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 553
 554   print "Are you sure you want to do this? (type YES to confirm) \n";
 555   my $response = <STDIN>;
 556
 557   return ($response=~/^YES/);
 558 }
 559
 560 sub _find_stanza {
 561   my ($self, $cfg, $stanza) = @_;
 562   my @path = split /::/, $stanza;
 563   while (my $path = shift @path) {
 564     if (exists $cfg->{$path}) {
 565       $cfg = $cfg->{$path};
 566     }
 567     else {
 568       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 569     }
 570   }
 571   return $cfg;
 572 }
 573
 574 =head1 AUTHOR
 575
 576 See L<DBIx::Class/CONTRIBUTORS>.
 577
 578 =head1 LICENSE
 579
 580 You may distribute this code under the same terms as Perl itself
 581
 582 =cut
 583
 584 1;