[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / Storage / DBI / Sybase / NoBindVars.pm

package DBIx::Class::Storage::DBI::Sybase::NoBindVars;

use base qw/
  DBIx::Class::Storage::DBI::NoBindVars
  DBIx::Class::Storage::DBI::Sybase
/;
use mro 'c3';
use List::Util ();
use Scalar::Util ();

sub _init {
  my $self = shift;
  $self->disable_sth_caching(1);
  $self->_identity_method('@@IDENTITY');
  $self->next::method (@_);
}

sub _fetch_identity_sql { 'SELECT ' . $_[0]->_identity_method }

my $number = sub { Scalar::Util::looks_like_number($_[0]) };

my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };

my %noquote = (
    int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
    bit => => sub { $_[0] =~ /^[01]\z/ },
    money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
    float => $number,
    real => $number,
    double => $number,
    decimal => $decimal,
    numeric => $decimal,
);

sub interpolate_unquoted {
  my $self = shift;
  my ($type, $value) = @_;

  return $self->next::method(@_) if not defined $value or not defined $type;

  if (my $key = List::Util::first { $type =~ /$_/i } keys %noquote) {
    return 1 if $noquote{$key}->($value);
  }
  elsif ($self->is_datatype_numeric($type) && $number->($value)) {
    return 1;
  }

  return $self->next::method(@_);
}

sub _prep_interpolated_value {
  my ($self, $type, $value) = @_;

  if ($type =~ /money/i && defined $value) {
    # change a ^ not followed by \$ to a \$
    $value =~ s/^ (?! \$) /\$/x;
  }

  return $value;
}

1;

=head1 NAME

DBIx::Class::Storage::DBI::Sybase::NoBindVars - Storage::DBI subclass for Sybase
without placeholder support

=head1 DESCRIPTION

If you're using this driver than your version of Sybase, or the libraries you
use to connect to it, do not support placeholders.

You can also enable this driver explicitly using:

  my $schema = SchemaClass->clone;
  $schema->storage_type('::DBI::Sybase::NoBindVars');
  $schema->connect($dsn, $user, $pass, \%opts);

See the discussion in L<< DBD::Sybase/Using ? Placeholders & bind parameters to
$sth->execute >> for details on the pros and cons of using placeholders.

One advantage of not using placeholders is that C<select @@identity> will work
for obtainging the last insert id of an C<IDENTITY> column, instead of having to
do C<select max(col)> in a transaction as the base Sybase driver does.

When using this driver, bind variables will be interpolated (properly quoted of
course) into the SQL query itself, without using placeholders.

The caching of prepared statements is also explicitly disabled, as the
interpolation renders it useless.

=head1 AUTHORS

See L<DBIx::Class/CONTRIBUTORS>.

=head1 LICENSE

You may distribute this code under the same terms as Perl itself.

=cut
# vim:sts=2 sw=2:
Commit	Line	Data
d867eeda	1	package DBIx::Class::Storage::DBI::Sybase::NoBindVars;
	2
	3	use base qw/
	4	DBIx::Class::Storage::DBI::NoBindVars
	5	DBIx::Class::Storage::DBI::Sybase
	6	/;
	7	use mro 'c3';
	8	use List::Util ();
	9	use Scalar::Util ();
	10
	11	sub _init {
	12	my $self = shift;
	13	$self->disable_sth_caching(1);
	14	$self->_identity_method('@@IDENTITY');
	15	$self->next::method (@_);
	16	}
	17
	18	sub _fetch_identity_sql { 'SELECT ' . $_[0]->_identity_method }
	19
	20	my $number = sub { Scalar::Util::looks_like_number($_[0]) };
	21
	22	my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };
	23
	24	my %noquote = (
	25	int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
	26	bit => => sub { $_[0] =~ /^[01]\z/ },
	27	money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
	28	float => $number,
	29	real => $number,
	30	double => $number,
	31	decimal => $decimal,
	32	numeric => $decimal,
	33	);
	34
	35	sub interpolate_unquoted {
	36	my $self = shift;
	37	my ($type, $value) = @_;
	38
	39	return $self->next::method(@_) if not defined $value or not defined $type;
	40
	41	if (my $key = List::Util::first { $type =~ /$_/i } keys %noquote) {
	42	return 1 if $noquote{$key}->($value);
	43	}
	44	elsif ($self->is_datatype_numeric($type) && $number->($value)) {
	45	return 1;
	46	}
	47
	48	return $self->next::method(@_);
	49	}
	50
	51	sub _prep_interpolated_value {
	52	my ($self, $type, $value) = @_;
	53
	54	if ($type =~ /money/i && defined $value) {
	55	# change a ^ not followed by \$ to a \$
	56	$value =~ s/^ (?! \$) /\$/x;
	57	}
	58
	59	return $value;
	60	}
	61
	62	1;
	63
	64	=head1 NAME
65
66	DBIx::Class::Storage::DBI::Sybase::NoBindVars - Storage::DBI subclass for Sybase
67	without placeholder support
68
69	=head1 DESCRIPTION
70
71	If you're using this driver than your version of Sybase, or the libraries you
72	use to connect to it, do not support placeholders.
73
74	You can also enable this driver explicitly using:
75
76	my $schema = SchemaClass->clone;
77	$schema->storage_type('::DBI::Sybase::NoBindVars');
78	$schema->connect($dsn, $user, $pass, \%opts);
79
80	See the discussion in L<< DBD::Sybase/Using ? Placeholders & bind parameters to
81	$sth->execute >> for details on the pros and cons of using placeholders.
82
83	One advantage of not using placeholders is that C<select @@identity> will work
84	for obtainging the last insert id of an C<IDENTITY> column, instead of having to
85	do C<select max(col)> in a transaction as the base Sybase driver does.
86
87	When using this driver, bind variables will be interpolated (properly quoted of
88	course) into the SQL query itself, without using placeholders.
89
90	The caching of prepared statements is also explicitly disabled, as the
91	interpolation renders it useless.
92
93	=head1 AUTHORS
94
95	See L<DBIx::Class/CONTRIBUTORS>.
96
97	=head1 LICENSE
98
99	You may distribute this code under the same terms as Perl itself.
100
101	=cut
102	# vim:sts=2 sw=2: