[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / InflateColumn / DateTime.pm

package DBIx::Class::InflateColumn::DateTime;

use strict;
use warnings;
use base qw/DBIx::Class/;
use Carp::Clan qw/^DBIx::Class/;
use Try::Tiny;

=head1 NAME

DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.

=head1 SYNOPSIS

Load this component and then declare one or more 
columns to be of the datetime, timestamp or date datatype.

  package Event;
  use base 'DBIx::Class::Core';

  __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  __PACKAGE__->add_columns(
    starts_when => { data_type => 'datetime' }
    create_date => { data_type => 'date' }
  );

Then you can treat the specified column as a L<DateTime> object.

  print "This event starts the month of ".
    $event->starts_when->month_name();

If you want to set a specific timezone and locale for that field, use:

  __PACKAGE__->add_columns(
    starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  );

If you want to inflate no matter what data_type your column is,
use inflate_datetime or inflate_date:

  __PACKAGE__->add_columns(
    starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  );

  __PACKAGE__->add_columns(
    starts_when => { data_type => 'varchar', inflate_date => 1 }
  );

It's also possible to explicitly skip inflation:

  __PACKAGE__->add_columns(
    starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  );

NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
The column is set directly for any non-references and C<InflateColumn::DateTime>
is completely bypassed.  Instead, use an input parser to create a DateTime
object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
use C<DateTime::Format::ISO8601> thusly:

  use DateTime::Format::ISO8601;
  my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');

=head1 DESCRIPTION

This module figures out the type of DateTime::Format::* class to 
inflate/deflate with based on the type of DBIx::Class::Storage::DBI::* 
that you are using.  If you switch from one database to a different 
one your code should continue to work without modification (though note
that this feature is new as of 0.07, so it may not be perfect yet - bug
reports to the list very much welcome).

If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
a derivative of these datatypes, e.g. C<timestamp with timezone>), this
module will automatically call the appropriate parse/format method for
deflation/inflation as defined in the storage class. For instance, for
a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
would be called on deflation/inflation. If the storage class does not
provide a specialized inflator/deflator, C<[parse|format]_datetime> will
be used as a fallback. See L<DateTime::Format> for more information on
date formatting.

For more help with using components, see L<DBIx::Class::Manual::Component/USING>.

=cut

__PACKAGE__->load_components(qw/InflateColumn/);

=head2 register_column

Chains with the L<DBIx::Class::Row/register_column> method, and sets
up datetime columns appropriately.  This would not normally be
directly called by end users.

In the case of an invalid date, L<DateTime> will throw an exception.  To
bypass these exceptions and just have the inflation return undef, use
the C<datetime_undef_if_invalid> option in the column info:

    "broken_date",
    {
        data_type => "datetime",
        default_value => '0000-00-00',
        is_nullable => 1,
        datetime_undef_if_invalid => 1
    }

=cut

sub register_column {
  my ($self, $column, $info, @rest) = @_;
  $self->next::method($column, $info, @rest);
  return unless defined($info->{data_type});

  my $type;

  for (qw/date datetime timestamp/) {
    my $key = "inflate_${_}";

    next unless exists $info->{$key};
    return unless $info->{$key};

    $type = $_;
    last;
  }

  unless ($type) {
    $type = lc($info->{data_type});
    if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
      $type = "timestamp";
      $info->{_ic_dt_method} ||= "timestamp_with_timezone";
    } elsif ($type eq "timestamp without time zone") {
      $type = "timestamp";
      $info->{_ic_dt_method} ||= "timestamp_without_timezone";
    } elsif ($type eq "smalldatetime") {
      $type = "datetime";
      $info->{_ic_dt_method} ||= "smalldatetime";
    }
  }

  if ( defined $info->{extra}{timezone} ) {
    carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
         "please put it directly into the '$column' column definition.";
    $info->{timezone} = $info->{extra}{timezone} unless defined $info->{timezone};
  }

  if ( defined $info->{extra}{locale} ) {
    carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
         "please put it directly into the '$column' column definition.";
    $info->{locale} = $info->{extra}{locale} unless defined $info->{locale};
  }

  my $undef_if_invalid = $info->{datetime_undef_if_invalid};

  if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
    # This shallow copy of %info avoids t/52_cycle.t treating
    # the resulting deflator as a circular reference.
    my %info = ( '_ic_dt_method' => $type , %{ $info } );

    if (defined $info->{extra}{floating_tz_ok}) {
      carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
           "please put it directly into the '$column' column definition.";
      $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
    }

    $self->inflate_column(
      $column =>
        {
          inflate => sub {
            my ($value, $obj) = @_;

            my $dt = try
              { $obj->_inflate_to_datetime( $value, \%info ) }
              catch {
                $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $_")
                  unless $undef_if_invalid;
                undef;  # rv
              };

            return (defined $dt)
              ? $obj->_post_inflate_datetime( $dt, \%info )
              : undef
            ;
          },
          deflate => sub {
            my ($value, $obj) = @_;

            $value = $obj->_pre_deflate_datetime( $value, \%info );
            $obj->_deflate_from_datetime( $value, \%info );
          },
        }
    );
  }
}

