[dbsrgits/DBIx-Class.git] / t / lib / DBICTest / Util / LeakTracer.pm

package DBICTest::Util::LeakTracer;

use warnings;
use strict;

use ANFANG;
use Carp;
use Scalar::Util qw(isweak weaken blessed reftype);
use DBIx::Class::_Util qw(refcount hrefaddr refdesc);
use DBICTest::RunMode;
use Data::Dumper::Concise;
use DBICTest::Util qw( stacktrace visit_namespaces );
use constant {
  CV_TRACING => !!(
    !DBICTest::RunMode->is_plain
      &&
    require DBIx::Class::Optional::Dependencies
      &&
    DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy')
  ),
};

use base 'Exporter';
our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);

my $refs_traced = 0;
my $leaks_found = 0;
my %reg_of_regs;

sub populate_weakregistry {
  my ($weak_registry, $target, $note) = @_;

  croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
  croak 'Target is not a reference' unless length ref $target;

  my $refaddr = hrefaddr $target;

  # a registry could be fed to itself or another registry via recursive sweeps
  return $target if $reg_of_regs{$refaddr};

  weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
    unless( $reg_of_regs{ hrefaddr($weak_registry) } );

  # an explicit "garbage collection" pass every time we store a ref
  # if we do not do this the registry will keep growing appearing
  # as if the traced program is continuously slowly leaking memory
  for my $reg (values %reg_of_regs) {
    (defined $reg->{$_}{weakref}) or delete $reg->{$_}
      for keys %$reg;
  }

  if (! defined $weak_registry->{$refaddr}{weakref}) {
    $weak_registry->{$refaddr} = {
      stacktrace => stacktrace(1),
      weakref => $target,
    };

    # on perl < 5.8.3 sometimes a weaken can throw (can't find RT)
    # so guard against that unlikely event
    local $SIG{__DIE__} if $SIG{__DIE__};
    local $@;
    eval { weaken( $weak_registry->{$refaddr}{weakref} ); $refs_traced++ }
      or delete $weak_registry->{$refaddr};
  }

  my $desc = refdesc $target;
  $weak_registry->{$refaddr}{slot_names}{$desc} = 1;
  if ($note) {
    $note =~ s/\s*\Q$desc\E\s*//g;
    $weak_registry->{$refaddr}{slot_names}{$note} = 1;
  }

  $target;
}

# Regenerate the slots names on a thread spawn
sub CLONE {
  my @individual_regs = grep { scalar keys %{$_||{}} } values %reg_of_regs;
  %reg_of_regs = ();

  for my $reg (@individual_regs) {
    my @live_slots = grep { defined $_->{weakref} } values %$reg
      or next;

    $reg = {};  # get a fresh hashref in the new thread ctx
    weaken( $reg_of_regs{hrefaddr($reg)} = $reg );

    for my $slot_info (@live_slots) {
      my $new_addr = hrefaddr $slot_info->{weakref};

      # replace all slot names
      $slot_info->{slot_names} = { map {
        my $name = $_;
        $name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
        ($name => 1);
      } keys %{$slot_info->{slot_names}} };

      $reg->{$new_addr} = $slot_info;
    }
  }

  # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
  # collected before leaving this scope. Depending on the code above, this
  # may very well be just a preventive measure guarding future modifications
  undef;
}

sub visit_refs {
  my $args = { (ref $_[0]) ? %{$_[0]} : @_ };

  $args->{seen_refs} ||= {};

  my $visited_cnt = '0E0';
  for my $i (0 .. $#{$args->{refs}} ) {

    next unless length ref $args->{refs}[$i]; # not-a-ref

    my $addr = hrefaddr $args->{refs}[$i];

    # no diving into weakregistries
    next if $reg_of_regs{$addr};

    next if $args->{seen_refs}{$addr}++;
    $visited_cnt++;

    my $r = $args->{refs}[$i];

    $args->{action}->($r) or next;

    # This may end up being necessarry some day, but do not slow things
    # down for now
    #if ( defined( my $t = tied($r) ) ) {
    #  $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
    #}

    my $type = reftype $r;

    local $SIG{__DIE__} if $SIG{__DIE__};
    local $@;
    eval {
      if ($type eq 'HASH') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($r->{$_}) ) ? $r->{$_} : ()
        } keys %$r ] });
      }
      elsif ($type eq 'ARRAY') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($r->[$_]) ) ? $r->[$_] : ()
        } 0..$#$r ] });
      }
      elsif ($type eq 'REF' and !isweak($$r)) {
        $visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
      }
      elsif (CV_TRACING and $type eq 'CODE') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($_) ) ? $_ : ()
        } values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
      }
      1;
    } or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
  }
  $visited_cnt;
}

