[dbsrgits/DBIx-Class.git] / t / 752sqlite.t

use strict;
use warnings;

use Test::More;
use Test::Exception;
use Test::Warn;
use Time::HiRes 'time';
use Math::BigInt;

use lib qw(t/lib);
use DBICTest;
use DBIx::Class::_Util qw(sigwarn_silencer modver_gt_or_eq);

# savepoints test
{
  my $schema = DBICTest->init_schema(auto_savepoint => 1);

  my $ars = $schema->resultset('Artist');

  # test two-phase commit and inner transaction rollback from nested transactions
  $schema->txn_do(sub {
    $ars->create({ name => 'in_outer_transaction' });
    $schema->txn_do(sub {
      $ars->create({ name => 'in_inner_transaction' });
    });
    ok($ars->search({ name => 'in_inner_transaction' })->first,
      'commit from inner transaction visible in outer transaction');
    throws_ok {
      $schema->txn_do(sub {
        $ars->create({ name => 'in_inner_transaction_rolling_back' });
        die 'rolling back inner transaction';
      });
    } qr/rolling back inner transaction/, 'inner transaction rollback executed';
    $ars->create({ name => 'in_outer_transaction2' });
  });

  ok($ars->search({ name => 'in_outer_transaction' })->first,
    'commit from outer transaction');
  ok($ars->search({ name => 'in_outer_transaction2' })->first,
    'second commit from outer transaction');
  ok($ars->search({ name => 'in_inner_transaction' })->first,
    'commit from inner transaction');
  is $ars->search({ name => 'in_inner_transaction_rolling_back' })->first,
    undef,
    'rollback from inner transaction';
}

# check that we work somewhat OK with braindead SQLite transaction handling
#
# As per https://metacpan.org/source/ADAMK/DBD-SQLite-1.37/lib/DBD/SQLite.pm#L921
# SQLite does *not* try to synchronize
#
# However DBD::SQLite 1.38_02 seems to fix this, with an accompanying test:
# https://metacpan.org/source/ADAMK/DBD-SQLite-1.38_02/t/54_literal_txn.t

my $lit_txn_todo = modver_gt_or_eq('DBD::SQLite', '1.38_02')
  ? undef
  : "DBD::SQLite before 1.38_02 is retarded wrt detecting literal BEGIN/COMMIT statements"
;

for my $prefix_comment (qw/Begin_only Commit_only Begin_and_Commit/) {
  note "Testing with comment prefixes on $prefix_comment";

  # FIXME warning won't help us for the time being
  # perhaps when (if ever) DBD::SQLite gets fixed,
  # we can do something extra here
  local $SIG{__WARN__} = sigwarn_silencer( qr/Internal transaction state .+? does not seem to match/ )
    if ( $lit_txn_todo && !$ENV{TEST_VERBOSE} );

  my ($c_begin, $c_commit) = map { $prefix_comment =~ $_ ? 1 : 0 } (qr/Begin/, qr/Commit/);

  my $schema = DBICTest->init_schema( no_deploy => 1 );
  my $ars = $schema->resultset('Artist');

  ok (! $schema->storage->connected, 'No connection yet');

  $schema->storage->dbh->do(<<'DDL');
CREATE TABLE artist (
  artistid INTEGER PRIMARY KEY NOT NULL,
  name varchar(100),
  rank integer DEFAULT 13,
  charfield char(10) NULL
);
DDL

  my $artist = $ars->create({ name => 'Artist_' . time() });
  is ($ars->count, 1, 'Inserted artist ' . $artist->name);

  ok ($schema->storage->connected, 'Connected');
  ok ($schema->storage->_dbh->{AutoCommit}, 'DBD not in txn yet');

  $schema->storage->dbh->do(join "\n",
    $c_begin ? '-- comment' : (),
    'BEGIN TRANSACTION'
  );
  ok ($schema->storage->connected, 'Still connected');
  {
    local $TODO = $lit_txn_todo if $c_begin;
    ok (! $schema->storage->_dbh->{AutoCommit}, "DBD aware of txn begin with comments on $prefix_comment");
  }

  $schema->storage->dbh->do(join "\n",
    $c_commit ? '-- comment' : (),
    'COMMIT'
  );
  ok ($schema->storage->connected, 'Still connected');
  {
    local $TODO = $lit_txn_todo if $c_commit and ! $c_begin;
    ok ($schema->storage->_dbh->{AutoCommit}, "DBD aware txn ended with comments on $prefix_comment");
  }

  is ($ars->count, 1, 'Inserted artists still there');

  {
    # this never worked in the 1st place
    local $TODO = $lit_txn_todo if ! $c_begin and $c_commit;

    # odd argument passing, because such nested crefs leak on 5.8
    lives_ok {
      $schema->storage->txn_do (sub {
        ok ($_[0]->find({ name => $_[1] }), "Artist still where we left it after cycle with comments on $prefix_comment");
      }, $ars, $artist->name );
    } "Succesfull transaction with comments on $prefix_comment";
  }
}


