lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 # check deps
   4 BEGIN {
   5     my @_deps = qw(
   6         Moose MooseX::Types MooseX::Types::JSON MooseX::Types::Path::Class
   7         Try::Tiny parent JSON::Any Class::C3::Componentised
   8         namespace::autoclean
   9     );
  10
  11     my @_missing_deps;
  12     foreach my $dep (@_deps) {
  13       eval "require $dep";
  14       if ($@) {
  15         push @_missing_deps, $dep;
  16       }
  17     }
  18
  19     if (@_missing_deps > 0) {
  20       die "The following dependecies are missing " . join ",", @_missing_deps;
  21     }
  22 }
  23
  24 use Moose;
  25 use parent 'DBIx::Class::Schema';
  26 use Carp::Clan qw/^DBIx::Class/;
  27
  28 use MooseX::Types::Moose qw/Int Str Any Bool/;
  29 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  30 use MooseX::Types::JSON qw(JSON);
  31 use MooseX::Types::Path::Class qw(Dir File);
  32 use Try::Tiny;
  33 use JSON::Any;
  34 use namespace::autoclean;
  35
  36
  37 =head1 NAME
  38
  39 DBIx::Class::Admin - Administration object for schemas
  40
  41 =head1 SYNOPSIS
  42
  43   use DBIx::Class::Admin;
  44
  45   # ddl manipulation
  46   my $admin = DBIx::Class::Admin->new(
  47     schema_class=> 'MY::Schema',
  48     sql_dir=> $sql_dir,
  49     connect_info => { dsn => $dsn, user => $user, password => $pass },
  50   );
  51
  52   # create SQLite sql
  53   $admin->create('SQLite');
  54
  55   # create SQL diff for an upgrade
  56   $admin->create('SQLite', {} , "1.0");
  57
  58   # upgrade a database
  59   $admin->upgrade();
  60
  61   # install a version for an unversioned schema
  62   $admin->install("3.0");
  63
  64 =head1 Attributes
  65
  66 =head2 schema_class
  67
  68 the class of the schema to load
  69
  70 =cut
  71
  72 has 'schema_class' => (
  73   is    => 'ro',
  74   isa    => Str,
  75 );
  76
  77
  78 =head2 schema
  79
  80 A pre-connected schema object can be provided for manipulation
  81
  82 =cut
  83
  84 has 'schema' => (
  85   is      => 'ro',
  86   isa      => 'DBIx::Class::Schema',
  87   lazy_build  => 1,
  88 );
  89
  90 sub _build_schema {
  91   my ($self)  = @_;
  92   $self->ensure_class_loaded($self->schema_class);
  93
  94   $self->connect_info->[3]->{ignore_version} =1;
  95   return $self->schema_class->connect(@{$self->connect_info()} ); # ,  $self->connect_info->[3], { ignore_version => 1} );
  96 }
  97
  98
  99 =head2 resultset
 100
 101 a resultset from the schema to operate on
 102
 103 =cut
 104
 105 has 'resultset' => (
 106   is      => 'rw',
 107   isa      => Str,
 108 );
 109
 110
 111 =head2 where
 112
 113 a hash ref or json string to be used for identifying data to manipulate
 114
 115 =cut
 116
 117 has 'where' => (
 118   is      => 'rw',
 119   isa      => DBICHashRef,
 120   coerce    => 1,
 121 );
 122
 123
 124 =head2 set
 125
 126 a hash ref or json string to be used for inserting or updating data
 127
 128 =cut
 129
 130 has 'set' => (
 131   is      => 'rw',
 132   isa      => DBICHashRef,
 133   coerce    => 1,
 134 );
 135
 136
 137 =head2 attrs
 138
 139 a hash ref or json string to be used for passing additonal info to the ->search call
 140
 141 =cut
 142
 143 has 'attrs' => (
 144   is       => 'rw',
 145   isa      => DBICHashRef,
 146   coerce    => 1,
 147 );
 148
 149
 150 =head2 connect_info
 151
 152 connect_info the arguments to provide to the connect call of the schema_class
 153
 154 =cut
 155
 156 has 'connect_info' => (
 157   is      => 'ro',
 158   isa      => DBICConnectInfo,
 159   lazy_build  => 1,
 160   coerce    => 1,
 161 );
 162
 163 sub _build_connect_info {
 164   my ($self) = @_;
 165   return $self->_find_stanza($self->config, $self->config_stanza);
 166 }
 167
 168
 169 =head2 config_file
 170
 171 config_file provide a config_file to read connect_info from, if this is provided
 172 config_stanze should also be provided to locate where the connect_info is in the config
 173 The config file should be in a format readable by Config::General
 174
 175 =cut
 176
 177 has config_file => (
 178   is      => 'ro',
 179   isa      => File,
 180   coerce    => 1,
 181 );
 182
 183
 184 =head2 config_stanza
 185
 186 config_stanza for use with config_file should be a '::' deliminated 'path' to the connection information
 187 designed for use with catalyst config files
 188
 189 =cut
 190
 191 has 'config_stanza' => (
 192   is      => 'ro',
 193   isa      => Str,
 194 );
 195
 196
 197 =head2 config
 198
 199 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 200 config_stanza will still be required.
 201
 202 =cut
 203
 204 has config => (
 205   is      => 'ro',
 206   isa      => DBICHashRef,
 207   lazy_build  => 1,
 208 );
 209
 210 sub _build_config {
 211   my ($self) = @_;
 212   try { require Config::Any } catch { $self->throw_exception( "Config::Any is required to parse the config file"); };
 213
 214   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 215
 216   # just grab the config from the config file
 217   $cfg = $cfg->{$self->config_file};
 218   return $cfg;
 219 }
 220
 221
 222 =head2 sql_dir
 223
 224 The location where sql ddl files should be created or found for an upgrade.
 225
 226 =cut
 227
 228 has 'sql_dir' => (
 229   is      => 'ro',
 230   isa      => Dir,
 231   coerce    => 1,
 232 );
 233
 234
 235 =head2 version
 236
 237 Used for install, the version which will be 'installed' in the schema
 238
 239 =cut
 240
 241 has version => (
 242   is      => 'rw',
 243   isa      => Str,
 244 );
 245
 246
 247 =head2 preversion
 248
 249 Previouse version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 250
 251 =cut
 252
 253 has preversion => (
 254   is      => 'rw',
 255   isa      => Str,
 256 );
 257
 258
 259 =head2 force
 260
 261 Try and force certain operations.
 262
 263 =cut
 264
 265 has force => (
 266   is      => 'rw',
 267   isa      => Bool,
 268 );
 269
 270
 271 =head2 quiet
 272
 273 Be less verbose about actions
 274
 275 =cut
 276
 277 has quiet => (
 278   is      => 'rw',
 279   isa      => Bool,
 280 );
 281
 282 has '_confirm' => (
 283   is    => 'bare',
 284   isa    => Bool,
 285 );
 286
 287
 288 =head1 METHODS
 289
 290 =head2 create
 291
 292 =over 4
 293
 294 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 295
 296 =back
 297
 298 L<create> will generate sql for the supplied schema_class in sql_dir.  The flavour of sql to
 299 generate can be controlled by suppling a sqlt_type which should be a L<SQL::Translator> name.
 300
 301 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 302
 303 Optional preversion can be supplied to generate a diff to be used by upgrade.
 304
 305 =cut
 306
 307 sub create {
 308   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 309
 310   $preversion ||= $self->preversion();
 311
 312   my $schema = $self->schema();
 313   # create the dir if does not exist
 314   $self->sql_dir->mkpath() if ( ! -d $self->sql_dir);
 315
 316   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 317 }
 318
 319
 320 =head2 upgrade
 321
 322 =over 4
 323
 324 =item Arguments: <none>
 325
 326 =back
 327
 328 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 329 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 330
 331 =cut
 332
 333 sub upgrade {
 334   my ($self) = @_;
 335   my $schema = $self->schema();
 336   if (!$schema->get_db_version()) {
 337     # schema is unversioned
 338     $self->throw_exception ("could not determin current schema version, please either install or deploy");
 339   } else {
 340     my $ret = $schema->upgrade();
 341     return $ret;
 342   }
 343 }
 344
 345
 346 =head2 install
 347
 348 =over 4
 349
 350 =item Arguments: $version
 351
 352 =back
 353
 354 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 355 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 356 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 357 already versioned databases.
 358
 359 =cut
 360
 361 sub install {
 362   my ($self, $version) = @_;
 363
 364   my $schema = $self->schema();
 365   $version ||= $self->version();
 366   if (!$schema->get_db_version() ) {
 367     # schema is unversioned
 368     print "Going to install schema version\n";
 369     my $ret = $schema->install($version);
 370     print "retun is $ret\n";
 371   }
 372   elsif ($schema->get_db_version() and $self->force ) {
 373     carp "Forcing install may not be a good idea";
 374     if($self->_confirm() ) {
 375       $self->schema->_set_db_version({ version => $version});
 376     }
 377   }
 378   else {
 379     $self->throw_exception ("schema already has a version not installing, try upgrade instead");
 380   }
 381
 382 }
 383
 384
 385 =head2 deploy
 386
 387 =over 4
 388
 389 =item Arguments: $args
 390
 391 =back
 392
 393 deploy will create the schema at the connected database.  C<$args> are passed straight to
 394 L<DBIx::Class::Schema/deploy>.
 395
 396 =cut
 397
 398 sub deploy {
 399   my ($self, $args) = @_;
 400   my $schema = $self->schema();
 401   if (!$schema->get_db_version() ) {
 402     # schema is unversioned
 403     $schema->deploy( $args, $self->sql_dir)
 404       or $self->throw_exception ("could not deploy schema");
 405   } else {
 406     $self->throw_exception("there already is a database with a version here, try upgrade instead");
 407   }
 408 }
 409
 410 =head2 insert
 411
 412 =over 4
 413
 414 =item Arguments: $rs, $set
 415
 416 =back
 417
 418 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 419 into that resultset
 420
 421 =cut
 422
 423 sub insert {
 424   my ($self, $rs, $set) = @_;
 425
 426   $rs ||= $self->resultset();
 427   $set ||= $self->set();
 428   my $resultset = $self->schema->resultset($rs);
 429   my $obj = $resultset->create( $set );
 430   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 431 }
 432
 433
 434 =head2 update
 435
 436 =over 4
 437
 438 =item Arguments: $rs, $set, $where
 439
 440 =back
 441
 442 update takes the name of a resultset from the schema_class, a hashref of data to update and
 443 a where hash used to form the search for the rows to update.
 444
 445 =cut
 446
 447 sub update {
 448   my ($self, $rs, $set, $where) = @_;
 449
 450   $rs ||= $self->resultset();
 451   $where ||= $self->where();
 452   $set ||= $self->set();
 453   my $resultset = $self->schema->resultset($rs);
 454   $resultset = $resultset->search( ($where||{}) );
 455
 456   my $count = $resultset->count();
 457   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 458
 459   if ( $self->force || $self->_confirm() ) {
 460     $resultset->update_all( $set );
 461   }
 462 }
 463
 464
 465 =head2 delete
 466
 467 =over 4
 468
 469 =item Arguments: $rs, $where, $attrs
 470
 471 =back
 472
 473 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 474 The found data is deleted and cannot be recovered.
 475
 476 =cut
 477
 478 sub delete {
 479   my ($self, $rs, $where, $attrs) = @_;
 480
 481   $rs ||= $self->resultset();
 482   $where ||= $self->where();
 483   $attrs ||= $self->attrs();
 484   my $resultset = $self->schema->resultset($rs);
 485   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 486
 487   my $count = $resultset->count();
 488   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 489
 490   if ( $self->force || $self->_confirm() ) {
 491     $resultset->delete_all();
 492   }
 493 }
 494
 495
 496 =head2 select
 497
 498 =over 4
 499
 500 =item Arguments: $rs, $where, $attrs
 501
 502 =back
 503
 504 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 505 The found data is returned in a array ref where the first row will be the columns list.
 506
 507 =cut
 508
 509 sub select {
 510   my ($self, $rs, $where, $attrs) = @_;
 511
 512   $rs ||= $self->resultset();
 513   $where ||= $self->where();
 514   $attrs ||= $self->attrs();
 515   my $resultset = $self->schema->resultset($rs);
 516   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 517
 518   my @data;
 519   my @columns = $resultset->result_source->columns();
 520   push @data, [@columns];#
 521
 522   while (my $row = $resultset->next()) {
 523     my @fields;
 524     foreach my $column (@columns) {
 525       push( @fields, $row->get_column($column) );
 526     }
 527     push @data, [@fields];
 528   }
 529
 530   return \@data;
 531 }
 532
 533 sub _confirm {
 534   my ($self) = @_;
 535   print "Are you sure you want to do this? (type YES to confirm) \n";
 536   # mainly here for testing
 537   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 538   my $response = <STDIN>;
 539   return 1 if ($response=~/^YES/);
 540   return;
 541 }
 542
 543 sub _find_stanza {
 544   my ($self, $cfg, $stanza) = @_;
 545   my @path = split /::/, $stanza;
 546   while (my $path = shift @path) {
 547     if (exists $cfg->{$path}) {
 548       $cfg = $cfg->{$path};
 549     }
 550     else {
 551       $self->throw_exception("could not find $stanza in config, $path did not seem to exist");
 552     }
 553   }
 554   return $cfg;
 555 }
 556
 557 =head1 AUTHORS
 558
 559 See L<DBIx::Class/CONTRIBUTORS>.
 560
 561 =head1 LICENSE
 562
 563 You may distribute this code under the same terms as Perl itself
 564
 565 =cut
 566
 567 1;