# compiles a list of addresses stored as globals (possibly even catching
# class data in the form of method closures), so we can skip them further on
sub symtable_referenced_addresses {

  my $refs_per_pkg;

  my $seen_refs = {};
  visit_namespaces(
    action => sub {

      no strict 'refs';

      my $pkg = shift;

      # the unless regex at the end skips some dangerous namespaces outright
      # (but does not prevent descent)
      $refs_per_pkg->{$pkg} += visit_refs (
        seen_refs => $seen_refs,

        action => sub { 1 },

        refs => [ map { my $sym = $_;
          # *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
          ( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),

          ( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
            ? ${"${pkg}::$sym"} : ()
          ,

          ( map {
            ( defined *{"${pkg}::$sym"}{$_} and ! isweak(defined *{"${pkg}::$sym"}{$_}) )
              ? *{"${pkg}::$sym"}{$_}
              : ()
          } qw(HASH ARRAY IO GLOB) ),

        } keys %{"${pkg}::"} ],
      ) unless $pkg =~ /^ (?:
        DB | next | B | .+? ::::ISA (?: ::CACHE ) | Class::C3
      ) $/x;
    }
  );

#  use Devel::Dwarn;
#  Ddie [ map
#    { { $_ => $refs_per_pkg->{$_} } }
#    sort
#      {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
#      keys %$refs_per_pkg
#  ];

  $seen_refs;
}

sub assert_empty_weakregistry {
  my ($weak_registry, $quiet) = @_;

  # in case we hooked bless any extra object creation will wreak
  # havoc during the assert phase
  local *CORE::GLOBAL::bless;
  *CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : CORE::caller() ) };

  croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';

  defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
    for keys %$weak_registry;

  return unless keys %$weak_registry;

  my $tb = eval { Test::Builder->new }
    or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";

  for my $addr (keys %$weak_registry) {
    $weak_registry->{$addr}{display_name} = join ' | ', (
      sort
        { length $a <=> length $b or $a cmp $b }
        keys %{$weak_registry->{$addr}{slot_names}}
    );

    $tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
      if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
  }

  # the symtable walk is very expensive
  # if we are $quiet (running in an END block) we do not really need to be
  # that thorough - can get by with only %Sub::Quote::QUOTED
  delete $weak_registry->{$_} for $quiet
    ? do {
      my $refs = {};
      visit_refs (
        # only look at the closed over stuffs
        refs => [ grep { length ref $_ } map { values %{$_->[2]} } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ],
        seen_refs => $refs,
        action => sub { 1 },
      );
      keys %$refs;
    }
    : (
      # full sumtable walk, starting from ::
      keys %{ symtable_referenced_addresses() }
    )
  ;

  for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {

    next if ! defined $weak_registry->{$addr}{weakref};

    $leaks_found++ unless $tb->in_todo;
    $tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");

    my $diag = do {
      local $Data::Dumper::Maxdepth = 1;
      sprintf "\n%s (refcnt %d) => %s\n",
        $weak_registry->{$addr}{display_name},
        refcount($weak_registry->{$addr}{weakref}),
        (
          ref($weak_registry->{$addr}{weakref}) eq 'CODE'
            and
          B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
        ) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
      ;
    };

    # FIXME - need to add a circular reference seeker based on the visitor
    # (will need a bunch of modifications, punting with just a stub for now)

    $diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
      if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });

    $diag =~ s/^/    /mg;

    if (my $stack = $weak_registry->{$addr}{stacktrace}) {
      $diag .= "    Reference first seen$stack";
    }

    $tb->diag($diag);