my $schema = DBICTest->init_schema();

# make sure the side-effects of RT#67581 do not result in data loss
my $row;
warnings_exist { $row = $schema->resultset('Artist')->create ({ name => 'alpha rank', rank => 'abc' }) }
  [qr/Non-integer value supplied for column 'rank' despite the integer datatype/],
  'proper warning on string insertion into an numeric column'
;
$row->discard_changes;
is ($row->rank, 'abc', 'proper rank inserted into database');

# and make sure we do not lose actual bigints
{
  package DBICTest::BigIntArtist;
  use base 'DBICTest::Schema::Artist';
  __PACKAGE__->table('artist');
  __PACKAGE__->add_column(bigint => { data_type => 'bigint' });
}
$schema->register_class(BigIntArtist => 'DBICTest::BigIntArtist');
$schema->storage->dbh_do(sub {
  $_[1]->do('ALTER TABLE artist ADD COLUMN bigint BIGINT');
});

my $sqlite_broken_bigint = (
  modver_gt_or_eq('DBD::SQLite', '1.34') and ! modver_gt_or_eq('DBD::SQLite', '1.37')
);

# 63 bit integer
my $many_bits = (Math::BigInt->new(2) ** 62);

# test upper/lower boundaries for sqlite and some values inbetween
# range is -(2**63) .. 2**63 - 1
#
# Not testing -0 - it seems to overflow to ~0 on some combinations,
# thus not triggering the >32 bit guards
# interesting read: https://en.wikipedia.org/wiki/Signed_zero#Representations
for my $bi ( qw(
  -2
  -1
  0
  +0
  1
  2

  -9223372036854775808
  -9223372036854775807
  -8694837494948124658
  -6848440844435891639
  -5664812265578554454
  -5380388020020483213
  -2564279463598428141
  2442753333597784273
  4790993557925631491
  6773854980030157393
  7627910776496326154
  8297530189347439311
  9223372036854775806
  9223372036854775807

  4294967295
  4294967296

  -4294967296
  -4294967295
  -4294967294

  -2147483649
  -2147483648
  -2147483647
  -2147483646

  2147483646
  2147483647
),
  # these values cause exceptions even with all workarounds in place on these
  # fucked DBD::SQLite versions *regardless* of ivsize >.<
  $sqlite_broken_bigint
    ? ()
    : ( '2147483648', '2147483649' )
) {
  # unsigned 32 bit ints have a range of −2,147,483,648 to 2,147,483,647
  # alternatively expressed as the hexadecimal numbers below
  # the comparison math will come out right regardless of ivsize, since
  # we are operating within 31 bits
  # P.S. 31 because one bit is lost for the sign
  my $v_bits = ($bi > 0x7fff_ffff || $bi < -0x8000_0000) ? 64 : 32;

  my $v_desc = sprintf '%s (%d bit signed int)', $bi, $v_bits;

  my @w;
  local $SIG{__WARN__} = sub { $_[0] =~ /datatype mismatch/ ? push @w, @_ : warn @_ };

  # some combinations of SQLite 1.35 and older 5.8 faimly is wonky
  # instead of a warning we get a full exception. Sod it
  eval {
    $row = $schema->resultset('BigIntArtist')->create({ bigint => $bi });
  } or do {
    fail("Exception on inserting $v_desc") unless $sqlite_broken_bigint;
    next;
  };

  # explicitly using eq, to make sure we did not nummify the argument
  # which can be an issue on 32 bit ivsize
  cmp_ok ($row->bigint, 'eq', $bi, "value in object correct ($v_desc)");

  $row->discard_changes;

  cmp_ok (
    $row->bigint,

    # the test will not pass an == if we are running under 32 bit ivsize
    # use 'eq' on the numified (and possibly "scientificied") returned value
    (DBIx::Class::_ENV_::IV_SIZE < 8 and $v_bits > 32) ? 'eq' : '==',

    # in 1.37 DBD::SQLite switched to proper losless representation of bigints
    # regardless of ivize
    # before this use 'eq' (from above) on the numified (and possibly
    # "scientificied") returned value
    (DBIx::Class::_ENV_::IV_SIZE < 8 and ! modver_gt_or_eq('DBD::SQLite', '1.37')) ? $bi+0 : $bi,

    "value in database correct ($v_desc)"
  );

# FIXME - temporary smoke-only escape
SKIP: {
  skip 'Potential for false negatives - investigation pending', 1
    if DBICTest::RunMode->is_plain;

  # check if math works
  # start by adding/subtracting a 50 bit integer, and then divide by 2 for good measure
  my ($sqlop, $expect) = $bi < 0
    ? ( '(bigint + ? )', ($bi + $many_bits) )
    : ( '(bigint - ? )', ($bi - $many_bits) )
  ;

  $expect = ($expect + ($expect % 2)) / 2;

  # read https://en.wikipedia.org/wiki/Modulo_operation#Common_pitfalls
  # and check the tables on the right side of the article for an
  # enlightening journey on why a mere bigint % 2 won't work
  $sqlop = "( $sqlop + ( ((bigint % 2)+2)%2 ) ) / 2";

  for my $dtype (undef, \'int', \'bigint') {

    # FIXME - the double-load should not be needed
    # will fix in the future
    $row->update({ bigint => $bi });
    $row->discard_changes;
    $row->update({ bigint => \[ $sqlop, [ $dtype => $many_bits ] ] });
    $row->discard_changes;

    # can't use cmp_ok - will not engage the M::BI overload of $many_bits
    ok (
      $row->bigint

      ==

      (DBIx::Class::_ENV_::IV_SIZE < 8 and ! modver_gt_or_eq('DBD::SQLite', '1.37')) ? $expect->bstr + 0 : $expect
    , "simple integer math with@{[ $dtype ? '' : 'out' ]} bindtype in database correct (base $v_desc)")
      or diag sprintf '%s != %s', $row->bigint, $expect;
  }
# end of fixme
}

  is_deeply (\@w, [], "No mismatch warnings on bigint operations ($v_desc)" );
}

done_testing;

# vim:sts=2 sw=2:
Commit	Line	Data
86a51471	1	use strict;
	2	use warnings;
	3
	4	use Test::More;
	5	use Test::Exception;
632d1e0f	6	use Test::Warn;
2aeb3c7f	7	use Time::HiRes 'time';
f3b1224b	8	use Math::BigInt;
67b35a45	9
86a51471	10	use lib qw(t/lib);
86a51471	11	use DBICTest;
052a832c	12	use DBIx::Class::_Util qw(sigwarn_silencer modver_gt_or_eq);
86a51471	13
67b35a45	14	# savepoints test
	15	{
	16	my $schema = DBICTest->init_schema(auto_savepoint => 1);
86a51471	17
67b35a45	18	my $ars = $schema->resultset('Artist');
86a51471	19
67b35a45	20	# test two-phase commit and inner transaction rollback from nested transactions
86a51471	21	$schema->txn_do(sub {
67b35a45	22	$ars->create({ name => 'in_outer_transaction' });
86a51471	23	$schema->txn_do(sub {
67b35a45	24	$ars->create({ name => 'in_inner_transaction' });
86a51471	25	});
67b35a45	26	ok($ars->search({ name => 'in_inner_transaction' })->first,
	27	'commit from inner transaction visible in outer transaction');
	28	throws_ok {
	29	$schema->txn_do(sub {
	30	$ars->create({ name => 'in_inner_transaction_rolling_back' });
	31	die 'rolling back inner transaction';
	32	});
	33	} qr/rolling back inner transaction/, 'inner transaction rollback executed';
	34	$ars->create({ name => 'in_outer_transaction2' });
	35	});
	36
	37	ok($ars->search({ name => 'in_outer_transaction' })->first,
	38	'commit from outer transaction');
	39	ok($ars->search({ name => 'in_outer_transaction2' })->first,
	40	'second commit from outer transaction');
	41	ok($ars->search({ name => 'in_inner_transaction' })->first,
	42	'commit from inner transaction');
	43	is $ars->search({ name => 'in_inner_transaction_rolling_back' })->first,
	44	undef,
	45	'rollback from inner transaction';
	46	}
