lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 # check deps
   4 BEGIN {
   5   use Carp::Clan qw/^DBIx::Class/;
   6   use DBIx::Class;
   7   croak('The following modules are required for DBIx::Class::Admin ' . DBIx::Class::Optional::Dependencies->req_missing_for ('admin') )
   8     unless DBIx::Class::Optional::Dependencies->req_ok_for ('admin');
   9 }
  10
  11 use Moose;
  12 use MooseX::Types::Moose qw/Int Str Any Bool/;
  13 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  14 use MooseX::Types::JSON qw(JSON);
  15 use MooseX::Types::Path::Class qw(Dir File);
  16 use Try::Tiny;
  17 use JSON::Any qw(DWIW XS JSON);
  18 use namespace::autoclean;
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Admin - Administration object for schemas
  23
  24 =head1 SYNOPSIS
  25
  26   $ dbicadmin --help
  27
  28   $ dbicadmin --schema=MyApp::Schema \
  29     --connect='["dbi:SQLite:my.db", "", ""]' \
  30     --deploy
  31
  32   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  33     --connect='["dbi:SQLite:my.db", "", ""]' \
  34     --op=update --set='{ "name": "New_Employee" }'
  35
  36   use DBIx::Class::Admin;
  37
  38   # ddl manipulation
  39   my $admin = DBIx::Class::Admin->new(
  40     schema_class=> 'MY::Schema',
  41     sql_dir=> $sql_dir,
  42     connect_info => { dsn => $dsn, user => $user, password => $pass },
  43   );
  44
  45   # create SQLite sql
  46   $admin->create('SQLite');
  47
  48   # create SQL diff for an upgrade
  49   $admin->create('SQLite', {} , "1.0");
  50
  51   # upgrade a database
  52   $admin->upgrade();
  53
  54   # install a version for an unversioned schema
  55   $admin->install("3.0");
  56
  57 =head1 REQUIREMENTS
  58
  59 The Admin interface has additional requirements not currently part of
  60 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  61
  62 =head1 ATTRIBUTES
  63
  64 =head2 schema_class
  65
  66 the class of the schema to load
  67
  68 =cut
  69
  70 has 'schema_class' => (
  71   is  => 'ro',
  72   isa => Str,
  73 );
  74
  75
  76 =head2 schema
  77
  78 A pre-connected schema object can be provided for manipulation
  79
  80 =cut
  81
  82 has 'schema' => (
  83   is          => 'ro',
  84   isa         => 'DBIx::Class::Schema',
  85   lazy_build  => 1,
  86 );
  87
  88 sub _build_schema {
  89   my ($self)  = @_;
  90   require Class::MOP;
  91   {
  92     my @include_dirs = @{$self->include_dirs};
  93     local @INC = (@include_dirs, @INC);
  94     Class::MOP::load_class($self->schema_class);
  95   }
  96   $self->connect_info->[3]->{ignore_version} =1;
  97   return $self->schema_class->connect(@{$self->connect_info()} ); # ,  $self->connect_info->[3], { ignore_version => 1} );
  98 }
  99
 100 =head2 include_dirs
 101
 102 Extra include directories to look when loading C<schema_class>
 103
 104 =cut
 105
 106 has 'include_dirs' => (
 107     is => 'rw',
 108     isa => 'ArrayRef',
 109     default => sub {[]}
 110 );
 111
 112 =head2 resultset
 113
 114 a resultset from the schema to operate on
 115
 116 =cut
 117
 118 has 'resultset' => (
 119   is  => 'rw',
 120   isa => Str,
 121 );
 122
 123
 124 =head2 where
 125
 126 a hash ref or json string to be used for identifying data to manipulate
 127
 128 =cut
 129
 130 has 'where' => (
 131   is      => 'rw',
 132   isa     => DBICHashRef,
 133   coerce  => 1,
 134 );
 135
 136
 137 =head2 set
 138
 139 a hash ref or json string to be used for inserting or updating data
 140
 141 =cut
 142
 143 has 'set' => (
 144   is      => 'rw',
 145   isa     => DBICHashRef,
 146   coerce  => 1,
 147 );
 148
 149
 150 =head2 attrs
 151
 152 a hash ref or json string to be used for passing additonal info to the ->search call
 153
 154 =cut
 155
 156 has 'attrs' => (
 157   is      => 'rw',
 158   isa     => DBICHashRef,
 159   coerce  => 1,
 160 );
 161
 162
 163 =head2 connect_info
 164
 165 connect_info the arguments to provide to the connect call of the schema_class
 166
 167 =cut
 168
 169 has 'connect_info' => (
 170   is          => 'ro',
 171   isa         => DBICConnectInfo,
 172   lazy_build  => 1,
 173   coerce      => 1,
 174 );
 175
 176 sub _build_connect_info {
 177   my ($self) = @_;
 178   return $self->_find_stanza($self->config, $self->config_stanza);
 179 }
 180
 181
 182 =head2 config_file
 183
 184 config_file provide a config_file to read connect_info from, if this is provided
 185 config_stanze should also be provided to locate where the connect_info is in the config
 186 The config file should be in a format readable by Config::General
 187
 188 =cut
 189
 190 has config_file => (
 191   is      => 'ro',
 192   isa     => File,
 193   coerce  => 1,
 194 );
 195
 196
 197 =head2 config_stanza
 198
 199 config_stanza for use with config_file should be a '::' deliminated 'path' to the connection information
 200 designed for use with catalyst config files
 201
 202 =cut
 203
 204 has 'config_stanza' => (
 205   is  => 'ro',
 206   isa => Str,
 207 );
 208
 209
 210 =head2 config
 211
 212 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 213 config_stanza will still be required.
 214
 215 =cut
 216
 217 has config => (
 218   is          => 'ro',
 219   isa         => DBICHashRef,
 220   lazy_build  => 1,
 221 );
 222
 223 sub _build_config {
 224   my ($self) = @_;
 225
 226   try { require Config::Any }
 227     catch { die ("Config::Any is required to parse the config file.\n") };
 228
 229   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 230
 231   # just grab the config from the config file
 232   $cfg = $cfg->{$self->config_file};
 233   return $cfg;
 234 }
 235
 236
 237 =head2 sql_dir
 238
 239 The location where sql ddl files should be created or found for an upgrade.
 240
 241 =cut
 242
 243 has 'sql_dir' => (
 244   is      => 'ro',
 245   isa     => Dir,
 246   coerce  => 1,
 247 );
 248
 249
 250 =head2 version
 251
 252 Used for install, the version which will be 'installed' in the schema
 253
 254 =cut
 255
 256 has version => (
 257   is  => 'rw',
 258   isa => Str,
 259 );
 260
 261
 262 =head2 preversion
 263
 264 Previouse version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 265
 266 =cut
 267
 268 has preversion => (
 269   is  => 'rw',
 270   isa => Str,
 271 );
 272
 273
 274 =head2 force
 275
 276 Try and force certain operations.
 277
 278 =cut
 279
 280 has force => (
 281   is  => 'rw',
 282   isa => Bool,
 283 );
 284
 285
 286 =head2 quiet
 287
 288 Be less verbose about actions
 289
 290 =cut
 291
 292 has quiet => (
 293   is  => 'rw',
 294   isa => Bool,
 295 );
 296
 297 has '_confirm' => (
 298   is  => 'bare',
 299   isa => Bool,
 300 );
 301
 302
 303 =head1 METHODS
 304
 305 =head2 create
 306
 307 =over 4
 308
 309 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 310
 311 =back
 312
 313 L<create> will generate sql for the supplied schema_class in sql_dir.  The flavour of sql to
 314 generate can be controlled by suppling a sqlt_type which should be a L<SQL::Translator> name.
 315
 316 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 317
 318 Optional preversion can be supplied to generate a diff to be used by upgrade.
 319
 320 =cut
 321
 322 sub create {
 323   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 324
 325   $preversion ||= $self->preversion();
 326
 327   my $schema = $self->schema();
 328   # create the dir if does not exist
 329   $self->sql_dir->mkpath() if ( ! -d $self->sql_dir);
 330
 331   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 332 }
 333
 334
 335 =head2 upgrade
 336
 337 =over 4
 338
 339 =item Arguments: <none>
 340
 341 =back
 342
 343 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 344 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 345
 346 =cut
 347
 348 sub upgrade {
 349   my ($self) = @_;
 350   my $schema = $self->schema();
 351
 352   if (!$schema->get_db_version()) {
 353     # schema is unversioned
 354     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 355   } else {
 356     $schema->upgrade_directory ($self->sql_dir) if $self->sql_dir;  # this will override whatever default the schema has
 357     my $ret = $schema->upgrade();
 358     return $ret;
 359   }
 360 }
 361
 362
 363 =head2 install
 364
 365 =over 4
 366
 367 =item Arguments: $version
 368
 369 =back
 370
 371 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 372 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 373 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 374 already versioned databases.
 375
 376 =cut
 377
 378 sub install {
 379   my ($self, $version) = @_;
 380
 381   my $schema = $self->schema();
 382   $version ||= $self->version();
 383   if (!$schema->get_db_version() ) {
 384     # schema is unversioned
 385     print "Going to install schema version\n" if (!$self->quiet);
 386     my $ret = $schema->install($version);
 387     print "return is $ret\n" if (!$self->quiet);
 388   }
 389   elsif ($schema->get_db_version() and $self->force ) {
 390     carp "Forcing install may not be a good idea";
 391     if($self->_confirm() ) {
 392       $self->schema->_set_db_version({ version => $version});
 393     }
 394   }
 395   else {
 396     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 397   }
 398
 399 }
 400
 401
 402 =head2 deploy
 403
 404 =over 4
 405
 406 =item Arguments: $args
 407
 408 =back
 409
 410 deploy will create the schema at the connected database.  C<$args> are passed straight to
 411 L<DBIx::Class::Schema/deploy>.
 412
 413 =cut
 414
 415 sub deploy {
 416   my ($self, $args) = @_;
 417   my $schema = $self->schema();
 418   $schema->deploy( $args, $self->sql_dir );
 419 }
 420
 421 =head2 insert
 422
 423 =over 4
 424
 425 =item Arguments: $rs, $set
 426
 427 =back
 428
 429 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 430 into that resultset
 431
 432 =cut
 433
 434 sub insert {
 435   my ($self, $rs, $set) = @_;
 436
 437   $rs ||= $self->resultset();
 438   $set ||= $self->set();
 439   my $resultset = $self->schema->resultset($rs);
 440   my $obj = $resultset->create( $set );
 441   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 442 }
 443
 444
 445 =head2 update
 446
 447 =over 4
 448
 449 =item Arguments: $rs, $set, $where
 450
 451 =back
 452
 453 update takes the name of a resultset from the schema_class, a hashref of data to update and
 454 a where hash used to form the search for the rows to update.
 455
 456 =cut
 457
 458 sub update {
 459   my ($self, $rs, $set, $where) = @_;
 460
 461   $rs ||= $self->resultset();
 462   $where ||= $self->where();
 463   $set ||= $self->set();
 464   my $resultset = $self->schema->resultset($rs);
 465   $resultset = $resultset->search( ($where||{}) );
 466
 467   my $count = $resultset->count();
 468   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 469
 470   if ( $self->force || $self->_confirm() ) {
 471     $resultset->update_all( $set );
 472   }
 473 }
 474
 475
 476 =head2 delete
 477
 478 =over 4
 479
 480 =item Arguments: $rs, $where, $attrs
 481
 482 =back
 483
 484 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 485 The found data is deleted and cannot be recovered.
 486
 487 =cut
 488
 489 sub delete {
 490   my ($self, $rs, $where, $attrs) = @_;
 491
 492   $rs ||= $self->resultset();
 493   $where ||= $self->where();
 494   $attrs ||= $self->attrs();
 495   my $resultset = $self->schema->resultset($rs);
 496   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 497
 498   my $count = $resultset->count();
 499   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 500
 501   if ( $self->force || $self->_confirm() ) {
 502     $resultset->delete_all();
 503   }
 504 }
 505
 506
 507 =head2 select
 508
 509 =over 4
 510
 511 =item Arguments: $rs, $where, $attrs
 512
 513 =back
 514
 515 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 516 The found data is returned in a array ref where the first row will be the columns list.
 517
 518 =cut
 519
 520 sub select {
 521   my ($self, $rs, $where, $attrs) = @_;
 522
 523   $rs ||= $self->resultset();
 524   $where ||= $self->where();
 525   $attrs ||= $self->attrs();
 526   my $resultset = $self->schema->resultset($rs);
 527   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 528
 529   my @data;
 530   my @columns = $resultset->result_source->columns();
 531   push @data, [@columns];#
 532
 533   while (my $row = $resultset->next()) {
 534     my @fields;
 535     foreach my $column (@columns) {
 536       push( @fields, $row->get_column($column) );
 537     }
 538     push @data, [@fields];
 539   }
 540
 541   return \@data;
 542 }
 543
 544 sub _confirm {
 545   my ($self) = @_;
 546
 547   # mainly here for testing
 548   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 549
 550   print "Are you sure you want to do this? (type YES to confirm) \n";
 551   my $response = <STDIN>;
 552
 553   return ($response=~/^YES/);
 554 }
 555
 556 sub _find_stanza {
 557   my ($self, $cfg, $stanza) = @_;
 558   my @path = split /::/, $stanza;
 559   while (my $path = shift @path) {
 560     if (exists $cfg->{$path}) {
 561       $cfg = $cfg->{$path};
 562     }
 563     else {
 564       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 565     }
 566   }
 567   return $cfg;
 568 }
 569
 570 =head1 AUTHOR
 571
 572 See L<DBIx::Class/CONTRIBUTORS>.
 573
 574 =head1 LICENSE
 575
 576 You may distribute this code under the same terms as Perl itself
 577
 578 =cut
 579
 580 1;