Revert r482[45], by implementing a better version of r4760

[dbsrgits/DBIx-Class.git] / t / 68inflate_resultclass_hashrefinflator.t

use strict;
use warnings;  

use Test::More qw(no_plan);
use lib qw(t/lib);
use Scalar::Util qw/blessed/;
use DateTime;
use DBICTest;
use DBIx::Class::ResultClass::HashRefInflator;
my $schema = DBICTest->init_schema();


# Under some versions of SQLite if the $rs is left hanging around it will lock
# So we create a scope here cos I'm lazy
{
    my $rs = $schema->resultset('CD');

    # get the defined columns
    my @dbic_cols = sort $rs->result_source->columns;

    # use the hashref inflator class as result class
    $rs->result_class('DBIx::Class::ResultClass::HashRefInflator');

    # fetch first record
    my $datahashref1 = $rs->first;

    my @hashref_cols = sort keys %$datahashref1;

    is_deeply( \@dbic_cols, \@hashref_cols, 'returned columns' );
}


sub check_cols_of {
    my ($dbic_obj, $datahashref) = @_;
    
    foreach my $col (keys %$datahashref) {
        # plain column
        if (not ref ($datahashref->{$col}) ) {
            is ($datahashref->{$col}, $dbic_obj->get_column($col), 'same value');
        }
        # related table entry (belongs_to)
        elsif (ref ($datahashref->{$col}) eq 'HASH') {
            check_cols_of($dbic_obj->$col, $datahashref->{$col});
        }
        # multiple related entries (has_many)
        elsif (ref ($datahashref->{$col}) eq 'ARRAY') {
            my @dbic_reltable = $dbic_obj->$col;
            my @hashref_reltable = @{$datahashref->{$col}};
  
            is (scalar @hashref_reltable, scalar @dbic_reltable, 'number of related entries');

            # for my $index (0..scalar @hashref_reltable) {
            for my $index (0..scalar @dbic_reltable) {
                my $dbic_reltable_obj       = $dbic_reltable[$index];
                my $hashref_reltable_entry  = $hashref_reltable[$index];
                
                check_cols_of($dbic_reltable_obj, $hashref_reltable_entry);
            }
        }
    }
}

# create a cd without tracks for testing empty has_many relationship
$schema->resultset('CD')->create({ title => 'Silence is golden', artist => 3, year => 2006 });

# order_by to ensure both resultsets have the rows in the same order
my $rs_dbic = $schema->resultset('CD')->search(undef,
    {
        prefetch    => [ qw/ artist tracks / ],
        order_by    => [ 'me.cdid', 'tracks.position' ],
    }
);
my $rs_hashrefinf = $schema->resultset('CD')->search(undef,
    {
        prefetch    => [ qw/ artist tracks / ],
        order_by    => [ 'me.cdid', 'tracks.position' ],
    }
);
$rs_hashrefinf->result_class('DBIx::Class::ResultClass::HashRefInflator');

my @dbic        = $rs_dbic->all;
my @hashrefinf  = $rs_hashrefinf->all;

for my $index (0 .. $#hashrefinf) {
    my $dbic_obj    = $dbic[$index];
    my $datahashref = $hashrefinf[$index];

    check_cols_of($dbic_obj, $datahashref);
}

# sometimes for ultra-mega-speed you want to fetch columns in esoteric ways
# check the inflator over a non-fetching join 
$rs_dbic = $schema->resultset ('Artist')->search ({ 'me.artistid' => 1}, {
    prefetch => { cds => 'tracks' },
    order_by => [qw/cds.cdid tracks.trackid/],
});

$rs_hashrefinf = $schema->resultset ('Artist')->search ({ 'me.artistid' => 1}, {
    join     => { cds => 'tracks' },
    select   => [qw/name   tracks.title      tracks.cd       /],
    as       => [qw/name   cds.tracks.title  cds.tracks.cd   /],
    order_by => [qw/cds.cdid tracks.trackid/],
});
$rs_hashrefinf->result_class('DBIx::Class::ResultClass::HashRefInflator');

@dbic = map { $_->tracks->all } ($rs_dbic->first->cds->all);
@hashrefinf  = $rs_hashrefinf->all;

is (scalar @dbic, scalar @hashrefinf, 'Equal number of tracks fetched');

for my $index (0 .. $#hashrefinf) {
    my $track       = $dbic[$index];
    my $datahashref = $hashrefinf[$index];

    is ($track->cd->artist->name, $datahashref->{name}, 'Brought back correct artist');
    for my $col (keys %{$datahashref->{cds}{tracks}}) {
        is ($track->get_column ($col), $datahashref->{cds}{tracks}{$col}, "Correct track '$col'");
    }
}

# Test the data inflator

is_deeply (
    DBIx::Class::ResultClass::HashRefInflator->new (inflate_columns => 1),
    DBIx::Class::ResultClass::HashRefInflator->new ({inflate_columns => 1}),
    'Make sure arguments as list and as hashref work identically'
);

$schema->class('CD')->inflate_column( 'year',
    { inflate => sub { DateTime->new( year => shift ) },
      deflate => sub { shift->year } }
);

my $cd_rs = $schema->resultset("CD")->search ({cdid => 3});
$cd_rs->result_class('DBIx::Class::ResultClass::HashRefInflator');

my $cd = $cd_rs->first;
ok ( (not blessed $cd->{year}), "Plain string returned for year");
is ( $cd->{year}, '1997', "We are looking at the right year");

# try again with a HRI instance
$cd_rs->reset;
$cd_rs->result_class(DBIx::Class::ResultClass::HashRefInflator->new);
my $cd2 = $cd_rs->first;
is_deeply ($cd, $cd2, "HRI used as instance returns the same hashref as the old result_class ('class')");

# try it again with inflation requested
$cd_rs->reset;
$cd_rs->result_class(DBIx::Class::ResultClass::HashRefInflator->new (inflate_columns => 1));
my $cd3 = $cd_rs->first;
isa_ok ($cd3->{year}, 'DateTime', "Inflated object");
is ($cd3->{year}, DateTime->new ( year => 1997 ), "Correct year was inflated");