sub _flate_or_fallback
{
  my( $self, $value, $info, $method_fmt ) = @_;

  my $parser = $self->_datetime_parser;
  my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
  my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
  return $parser->$method($value);
}

sub _inflate_to_datetime {
  my( $self, $value, $info ) = @_;
  return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
}

sub _deflate_from_datetime {
  my( $self, $value, $info ) = @_;
  return $self->_flate_or_fallback( $value, $info, 'format_%s' );
}

sub _datetime_parser {
  shift->result_source->storage->datetime_parser (@_);
}

sub _post_inflate_datetime {
  my( $self, $dt, $info ) = @_;

  $dt->set_time_zone($info->{timezone}) if defined $info->{timezone};
  $dt->set_locale($info->{locale}) if defined $info->{locale};

  return $dt;
}

sub _pre_deflate_datetime {
  my( $self, $dt, $info ) = @_;

  if (defined $info->{timezone}) {
    carp "You're using a floating timezone, please see the documentation of"
      . " DBIx::Class::InflateColumn::DateTime for an explanation"
      if ref( $dt->time_zone ) eq 'DateTime::TimeZone::Floating'
          and not $info->{floating_tz_ok}
          and not $ENV{DBIC_FLOATING_TZ_OK};

    $dt->set_time_zone($info->{timezone});
  }

  $dt->set_locale($info->{locale}) if defined $info->{locale};

  return $dt;
}

1;
__END__

=head1 USAGE NOTES

If you have a datetime column with an associated C<timezone>, and subsequently
create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
timezone, you will get a warning (as there is a very good chance this will not have the
result you expect). For example:

  __PACKAGE__->add_columns(
    starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
  );

  my $event = $schema->resultset('EventTZ')->create({
    starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
  });

The warning can be avoided in several ways:

=over

=item Fix your broken code

When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
set to the requested value, and B<no time conversion takes place>. It is always a good idea
to be supply explicit times to the database:

  my $event = $schema->resultset('EventTZ')->create({
    starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
  });

=item Suppress the check on per-column basis

  __PACKAGE__->add_columns(
    starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
  );

=item Suppress the check globally

Set the environment variable DBIC_FLOATING_TZ_OK to some true value.

=back

Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
Instead put it directly into the columns definition like in the examples above. If you still
use the old way you'll see a warning - please fix your code then!

=head1 SEE ALSO

=over 4

=item More information about the add_columns method, and column metadata, 
      can be found in the documentation for L<DBIx::Class::ResultSource>.

=item Further discussion of problems inherent to the Floating timezone:
      L<Floating DateTimes|DateTime/Floating_DateTimes> 
      and L<< $dt->set_time_zone|DateTime/"Set" Methods >>

=back

=head1 AUTHOR

Matt S. Trout <mst@shadowcatsystems.co.uk>

=head1 CONTRIBUTORS

Aran Deltac <bluefeet@cpan.org>

