[dbsrgits/DBIx-Class.git] / t / lib / DBICTest / Util / LeakTracer.pm

package DBICTest::Util::LeakTracer;

use warnings;
use strict;

use Carp;
use Scalar::Util qw(isweak weaken blessed reftype);
use DBIx::Class::_Util qw(refcount hrefaddr refdesc);
use DBIx::Class::Optional::Dependencies;
use Data::Dumper::Concise;
use DBICTest::Util qw( stacktrace visit_namespaces );
use constant {
  CV_TRACING => !DBICTest::RunMode->is_plain && DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy'),
};

use base 'Exporter';
our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);

my $refs_traced = 0;
my $leaks_found = 0;
my %reg_of_regs;

sub populate_weakregistry {
  my ($weak_registry, $target, $note) = @_;

  croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
  croak 'Target is not a reference' unless length ref $target;

  my $refaddr = hrefaddr $target;

  # a registry could be fed to itself or another registry via recursive sweeps
  return $target if $reg_of_regs{$refaddr};

  weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
    unless( $reg_of_regs{ hrefaddr($weak_registry) } );

  # an explicit "garbage collection" pass every time we store a ref
  # if we do not do this the registry will keep growing appearing
  # as if the traced program is continuously slowly leaking memory
  for my $reg (values %reg_of_regs) {
    (defined $reg->{$_}{weakref}) or delete $reg->{$_}
      for keys %$reg;
  }

  if (! defined $weak_registry->{$refaddr}{weakref}) {
    $weak_registry->{$refaddr} = {
      stacktrace => stacktrace(1),
      weakref => $target,
    };
    weaken( $weak_registry->{$refaddr}{weakref} );
    $refs_traced++;
  }

  my $desc = refdesc $target;
  $weak_registry->{$refaddr}{slot_names}{$desc} = 1;
  if ($note) {
    $note =~ s/\s*\Q$desc\E\s*//g;
    $weak_registry->{$refaddr}{slot_names}{$note} = 1;
  }

  $target;
}

# Regenerate the slots names on a thread spawn
sub CLONE {
  my @individual_regs = grep { scalar keys %{$_||{}} } values %reg_of_regs;
  %reg_of_regs = ();

  for my $reg (@individual_regs) {
    my @live_slots = grep { defined $_->{weakref} } values %$reg
      or next;

    $reg = {};  # get a fresh hashref in the new thread ctx
    weaken( $reg_of_regs{hrefaddr($reg)} = $reg );

    for my $slot_info (@live_slots) {
      my $new_addr = hrefaddr $slot_info->{weakref};

      # replace all slot names
      $slot_info->{slot_names} = { map {
        my $name = $_;
        $name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
        ($name => 1);
      } keys %{$slot_info->{slot_names}} };

      $reg->{$new_addr} = $slot_info;
    }
  }
}

sub visit_refs {
  my $args = { (ref $_[0]) ? %{$_[0]} : @_ };

  $args->{seen_refs} ||= {};

  my $visited_cnt = '0E0';
  for my $i (0 .. $#{$args->{refs}} ) {

    next unless length ref $args->{refs}[$i]; # not-a-ref

    my $addr = hrefaddr $args->{refs}[$i];

    # no diving into weakregistries
    next if $reg_of_regs{$addr};

    next if $args->{seen_refs}{$addr}++;
    $visited_cnt++;

    my $r = $args->{refs}[$i];

    $args->{action}->($r) or next;

    # This may end up being necessarry some day, but do not slow things
    # down for now
    #if ( defined( my $t = tied($r) ) ) {
    #  $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
    #}

    my $type = reftype $r;

    local $@;
    eval {
      if ($type eq 'HASH') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($r->{$_}) ) ? $r->{$_} : ()
        } keys %$r ] });
      }
      elsif ($type eq 'ARRAY') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($r->[$_]) ) ? $r->[$_] : ()
        } 0..$#$r ] });
      }
      elsif ($type eq 'REF' and !isweak($$r)) {
        $visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
      }
      elsif (CV_TRACING and $type eq 'CODE') {
        $visited_cnt += visit_refs({ %$args, refs => [ map {
          ( !isweak($_) ) ? $_ : ()
        } values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
      }
      1;
    } or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
  }
  $visited_cnt;
}

# compiles a list of addresses stored as globals (possibly even catching
# class data in the form of method closures), so we can skip them further on
sub symtable_referenced_addresses {

  my $refs_per_pkg;

  my $seen_refs = {};
  visit_namespaces(
    action => sub {

      no strict 'refs';

      my $pkg = shift;

      # the unless regex at the end skips some dangerous namespaces outright
      # (but does not prevent descent)
      $refs_per_pkg->{$pkg} += visit_refs (
        seen_refs => $seen_refs,

        action => sub { 1 },

        refs => [ map { my $sym = $_;
          # *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
          ( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),

          ( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
            ? ${"${pkg}::$sym"} : ()
          ,

          ( map {
            ( defined *{"${pkg}::$sym"}{$_} and ! isweak(defined *{"${pkg}::$sym"}{$_}) )
              ? *{"${pkg}::$sym"}{$_}
              : ()
          } qw(HASH ARRAY IO GLOB) ),

        } keys %{"${pkg}::"} ],
      ) unless $pkg =~ /^ (?:
        DB | next | B | .+? ::::ISA (?: ::CACHE ) | Class::C3
      ) $/x;
    }
  );

#  use Devel::Dwarn;
#  Ddie [ map
#    { { $_ => $refs_per_pkg->{$_} } }
#    sort
#      {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
#      keys %$refs_per_pkg
#  ];

  $seen_refs;
}

sub assert_empty_weakregistry {
  my ($weak_registry, $quiet) = @_;

  # in case we hooked bless any extra object creation will wreak
  # havoc during the assert phase
  local *CORE::GLOBAL::bless;
  *CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() ) };

  croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';

  defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
    for keys %$weak_registry;

  return unless keys %$weak_registry;

  my $tb = eval { Test::Builder->new }
    or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";

  for my $addr (keys %$weak_registry) {
    $weak_registry->{$addr}{display_name} = join ' | ', (
      sort
        { length $a <=> length $b or $a cmp $b }
        keys %{$weak_registry->{$addr}{slot_names}}
    );

    $tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
      if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
  }

  # the symtable walk is very expensive
  # if we are $quiet (running in an END block) we do not really need to be
  # that thorough - can get by with only %Sub::Quote::QUOTED
  delete $weak_registry->{$_} for $quiet
    ? do {
      my $refs = {};
      visit_refs (
        # only look at the closed over stuffs
        refs => [ grep { length ref $_ } (

          # old style Sub::Quote
          ( map { values %{ $_->[2]}        } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ),

          # new style Sub::Quote
          ( map { values %{ $_->{captures}} } grep { ref $_ eq 'HASH'  } values %Sub::Quote::QUOTED ),

        )],
        seen_refs => $refs,
        action => sub { 1 },
      );
      keys %$refs;
    }
    : (
      # full sumtable walk, starting from ::
      keys %{ symtable_referenced_addresses() }
    )
  ;

  for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {

    next if ! defined $weak_registry->{$addr}{weakref};

    $leaks_found++ unless $tb->in_todo;
    $tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");

    my $diag = do {
      local $Data::Dumper::Maxdepth = 1;
      sprintf "\n%s (refcnt %d) => %s\n",
        $weak_registry->{$addr}{display_name},
        refcount($weak_registry->{$addr}{weakref}),
        (
          ref($weak_registry->{$addr}{weakref}) eq 'CODE'
            and
          B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
        ) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
      ;
    };

    # FIXME - need to add a circular reference seeker based on the visitor
    # (will need a bunch of modifications, punting with just a stub for now)

    $diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
      if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });

    $diag =~ s/^/    /mg;

    if (my $stack = $weak_registry->{$addr}{stacktrace}) {
      $diag .= "    Reference first seen$stack";
    }

    $tb->diag($diag);