#    if ($leaks_found == 1) {
#      # using the fh dumper due to intermittent buffering issues
#      # in case we decide to exit soon after (possibly via _exit)
#      require Devel::MAT::Dumper;
#      local $Devel::MAT::Dumper::MAX_STRING = -1;
#      open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
#      Devel::MAT::Dumper::dumpfh( $fh );
#      close ($fh) or die $!;
#
#      require POSIX;
#      POSIX::_exit(1);
#    }
  }

  if (! $quiet and !$leaks_found and ! $tb->in_todo) {
    $tb->ok(1, sprintf "No leaks found at %s line %d", (CORE::caller())[1,2] );
  }
}

END {
  if (
    $INC{'Test/Builder.pm'}
      and
    my $tb = do {
      local $@;
      my $t = eval { Test::Builder->new }
        or warn "Test::Builder->new failed:\n$@\n";
      $t;
    }
  ) {
    # we check for test passage - a leak may be a part of a TODO
    if ($leaks_found and !$tb->is_passing) {

      $tb->diag(sprintf
        "\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
      . '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
      . "\n\n%s\n%s\n\n", ('#' x 16) x 4
      ) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );

    }
    else {
      $tb->note("Auto checked $refs_traced references for leaks - none detected");
    }

    # also while we are here and not in plain runmode: make sure we never
    # loaded any of the strictures XS bullshit (it's a leak in a sense)
    unless (
      $ENV{MOO_FATAL_WARNINGS}
        or
      # FIXME - SQLT loads strictures explicitly, /facedesk
      # remove this INC check when 0fb58589 and 45287c815 are rectified
      $INC{'SQL/Translator.pm'}
        or
      DBICTest::RunMode->is_plain
    ) {
      for (qw(indirect multidimensional bareword::filehandles)) {
        exists $INC{ Module::Runtime::module_notional_filename($_) }
          and
        $tb->ok(0, "$_ load should not have been attempted!!!" )
      }
    }
  }
}

1;
Commit	Line	Data
218b7c12	1	package DBICTest::Util::LeakTracer;
	2
	3	use warnings;
	4	use strict;
	5
c0329273	6	use ANFANG;
218b7c12	7	use Carp;
96577657	8	use Scalar::Util qw(isweak weaken blessed reftype);
8433421f	9	use DBIx::Class::_Util qw(refcount hrefaddr refdesc);
c0329273	10	use DBICTest::RunMode;
96577657	11	use Data::Dumper::Concise;
c9abd679	12	use DBICTest::Util qw( stacktrace visit_namespaces );
556c4fe6	13	use constant {
18a2903b	14	CV_TRACING => !!(
	15	!DBICTest::RunMode->is_plain
	16	&&
	17	require DBIx::Class::Optional::Dependencies
	18	&&
	19	DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy')
	20	),
556c4fe6	21	};
218b7c12	22
218b7c12	23	use base 'Exporter';
bf302897	24	our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);
218b7c12	25
218b7c12	26	my $refs_traced = 0;
96577657	27	my $leaks_found = 0;
218b7c12	28	my %reg_of_regs;
	29
	30	sub populate_weakregistry {
96577657	31	my ($weak_registry, $target, $note) = @_;
218b7c12	32
	33	croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
	34	croak 'Target is not a reference' unless length ref $target;
	35
96577657	36	my $refaddr = hrefaddr $target;
8fa57d17	37
96577657	38	# a registry could be fed to itself or another registry via recursive sweeps
96577657	39	return $target if $reg_of_regs{$refaddr};
218b7c12	40
85ad63df	41	weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
	42	unless( $reg_of_regs{ hrefaddr($weak_registry) } );
	43
	44	# an explicit "garbage collection" pass every time we store a ref
	45	# if we do not do this the registry will keep growing appearing
	46	# as if the traced program is continuously slowly leaking memory
	47	for my $reg (values %reg_of_regs) {
	48	(defined $reg->{$_}{weakref}) or delete $reg->{$_}
	49	for keys %$reg;
	50	}
	51
96577657	52	if (! defined $weak_registry->{$refaddr}{weakref}) {
96577657	53	$weak_registry->{$refaddr} = {
8fa57d17	54	stacktrace => stacktrace(1),
96577657	55	weakref => $target,
8fa57d17	56	};
4841171c	57
	58	# on perl < 5.8.3 sometimes a weaken can throw (can't find RT)
	59	# so guard against that unlikely event
5c33c8be	60	local $SIG{__DIE__} if $SIG{__DIE__};
4841171c	61	local $@;
	62	eval { weaken( $weak_registry->{$refaddr}{weakref} ); $refs_traced++ }
	63	or delete $weak_registry->{$refaddr};
218b7c12	64	}
218b7c12	65
8433421f	66	my $desc = refdesc $target;
96577657	67	$weak_registry->{$refaddr}{slot_names}{$desc} = 1;
	68	if ($note) {
	69	$note =~ s/\s\Q$desc\E\s//g;
	70	$weak_registry->{$refaddr}{slot_names}{$note} = 1;
	71	}
	72
218b7c12	73	$target;
	74	}
	75
