lib/DBIx/Class.pm

   1 package DBIx::Class;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION;
   7 # Always remember to do all digits for the version even if they're 0
   8 # i.e. first release of 0.XX *must* be 0.XX000. This avoids fBSD ports
   9 # brain damage and presumably various other packaging systems too
  10
  11 # $VERSION declaration must stay up here, ahead of any other package
  12 # declarations, as to not confuse various modules attempting to determine
  13 # this ones version, whether that be s.c.o. or Module::Metadata, etc
  14 $VERSION = '0.082801';
  15
  16 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
  17
  18 use DBIx::Class::_Util;
  19 use mro 'c3';
  20
  21 use DBIx::Class::Optional::Dependencies;
  22
  23 use base qw/DBIx::Class::Componentised DBIx::Class::AccessorGroup/;
  24 use DBIx::Class::StartupCheck;
  25 use DBIx::Class::Exception;
  26
  27 __PACKAGE__->mk_group_accessors(inherited => '_skip_namespace_frames');
  28 __PACKAGE__->_skip_namespace_frames('^DBIx::Class|^SQL::Abstract|^Try::Tiny|^Class::Accessor::Grouped|^Context::Preserve');
  29
  30 sub mk_classdata {
  31   shift->mk_classaccessor(@_);
  32 }
  33
  34 sub mk_classaccessor {
  35   my $self = shift;
  36   $self->mk_group_accessors('inherited', $_[0]);
  37   $self->set_inherited(@_) if @_ > 1;
  38 }
  39
  40 sub component_base_class { 'DBIx::Class' }
  41
  42 sub MODIFY_CODE_ATTRIBUTES {
  43   my ($class,$code,@attrs) = @_;
  44   $class->mk_classdata('__attr_cache' => {})
  45     unless $class->can('__attr_cache');
  46   $class->__attr_cache->{$code} = [@attrs];
  47   return ();
  48 }
  49
  50 sub _attr_cache {
  51   my $self = shift;
  52   my $cache = $self->can('__attr_cache') ? $self->__attr_cache : {};
  53
  54   return {
  55     %$cache,
  56     %{ $self->maybe::next::method || {} },
  57   };
  58 }
  59
  60 # *DO NOT* change this URL nor the identically named =head1 below
  61 # it is linked throughout the ecosystem
  62 sub DBIx::Class::_ENV_::HELP_URL () {
  63   'http://p3rl.org/DBIx::Class#GETTING_HELP/SUPPORT'
  64 }
  65
  66 1;
  67
  68 __END__
  69
  70 =head1 NAME
  71
  72 DBIx::Class - Extensible and flexible object <-> relational mapper.
  73
  74 =head1 WHERE TO START READING
  75
  76 See L<DBIx::Class::Manual::DocMap> for an overview of the exhaustive documentation.
  77 To get the most out of DBIx::Class with the least confusion it is strongly
  78 recommended to read (at the very least) the
  79 L<Manuals|DBIx::Class::Manual::DocMap/Manuals> in the order presented there.
  80
  81 =cut
  82
  83 =head1 GETTING HELP/SUPPORT
  84
  85 Due to the sheer size of its problem domain, DBIx::Class is a relatively
  86 complex framework. After you start using DBIx::Class questions will inevitably
  87 arise. If you are stuck with a problem or have doubts about a particular
  88 approach do not hesitate to contact us via any of the following options (the
  89 list is sorted by "fastest response time"):
  90
  91 =over
  92
  93 =item * IRC: irc.perl.org#dbix-class
  94
  95 =for html
  96 <a href="https://chat.mibbit.com/#dbix-class@irc.perl.org">(click for instant chatroom login)</a>
  97
  98 =item * Mailing list: L<http://lists.scsys.co.uk/mailman/listinfo/dbix-class>
  99
 100 =item * RT Bug Tracker: L<https://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class>
 101
 102 =item * Twitter: L<https://www.twitter.com/dbix_class>
 103
 104 =item * Web Site: L<http://www.dbix-class.org/>
 105
 106 =back
 107
 108 =head1 SYNOPSIS
 109
 110 For the very impatient: L<DBIx::Class::Manual::QuickStart>
 111
 112 This code in the next step can be generated automatically from an existing
 113 database, see L<dbicdump> from the distribution C<DBIx-Class-Schema-Loader>.
 114
 115 =head2 Schema classes preparation
 116
 117 Create a schema class called F<MyApp/Schema.pm>:
 118
 119   package MyApp::Schema;
 120   use base qw/DBIx::Class::Schema/;
 121
 122   __PACKAGE__->load_namespaces();
 123
 124   1;
 125
 126 Create a result class to represent artists, who have many CDs, in
 127 F<MyApp/Schema/Result/Artist.pm>:
 128
 129 See L<DBIx::Class::ResultSource> for docs on defining result classes.
 130
 131   package MyApp::Schema::Result::Artist;
 132   use base qw/DBIx::Class::Core/;
 133
 134   __PACKAGE__->table('artist');
 135   __PACKAGE__->add_columns(qw/ artistid name /);
 136   __PACKAGE__->set_primary_key('artistid');
 137   __PACKAGE__->has_many(cds => 'MyApp::Schema::Result::CD', 'artistid');
 138
 139   1;
 140
 141 A result class to represent a CD, which belongs to an artist, in
 142 F<MyApp/Schema/Result/CD.pm>:
 143
 144   package MyApp::Schema::Result::CD;
 145   use base qw/DBIx::Class::Core/;
 146
 147   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
 148   __PACKAGE__->table('cd');
 149   __PACKAGE__->add_columns(qw/ cdid artistid title year /);
 150   __PACKAGE__->set_primary_key('cdid');
 151   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Result::Artist', 'artistid');
 152
 153   1;
 154
 155 =head2 API usage
 156
 157 Then you can use these classes in your application's code:
 158
 159   # Connect to your database.
 160   use MyApp::Schema;
 161   my $schema = MyApp::Schema->connect($dbi_dsn, $user, $pass, \%dbi_params);
 162
 163   # Query for all artists and put them in an array,
 164   # or retrieve them as a result set object.
 165   # $schema->resultset returns a DBIx::Class::ResultSet
 166   my @all_artists = $schema->resultset('Artist')->all;
 167   my $all_artists_rs = $schema->resultset('Artist');
 168
 169   # Output all artists names
 170   # $artist here is a DBIx::Class::Row, which has accessors
 171   # for all its columns. Rows are also subclasses of your Result class.
 172   foreach $artist (@all_artists) {
 173     print $artist->name, "\n";
 174   }
 175
 176   # Create a result set to search for artists.
 177   # This does not query the DB.
 178   my $johns_rs = $schema->resultset('Artist')->search(
 179     # Build your WHERE using an SQL::Abstract structure:
 180     { name => { like => 'John%' } }
 181   );
 182
 183   # Execute a joined query to get the cds.
 184   my @all_john_cds = $johns_rs->search_related('cds')->all;
 185
 186   # Fetch the next available row.
 187   my $first_john = $johns_rs->next;
 188
 189   # Specify ORDER BY on the query.
 190   my $first_john_cds_by_title_rs = $first_john->cds(
 191     undef,
 192     { order_by => 'title' }
 193   );
 194
 195   # Create a result set that will fetch the artist data
 196   # at the same time as it fetches CDs, using only one query.
 197   my $millennium_cds_rs = $schema->resultset('CD')->search(
 198     { year => 2000 },
 199     { prefetch => 'artist' }
 200   );
 201
 202   my $cd = $millennium_cds_rs->next; # SELECT ... FROM cds JOIN artists ...
 203   my $cd_artist_name = $cd->artist->name; # Already has the data so no 2nd query
 204
 205   # new() makes a Result object but doesnt insert it into the DB.
 206   # create() is the same as new() then insert().
 207   my $new_cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 208   $new_cd->artist($cd->artist);
 209   $new_cd->insert; # Auto-increment primary key filled in after INSERT
 210   $new_cd->title('Fork');
 211
 212   $schema->txn_do(sub { $new_cd->update }); # Runs the update in a transaction
 213
 214   # change the year of all the millennium CDs at once
 215   $millennium_cds_rs->update({ year => 2002 });
 216
 217 =head1 DESCRIPTION
 218
 219 This is an SQL to OO mapper with an object API inspired by L<Class::DBI>
 220 (with a compatibility layer as a springboard for porting) and a resultset API
 221 that allows abstract encapsulation of database operations. It aims to make
 222 representing queries in your code as perl-ish as possible while still
 223 providing access to as many of the capabilities of the database as possible,
 224 including retrieving related records from multiple tables in a single query,
 225 C<JOIN>, C<LEFT JOIN>, C<COUNT>, C<DISTINCT>, C<GROUP BY>, C<ORDER BY> and
 226 C<HAVING> support.
 227
 228 DBIx::Class can handle multi-column primary and foreign keys, complex
 229 queries and database-level paging, and does its best to only query the
 230 database in order to return something you've directly asked for. If a
 231 resultset is used as an iterator it only fetches rows off the statement
 232 handle as requested in order to minimise memory usage. It has auto-increment
 233 support for SQLite, MySQL, PostgreSQL, Oracle, SQL Server and DB2 and is
 234 known to be used in production on at least the first four, and is fork-
 235 and thread-safe out of the box (although
 236 L<your DBD may not be|DBI/Threads and Thread Safety>).
 237
 238 This project is still under rapid development, so large new features may be
 239 marked B<experimental> - such APIs are still usable but may have edge bugs.
 240 Failing test cases are I<always> welcome and point releases are put out rapidly
 241 as bugs are found and fixed.
 242
 243 We do our best to maintain full backwards compatibility for published
 244 APIs, since DBIx::Class is used in production in many organisations,
 245 and even backwards incompatible changes to non-published APIs will be fixed
 246 if they're reported and doing so doesn't cost the codebase anything.
 247
 248 The test suite is quite substantial, and several developer releases
 249 are generally made to CPAN before the branch for the next release is
 250 merged back to trunk for a major release.
 251
 252 =head1 HOW TO CONTRIBUTE
 253
 254 Contributions are always welcome, in all usable forms (we especially
 255 welcome documentation improvements). The delivery methods include git-
 256 or unified-diff formatted patches, GitHub pull requests, or plain bug
 257 reports either via RT or the Mailing list. Contributors are generally
 258 granted access to the official repository after their first several
 259 patches pass successful review. Don't hesitate to
 260 L<contact|/GETTING HELP/SUPPORT> either of the L</CAT HERDERS> with
 261 any further questions you may have.
 262
 263 =for comment
 264 FIXME: Getty, frew and jnap need to get off their asses and finish the contrib section so we can link it here ;)
 265
 266 This project is maintained in a git repository. The code and related tools are
 267 accessible at the following locations:
 268
 269 =over
 270
 271 =item * Official repo: L<git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git>
 272
 273 =item * Official gitweb: L<http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/DBIx-Class.git>
 274
 275 =item * GitHub mirror: L<https://github.com/dbsrgits/DBIx-Class>
 276
 277 =item * Authorized committers: L<ssh://dbsrgits@git.shadowcat.co.uk/DBIx-Class.git>
 278
 279 =item * Travis-CI log: L<https://travis-ci.org/dbsrgits/dbix-class/builds>
 280
 281 =for html
 282 &#x21AA; Stable branch CI status: <img src="https://secure.travis-ci.org/dbsrgits/dbix-class.png?branch=master"></img>
 283
 284 =back
 285
 286 =head1 AUTHORS
 287
 288 Even though a large portion of the source I<appears> to be written by just a
 289 handful of people, this library continues to remain a collaborative effort -
 290 perhaps one of the most successful such projects on L<CPAN|http://cpan.org>.
 291 It is important to remember that ideas do not always result in a direct code
 292 contribution, but deserve acknowledgement just the same. Time and time again
 293 the seemingly most insignificant questions and suggestions have been shown
 294 to catalyze monumental improvements in consistency, accuracy and performance.
 295
 296 =for comment this line is replaced with the author list at dist-building time
 297
 298 The canonical source of authors and their details is the F<AUTHORS> file at
 299 the root of this distribution (or repository). The canonical source of
 300 per-line authorship is the L<git repository|/HOW TO CONTRIBUTE> history
 301 itself.
 302
 303 =head1 CAT HERDERS
 304
 305 The fine folks nudging the project in a particular direction:
 306
 307 =over
 308
 309 B<ribasushi>: Peter Rabbitson <ribasushi@cpan.org>
 310 (present day maintenance and controlled evolution)
 311
 312 B<castaway>: Jess Robinson <castaway@desert-island.me.uk>
 313 (lions share of the reference documentation and manuals)
 314
 315 B<mst>: Matt S Trout <mst@shadowcat.co.uk> (project founder -
 316 original idea, architecture and implementation)
 317
 318 =back
 319
 320 =head1 COPYRIGHT AND LICENSE
 321
 322 Copyright (c) 2005 by mst, castaway, ribasushi, and other DBIx::Class
 323 L</AUTHORS> as listed above and in F<AUTHORS>.
 324
 325 This library is free software and may be distributed under the same terms
 326 as perl5 itself. See F<LICENSE> for the complete licensing terms.