#    if ($leaks_found == 1) {
#      # using the fh dumper due to intermittent buffering issues
#      # in case we decide to exit soon after (possibly via _exit)
#      require Devel::MAT::Dumper;
#      local $Devel::MAT::Dumper::MAX_STRING = -1;
#      open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
#      Devel::MAT::Dumper::dumpfh( $fh );
#      close ($fh) or die $!;
#
#      use POSIX;
#      POSIX::_exit(1);
#    }
  }

  if (! $quiet and !$leaks_found and ! $tb->in_todo) {
    $tb->ok(1, sprintf "No leaks found at %s line %d", (caller())[1,2] );
  }
}

END {
  if (
    $INC{'Test/Builder.pm'}
      and
    my $tb = do {
      local $@;
      my $t = eval { Test::Builder->new }
        or warn "Test::Builder->new failed:\n$@\n";
      $t;
    }
  ) {
    # we check for test passage - a leak may be a part of a TODO
    if ($leaks_found and !$tb->is_passing) {

      $tb->diag(sprintf
        "\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
      . '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
      . "\n\n%s\n%s\n\n", ('#' x 16) x 4
      ) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );

    }
    else {
      $tb->note("Auto checked $refs_traced references for leaks - none detected");
    }

    # also while we are here and not in plain runmode: make sure we never
    # loaded any of the strictures XS bullshit (it's a leak in a sense)
    unless (
      $ENV{MOO_FATAL_WARNINGS}
        or
      # FIXME - SQLT loads strictures explicitly, /facedesk
      # remove this INC check when 0fb58589 and 45287c815 are rectified
      $INC{'SQL/Translator.pm'}
        or
      DBICTest::RunMode->is_plain
    ) {
      for my $mod (qw(indirect multidimensional bareword::filehandles)) {
        ( my $fn = "$mod.pm" ) =~ s|::|/|g;

        $tb->ok(0, "Load of '$mod' should not have been attempted!!!" )
          if exists $INC{$fn};
      }
    }
  }
}

1;
Commit	Line	Data
218b7c12	1	package DBICTest::Util::LeakTracer;
	2
	3	use warnings;
	4	use strict;
	5
	6	use Carp;
96577657	7	use Scalar::Util qw(isweak weaken blessed reftype);
8433421f	8	use DBIx::Class::_Util qw(refcount hrefaddr refdesc);
556c4fe6	9	use DBIx::Class::Optional::Dependencies;
96577657	10	use Data::Dumper::Concise;
2f48c52f	11	use DBICTest::Util qw( stacktrace visit_namespaces );
556c4fe6	12	use constant {
b78fd146	13	CV_TRACING => !DBICTest::RunMode->is_plain && DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy'),
556c4fe6	14	};
218b7c12	15
218b7c12	16	use base 'Exporter';
bf302897	17	our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);
218b7c12	18
218b7c12	19	my $refs_traced = 0;
96577657	20	my $leaks_found = 0;
218b7c12	21	my %reg_of_regs;
	22
	23	sub populate_weakregistry {
96577657	24	my ($weak_registry, $target, $note) = @_;
218b7c12	25
	26	croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
	27	croak 'Target is not a reference' unless length ref $target;
	28
96577657	29	my $refaddr = hrefaddr $target;
8fa57d17	30
96577657	31	# a registry could be fed to itself or another registry via recursive sweeps
96577657	32	return $target if $reg_of_regs{$refaddr};
218b7c12	33
85ad63df	34	weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
	35	unless( $reg_of_regs{ hrefaddr($weak_registry) } );
	36
	37	# an explicit "garbage collection" pass every time we store a ref
	38	# if we do not do this the registry will keep growing appearing
	39	# as if the traced program is continuously slowly leaking memory
	40	for my $reg (values %reg_of_regs) {
	41	(defined $reg->{$_}{weakref}) or delete $reg->{$_}
	42	for keys %$reg;
	43	}
	44
96577657	45	if (! defined $weak_registry->{$refaddr}{weakref}) {
96577657	46	$weak_registry->{$refaddr} = {
8fa57d17	47	stacktrace => stacktrace(1),
96577657	48	weakref => $target,
8fa57d17	49	};
96577657	50	weaken( $weak_registry->{$refaddr}{weakref} );
8fa57d17	51	$refs_traced++;
218b7c12	52	}
218b7c12	53
8433421f	54	my $desc = refdesc $target;
96577657	55	$weak_registry->{$refaddr}{slot_names}{$desc} = 1;
	56	if ($note) {
	57	$note =~ s/\s\Q$desc\E\s//g;
	58	$weak_registry->{$refaddr}{slot_names}{$note} = 1;
	59	}
	60
218b7c12	61	$target;
	62	}
	63
96577657	64	# Regenerate the slots names on a thread spawn
218b7c12	65	sub CLONE {
	66	my @individual_regs = grep { scalar keys %{$_\|\|{}} } values %reg_of_regs;
	67	%reg_of_regs = ();
	68
	69	for my $reg (@individual_regs) {
96577657	70	my @live_slots = grep { defined $_->{weakref} } values %$reg
218b7c12	71	or next;
cf8fa286	72
cf8fa286	73	$reg = {}; # get a fresh hashref in the new thread ctx
96577657	74	weaken( $reg_of_regs{hrefaddr($reg)} = $reg );
218b7c12	75
96577657	76	for my $slot_info (@live_slots) {
96577657	77	my $new_addr = hrefaddr $slot_info->{weakref};
8fa57d17	78
96577657	79	# replace all slot names
	80	$slot_info->{slot_names} = { map {
	81	my $name = $_;
	82	$name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
	83	($name => 1);
	84	} keys %{$slot_info->{slot_names}} };
218b7c12	85
96577657	86	$reg->{$new_addr} = $slot_info;
218b7c12	87	}
	88	}
	89	}
	90
556c4fe6	91	sub visit_refs {
	92	my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
	93
	94	$args->{seen_refs} \|\|= {};
	95
	96	my $visited_cnt = '0E0';
	97	for my $i (0 .. $#{$args->{refs}} ) {
556c4fe6	98
a42634cd	99	next unless length ref $args->{refs}[$i]; # not-a-ref
556c4fe6	100
a42634cd	101	my $addr = hrefaddr $args->{refs}[$i];
556c4fe6	102
6ae62c5c	103	# no diving into weakregistries
a42634cd	104	next if $reg_of_regs{$addr};
556c4fe6	105
a42634cd	106	next if $args->{seen_refs}{$addr}++;
556c4fe6	107	$visited_cnt++;
a42634cd	108
	109	my $r = $args->{refs}[$i];
	110
556c4fe6	111	$args->{action}->($r) or next;
556c4fe6	112
6ae62c5c	113	# This may end up being necessarry some day, but do not slow things
	114	# down for now
	115	#if ( defined( my $t = tied($r) ) ) {
	116	# $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
	117	#}
	118
a42634cd	119	my $type = reftype $r;
a42634cd	120
7664b1a0	121	local $@;
7664b1a0	122	eval {
7664b1a0	123	if ($type eq 'HASH') {
	124	$visited_cnt += visit_refs({ %$args, refs => [ map {
	125	( !isweak($r->{$_}) ) ? $r->{$_} : ()
	126	} keys %$r ] });
	127	}
	128	elsif ($type eq 'ARRAY') {
	129	$visited_cnt += visit_refs({ %$args, refs => [ map {
	130	( !isweak($r->[$_]) ) ? $r->[$_] : ()
	131	} 0..$#$r ] });
	132	}
	133	elsif ($type eq 'REF' and !isweak($$r)) {
	134	$visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
	135	}
	136	elsif (CV_TRACING and $type eq 'CODE') {
	137	$visited_cnt += visit_refs({ %$args, refs => [ map {
	138	( !isweak($_) ) ? $_ : ()
627d2b3d	139	} values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
7664b1a0	140	}
7664b1a0	141	1;
8433421f	142	} or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
556c4fe6	143	}
	144	$visited_cnt;
	145	}
	146
a42634cd	147	# compiles a list of addresses stored as globals (possibly even catching
	148	# class data in the form of method closures), so we can skip them further on
	149	sub symtable_referenced_addresses {
	150
	151	my $refs_per_pkg;
	152
a42634cd	153	my $seen_refs = {};
	154	visit_namespaces(
	155	action => sub {
556c4fe6	156
556c4fe6	157	no strict 'refs';
556c4fe6	158
a42634cd	159	my $pkg = shift;
a42634cd	160
556c4fe6	161	# the unless regex at the end skips some dangerous namespaces outright
556c4fe6	162	# (but does not prevent descent)
a42634cd	163	$refs_per_pkg->{$pkg} += visit_refs (
556c4fe6	164	seen_refs => $seen_refs,
a42634cd	165
627d2b3d	166	action => sub { 1 },
a42634cd	167
556c4fe6	168	refs => [ map { my $sym = $_;
2f48c52f	169	# *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
2f48c52f	170	( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),
556c4fe6	171
2f48c52f	172	( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
2f48c52f	173	? ${"${pkg}::$sym"} : ()
556c4fe6	174	,
a42634cd	175
556c4fe6	176	( map {
2f48c52f	177	( defined {"${pkg}::$sym"}{$_} and ! isweak(defined {"${pkg}::$sym"}{$_}) )
2f48c52f	178	? *{"${pkg}::$sym"}{$_}
556c4fe6	179	: ()
556c4fe6	180	} qw(HASH ARRAY IO GLOB) ),
a42634cd	181
2f48c52f	182	} keys %{"${pkg}::"} ],
2f48c52f	183	) unless $pkg =~ /^ (?:
556c4fe6	184	DB \| next \| B \| .+? ::::ISA (?: ::CACHE ) \| Class::C3
2f48c52f	185	) $/x;
a42634cd	186	}
a42634cd	187	);
556c4fe6	188
a42634cd	189	# use Devel::Dwarn;
	190	# Ddie [ map
	191	# { { $_ => $refs_per_pkg->{$_} } }
	192	# sort
	193	# {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
	194	# keys %$refs_per_pkg
	195	# ];
	196
	197	$seen_refs;
	198	}
	199
	200	sub assert_empty_weakregistry {
	201	my ($weak_registry, $quiet) = @_;
	202
	203	# in case we hooked bless any extra object creation will wreak
	204	# havoc during the assert phase
	205	local *CORE::GLOBAL::bless;
	206	*CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() ) };
	207
	208	croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
	209
	210	defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
	211	for keys %$weak_registry;
	212
	213	return unless keys %$weak_registry;
8fa57d17	214
a42634cd	215	my $tb = eval { Test::Builder->new }
a42634cd	216	or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";
8fa57d17	217
a42634cd	218	for my $addr (keys %$weak_registry) {
	219	$weak_registry->{$addr}{display_name} = join ' \| ', (
	220	sort
	221	{ length $a <=> length $b or $a cmp $b }
	222	keys %{$weak_registry->{$addr}{slot_names}}
	223	);
	224
	225	$tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
	226	if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
	227	}
	228
8d73fcd4	229	# the symtable walk is very expensive
	230	# if we are $quiet (running in an END block) we do not really need to be
	231	# that thorough - can get by with only %Sub::Quote::QUOTED
	232	delete $weak_registry->{$_} for $quiet
	233	? do {
	234	my $refs = {};
	235	visit_refs (
	236	# only look at the closed over stuffs
58fc8e62	237	refs => [ grep { length ref $_ } (
	238
	239	# old style Sub::Quote
	240	( map { values %{ $_->[2]} } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ),
	241
	242	# new style Sub::Quote
	243	( map { values %{ $_->{captures}} } grep { ref $_ eq 'HASH' } values %Sub::Quote::QUOTED ),
	244
	245	)],
8d73fcd4	246	seen_refs => $refs,
	247	action => sub { 1 },
	248	);
	249	keys %$refs;
	250	}
	251	: (
	252	# full sumtable walk, starting from ::
	253	keys %{ symtable_referenced_addresses() }
	254	)
	255	;
556c4fe6	256
96577657	257	for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {
96577657	258
1a44a267	259	next if ! defined $weak_registry->{$addr}{weakref};
1a44a267	260
5dc4301c	261	$leaks_found++ unless $tb->in_todo;
ee20ecfc	262	$tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");
1a44a267	263
	264	my $diag = do {
	265	local $Data::Dumper::Maxdepth = 1;
	266	sprintf "\n%s (refcnt %d) => %s\n",
	267	$weak_registry->{$addr}{display_name},
	268	refcount($weak_registry->{$addr}{weakref}),
	269	(
	270	ref($weak_registry->{$addr}{weakref}) eq 'CODE'
	271	and
	272	B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
	273	) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
	274	;
218b7c12	275	};
1a44a267	276
5dc4301c	277	# FIXME - need to add a circular reference seeker based on the visitor
	278	# (will need a bunch of modifications, punting with just a stub for now)
	279
556c4fe6	280	$diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
1a44a267	281	if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
	282
	283	$diag =~ s/^/ /mg;
	284
	285	if (my $stack = $weak_registry->{$addr}{stacktrace}) {
	286	$diag .= " Reference first seen$stack";
	287	}
	288
	289	$tb->diag($diag);
6ae62c5c	290
	291	# if ($leaks_found == 1) {
	292	# # using the fh dumper due to intermittent buffering issues
	293	# # in case we decide to exit soon after (possibly via _exit)
	294	# require Devel::MAT::Dumper;
	295	# local $Devel::MAT::Dumper::MAX_STRING = -1;
	296	# open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
	297	# Devel::MAT::Dumper::dumpfh( $fh );
	298	# close ($fh) or die $!;
	299	#
	300	# use POSIX;
	301	# POSIX::_exit(1);
	302	# }
1a44a267	303	}
1a44a267	304
5dc4301c	305	if (! $quiet and !$leaks_found and ! $tb->in_todo) {
1a44a267	306	$tb->ok(1, sprintf "No leaks found at %s line %d", (caller())[1,2] );
218b7c12	307	}
	308	}
	309
	310	END {
b77a61d8	311	if (
	312	$INC{'Test/Builder.pm'}
	313	and
	314	my $tb = do {
	315	local $@;
	316	my $t = eval { Test::Builder->new }
	317	or warn "Test::Builder->new failed:\n$@\n";
	318	$t;
	319	}
	320	) {
218b7c12	321	# we check for test passage - a leak may be a part of a TODO
	322	if ($leaks_found and !$tb->is_passing) {
	323
	324	$tb->diag(sprintf
	325	"\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
	326	. '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
	327	. "\n\n%s\n%s\n\n", ('#' x 16) x 4
	328	) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );
	329
	330	}
	331	else {
	332	$tb->note("Auto checked $refs_traced references for leaks - none detected");
	333	}
cbd7f87a	334
cbd7f87a	335	# also while we are here and not in plain runmode: make sure we never
cbd7f87a	336	# loaded any of the strictures XS bullshit (it's a leak in a sense)
8ab47674	337	unless (
	338	$ENV{MOO_FATAL_WARNINGS}
	339	or
	340	# FIXME - SQLT loads strictures explicitly, /facedesk
	341	# remove this INC check when 0fb58589 and 45287c815 are rectified
	342	$INC{'SQL/Translator.pm'}
	343	or
	344	DBICTest::RunMode->is_plain
	345	) {
2b2c98dd	346	for my $mod (qw(indirect multidimensional bareword::filehandles)) {
	347	( my $fn = "$mod.pm" ) =~ s\|::\|/\|g;
	348
	349	$tb->ok(0, "Load of '$mod' should not have been attempted!!!" )
	350	if exists $INC{$fn};
cbd7f87a	351	}
cbd7f87a	352	}
218b7c12	353	}
	354	}
	355
	356	1;