632d1e0f	47
2aeb3c7f	48	# check that we work somewhat OK with braindead SQLite transaction handling
	49	#
	50	# As per https://metacpan.org/source/ADAMK/DBD-SQLite-1.37/lib/DBD/SQLite.pm#L921
	51	# SQLite does not try to synchronize
ab0b0a09	52	#
	53	# However DBD::SQLite 1.38_02 seems to fix this, with an accompanying test:
	54	# https://metacpan.org/source/ADAMK/DBD-SQLite-1.38_02/t/54_literal_txn.t
	55
b1dbf716	56	my $lit_txn_todo = modver_gt_or_eq('DBD::SQLite', '1.38_02')
ab0b0a09	57	? undef
	58	: "DBD::SQLite before 1.38_02 is retarded wrt detecting literal BEGIN/COMMIT statements"
	59	;
2aeb3c7f	60
	61	for my $prefix_comment (qw/Begin_only Commit_only Begin_and_Commit/) {
	62	note "Testing with comment prefixes on $prefix_comment";
	63
	64	# FIXME warning won't help us for the time being
	65	# perhaps when (if ever) DBD::SQLite gets fixed,
	66	# we can do something extra here
052a832c	67	local $SIG{__WARN__} = sigwarn_silencer( qr/Internal transaction state .+? does not seem to match/ )
ab0b0a09	68	if ( $lit_txn_todo && !$ENV{TEST_VERBOSE} );
2aeb3c7f	69
	70	my ($c_begin, $c_commit) = map { $prefix_comment =~ $_ ? 1 : 0 } (qr/Begin/, qr/Commit/);
	71
	72	my $schema = DBICTest->init_schema( no_deploy => 1 );
	73	my $ars = $schema->resultset('Artist');
	74
	75	ok (! $schema->storage->connected, 'No connection yet');
	76
	77	$schema->storage->dbh->do(<<'DDL');
	78	CREATE TABLE artist (
	79	artistid INTEGER PRIMARY KEY NOT NULL,
	80	name varchar(100),
	81	rank integer DEFAULT 13,
	82	charfield char(10) NULL
	83	);
	84	DDL
	85
	86	my $artist = $ars->create({ name => 'Artist_' . time() });
	87	is ($ars->count, 1, 'Inserted artist ' . $artist->name);
	88
	89	ok ($schema->storage->connected, 'Connected');
	90	ok ($schema->storage->_dbh->{AutoCommit}, 'DBD not in txn yet');
	91
	92	$schema->storage->dbh->do(join "\n",
	93	$c_begin ? '-- comment' : (),
	94	'BEGIN TRANSACTION'
	95	);
	96	ok ($schema->storage->connected, 'Still connected');
	97	{
ab0b0a09	98	local $TODO = $lit_txn_todo if $c_begin;
2aeb3c7f	99	ok (! $schema->storage->_dbh->{AutoCommit}, "DBD aware of txn begin with comments on $prefix_comment");
	100	}
	101
	102	$schema->storage->dbh->do(join "\n",
	103	$c_commit ? '-- comment' : (),
	104	'COMMIT'
	105	);
	106	ok ($schema->storage->connected, 'Still connected');
	107	{
ab0b0a09	108	local $TODO = $lit_txn_todo if $c_commit and ! $c_begin;
2aeb3c7f	109	ok ($schema->storage->_dbh->{AutoCommit}, "DBD aware txn ended with comments on $prefix_comment");
	110	}
	111
	112	is ($ars->count, 1, 'Inserted artists still there');
	113
	114	{
	115	# this never worked in the 1st place
ab0b0a09	116	local $TODO = $lit_txn_todo if ! $c_begin and $c_commit;
2aeb3c7f	117
08615cfb	118	# odd argument passing, because such nested crefs leak on 5.8
2aeb3c7f	119	lives_ok {
2aeb3c7f	120	$schema->storage->txn_do (sub {
08615cfb	121	ok ($_[0]->find({ name => $_[1] }), "Artist still where we left it after cycle with comments on $prefix_comment");
08615cfb	122	}, $ars, $artist->name );
2aeb3c7f	123	} "Succesfull transaction with comments on $prefix_comment";
	124	}
	125	}
	126
	127
67b35a45	128	my $schema = DBICTest->init_schema();
86a51471	129
632d1e0f	130	# make sure the side-effects of RT#67581 do not result in data loss
632d1e0f	131	my $row;
67b35a45	132	warnings_exist { $row = $schema->resultset('Artist')->create ({ name => 'alpha rank', rank => 'abc' }) }
445bc0cd	133	[qr/Non-integer value supplied for column 'rank' despite the integer datatype/],
632d1e0f	134	'proper warning on string insertion into an numeric column'
	135	;
	136	$row->discard_changes;
	137	is ($row->rank, 'abc', 'proper rank inserted into database');
	138
67b35a45	139	# and make sure we do not lose actual bigints
	140	{
	141	package DBICTest::BigIntArtist;
	142	use base 'DBICTest::Schema::Artist';
	143	__PACKAGE__->table('artist');
	144	__PACKAGE__->add_column(bigint => { data_type => 'bigint' });
	145	}
	146	$schema->register_class(BigIntArtist => 'DBICTest::BigIntArtist');
	147	$schema->storage->dbh_do(sub {
	148	$_[1]->do('ALTER TABLE artist ADD COLUMN bigint BIGINT');
	149	});
	150
f3b1224b	151	my $sqlite_broken_bigint = (
	152	modver_gt_or_eq('DBD::SQLite', '1.34') and ! modver_gt_or_eq('DBD::SQLite', '1.37')
	153	);
	154
	155	# 63 bit integer
	156	my $many_bits = (Math::BigInt->new(2) ** 62);
	157
67b35a45	158	# test upper/lower boundaries for sqlite and some values inbetween
67b35a45	159	# range is -(263) .. 263 - 1
f3b1224b	160	#
	161	# Not testing -0 - it seems to overflow to ~0 on some combinations,
	162	# thus not triggering the >32 bit guards
	163	# interesting read: https://en.wikipedia.org/wiki/Signed_zero#Representations