=head1 LICENSE

You may distribute this code under the same terms as Perl itself.
Commit	Line	Data
445e5e31	1	package DBIx::Class::InflateColumn::DateTime;
	2
	3	use strict;
	4	use warnings;
	5	use base qw/DBIx::Class/;
341d5ede	6	use Carp::Clan qw/^DBIx::Class/;
ed7ab0f4	7	use Try::Tiny;
445e5e31	8
0b375b68	9	=head1 NAME
0b375b68	10
5d0a2955	11	DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
0b375b68	12
	13	=head1 SYNOPSIS
	14
	15	Load this component and then declare one or more
679a304a	16	columns to be of the datetime, timestamp or date datatype.
0b375b68	17
0b375b68	18	package Event;
d88ecca6	19	use base 'DBIx::Class::Core';
	20
	21	__PACKAGE__->load_components(qw/InflateColumn::DateTime/);
0b375b68	22	__PACKAGE__->add_columns(
0b375b68	23	starts_when => { data_type => 'datetime' }
9c71b5e2	24	create_date => { data_type => 'date' }
0b375b68	25	);
	26
	27	Then you can treat the specified column as a L<DateTime> object.
	28
	29	print "This event starts the month of ".
	30	$event->starts_when->month_name();
	31
8d689133	32	If you want to set a specific timezone and locale for that field, use:
dda9af55	33
dda9af55	34	__PACKAGE__->add_columns(
92ed0695	35	starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
dda9af55	36	);
dda9af55	37
a97fe7e0	38	If you want to inflate no matter what data_type your column is,
	39	use inflate_datetime or inflate_date:
	40
	41	__PACKAGE__->add_columns(
	42	starts_when => { data_type => 'varchar', inflate_datetime => 1 }
	43	);
d4daee7b	44
a97fe7e0	45	__PACKAGE__->add_columns(
	46	starts_when => { data_type => 'varchar', inflate_date => 1 }
	47	);
	48
ff8a6e3b	49	It's also possible to explicitly skip inflation:
d4daee7b	50
ff8a6e3b	51	__PACKAGE__->add_columns(
	52	starts_when => { data_type => 'datetime', inflate_datetime => 0 }
	53	);
	54
8bf37b16	55	NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
	56	The column is set directly for any non-references and C<InflateColumn::DateTime>
	57	is completely bypassed. Instead, use an input parser to create a DateTime
	58	object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
	59	use C<DateTime::Format::ISO8601> thusly:
d6aed638	60
	61	use DateTime::Format::ISO8601;
	62	my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
	63
0b375b68	64	=head1 DESCRIPTION
	65
	66	This module figures out the type of DateTime::Format::* class to
	67	inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
	68	that you are using. If you switch from one database to a different
5d0a2955	69	one your code should continue to work without modification (though note
	70	that this feature is new as of 0.07, so it may not be perfect yet - bug
	71	reports to the list very much welcome).
0b375b68	72
9c71b5e2	73	If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
f59e543b	74	a derivative of these datatypes, e.g. C<timestamp with timezone>), this
9c71b5e2	75	module will automatically call the appropriate parse/format method for
	76	deflation/inflation as defined in the storage class. For instance, for
	77	a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
	78	would be called on deflation/inflation. If the storage class does not
	79	provide a specialized inflator/deflator, C<[parse\|format]_datetime> will
	80	be used as a fallback. See L<DateTime::Format> for more information on
	81	date formatting.
	82
943f93f2	83	For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
de78905b	84
0b375b68	85	=cut
0b375b68	86
445e5e31	87	__PACKAGE__->load_components(qw/InflateColumn/);
445e5e31	88
9b83fccd	89	=head2 register_column
	90
	91	Chains with the L<DBIx::Class::Row/register_column> method, and sets
	92	up datetime columns appropriately. This would not normally be
	93	directly called by end users.
	94
33a126ef	95	In the case of an invalid date, L<DateTime> will throw an exception. To
	96	bypass these exceptions and just have the inflation return undef, use
	97	the C<datetime_undef_if_invalid> option in the column info:
d4daee7b	98
33a126ef	99	"broken_date",
	100	{
	101	data_type => "datetime",
	102	default_value => '0000-00-00',
	103	is_nullable => 1,
	104	datetime_undef_if_invalid => 1
	105	}
	106
9b83fccd	107	=cut
9b83fccd	108
445e5e31	109	sub register_column {
	110	my ($self, $column, $info, @rest) = @_;
	111	$self->next::method($column, $info, @rest);
c209c4fd	112	return unless defined($info->{data_type});
bb90689c	113
	114	my $type;
	115
abc914bd	116	for (qw/date datetime timestamp/) {
bb90689c	117	my $key = "inflate_${_}";
	118
	119	next unless exists $info->{$key};
	120	return unless $info->{$key};
	121
	122	$type = $_;
	123	last;
	124	}
	125
	126	unless ($type) {
	127	$type = lc($info->{data_type});
6c99a3ee	128	if ($type eq "timestamp with time zone" \|\| $type eq "timestamptz") {
	129	$type = "timestamp";
	130	$info->{_ic_dt_method} \|\|= "timestamp_with_timezone";
65b386df	131	} elsif ($type eq "timestamp without time zone") {
	132	$type = "timestamp";
	133	$info->{_ic_dt_method} \|\|= "timestamp_without_timezone";
4a80eede	134	} elsif ($type eq "smalldatetime") {
4a80eede	135	$type = "datetime";
fb95dc4d	136	$info->{_ic_dt_method} \|\|= "smalldatetime";
6c99a3ee	137	}
bb90689c	138	}
bb90689c	139
8d689133	140	if ( defined $info->{extra}{timezone} ) {
341d5ede	141	carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
6c9d0c63	142	"please put it directly into the '$column' column definition.";
c3ed0bde	143	$info->{timezone} = $info->{extra}{timezone} unless defined $info->{timezone};
dda9af55	144	}
dda9af55	145
8d689133	146	if ( defined $info->{extra}{locale} ) {
341d5ede	147	carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
6c9d0c63	148	"please put it directly into the '$column' column definition.";
c3ed0bde	149	$info->{locale} = $info->{extra}{locale} unless defined $info->{locale};
8d689133	150	}
d4daee7b	151
dceeddc7	152	my $undef_if_invalid = $info->{datetime_undef_if_invalid};
dceeddc7	153
abc914bd	154	if ($type eq 'datetime' \|\| $type eq 'date' \|\| $type eq 'timestamp') {
ab969dd4	155	# This shallow copy of %info avoids t/52_cycle.t treating
	156	# the resulting deflator as a circular reference.
	157	my %info = ( '_ic_dt_method' => $type , %{ $info } );
	158
92ed0695	159	if (defined $info->{extra}{floating_tz_ok}) {
341d5ede	160	carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
6c9d0c63	161	"please put it directly into the '$column' column definition.";
b1e4a1df	162	$info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
92ed0695	163	}
45147005	164
445e5e31	165	$self->inflate_column(
	166	$column =>
	167	{
	168	inflate => sub {
	169	my ($value, $obj) = @_;
40f75181	170
9780718f	171	my $dt = try
	172	{ $obj->_inflate_to_datetime( $value, \%info ) }
	173	catch {
	174	$self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $_")
	175	unless $undef_if_invalid;
	176	undef; # rv
	177	};
	178
	179	return (defined $dt)
	180	? $obj->_post_inflate_datetime( $dt, \%info )
	181	: undef
	182	;
445e5e31	183	},
	184	deflate => sub {
	185	my ($value, $obj) = @_;
f856fe01	186
f856fe01	187	$value = $obj->_pre_deflate_datetime( $value, \%info );
ab969dd4	188	$obj->_deflate_from_datetime( $value, \%info );
445e5e31	189	},
	190	}
	191	);
	192	}
	193	}
	194
ab969dd4	195	sub _flate_or_fallback
	196	{
	197	my( $self, $value, $info, $method_fmt ) = @_;
	198
	199	my $parser = $self->_datetime_parser;
	200	my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
	201	my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
	202	return $parser->$method($value);
	203	}
	204
	205	sub _inflate_to_datetime {
	206	my( $self, $value, $info ) = @_;
	207	return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
	208	}
	209
	210	sub _deflate_from_datetime {
	211	my( $self, $value, $info ) = @_;
	212	return $self->_flate_or_fallback( $value, $info, 'format_%s' );
	213	}
abc914bd	214
445e5e31	215	sub _datetime_parser {
f568d83b	216	shift->result_source->storage->datetime_parser (@_);
445e5e31	217	}
445e5e31	218
f856fe01	219	sub _post_inflate_datetime {
	220	my( $self, $dt, $info ) = @_;
	221
c3ed0bde	222	$dt->set_time_zone($info->{timezone}) if defined $info->{timezone};
c3ed0bde	223	$dt->set_locale($info->{locale}) if defined $info->{locale};
f856fe01	224
	225	return $dt;
	226	}
	227
	228	sub _pre_deflate_datetime {
	229	my( $self, $dt, $info ) = @_;
	230
c3ed0bde	231	if (defined $info->{timezone}) {
f856fe01	232	carp "You're using a floating timezone, please see the documentation of"
	233	. " DBIx::Class::InflateColumn::DateTime for an explanation"
	234	if ref( $dt->time_zone ) eq 'DateTime::TimeZone::Floating'
	235	and not $info->{floating_tz_ok}
	236	and not $ENV{DBIC_FLOATING_TZ_OK};
	237
c3ed0bde	238	$dt->set_time_zone($info->{timezone});
f856fe01	239	}
f856fe01	240
c3ed0bde	241	$dt->set_locale($info->{locale}) if defined $info->{locale};
f856fe01	242
	243	return $dt;
	244	}
	245
445e5e31	246	1;
0b375b68	247	__END__
0b375b68	248
45147005	249	=head1 USAGE NOTES
45147005	250
97983826	251	If you have a datetime column with an associated C<timezone>, and subsequently
45147005	252	create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
	253	timezone, you will get a warning (as there is a very good chance this will not have the
	254	result you expect). For example:
	255
	256	__PACKAGE__->add_columns(
92ed0695	257	starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
45147005	258	);
	259
	260	my $event = $schema->resultset('EventTZ')->create({
	261	starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
	262	});
	263
	264	The warning can be avoided in several ways:
	265
	266	=over
	267
	268	=item Fix your broken code
	269
	270	When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
	271	set to the requested value, and B<no time conversion takes place>. It is always a good idea
	272	to be supply explicit times to the database:
	273
	274	my $event = $schema->resultset('EventTZ')->create({
	275	starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
	276	});
	277
	278	=item Suppress the check on per-column basis
	279
	280	__PACKAGE__->add_columns(
92ed0695	281	starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
45147005	282	);
	283
	284	=item Suppress the check globally
	285
	286	Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
	287
	288	=back
	289
92ed0695	290	Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
	291	B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
	292	Instead put it directly into the columns definition like in the examples above. If you still
	293	use the old way you'll see a warning - please fix your code then!
45147005	294
0b375b68	295	=head1 SEE ALSO
	296
	297	=over 4
	298
	299	=item More information about the add_columns method, and column metadata,
	300	can be found in the documentation for L<DBIx::Class::ResultSource>.
	301
45147005	302	=item Further discussion of problems inherent to the Floating timezone:
	303	L<Floating DateTimes\|DateTime/Floating_DateTimes>
	304	and L<< $dt->set_time_zone\|DateTime/"Set" Methods >>
	305
0b375b68	306	=back
	307
	308	=head1 AUTHOR
	309
	310	Matt S. Trout <mst@shadowcatsystems.co.uk>
	311
	312	=head1 CONTRIBUTORS
	313
	314	Aran Deltac <bluefeet@cpan.org>
	315
	316	=head1 LICENSE
	317
	318	You may distribute this code under the same terms as Perl itself.
	319