lib/Catalyst/Manual/Tutorial/Authorization.pod

   1 =head1 NAME
   2
   3 Catalyst::Manual::Tutorial::Authorization - Catalyst Tutorial - Chapter 6: Authorization
   4
   5
   6 =head1 OVERVIEW
   7
   8 This is B<Chapter 6 of 10> for the Catalyst tutorial.
   9
  10 L<Tutorial Overview|Catalyst::Manual::Tutorial>
  11
  12 =over 4
  13
  14 =item 1
  15
  16 L<Introduction|Catalyst::Manual::Tutorial::Intro>
  17
  18 =item 2
  19
  20 L<Catalyst Basics|Catalyst::Manual::Tutorial::CatalystBasics>
  21
  22 =item 3
  23
  24 L<More Catalyst Basics|Catalyst::Manual::Tutorial::MoreCatalystBasics>
  25
  26 =item 4
  27
  28 L<Basic CRUD|Catalyst::Manual::Tutorial::BasicCRUD>
  29
  30 =item 5
  31
  32 L<Authentication|Catalyst::Manual::Tutorial::Authentication>
  33
  34 =item 6
  35
  36 B<Authorization>
  37
  38 =item 7
  39
  40 L<Debugging|Catalyst::Manual::Tutorial::Debugging>
  41
  42 =item 8
  43
  44 L<Testing|Catalyst::Manual::Tutorial::Testing>
  45
  46 =item 9
  47
  48 L<Advanced CRUD|Catalyst::Manual::Tutorial::AdvancedCRUD>
  49
  50 =item 10
  51
  52 L<Appendices|Catalyst::Manual::Tutorial::Appendices>
  53
  54 =back
  55
  56
  57 =head1 DESCRIPTION
  58
  59 This chapter of the tutorial adds role-based authorization to the
  60 existing authentication implemented in Chapter 5.  It provides simple
  61 examples of how to use roles in both TT templates and controller
  62 actions.  The first half looks at basic authorization concepts. The
  63 second half looks at how moving your authorization code to your model
  64 can simplify your code and make things easier to maintain.
  65
  66 You can checkout the source code for this example from the catalyst
  67 subversion repository as per the instructions in
  68 L<Catalyst::Manual::Tutorial::Intro|Catalyst::Manual::Tutorial::Intro>.
  69
  70
  71 =head1 BASIC AUTHORIZATION
  72
  73 In this section you learn the basics of how authorization works under
  74 Catalyst.
  75
  76
  77 =head2 Update Plugins to Include Support for Authorization
  78
  79 Edit C<lib/MyApp.pm> and add C<Authorization::Roles> to the list:
  80
  81     # Load plugins
  82     use Catalyst qw/-Debug
  83                 ConfigLoader
  84                 Static::Simple
  85
  86                 StackTrace
  87
  88                 Authentication
  89                 Authorization::Roles
  90
  91                 Session
  92                 Session::Store::FastMmap
  93                 Session::State::Cookie
  94                 /;
  95
  96 B<Note:> As discussed in MoreCatalystBasics, different versions of
  97 C<Catalyst::Devel> have used a variety of methods to load the plugins.
  98 You can put the plugins in the C<use Catalyst> statement if you
  99 prefer.
 100
 101
 102 =head2 Add Role-Specific Logic to the "Book List" Template
 103
 104 Open C<root/src/books/list.tt2> in your editor and add the following
 105 lines to the bottom of the file:
 106
 107     ...
 108     <p>Hello [% c.user.username %], you have the following roles:</p>
 109
 110     <ul>
 111       [% # Dump list of roles -%]
 112       [% FOR role = c.user.roles %]<li>[% role %]</li>[% END %]
 113     </ul>
 114
 115     <p>
 116     [% # Add some simple role-specific logic to template %]
 117     [% # Use $c->check_user_roles() to check authz -%]
 118     [% IF c.check_user_roles('user') %]
 119       [% # Give normal users a link for 'logout' %]
 120       <a href="[% c.uri_for('/logout') %]">User Logout</a>
 121     [% END %]
 122
 123     [% # Can also use $c->user->check_roles() to check authz -%]
 124     [% IF c.check_user_roles('admin') %]
 125       [% # Give admin users a link for 'create' %]
 126       <a href="[% c.uri_for(c.controller.action_for('form_create')) %]">Admin Create</a>
 127     [% END %]
 128     </p>
 129
 130 This code displays a different combination of links depending on the
 131 roles assigned to the user.
 132
 133
 134 =head2 Limit Books::add to 'admin' Users
 135
 136 C<IF> statements in TT templates simply control the output that is sent
 137 to the user's browser; it provides no real enforcement (if users know or
 138 guess the appropriate URLs, they are still perfectly free to hit any
 139 action within your application).  We need to enhance the controller
 140 logic to wrap restricted actions with role-validation logic.
 141
 142 For example, we might want to restrict the "formless create" action to
 143 admin-level users by editing C<lib/MyApp/Controller/Books.pm> and
 144 updating C<url_create> to match the following code:
 145
 146     =head2 url_create
 147
 148     Create a book with the supplied title and rating,
 149     with manual authorization
 150
 151     =cut
 152
 153     sub url_create :Chained('base') :PathPart('url_create') :Args(3) {
 154         # In addition to self & context, get the title, rating & author_id args
 155         # from the URL.  Note that Catalyst automatically puts extra information
 156         # after the "/<controller_name>/<action_name/" into @_
 157         my ($self, $c, $title, $rating, $author_id) = @_;
 158
 159         # Check the user's roles
 160         if ($c->check_user_roles('admin')) {
 161             # Call create() on the book model object. Pass the table
 162             # columns/field values we want to set as hash values
 163             my $book = $c->model('DB::Books')->create({
 164                     title   => $title,
 165                     rating  => $rating
 166                 });
 167
 168             # Add a record to the join table for this book, mapping to
 169             # appropriate author
 170             $book->add_to_book_authors({author_id => $author_id});
 171             # Note: Above is a shortcut for this:
 172             # $book->create_related('book_authors', {author_id => $author_id});
 173
 174             # Assign the Book object to the stash for display in the view
 175             $c->stash->{book} = $book;
 176
 177             # This is a hack to disable XSUB processing in Data::Dumper
 178             # (it's used in the view).  This is a work-around for a bug in
 179             # the interaction of some versions or Perl, Data::Dumper & DBIC.
 180             # You won't need this if you aren't using Data::Dumper (or if
 181             # you are running DBIC 0.06001 or greater), but adding it doesn't
 182             # hurt anything either.
 183             $Data::Dumper::Useperl = 1;
 184
 185             # Set the TT template to use
 186             $c->stash->{template} = 'books/create_done.tt2';
 187         } else {
 188             # Provide very simple feedback to the user.
 189             $c->response->body('Unauthorized!');
 190         }
 191     }
 192
 193
 194 To add authorization, we simply wrap the main code of this method in an
 195 C<if> statement that calls C<check_user_roles>.  If the user does not
 196 have the appropriate permissions, they receive an "Unauthorized!"
 197 message.  Note that we intentionally chose to display the message this
 198 way to demonstrate that TT templates will not be used if the response
 199 body has already been set.  In reality you would probably want to use a
 200 technique that maintains the visual continuity of your template layout
 201 (for example, using the "status" or "error" message feature added in
 202 Chapter 3 or C<detach> to an action that shows an "unauthorized" page).
 203
 204 B<TIP>: If you want to keep your existing C<url_create> method, you can
 205 create a new copy and comment out the original by making it look like a
 206 Pod comment.  For example, put something like C<=begin> before
 207 C<sub add : Local {> and C<=end> after the closing C<}>.
 208
 209
 210 =head2 Try Out Authentication And Authorization
 211
 212 Press C<Ctrl-C> to kill the previous server instance (if it's still
 213 running) and restart it:
 214
 215     $ script/myapp_server.pl
 216
 217 Now trying going to L<http://localhost:3000/books/list> and you should
 218 be taken to the login page (you might have to C<Shift+Reload> or
 219 C<Ctrl+Reload> your browser and/or click the "User Logout" link on the book
 220 list page).  Try logging in with both C<test01> and C<test02> (both
 221 use a password of C<mypass>) and notice how the roles information
 222 updates at the bottom of the "Book List" page. Also try the "User Logout"
 223 link on the book list page.
 224
 225 Now the "url_create" URL will work if you are already logged in as user
 226 C<test01>, but receive an authorization failure if you are logged in as
 227 C<test02>.  Try:
 228
 229     http://localhost:3000/books/url_create/test/1/6
 230
 231 while logged in as each user.  Use one of the "logout" links (or go to
 232 L<http://localhost:3000/logout> in your browser directly) when you are
 233 done.
 234
 235
 236 =head1 ENABLE MODEL-BASED AUTHORIZATION
 237
 238 Hopefully it's fairly obvious that adding detailed permission checking
 239 logic to our controllers and view templates isn't a very clean or
 240 scalable way to build role-based permissions into out application.  As
 241 with many other aspects of MVC web development, the goal is to have
 242 your controllers and views be an "thin" as possible, with all of the
 243 "fancy business logic" built into your model.
 244
 245 For example, let's add a method to our C<Books.pm> Result Class to
 246 check if a user is allowed to delete a book.  Open
 247 C<lib/MyApp/Schema/Result/Books.pm> and add the following method
 248 (be sure to add it below the "C<DO NOT MODIFY ...>" line):
 249
 250     =head2 delete_allowed_by
 251
 252     Can the specified user delete the current book?
 253
 254     =cut
 255
 256     sub delete_allowed_by {
 257         my ($self, $user) = @_;
 258
 259         # Only allow delete if user has 'admin' role
 260         return $user->has_role('admin');
 261     }
 262
 263 Here we call a C<has_role> method on our user object, so we should add
 264 this method to our Result Class.  Open
 265 C<lib/MyApp/Schema/Result/Users.pm> and add the following method below
 266 the "C<DO NOT MODIFY ...>" line:
 267
 268     =head 2 has_role
 269
 270     Check if a user has the specified role
 271
 272     =cut
 273
 274     use Perl6::Junction qw/any/;
 275     sub has_role {
 276         my ($self, $role) = @_;
 277
 278         # Does this user posses the required role?
 279         return any(map { $_->role } $self->roles) eq $role;
 280     }
 281
 282 Now we need to add some enforcement inside our controller.  Open
 283 C<lib/MyApp/Controller/Books.pm> and update the C<delete> method to
 284 match the following code:
 285
 286     =head2 delete
 287
 288     Delete a book
 289
 290     =cut
 291
 292     sub delete :Chained('object') :PathPart('delete') :Args(0) {
 293         my ($self, $c) = @_;
 294
 295         # Check permissions
 296         $c->detach('/error_noperms')
 297             unless $c->stash->{object}->delete_allowed_by($c->user->get_object);
 298
 299         # Use the book object saved by 'object' and delete it along
 300         # with related 'book_authors' entries
 301         $c->stash->{object}->delete;
 302
 303         # Use 'flash' to save information across requests until it's read
 304         $c->flash->{status_msg} = "Book deleted";
 305
 306         # Redirect the user back to the list page
 307         $c->response->redirect($c->uri_for($self->action_for('list')));
 308     }
 309
 310 Here, we C<detach> to an error page if the user is lacking the
 311 appropriate permissions.  For this to work, we need to make
 312 arrangements for the '/error_noperms' action to work.  Open
 313 C<lib/MyApp/Controller/Root.pm> and add this method:
 314
 315     =head2 error_noperms
 316
 317     Permissions error screen
 318
 319     =cut
 320
 321     sub error_noperms :Chained('/') :PathPath('error_noperms') :Args(0) {
 322         my ($self, $c) = @_;
 323
 324         $c->stash->{template} = 'error_noperms.tt2';
 325     }
 326
 327 And also add the template file by putting the following text into
 328 C<root/src/error_noperms.tt2>:
 329
 330     <span class="error">Permission Denied</span>
 331
 332 Then run the Catalyst development server script:
 333
 334     $ script/myapp_server.pl
 335
 336 Log in as C<test01> and create several new books using the C<url_create>
 337 feature:
 338
 339     http://localhost:3000/books/url_create/Test/1/4
 340
 341 Then, while still logged in as C<test01>, click the "Delete" link next
 342 to one of these books.  The book should be removed and you should see
 343 the usual green "Book deleted" message.  Next, click the "User Logout"
 344 link and log back in as C<test02>.  Now try deleting one of the books.
 345 You should be taken to the red "Permission Denied" message on our
 346 error page.
 347
 348 Use one of the 'Logout' links (or go to the
 349 L<http://localhost:3000/logout> URL directly) when you are done.
 350
 351
 352 =head1 AUTHOR
 353
 354 Kennedy Clark, C<hkclark@gmail.com>
 355
 356 Please report any errors, issues or suggestions to the author.  The
 357 most recent version of the Catalyst Tutorial can be found at
 358 L<http://dev.catalyst.perl.org/repos/Catalyst/Catalyst-Manual/5.70/trunk/lib/Catalyst/Manual/Tutorial/>.
 359
 360 Copyright 2006-2008, Kennedy Clark, under Creative Commons License
 361 (L<http://creativecommons.org/licenses/by-sa/3.0/us/>).
 362