[dbsrgits/DBIx-Class.git] / lib / SQL / Translator / Parser / DBIx / Class.pm

package SQL::Translator::Parser::DBIx::Class;

# AUTHOR: Jess Robinson

# Some mistakes the fault of Matt S Trout

# Others the fault of Ash Berlin

use strict;
use warnings;
use vars qw($DEBUG $VERSION @EXPORT_OK);
$VERSION = '1.10';
$DEBUG = 0 unless defined $DEBUG;

use Exporter;
use SQL::Translator::Utils qw(debug normalize_name);
use Carp::Clan qw/^SQL::Translator|^DBIx::Class/;
use Scalar::Util ();

use base qw(Exporter);

@EXPORT_OK = qw(parse);

# -------------------------------------------------------------------
# parse($tr, $data)
#
# setting parser_args => { add_fk_index => 0 } will prevent
# the auto-generation of an index for each FK.
#
# Note that $data, in the case of this parser, is not useful.
# We're working with DBIx::Class Schemas, not data streams.
# -------------------------------------------------------------------
sub parse {
    # this is a hack to prevent schema leaks due to a retarded SQLT implementation
    # DO NOT REMOVE (until SQLT2 is out, the all of this will be rewritten anyway)
    Scalar::Util::weaken ($_[1]);

    my ($tr, $data)   = @_;
    my $args          = $tr->parser_args;
    my $dbicschema    = $args->{'DBIx::Class::Schema'} ||  $args->{"DBIx::Schema"} ||$data;
    $dbicschema     ||= $args->{'package'};
    my $limit_sources = $args->{'sources'};

    croak 'No DBIx::Class::Schema' unless ($dbicschema);
    if (!ref $dbicschema) {
      eval "use $dbicschema;";
      croak "Can't load $dbicschema ($@)" if($@);
    }

    my $schema      = $tr->schema;
    my $table_no    = 0;

    $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
      unless ($schema->name);

    my @monikers = sort $dbicschema->sources;
    if ($limit_sources) {
        my $ref = ref $limit_sources || '';
        $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
          unless( $ref eq 'ARRAY' || ref eq 'HASH' );

        # limit monikers to those specified in 
        my $sources;
        if ($ref eq 'ARRAY') {
            $sources->{$_} = 1 for (@$limit_sources);
        } else {
            $sources = $limit_sources;
        }
        @monikers = grep { $sources->{$_} } @monikers;
    }


    my(%table_monikers, %view_monikers);
    for my $moniker (@monikers){
      my $source = $dbicschema->source($moniker);
       if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
         $table_monikers{$moniker}++;
      } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
          next if $source->is_virtual;
         $view_monikers{$moniker}++;
      }
    }

    my %tables;
    foreach my $moniker (sort keys %table_monikers)
    {
        my $source = $dbicschema->source($moniker);
        my $table_name = $source->name;

        # FIXME - this isn't the right way to do it, but sqlt does not
        # support quoting properly to be signaled about this
        $table_name = $$table_name if ref $table_name eq 'SCALAR';

        # It's possible to have multiple DBIC sources using the same table
        next if $tables{$table_name};

        $tables{$table_name}{source} = $source;
        my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
                                       name => $table_name,
                                       type => 'TABLE',
                                       );
        foreach my $col ($source->columns)
        {
            # assuming column_info in dbic is the same as DBI (?)
            # data_type is a number, column_type is text?
            my %colinfo = (
              name => $col,
              size => 0,
              is_auto_increment => 0,
              is_foreign_key => 0,
              is_nullable => 0,
              %{$source->column_info($col)}
            );
            if ($colinfo{is_nullable}) {
              $colinfo{default} = '' unless exists $colinfo{default};
            }
            my $f = $table->add_field(%colinfo)
              || $dbicschema->throw_exception ($table->error);
        }

        my @primary = $source->primary_columns;

        $table->primary_key(@primary) if @primary;

        my %unique_constraints = $source->unique_constraints;
        foreach my $uniq (sort keys %unique_constraints) {
            if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
                $table->add_constraint(
                            type             => 'unique',
                            name             => $uniq,
                            fields           => $unique_constraints{$uniq}
                );
            }
        }

        my @rels = $source->relationships();

        my %created_FK_rels;

        # global add_fk_index set in parser_args
        my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;

        foreach my $rel (sort @rels)
        {

            my $rel_info = $source->relationship_info($rel);

            # Ignore any rel cond that isn't a straight hash
            next unless ref $rel_info->{cond} eq 'HASH';

            my $relsource = $source->related_source($rel);

            # related sources might be excluded via a {sources} filter or might be views
            next unless exists $table_monikers{$relsource->source_name};

            my $rel_table = $relsource->name;

            # FIXME - this isn't the right way to do it, but sqlt does not
            # support quoting properly to be signaled about this
            $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';

            my $reverse_rels = $source->reverse_relationship_info($rel);
            my ($otherrelname, $otherrelationship) = each %{$reverse_rels};

            # Force the order of @cond to match the order of ->add_columns
            my $idx;
            my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
            my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}}); 

            # Get the key information, mapping off the foreign/self markers
            my @refkeys = map {/^\w+\.(\w+)$/} @cond;
            my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;

            # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
            my $fk_constraint;

            #first it can be specified explicitly
            if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
                $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
            }
            # it can not be multi
            elsif ( $rel_info->{attrs}{accessor}
                    && $rel_info->{attrs}{accessor} eq 'multi' ) {
                $fk_constraint = 0;
            }
            # if indeed single, check if all self.columns are our primary keys.
            # this is supposed to indicate a has_one/might_have...
            # where's the introspection!!?? :)
            else {
                $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
            }

            my $cascade;
            for my $c (qw/delete update/) {
                if (exists $rel_info->{attrs}{"on_$c"}) {
                    if ($fk_constraint) {
                        $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
                    }
                    elsif ( $rel_info->{attrs}{"on_$c"} ) {
                        carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
                            . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
                    }
                }
                elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
                    $cascade->{$c} = 'CASCADE';
                }
            }

            if($rel_table)
            {
                # Constraints are added only if applicable
                next unless $fk_constraint;

                # Make sure we dont create the same foreign key constraint twice
                my $key_test = join("\x00", sort @keys);
                next if $created_FK_rels{$rel_table}->{$key_test};

                if (scalar(@keys)) {

                  $created_FK_rels{$rel_table}->{$key_test} = 1;

                  my $is_deferrable = $rel_info->{attrs}{is_deferrable};

                  # calculate dependencies: do not consider deferrable constraints and
                  # self-references for dependency calculations
                  if (! $is_deferrable and $rel_table ne $table_name) {
                    $tables{$table_name}{foreign_table_deps}{$rel_table}++;
                  }

                  $table->add_constraint(
                                    type             => 'foreign_key',
                                    name             => join('_', $table_name, 'fk', @keys),
                                    fields           => \@keys,
                                    reference_fields => \@refkeys,
                                    reference_table  => $rel_table,
                                    on_delete        => uc ($cascade->{delete} || ''),
                                    on_update        => uc ($cascade->{update} || ''),
                                    (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
                  );

                  # global parser_args add_fk_index param can be overridden on the rel def
                  my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;

                  if ($add_fk_index_rel) {
                      my $index = $table->add_index(
                                                    name   => join('_', $table_name, 'idx', @keys),
                                                    fields => \@keys,
                                                    type   => 'NORMAL',
                                                    );
                  }
              }
            }
        }

    }

    # attach the tables to the schema in dependency order
    my $dependencies = {
      map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
    };
    for my $table (sort
      {
        keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
          ||
        $a cmp $b
      }
      (keys %tables)
    ) {
      $schema->add_table ($tables{$table}{object});
      $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );

      # the hook might have already removed the table
      if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
        warn <<'EOW';

Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
"Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod

EOW

        # remove the table as there is no way someone might want to
        # actually deploy this
        $schema->drop_table ($table);
      }
    }

    my %views;
    foreach my $moniker (sort keys %view_monikers)
    {
        my $source = $dbicschema->source($moniker);
        my $view_name = $source->name;

        # FIXME - this isn't the right way to do it, but sqlt does not
        # support quoting properly to be signaled about this
        $view_name = $$view_name if ref $view_name eq 'SCALAR';

        # Skip custom query sources
        next if ref $view_name;

        # Its possible to have multiple DBIC source using same table
        next if $views{$view_name}++;

        $dbicschema->throw_exception ("view $view_name is missing a view_definition")
            unless $source->view_definition;

        my $view = $schema->add_view (
          name => $view_name,
          fields => [ $source->columns ],
          $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
        ) || $dbicschema->throw_exception ($schema->error);

        $source->_invoke_sqlt_deploy_hook($view);
    }


    if ($dbicschema->can('sqlt_deploy_hook')) {
      $dbicschema->sqlt_deploy_hook($schema);
    }

    return 1;
}

#
# Quick and dirty dependency graph calculator
#
sub _resolve_deps {
  my ($table, $tables, $seen) = @_;

  my $ret = {};
  $seen ||= {};

  # copy and bump all deps by one (so we can reconstruct the chain)
  my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
  $seen{$table} = 1;

  for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {

    if ($seen->{$dep}) {

      # warn and remove the circular constraint so we don't get flooded with the same warning over and over
      #carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
      #  join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
      #);
      #delete $tables->{$table}{foreign_table_deps}{$dep};

      return {};
    }

    my $subdeps = _resolve_deps ($dep, $tables, \%seen);
    $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );

    ++$ret->{$dep};
  }

  return $ret;
}

1;

=head1 NAME

SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
from a DBIx::Class::Schema instance

=head1 SYNOPSIS

 ## Via DBIx::Class
 use MyApp::Schema;
 my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 $schema->create_ddl_dir();
 ## or
 $schema->deploy();

 ## Standalone
 use MyApp::Schema;
 use SQL::Translator;

 my $schema = MyApp::Schema->connect;
 my $trans  = SQL::Translator->new (
      parser      => 'SQL::Translator::Parser::DBIx::Class',
      parser_args => { package => $schema },
      producer    => 'SQLite',
     ) or die SQL::Translator->error;
 my $out = $trans->translate() or die $trans->error;

=head1 DESCRIPTION

This class requires L<SQL::Translator> installed to work.

C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
interrogates the columns, and stuffs it all in an $sqlt_schema object.

Its primary use is in deploying database layouts described as a set
of L<DBIx::Class> classes, to a database. To do this, see
L<DBIx::Class::Schema/deploy>.

This can also be achieved by having DBIx::Class export the schema as a
set of SQL files ready for import into your database, or passed to
other machines that need to have your application installed but don't
have SQL::Translator installed. To do this see
L<DBIx::Class::Schema/create_ddl_dir>.

=head1 SEE ALSO

L<SQL::Translator>, L<DBIx::Class::Schema>

=head1 AUTHORS

Jess Robinson

Matt S Trout

Ash Berlin
Commit	Line	Data
392cebac	1	package SQL::Translator::Parser::DBIx::Class;
b02b20b5	2
	3	# AUTHOR: Jess Robinson
	4
1d996af5	5	# Some mistakes the fault of Matt S Trout
1d996af5	6
c385ecea	7	# Others the fault of Ash Berlin
c385ecea	8
b02b20b5	9	use strict;
b02b20b5	10	use warnings;
4a9f6cdc	11	use vars qw($DEBUG $VERSION @EXPORT_OK);
4a9f6cdc	12	$VERSION = '1.10';
b02b20b5	13	$DEBUG = 0 unless defined $DEBUG;
b02b20b5	14
b02b20b5	15	use Exporter;
b02b20b5	16	use SQL::Translator::Utils qw(debug normalize_name);
48850f9a	17	use Carp::Clan qw/^SQL::Translator\|^DBIx::Class/;
3bf702eb	18	use Scalar::Util ();
b02b20b5	19
	20	use base qw(Exporter);
	21
	22	@EXPORT_OK = qw(parse);
	23
	24	# -------------------------------------------------------------------
	25	# parse($tr, $data)
	26	#
0e2c6809	27	# setting parser_args => { add_fk_index => 0 } will prevent
	28	# the auto-generation of an index for each FK.
	29	#
880a1a0c	30	# Note that $data, in the case of this parser, is not useful.
b02b20b5	31	# We're working with DBIx::Class Schemas, not data streams.
	32	# -------------------------------------------------------------------
	33	sub parse {
3bf702eb	34	# this is a hack to prevent schema leaks due to a retarded SQLT implementation
2ad89bf5	35	# DO NOT REMOVE (until SQLT2 is out, the all of this will be rewritten anyway)
3bf702eb	36	Scalar::Util::weaken ($_[1]);
3bf702eb	37
499adf63	38	my ($tr, $data) = @_;
499adf63	39	my $args = $tr->parser_args;
b7e303a8	40	my $dbicschema = $args->{'DBIx::Class::Schema'} \|\| $args->{"DBIx::Schema"} \|\|$data;
b7e303a8	41	$dbicschema \|\|= $args->{'package'};
499adf63	42	my $limit_sources = $args->{'sources'};
48850f9a	43
eb0bc670	44	croak 'No DBIx::Class::Schema' unless ($dbicschema);
b7e303a8	45	if (!ref $dbicschema) {
b7e303a8	46	eval "use $dbicschema;";
eb0bc670	47	croak "Can't load $dbicschema ($@)" if($@);
b02b20b5	48	}
	49
	50	my $schema = $tr->schema;
	51	my $table_no = 0;
	52
b1f9d92e	53	$schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version \|\| '1.x'))
b7e303a8	54	unless ($schema->name);
38e48163	55
b7e303a8	56	my @monikers = sort $dbicschema->sources;
499adf63	57	if ($limit_sources) {
499adf63	58	my $ref = ref $limit_sources \|\| '';
eb0bc670	59	$dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
eb0bc670	60	unless( $ref eq 'ARRAY' \|\| ref eq 'HASH' );
499adf63	61
	62	# limit monikers to those specified in
	63	my $sources;
	64	if ($ref eq 'ARRAY') {
	65	$sources->{$_} = 1 for (@$limit_sources);
	66	} else {
	67	$sources = $limit_sources;
	68	}
	69	@monikers = grep { $sources->{$_} } @monikers;
	70	}
	71
	72
a7f4b74c	73	my(%table_monikers, %view_monikers);
1d521afd	74	for my $moniker (@monikers){
1d521afd	75	my $source = $dbicschema->source($moniker);
5f5e87cf	76	if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
a7f4b74c	77	$table_monikers{$moniker}++;
5f5e87cf	78	} elsif( $source->isa('DBIx::Class::ResultSource::View') ){
bccd177f	79	next if $source->is_virtual;
a7f4b74c	80	$view_monikers{$moniker}++;
1d521afd	81	}
1d521afd	82	}
499adf63	83
48850f9a	84	my %tables;
a7f4b74c	85	foreach my $moniker (sort keys %table_monikers)
b02b20b5	86	{
b7e303a8	87	my $source = $dbicschema->source($moniker);
48850f9a	88	my $table_name = $source->name;
39be4120	89
4678e9da	90	# FIXME - this isn't the right way to do it, but sqlt does not
4678e9da	91	# support quoting properly to be signaled about this
a8fcfb9f	92	$table_name = $$table_name if ref $table_name eq 'SCALAR';
b02b20b5	93
e3d5a547	94	# It's possible to have multiple DBIC sources using the same table
48850f9a	95	next if $tables{$table_name};
38e48163	96
48850f9a	97	$tables{$table_name}{source} = $source;
	98	my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
	99	name => $table_name,
b02b20b5	100	type => 'TABLE',
48850f9a	101	);
b02b20b5	102	foreach my $col ($source->columns)
b02b20b5	103	{
d6c79cb3	104	# assuming column_info in dbic is the same as DBI (?)
b02b20b5	105	# data_type is a number, column_type is text?
	106	my %colinfo = (
	107	name => $col,
b02b20b5	108	size => 0,
	109	is_auto_increment => 0,
	110	is_foreign_key => 0,
	111	is_nullable => 0,
	112	%{$source->column_info($col)}
	113	);
0009fa49	114	if ($colinfo{is_nullable}) {
	115	$colinfo{default} = '' unless exists $colinfo{default};
	116	}
eb0bc670	117	my $f = $table->add_field(%colinfo)
eb0bc670	118	\|\| $dbicschema->throw_exception ($table->error);
b02b20b5	119	}
b02b20b5	120
7b90bb13	121	my @primary = $source->primary_columns;
36e9e24f	122
	123	$table->primary_key(@primary) if @primary;
	124
7b90bb13	125	my %unique_constraints = $source->unique_constraints;
b7e303a8	126	foreach my $uniq (sort keys %unique_constraints) {
6d0ee587	127	if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
7b90bb13	128	$table->add_constraint(
7b90bb13	129	type => 'unique',
a7e65bb5	130	name => $uniq,
7b90bb13	131	fields => $unique_constraints{$uniq}
	132	);
	133	}
	134	}
	135
b02b20b5	136	my @rels = $source->relationships();
499adf63	137
499adf63	138	my %created_FK_rels;
48850f9a	139
2581038c	140	# global add_fk_index set in parser_args
a7f4b74c	141	my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
499adf63	142
454a5a42	143	foreach my $rel (sort @rels)
b02b20b5	144	{
a7f4b74c	145
b02b20b5	146	my $rel_info = $source->relationship_info($rel);
637ca936	147
637ca936	148	# Ignore any rel cond that isn't a straight hash
	149	next unless ref $rel_info->{cond} eq 'HASH';
	150
a7f4b74c	151	my $relsource = $source->related_source($rel);
	152
	153	# related sources might be excluded via a {sources} filter or might be views
	154	next unless exists $table_monikers{$relsource->source_name};
	155
	156	my $rel_table = $relsource->name;
4678e9da	157
	158	# FIXME - this isn't the right way to do it, but sqlt does not
	159	# support quoting properly to be signaled about this
	160	$rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
de60a93d	161
e377d723	162	my $reverse_rels = $source->reverse_relationship_info($rel);
	163	my ($otherrelname, $otherrelationship) = each %{$reverse_rels};
	164
d1b264d3	165	# Force the order of @cond to match the order of ->add_columns
d1b264d3	166	my $idx;
a7f4b74c	167	my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
d1b264d3	168	my @cond = sort { $other_columns_idx{$a} cmp $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
48850f9a	169
637ca936	170	# Get the key information, mapping off the foreign/self markers
637ca936	171	my @refkeys = map {/^\w+\.(\w+)$/} @cond;
	172	my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
	173
e377d723	174	# determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
e377d723	175	my $fk_constraint;
de60a93d	176
e377d723	177	#first it can be specified explicitly
	178	if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
	179	$fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
	180	}
	181	# it can not be multi
069e49b6	182	elsif ( $rel_info->{attrs}{accessor}
069e49b6	183	&& $rel_info->{attrs}{accessor} eq 'multi' ) {
e377d723	184	$fk_constraint = 0;
	185	}
	186	# if indeed single, check if all self.columns are our primary keys.
	187	# this is supposed to indicate a has_one/might_have...
	188	# where's the introspection!!?? :)
	189	else {
6d0ee587	190	$fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
e377d723	191	}
de60a93d	192
e377d723	193	my $cascade;
	194	for my $c (qw/delete update/) {
	195	if (exists $rel_info->{attrs}{"on_$c"}) {
	196	if ($fk_constraint) {
	197	$cascade->{$c} = $rel_info->{attrs}{"on_$c"};
	198	}
db79c254	199	elsif ( $rel_info->{attrs}{"on_$c"} ) {
48850f9a	200	carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
e377d723	201	. "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
	202	}
	203	}
	204	elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
	205	$cascade->{$c} = 'CASCADE';
de60a93d	206	}
e377d723	207	}
	208
	209	if($rel_table)
	210	{
	211	# Constraints are added only if applicable
	212	next unless $fk_constraint;
	213
	214	# Make sure we dont create the same foreign key constraint twice
e3d5a547	215	my $key_test = join("\x00", sort @keys);
e377d723	216	next if $created_FK_rels{$rel_table}->{$key_test};
de60a93d	217
48850f9a	218	if (scalar(@keys)) {
	219
	220	$created_FK_rels{$rel_table}->{$key_test} = 1;
13de943d	221
48850f9a	222	my $is_deferrable = $rel_info->{attrs}{is_deferrable};
48850f9a	223
a7f4b74c	224	# calculate dependencies: do not consider deferrable constraints and
a7f4b74c	225	# self-references for dependency calculations
48850f9a	226	if (! $is_deferrable and $rel_table ne $table_name) {
	227	$tables{$table_name}{foreign_table_deps}{$rel_table}++;
	228	}
a7f4b74c	229
7b5d0b84	230	$table->add_constraint(
0d865134	231	type => 'foreign_key',
48850f9a	232	name => join('_', $table_name, 'fk', @keys),
0d865134	233	fields => \@keys,
	234	reference_fields => \@refkeys,
	235	reference_table => $rel_table,
555b3385	236	on_delete => uc ($cascade->{delete} \|\| ''),
555b3385	237	on_update => uc ($cascade->{update} \|\| ''),
e394339b	238	(defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
7b5d0b84	239	);
48850f9a	240
	241	# global parser_args add_fk_index param can be overridden on the rel def
	242	my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
	243
2581038c	244	if ($add_fk_index_rel) {
0e2c6809	245	my $index = $table->add_index(
48850f9a	246	name => join('_', $table_name, 'idx', @keys),
0e2c6809	247	fields => \@keys,
	248	type => 'NORMAL',
	249	);
	250	}
	251	}
b02b20b5	252	}
b02b20b5	253	}
48850f9a	254
b02b20b5	255	}
d6c79cb3	256
48850f9a	257	# attach the tables to the schema in dependency order
	258	my $dependencies = {
	259	map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
	260	};
	261	for my $table (sort
	262	{
	263	keys %{$dependencies->{$a} \|\| {} } <=> keys %{ $dependencies->{$b} \|\| {} }
	264	\|\|
	265	$a cmp $b
	266	}
	267	(keys %tables)
	268	) {
	269	$schema->add_table ($tables{$table}{object});
	270	$tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
48850f9a	271
7adc2091	272	# the hook might have already removed the table
	273	if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
	274	warn <<'EOW';
a8fcfb9f	275
7adc2091	276	Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
	277	"Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
	278	or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
39be4120	279
7adc2091	280	EOW
39be4120	281
7adc2091	282	# remove the table as there is no way someone might want to
	283	# actually deploy this
	284	$schema->drop_table ($table);
39be4120	285	}
39be4120	286	}
48850f9a	287
48850f9a	288	my %views;
a7f4b74c	289	foreach my $moniker (sort keys %view_monikers)
1d521afd	290	{
1d521afd	291	my $source = $dbicschema->source($moniker);
48850f9a	292	my $view_name = $source->name;
4678e9da	293
	294	# FIXME - this isn't the right way to do it, but sqlt does not
	295	# support quoting properly to be signaled about this
	296	$view_name = $$view_name if ref $view_name eq 'SCALAR';
48850f9a	297
1d521afd	298	# Skip custom query sources
48850f9a	299	next if ref $view_name;
1d521afd	300
1d521afd	301	# Its possible to have multiple DBIC source using same table
48850f9a	302	next if $views{$view_name}++;
1d521afd	303
ab7e74aa	304	$dbicschema->throw_exception ("view $view_name is missing a view_definition")
ab7e74aa	305	unless $source->view_definition;
8f1617e2	306
48850f9a	307	my $view = $schema->add_view (
48850f9a	308	name => $view_name,
1d521afd	309	fields => [ $source->columns ],
f534e33b	310	$source->view_definition ? ( 'sql' => $source->view_definition ) : ()
eb0bc670	311	) \|\| $dbicschema->throw_exception ($schema->error);
a99b214b	312
a99b214b	313	$source->_invoke_sqlt_deploy_hook($view);
1d521afd	314	}
1d521afd	315
48850f9a	316
b7e303a8	317	if ($dbicschema->can('sqlt_deploy_hook')) {
b7e303a8	318	$dbicschema->sqlt_deploy_hook($schema);
d6c79cb3	319	}
d6c79cb3	320
637ca936	321	return 1;
75d07914	322	}
b02b20b5	323
48850f9a	324	#
	325	# Quick and dirty dependency graph calculator
	326	#
	327	sub _resolve_deps {
	328	my ($table, $tables, $seen) = @_;
	329
	330	my $ret = {};
	331	$seen \|\|= {};
	332
	333	# copy and bump all deps by one (so we can reconstruct the chain)
	334	my %seen = map { $_ => $seen->{$_} + 1 } (keys %$seen);
	335	$seen{$table} = 1;
	336
	337	for my $dep (keys %{$tables->{$table}{foreign_table_deps}} ) {
	338
	339	if ($seen->{$dep}) {
	340
	341	# warn and remove the circular constraint so we don't get flooded with the same warning over and over
	342	#carp sprintf ("Circular dependency detected, schema may not be deployable:\n%s\n",
	343	# join (' -> ', (sort { $seen->{$b} <=> $seen->{$a} } (keys %$seen) ), $table, $dep )
	344	#);
	345	#delete $tables->{$table}{foreign_table_deps}{$dep};
	346
	347	return {};
	348	}
	349
	350	my $subdeps = _resolve_deps ($dep, $tables, \%seen);
	351	$ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
	352
	353	++$ret->{$dep};
	354	}
	355
	356	return $ret;
	357	}
	358
0da8b7da	359	1;
7232ce07	360
	361	=head1 NAME
	362
	363	SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
	364	from a DBIx::Class::Schema instance
	365
	366	=head1 SYNOPSIS
	367
f26d4b95	368	## Via DBIx::Class
	369	use MyApp::Schema;
	370	my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
	371	$schema->create_ddl_dir();
	372	## or
	373	$schema->deploy();
	374
	375	## Standalone
7232ce07	376	use MyApp::Schema;
7232ce07	377	use SQL::Translator;
d4daee7b	378
7232ce07	379	my $schema = MyApp::Schema->connect;
	380	my $trans = SQL::Translator->new (
	381	parser => 'SQL::Translator::Parser::DBIx::Class',
	382	parser_args => { package => $schema },
	383	producer => 'SQLite',
	384	) or die SQL::Translator->error;
	385	my $out = $trans->translate() or die $trans->error;
	386
	387	=head1 DESCRIPTION
	388
f26d4b95	389	This class requires L<SQL::Translator> installed to work.
f26d4b95	390
7232ce07	391	C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
	392	interrogates the columns, and stuffs it all in an $sqlt_schema object.
	393
faaba25f	394	Its primary use is in deploying database layouts described as a set
db2b2eb6	395	of L<DBIx::Class> classes, to a database. To do this, see
db2b2eb6	396	L<DBIx::Class::Schema/deploy>.
f26d4b95	397
	398	This can also be achieved by having DBIx::Class export the schema as a
	399	set of SQL files ready for import into your database, or passed to
	400	other machines that need to have your application installed but don't
db2b2eb6	401	have SQL::Translator installed. To do this see
db2b2eb6	402	L<DBIx::Class::Schema/create_ddl_dir>.
f26d4b95	403
7232ce07	404	=head1 SEE ALSO
7232ce07	405
f26d4b95	406	L<SQL::Translator>, L<DBIx::Class::Schema>
7232ce07	407
	408	=head1 AUTHORS
	409
	410	Jess Robinson
	411
	412	Matt S Trout
	413
	414	Ash Berlin