96577657	76	# Regenerate the slots names on a thread spawn
218b7c12	77	sub CLONE {
	78	my @individual_regs = grep { scalar keys %{$_\|\|{}} } values %reg_of_regs;
	79	%reg_of_regs = ();
	80
	81	for my $reg (@individual_regs) {
96577657	82	my @live_slots = grep { defined $_->{weakref} } values %$reg
218b7c12	83	or next;
cf8fa286	84
cf8fa286	85	$reg = {}; # get a fresh hashref in the new thread ctx
96577657	86	weaken( $reg_of_regs{hrefaddr($reg)} = $reg );
218b7c12	87
96577657	88	for my $slot_info (@live_slots) {
96577657	89	my $new_addr = hrefaddr $slot_info->{weakref};
8fa57d17	90
96577657	91	# replace all slot names
	92	$slot_info->{slot_names} = { map {
	93	my $name = $_;
	94	$name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
	95	($name => 1);
	96	} keys %{$slot_info->{slot_names}} };
218b7c12	97
96577657	98	$reg->{$new_addr} = $slot_info;
218b7c12	99	}
218b7c12	100	}
d52fc26d	101
	102	# Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
	103	# collected before leaving this scope. Depending on the code above, this
	104	# may very well be just a preventive measure guarding future modifications
	105	undef;
218b7c12	106	}
218b7c12	107
556c4fe6	108	sub visit_refs {
	109	my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
	110
	111	$args->{seen_refs} \|\|= {};
	112
	113	my $visited_cnt = '0E0';
	114	for my $i (0 .. $#{$args->{refs}} ) {
556c4fe6	115
a42634cd	116	next unless length ref $args->{refs}[$i]; # not-a-ref
556c4fe6	117
a42634cd	118	my $addr = hrefaddr $args->{refs}[$i];
556c4fe6	119
6ae62c5c	120	# no diving into weakregistries
a42634cd	121	next if $reg_of_regs{$addr};
556c4fe6	122
a42634cd	123	next if $args->{seen_refs}{$addr}++;
556c4fe6	124	$visited_cnt++;
a42634cd	125
	126	my $r = $args->{refs}[$i];
	127
556c4fe6	128	$args->{action}->($r) or next;
556c4fe6	129
6ae62c5c	130	# This may end up being necessarry some day, but do not slow things
	131	# down for now
	132	#if ( defined( my $t = tied($r) ) ) {
	133	# $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
	134	#}
	135
a42634cd	136	my $type = reftype $r;
a42634cd	137
5c33c8be	138	local $SIG{__DIE__} if $SIG{__DIE__};
7664b1a0	139	local $@;
7664b1a0	140	eval {
7664b1a0	141	if ($type eq 'HASH') {
	142	$visited_cnt += visit_refs({ %$args, refs => [ map {
	143	( !isweak($r->{$_}) ) ? $r->{$_} : ()
	144	} keys %$r ] });
	145	}
	146	elsif ($type eq 'ARRAY') {
	147	$visited_cnt += visit_refs({ %$args, refs => [ map {
	148	( !isweak($r->[$_]) ) ? $r->[$_] : ()
	149	} 0..$#$r ] });
	150	}
	151	elsif ($type eq 'REF' and !isweak($$r)) {
	152	$visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
	153	}
	154	elsif (CV_TRACING and $type eq 'CODE') {
	155	$visited_cnt += visit_refs({ %$args, refs => [ map {
	156	( !isweak($_) ) ? $_ : ()
1a77219a	157	} values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
7664b1a0	158	}
7664b1a0	159	1;
8433421f	160	} or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
556c4fe6	161	}
	162	$visited_cnt;
	163	}
	164
a42634cd	165	# compiles a list of addresses stored as globals (possibly even catching
	166	# class data in the form of method closures), so we can skip them further on
	167	sub symtable_referenced_addresses {
	168
	169	my $refs_per_pkg;
	170
a42634cd	171	my $seen_refs = {};
	172	visit_namespaces(
	173	action => sub {
556c4fe6	174
556c4fe6	175	no strict 'refs';
556c4fe6	176
a42634cd	177	my $pkg = shift;
a42634cd	178
556c4fe6	179	# the unless regex at the end skips some dangerous namespaces outright
556c4fe6	180	# (but does not prevent descent)
a42634cd	181	$refs_per_pkg->{$pkg} += visit_refs (
556c4fe6	182	seen_refs => $seen_refs,
a42634cd	183
1a77219a	184	action => sub { 1 },
a42634cd	185
556c4fe6	186	refs => [ map { my $sym = $_;
c9abd679	187	# *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
c9abd679	188	( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),
556c4fe6	189
c9abd679	190	( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
c9abd679	191	? ${"${pkg}::$sym"} : ()
556c4fe6	192	,
a42634cd	193
556c4fe6	194	( map {
c9abd679	195	( defined {"${pkg}::$sym"}{$_} and ! isweak(defined {"${pkg}::$sym"}{$_}) )
c9abd679	196	? *{"${pkg}::$sym"}{$_}
556c4fe6	197	: ()
556c4fe6	198	} qw(HASH ARRAY IO GLOB) ),
a42634cd	199
c9abd679	200	} keys %{"${pkg}::"} ],
c9abd679	201	) unless $pkg =~ /^ (?:
556c4fe6	202	DB \| next \| B \| .+? ::::ISA (?: ::CACHE ) \| Class::C3
c9abd679	203	) $/x;
a42634cd	204	}
a42634cd	205	);
556c4fe6	206
a42634cd	207	# use Devel::Dwarn;
	208	# Ddie [ map
	209	# { { $_ => $refs_per_pkg->{$_} } }
	210	# sort
	211	# {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
	212	# keys %$refs_per_pkg
	213	# ];
	214
	215	$seen_refs;
	216	}
	217
	218	sub assert_empty_weakregistry {
	219	my ($weak_registry, $quiet) = @_;
	220
	221	# in case we hooked bless any extra object creation will wreak
	222	# havoc during the assert phase
	223	local *CORE::GLOBAL::bless;
821edc09	224	*CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : CORE::caller() ) };
a42634cd	225
	226	croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
	227
	228	defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
	229	for keys %$weak_registry;
	230
	231	return unless keys %$weak_registry;
8fa57d17	232
a42634cd	233	my $tb = eval { Test::Builder->new }
a42634cd	234	or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";
8fa57d17	235
a42634cd	236	for my $addr (keys %$weak_registry) {
	237	$weak_registry->{$addr}{display_name} = join ' \| ', (
	238	sort
	239	{ length $a <=> length $b or $a cmp $b }
	240	keys %{$weak_registry->{$addr}{slot_names}}
	241	);
	242
	243	$tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
	244	if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
	245	}
	246
8d73fcd4	247	# the symtable walk is very expensive
	248	# if we are $quiet (running in an END block) we do not really need to be
	249	# that thorough - can get by with only %Sub::Quote::QUOTED
	250	delete $weak_registry->{$_} for $quiet
	251	? do {
	252	my $refs = {};
	253	visit_refs (
	254	# only look at the closed over stuffs
	255	refs => [ grep { length ref $_ } map { values %{$_->[2]} } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ],
	256	seen_refs => $refs,
	257	action => sub { 1 },
	258	);
	259	keys %$refs;
	260	}
	261	: (
	262	# full sumtable walk, starting from ::
	263	keys %{ symtable_referenced_addresses() }
	264	)
	265	;
556c4fe6	266
96577657	267	for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {
96577657	268
1a44a267	269	next if ! defined $weak_registry->{$addr}{weakref};
1a44a267	270
5dc4301c	271	$leaks_found++ unless $tb->in_todo;
ee20ecfc	272	$tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");
1a44a267	273
	274	my $diag = do {
	275	local $Data::Dumper::Maxdepth = 1;
	276	sprintf "\n%s (refcnt %d) => %s\n",
	277	$weak_registry->{$addr}{display_name},
	278	refcount($weak_registry->{$addr}{weakref}),
	279	(
	280	ref($weak_registry->{$addr}{weakref}) eq 'CODE'
	281	and
	282	B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
	283	) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
	284	;
218b7c12	285	};
1a44a267	286
5dc4301c	287	# FIXME - need to add a circular reference seeker based on the visitor
	288	# (will need a bunch of modifications, punting with just a stub for now)
	289
556c4fe6	290	$diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
1a44a267	291	if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
	292
	293	$diag =~ s/^/ /mg;
	294
	295	if (my $stack = $weak_registry->{$addr}{stacktrace}) {
	296	$diag .= " Reference first seen$stack";
	297	}
	298
	299	$tb->diag($diag);
6ae62c5c	300
	301	# if ($leaks_found == 1) {
	302	# # using the fh dumper due to intermittent buffering issues
	303	# # in case we decide to exit soon after (possibly via _exit)
	304	# require Devel::MAT::Dumper;
	305	# local $Devel::MAT::Dumper::MAX_STRING = -1;
	306	# open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
	307	# Devel::MAT::Dumper::dumpfh( $fh );
	308	# close ($fh) or die $!;
	309	#
47603d6c	310	# require POSIX;
6ae62c5c	311	# POSIX::_exit(1);
6ae62c5c	312	# }
1a44a267	313	}
1a44a267	314
5dc4301c	315	if (! $quiet and !$leaks_found and ! $tb->in_todo) {
821edc09	316	$tb->ok(1, sprintf "No leaks found at %s line %d", (CORE::caller())[1,2] );
218b7c12	317	}
	318	}
	319
	320	END {
b77a61d8	321	if (
	322	$INC{'Test/Builder.pm'}
	323	and
	324	my $tb = do {
	325	local $@;
	326	my $t = eval { Test::Builder->new }
	327	or warn "Test::Builder->new failed:\n$@\n";
	328	$t;
	329	}
	330	) {
218b7c12	331	# we check for test passage - a leak may be a part of a TODO
	332	if ($leaks_found and !$tb->is_passing) {
	333
	334	$tb->diag(sprintf
	335	"\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
	336	. '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
	337	. "\n\n%s\n%s\n\n", ('#' x 16) x 4
	338	) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );
	339
	340	}
	341	else {
	342	$tb->note("Auto checked $refs_traced references for leaks - none detected");
	343	}
cbd7f87a	344
cbd7f87a	345	# also while we are here and not in plain runmode: make sure we never
cbd7f87a	346	# loaded any of the strictures XS bullshit (it's a leak in a sense)
0020e364	347	unless (
	348	$ENV{MOO_FATAL_WARNINGS}
	349	or
	350	# FIXME - SQLT loads strictures explicitly, /facedesk
	351	# remove this INC check when 0fb58589 and 45287c815 are rectified
	352	$INC{'SQL/Translator.pm'}
	353	or
	354	DBICTest::RunMode->is_plain
	355	) {
cbd7f87a	356	for (qw(indirect multidimensional bareword::filehandles)) {
	357	exists $INC{ Module::Runtime::module_notional_filename($_) }
	358	and
ee20ecfc	359	$tb->ok(0, "$_ load should not have been attempted!!!" )
cbd7f87a	360	}
cbd7f87a	361	}
218b7c12	362	}
	363	}
	364
	365	1;