04ab4eb1	164	for my $bi ( qw(
f3b1224b	165	-2
	166	-1
	167	0
	168	+0
	169	1
	170	2
	171
04ab4eb1	172	-9223372036854775808
	173	-9223372036854775807
	174	-8694837494948124658
	175	-6848440844435891639
	176	-5664812265578554454
	177	-5380388020020483213
	178	-2564279463598428141
	179	2442753333597784273
	180	4790993557925631491
	181	6773854980030157393
	182	7627910776496326154
	183	8297530189347439311
	184	9223372036854775806
	185	9223372036854775807
	186
	187	4294967295
	188	4294967296
	189
	190	-4294967296
	191	-4294967295
	192	-4294967294
	193
	194	-2147483649
	195	-2147483648
	196	-2147483647
	197	-2147483646
	198
	199	2147483646
	200	2147483647
	201	),
	202	# these values cause exceptions even with all workarounds in place on these
	203	# fucked DBD::SQLite versions regardless of ivsize >.<
f3b1224b	204	$sqlite_broken_bigint
04ab4eb1	205	? ()
	206	: ( '2147483648', '2147483649' )
	207	) {
	208	# unsigned 32 bit ints have a range of −2,147,483,648 to 2,147,483,647
	209	# alternatively expressed as the hexadecimal numbers below
	210	# the comparison math will come out right regardless of ivsize, since
	211	# we are operating within 31 bits
	212	# P.S. 31 because one bit is lost for the sign
	213	my $v_bits = ($bi > 0x7fff_ffff \|\| $bi < -0x8000_0000) ? 64 : 32;
	214
	215	my $v_desc = sprintf '%s (%d bit signed int)', $bi, $v_bits;
	216
1363f0f5	217	my @w;
	218	local $SIG{__WARN__} = sub { $_[0] =~ /datatype mismatch/ ? push @w, @_ : warn @_ };
	219
f3b1224b	220	# some combinations of SQLite 1.35 and older 5.8 faimly is wonky
	221	# instead of a warning we get a full exception. Sod it
	222	eval {
2e092442	223	$row = $schema->resultset('BigIntArtist')->create({ bigint => $bi });
f3b1224b	224	} or do {
	225	fail("Exception on inserting $v_desc") unless $sqlite_broken_bigint;
	226	next;
	227	};
04ab4eb1	228
	229	# explicitly using eq, to make sure we did not nummify the argument
	230	# which can be an issue on 32 bit ivsize
	231	cmp_ok ($row->bigint, 'eq', $bi, "value in object correct ($v_desc)");
	232
	233	$row->discard_changes;
	234
	235	cmp_ok (
	236	$row->bigint,
	237
	238	# the test will not pass an == if we are running under 32 bit ivsize
	239	# use 'eq' on the numified (and possibly "scientificied") returned value
f3b1224b	240	(DBIx::Class::_ENV_::IV_SIZE < 8 and $v_bits > 32) ? 'eq' : '==',
04ab4eb1	241
	242	# in 1.37 DBD::SQLite switched to proper losless representation of bigints
	243	# regardless of ivize
	244	# before this use 'eq' (from above) on the numified (and possibly
	245	# "scientificied") returned value
	246	(DBIx::Class::_ENV_::IV_SIZE < 8 and ! modver_gt_or_eq('DBD::SQLite', '1.37')) ? $bi+0 : $bi,
	247
	248	"value in database correct ($v_desc)"
	249	);
1363f0f5	250
f3b1224b	251	# FIXME - temporary smoke-only escape
	252	SKIP: {
	253	skip 'Potential for false negatives - investigation pending', 1
	254	if DBICTest::RunMode->is_plain;
	255
	256	# check if math works
	257	# start by adding/subtracting a 50 bit integer, and then divide by 2 for good measure
	258	my ($sqlop, $expect) = $bi < 0
	259	? ( '(bigint + ? )', ($bi + $many_bits) )
	260	: ( '(bigint - ? )', ($bi - $many_bits) )
	261	;
	262
	263	$expect = ($expect + ($expect % 2)) / 2;
	264
	265	# read https://en.wikipedia.org/wiki/Modulo_operation#Common_pitfalls
	266	# and check the tables on the right side of the article for an
	267	# enlightening journey on why a mere bigint % 2 won't work
	268	$sqlop = "( $sqlop + ( ((bigint % 2)+2)%2 ) ) / 2";
	269
	270	for my $dtype (undef, \'int', \'bigint') {
	271
	272	# FIXME - the double-load should not be needed
	273	# will fix in the future
	274	$row->update({ bigint => $bi });
	275	$row->discard_changes;
	276	$row->update({ bigint => \[ $sqlop, [ $dtype => $many_bits ] ] });
	277	$row->discard_changes;
	278
	279	# can't use cmp_ok - will not engage the M::BI overload of $many_bits
	280	ok (
	281	$row->bigint
	282
	283	==
	284
	285	(DBIx::Class::_ENV_::IV_SIZE < 8 and ! modver_gt_or_eq('DBD::SQLite', '1.37')) ? $expect->bstr + 0 : $expect
	286	, "simple integer math with@{[ $dtype ? '' : 'out' ]} bindtype in database correct (base $v_desc)")
	287	or diag sprintf '%s != %s', $row->bigint, $expect;
	288	}
	289	# end of fixme
	290	}
	291
	292	is_deeply (\@w, [], "No mismatch warnings on bigint operations ($v_desc)" );
67b35a45	293	}
67b35a45	294
86a51471	295	done_testing;
	296
	297	# vim:sts=2 sw=2: