lib/Catalyst/Manual/Tutorial/Authentication.pod

   1 =head1 NAME
   2
   3 Catalyst::Manual::Tutorial::Authentication - Catalyst Tutorial - Chapter 5: Authentication
   4
   5
   6 =head1 OVERVIEW
   7
   8 This is B<Chapter 5 of 10> for the Catalyst tutorial.
   9
  10 L<Tutorial Overview|Catalyst::Manual::Tutorial>
  11
  12 =over 4
  13
  14 =item 1
  15
  16 L<Introduction|Catalyst::Manual::Tutorial::Intro>
  17
  18 =item 2
  19
  20 L<Catalyst Basics|Catalyst::Manual::Tutorial::CatalystBasics>
  21
  22 =item 3
  23
  24 L<More Catalyst Basics|Catalyst::Manual::Tutorial::MoreCatalystBasics>
  25
  26 =item 4
  27
  28 L<Basic CRUD|Catalyst::Manual::Tutorial::BasicCRUD>
  29
  30 =item 5
  31
  32 B<Authentication>
  33
  34 =item 6
  35
  36 L<Authorization|Catalyst::Manual::Tutorial::Authorization>
  37
  38 =item 7
  39
  40 L<Debugging|Catalyst::Manual::Tutorial::Debugging>
  41
  42 =item 8
  43
  44 L<Testing|Catalyst::Manual::Tutorial::Testing>
  45
  46 =item 9
  47
  48 L<Advanced CRUD|Catalyst::Manual::Tutorial::AdvancedCRUD>
  49
  50 =item 10
  51
  52 L<Appendices|Catalyst::Manual::Tutorial::Appendices>
  53
  54 =back
  55
  56
  57 =head1 DESCRIPTION
  58
  59 Now that we finally have a simple yet functional application, we can
  60 focus on providing authentication (with authorization coming next in
  61 Chapter 6).
  62
  63 This chapter of the tutorial is divided into two main sections: 1) basic,
  64 cleartext authentication and 2) hash-based authentication.
  65
  66 You can checkout the source code for this example from the catalyst
  67 subversion repository as per the instructions in
  68 L<Catalyst::Manual::Tutorial::Intro|Catalyst::Manual::Tutorial::Intro>.
  69
  70
  71 =head1 BASIC AUTHENTICATION
  72
  73 This section explores how to add authentication logic to a Catalyst
  74 application.
  75
  76
  77 =head2 Add Users and Roles to the Database
  78
  79 First, we add both user and role information to the database (we will
  80 add the role information here although it will not be used until the
  81 authorization section, Chapter 6).  Create a new SQL script file by opening
  82 C<myapp02.sql> in your editor and insert:
  83
  84     --
  85     -- Add users and roles tables, along with a many-to-many join table
  86     --
  87     CREATE TABLE users (
  88             id            INTEGER PRIMARY KEY,
  89             username      TEXT,
  90             password      TEXT,
  91             email_address TEXT,
  92             first_name    TEXT,
  93             last_name     TEXT,
  94             active        INTEGER
  95     );
  96     CREATE TABLE roles (
  97             id   INTEGER PRIMARY KEY,
  98             role TEXT
  99     );
 100     CREATE TABLE user_roles (
 101             user_id INTEGER,
 102             role_id INTEGER,
 103             PRIMARY KEY (user_id, role_id)
 104     );
 105     --
 106     -- Load up some initial test data
 107     --
 108     INSERT INTO users VALUES (1, 'test01', 'mypass', 't01@na.com', 'Joe',  'Blow', 1);
 109     INSERT INTO users VALUES (2, 'test02', 'mypass', 't02@na.com', 'Jane', 'Doe',  1);
 110     INSERT INTO users VALUES (3, 'test03', 'mypass', 't03@na.com', 'No',   'Go',   0);
 111     INSERT INTO roles VALUES (1, 'user');
 112     INSERT INTO roles VALUES (2, 'admin');
 113     INSERT INTO user_roles VALUES (1, 1);
 114     INSERT INTO user_roles VALUES (1, 2);
 115     INSERT INTO user_roles VALUES (2, 1);
 116     INSERT INTO user_roles VALUES (3, 1);
 117
 118 Then load this into the C<myapp.db> database with the following command:
 119
 120     $ sqlite3 myapp.db < myapp02.sql
 121
 122
 123 =head2 Add User and Role Information to DBIC Schema
 124
 125 Although we could manually edit the DBIC schema information to include
 126 the new tables added in the previous step, let's use the C<create=static>
 127 option on the DBIC model helper to do most of the work for us:
 128
 129     $ script/myapp_create.pl model DB DBIC::Schema MyApp::Schema \
 130         create=static components=TimeStamp dbi:SQLite:myapp.db
 131      exists "/root/dev/MyApp/script/../lib/MyApp/Model"
 132      exists "/root/dev/MyApp/script/../t"
 133     Dumping manual schema for MyApp::Schema to directory /root/dev/MyApp/script/../lib ...
 134     Schema dump completed.
 135      exists "/root/dev/MyApp/script/../lib/MyApp/Model/DB.pm"
 136     $
 137     $ ls lib/MyApp/Schema/Result
 138     Authors.pm  BookAuthors.pm  Books.pm  Roles.pm  UserRoles.pm  Users.pm
 139
 140 Notice how the helper has added three new table-specific result source
 141 files to the C<lib/MyApp/Schema/Result> directory.  And, more
 142 importantly, even if there were changes to the existing result source
 143 files, those changes would have only been written above the C<# DO NOT
 144 MODIFY THIS OR ANYTHING ABOVE!> comment and your hand-edited
 145 enhancements would have been preserved.
 146
 147 Speaking of "hand-edit ted enhancements," we should now add
 148 relationship information to the three new result source files.  Edit
 149 each of these files and add the following information between the C<#
 150 DO NOT MODIFY THIS OR ANYTHING ABOVE!> comment and the closing C<1;>:
 151
 152 C<lib/MyApp/Schema/Result/Users.pm>:
 153
 154     #
 155     # Set relationships:
 156     #
 157
 158     # has_many():
 159     #   args:
 160     #     1) Name of relationship, DBIC will create accessor with this name
 161     #     2) Name of the model class referenced by this relationship
 162     #     3) Column name in *foreign* table (aka, foreign key in peer table)
 163     __PACKAGE__->has_many(map_user_role => 'MyApp::Schema::Result::UserRoles', 'user_id');
 164
 165     # many_to_many():
 166     #   args:
 167     #     1) Name of relationship, DBIC will create accessor with this name
 168     #     2) Name of has_many() relationship this many_to_many() is shortcut for
 169     #     3) Name of belongs_to() relationship in model class of has_many() above
 170     #   You must already have the has_many() defined to use a many_to_many().
 171     __PACKAGE__->many_to_many(roles => 'map_user_role', 'role');
 172
 173
 174 C<lib/MyApp/Schema/Result/Roles.pm>:
 175
 176     #
 177     # Set relationships:
 178     #
 179
 180     # has_many():
 181     #   args:
 182     #     1) Name of relationship, DBIC will create accessor with this name
 183     #     2) Name of the model class referenced by this relationship
 184     #     3) Column name in *foreign* table (aka, foreign key in peer table)
 185     __PACKAGE__->has_many(map_user_role => 'MyApp::Schema::Result::UserRoles', 'role_id');
 186
 187
 188 C<lib/MyApp/Schema/Result/UserRoles.pm>:
 189
 190     #
 191     # Set relationships:
 192     #
 193
 194     # belongs_to():
 195     #   args:
 196     #     1) Name of relationship, DBIC will create accessor with this name
 197     #     2) Name of the model class referenced by this relationship
 198     #     3) Column name in *this* table
 199     __PACKAGE__->belongs_to(user => 'MyApp::Schema::Result::Users', 'user_id');
 200
 201     # belongs_to():
 202     #   args:
 203     #     1) Name of relationship, DBIC will create accessor with this name
 204     #     2) Name of the model class referenced by this relationship
 205     #     3) Column name in *this* table
 206     __PACKAGE__->belongs_to(role => 'MyApp::Schema::Result::Roles', 'role_id');
 207
 208
 209 The code for these three sets of updates is obviously very similar to
 210 the edits we made to the C<Books>, C<Authors>, and C<BookAuthors>
 211 classes created in Chapter 3.
 212
 213 Note that we do not need to make any change to the
 214 C<lib/MyApp/Schema.pm> schema file.  It simply tells DBIC to load all
 215 of the Result Class and ResultSet Class files it finds in below the
 216 C<lib/MyApp/Schema> directory, so it will automatically pick up our
 217 new table information.
 218
 219
 220 =head2 Sanity-Check Reload of Development Server
 221
 222 We aren't ready to try out the authentication just yet; we only want
 223 to do a quick check to be sure our model loads correctly.  Press
 224 C<Ctrl-C> to kill the previous server instance (if it's still running)
 225 and restart it:
 226
 227     $ script/myapp_server.pl
 228
 229 Look for the three new model objects in the startup debug output:
 230
 231     ...
 232      .-------------------------------------------------------------------+----------.
 233     | Class                                                             | Type     |
 234     +-------------------------------------------------------------------+----------+
 235     | MyApp::Controller::Books                                          | instance |
 236     | MyApp::Controller::Root                                           | instance |
 237     | MyApp::Model::DB                                                  | instance |
 238     | MyApp::Model::DB::Author                                          | class    |
 239     | MyApp::Model::DB::Books                                           | class    |
 240     | MyApp::Model::DB::BookAuthors                                     | class    |
 241     | MyApp::Model::DB::Roles                                           | class    |
 242     | MyApp::Model::DB::Users                                           | class    |
 243     | MyApp::Model::DB::UserRoles                                       | class    |
 244     | MyApp::View::TT                                                   | instance |
 245     '-------------------------------------------------------------------+----------'
 246     ...
 247
 248 Again, notice that your "Result Class" classes have been "re-loaded"
 249 by Catalyst under C<MyApp::Model>.
 250
 251
 252 =head2 Include Authentication and Session Plugins
 253
 254 Edit C<lib/MyApp.pm> and update it as follows (everything below
 255 C<StackTrace> is new):
 256
 257     # Load plugins
 258     use Catalyst qw/-Debug
 259                 ConfigLoader
 260                 Static::Simple
 261
 262                 StackTrace
 263
 264                 Authentication
 265
 266                 Session
 267                 Session::Store::FastMmap
 268                 Session::State::Cookie
 269                 /;
 270
 271 B<Note:> As discussed in MoreCatalystBasics, different versions of
 272 C<Catalyst::Devel> have used a variety of methods to load the plugins.
 273 You can put the plugins in the C<use Catalyst> statement if you prefer.
 274
 275 The C<Authentication> plugin supports Authentication while the
 276 C<Session> plugins are required to maintain state across multiple HTTP
 277 requests.
 278
 279 Note that the only required Authentication class is the main one. This
 280 is a change that occurred in version 0.09999_01 of the
 281 C<Authentication> plugin. You B<do not need> to specify a particular
 282 Authentication::Store or Authentication::Credential plugin. Instead,
 283 indicate the Store and Credential you want to use in your application
 284 configuration (see below).
 285
 286 Note that there are several options for
 287 L<Session::Store|Catalyst::Plugin::Session::Store>
 288 (L<Session::Store::FastMmap|Catalyst::Plugin::Session::Store::FastMmap>
 289 is generally a good choice if you are on Unix; try
 290 L<Session::Store::File|Catalyst::Plugin::Session::Store::File> if you
 291 are on Win32) -- consult
 292 L<Session::Store|Catalyst::Plugin::Session::Store> and its subclasses
 293 for additional information and options (for example to use a database-
 294 backed session store).
 295
 296
 297 =head2 Configure Authentication
 298
 299 There are a variety of way to provide configuration information to
 300 L<Catalyst::Plugin::Authentication|Catalyst::Plugin::Authentication>.
 301 Here we will use
 302 L<Catalyst::Authentication::Realm::SimpleDB|Catalyst::Authentication::Realm::SimpleDB>
 303 because it automatically sets a reasonable set of defaults for us. Open
 304 C<lib/MyApp.pm> and place the following text above the call to
 305 C<__PACKAGE__-E<gt>setup();>:
 306
 307     # Configure SimpleDB Authentication
 308     __PACKAGE__->config->{'Plugin::Authentication'} = {
 309             default => {
 310                 class           => 'SimpleDB',
 311                 user_model      => 'DB::Users',
 312                 password_type   => 'clear',
 313             },
 314         };
 315
 316 We could have placed this configuration in C<myapp.conf>, but placing
 317 it in C<lib/MyApp.pm> is probably a better place since it's not likely
 318 something that users of your application will want to change during
 319 deployment.
 320
 321
 322 =head2 Add Login and Logout Controllers
 323
 324 Use the Catalyst create script to create two stub controller files:
 325
 326     $ script/myapp_create.pl controller Login
 327     $ script/myapp_create.pl controller Logout
 328
 329 You could easily use a single controller here.  For example, you could
 330 have a C<User> controller with both C<login> and C<logout> actions.
 331 Remember, Catalyst is designed to be very flexible, and leaves such
 332 matters up to you, the designer and programmer.
 333
 334 Then open C<lib/MyApp/Controller/Login.pm>, locate the
 335 C<sub index :Path :Args(0)> method (or C<sub index : Private> if you
 336 are using an older version of Catalyst) that was automatically
 337 inserted by the helpers when we created the Login controller above,
 338 and update the definition of C<sub index> to match:
 339
 340     =head2 index
 341
 342     Login logic
 343
 344     =cut
 345
 346     sub index :Path :Args(0) {
 347         my ($self, $c) = @_;
 348
 349         # Get the username and password from form
 350         my $username = $c->request->params->{username} || "";
 351         my $password = $c->request->params->{password} || "";
 352
 353         # If the username and password values were found in form
 354         if ($username && $password) {
 355             # Attempt to log the user in
 356             if ($c->authenticate({ username => $username,
 357                                    password => $password  } )) {
 358                 # If successful, then let them use the application
 359                 $c->response->redirect($c->uri_for(
 360                     $c->controller('Books')->action_for('list')));
 361                 return;
 362             } else {
 363                 # Set an error message
 364                 $c->stash->{error_msg} = "Bad username or password.";
 365             }
 366         }
 367
 368         # If either of above don't work out, send to the login page
 369         $c->stash->{template} = 'login.tt2';
 370     }
 371
 372 This controller fetches the C<username> and C<password> values from the
 373 login form and attempts to authenticate the user.  If successful, it
 374 redirects the user to the book list page.  If the login fails, the user
 375 will stay at the login page and receive an error message.  If the
 376 C<username> and C<password> values are not present in the form, the
 377 user will be taken to the empty login form.
 378
 379 Note that we could have used something like "C<sub default :Path>",
 380 however, it is generally recommended (partly for historical reasons,
 381 and partly for code clarity) only to use C<default> in
 382 C<MyApp::Controller::Root>, and then mainly to generate the 404 not
 383 found page for the application.
 384
 385 Instead, we are using "C<sub somename :Path :Args(0) {...}>" here to
 386 specifically match the URL C</login>. C<Path> actions (aka, "literal
 387 actions") create URI matches relative to the namespace of the
 388 controller where they are defined.  Although C<Path> supports
 389 arguments that allow relative and absolute paths to be defined, here
 390 we use an empty C<Path> definition to match on just the name of the
 391 controller itself.  The method name, C<index>, is arbitrary. We make
 392 the match even more specific with the C<:Args(0)> action modifier --
 393 this forces the match on I<only> C</login>, not
 394 C</login/somethingelse>.
 395
 396 Next, update the corresponding method in
 397 C<lib/MyApp/Controller/Logout.pm> to match:
 398
 399     =head2 index
 400
 401     Logout logic
 402
 403     =cut
 404
 405     sub index :Path :Args(0) {
 406         my ($self, $c) = @_;
 407
 408         # Clear the user's state
 409         $c->logout;
 410
 411         # Send the user to the starting point
 412         $c->response->redirect($c->uri_for('/'));
 413     }
 414
 415 As with the login controller, be sure to delete the
 416 C<$c-E<gt>response-E<gt>body('Matched MyApp::Controller::Logout in Logout.');>
 417 line of the C<sub index>.
 418
 419
 420 =head2 Add a Login Form TT Template Page
 421
 422 Create a login form by opening C<root/src/login.tt2> and inserting:
 423
 424     [% META title = 'Login' %]
 425
 426     <!-- Login form -->
 427     <form method="post" action="[% c.uri_for('/login') %]">
 428       <table>
 429         <tr>
 430           <td>Username:</td>
 431           <td><input type="text" name="username" size="40" /></td>
 432         </tr>
 433         <tr>
 434           <td>Password:</td>
 435           <td><input type="password" name="password" size="40" /></td>
 436         </tr>
 437         <tr>
 438           <td colspan="2"><input type="submit" name="submit" value="Submit" /></td>
 439         </tr>
 440       </table>
 441     </form>
 442
 443
 444 =head2 Add Valid User Check
 445
 446 We need something that provides enforcement for the authentication
 447 mechanism -- a I<global> mechanism that prevents users who have not
 448 passed authentication from reaching any pages except the login page.
 449 This is generally done via an C<auto> action/method (prior to Catalyst
 450 v5.66, this sort of thing would go in C<MyApp.pm>, but starting in
 451 v5.66, the preferred location is C<lib/MyApp/Controller/Root.pm>).
 452
 453 Edit the existing C<lib/MyApp/Controller/Root.pm> class file and insert
 454 the following method:
 455
 456     =head2 auto
 457
 458     Check if there is a user and, if not, forward to login page
 459
 460     =cut
 461
 462     # Note that 'auto' runs after 'begin' but before your actions and that
 463     # 'auto's "chain" (all from application path to most specific class are run)
 464     # See the 'Actions' section of 'Catalyst::Manual::Intro' for more info.
 465     sub auto : Private {
 466         my ($self, $c) = @_;
 467
 468         # Allow unauthenticated users to reach the login page.  This
 469         # allows unauthenticated users to reach any action in the Login
 470         # controller.  To lock it down to a single action, we could use:
 471         #   if ($c->action eq $c->controller('Login')->action_for('index'))
 472         # to only allow unauthenticated access to the 'index' action we
 473         # added above.
 474         if ($c->controller eq $c->controller('Login')) {
 475             return 1;
 476         }
 477
 478         # If a user doesn't exist, force login
 479         if (!$c->user_exists) {
 480             # Dump a log message to the development server debug output
 481             $c->log->debug('***Root::auto User not found, forwarding to /login');
 482             # Redirect the user to the login page
 483             $c->response->redirect($c->uri_for('/login'));
 484             # Return 0 to cancel 'post-auto' processing and prevent use of application
 485             return 0;
 486         }
 487
 488         # User found, so return 1 to continue with processing after this 'auto'
 489         return 1;
 490     }
 491
 492 As discussed in
 493 L<Catalyst::Manual::Tutorial::MoreCatalystBasics/CREATE A CATALYST CONTROLLER>,
 494 every C<auto> method from the application/root controller down to the
 495 most specific controller will be called.  By placing the
 496 authentication enforcement code inside the C<auto> method of
 497 C<lib/MyApp/Controller/Root.pm> (or C<lib/MyApp.pm>), it will be
 498 called for I<every> request that is received by the entire
 499 application.
 500
 501
 502 =head2 Displaying Content Only to Authenticated Users
 503
 504 Let's say you want to provide some information on the login page that
 505 changes depending on whether the user has authenticated yet.  To do
 506 this, open C<root/src/login.tt2> in your editor and add the following
 507 lines to the bottom of the file:
 508
 509     ...
 510     <p>
 511     [%
 512        # This code illustrates how certain parts of the TT
 513        # template will only be shown to users who have logged in
 514     %]
 515     [% IF c.user_exists %]
 516         Please Note: You are already logged in as '[% c.user.username %]'.
 517         You can <a href="[% c.uri_for('/logout') %]">logout</a> here.
 518     [% ELSE %]
 519         You need to log in to use this application.
 520     [% END %]
 521     [%#
 522        Note that this whole block is a comment because the "#" appears
 523        immediate after the "[%" (with no spaces in between).  Although it
 524        can be a handy way to temporarily "comment out" a whole block of
 525        TT code, it's probably a little too subtle for use in "normal"
 526        comments.
 527     %]
 528     </p>
 529
 530 Although most of the code is comments, the middle few lines provide a
 531 "you are already logged in" reminder if the user returns to the login
 532 page after they have already authenticated.  For users who have not yet
 533 authenticated, a "You need to log in..." message is displayed (note the
 534 use of an IF-THEN-ELSE construct in TT).
 535
 536
 537 =head2 Try Out Authentication
 538
 539 Press C<Ctrl-C> to kill the previous server instance (if it's still
 540 running) and restart it:
 541
 542     $ script/myapp_server.pl
 543
 544 B<IMPORTANT NOTE:> If you are having issues with authentication on
 545 Internet Explorer, be sure to check the system clocks on both your
 546 server and client machines.  Internet Explorer is very picky about
 547 timestamps for cookies.  You can quickly sync a Debian system by
 548 installing the "ntpdate" package:
 549
 550     sudo aptitude -y install ntpdate
 551
 552 And then run the following command:
 553
 554     sudo ntpdate-debian
 555
 556 Or, depending on your firewall configuration:
 557
 558     sudo ntpdate-debian -u
 559
 560 Note: NTP can be a little more finicky about firewalls because it uses
 561 UDP vs. the more common TCP that you see with most Internet protocols.
 562 Worse case, you might have to manually set the time on your development
 563 box instead of using NTP.
 564
 565 Now trying going to L<http://localhost:3000/books/list> and you should
 566 be redirected to the login page, hitting Shift+Reload or Ctrl+Reload
 567 if necessary (the "You are already logged in" message should I<not>
 568 appear -- if it does, click the C<logout> button and try again). Note
 569 the C<***Root::auto User not found...> debug message in the
 570 development server output.  Enter username C<test01> and password
 571 C<mypass>, and you should be taken to the Book List page.
 572
 573 Open C<root/src/books/list.tt2> and add the following lines to the
 574 bottom (below the closing </table> tag):
 575
 576     <p>
 577       <a href="[% c.uri_for('/login') %]">Login</a>
 578       <a href="[% c.uri_for(c.controller.action_for('form_create')) %]">Create</a>
 579     </p>
 580
 581 Reload your browser and you should now see a "Login" and "Create" links
 582 at the bottom of the page (as mentioned earlier, you can update template
 583 files without reloading the development server).  Click the first link
 584 to return to the login page.  This time you I<should> see the "You are
 585 already logged in" message.
 586
 587 Finally, click the C<You can logout here> link on the C</login> page.
 588 You should stay at the login page, but the message should change to "You
 589 need to log in to use this application."
 590
 591
 592 =head1 USING PASSWORD HASHES
 593
 594 In this section we increase the security of our system by converting
 595 from cleartext passwords to SHA-1 password hashes that include a
 596 random "salt" value to make them extremely difficult to crack with
 597 dictionary and "rainbow table" attacks.
 598
 599 B<Note:> This section is optional.  You can skip it and the rest of the
 600 tutorial will function normally.
 601
 602 Be aware that even with the techniques shown in this section, the browser
 603 still transmits the passwords in cleartext to your application.  We are
 604 just avoiding the I<storage> of cleartext passwords in the database by
 605 using a salted SHA-1 hash. If you are concerned about cleartext passwords
 606 between the browser and your application, consider using SSL/TLS, made
 607 easy with the Catalyst plugin Catalyst::Plugin:RequireSSL.
 608
 609
 610 =head2 Install DBIx::Class::EncodedColumn
 611
 612 L<DBIx::Class::EncodedColumn|DBIx::Class::EncodedColumn> provides features
 613 that can greatly simplify the maintenance of passwords.  It's currently
 614 not available as a .deb package in the normal Debian repositories, so let's
 615 install it directly from CPAN:
 616
 617     $ sudo cpan DBIx::Class::EncodedColumn
 618
 619
 620 =head2 Re-Run the DBIC::Schema Model Helper to Include DBIx::Class::EncodedColumn
 621
 622 Next, we can re-run the model helper to have it include
 623 L<DBIx::Class::EncodedColumn|DBIx::Class::EncodedColumn> in all of the
 624 Result Classes it generates for us.  Simply use the same command we
 625 saw in Chapters 3 and 4, but add C<,EncodedColumn> to the C<components>
 626 argument:
 627
 628     $ script/myapp_create.pl model DB DBIC::Schema MyApp::Schema \
 629         create=static components=TimeStamp,EncodedColumn dbi:SQLite:myapp.db
 630
 631 If you then open one of the Result Classes, you will see that it
 632 includes EncodedColumn in the C<load_components> line.  Take a look at
 633 C<lib/MyApp/Schema/Result/Users.pm> since that's the main class where we
 634 want to use hashed and salted passwords:
 635
 636     __PACKAGE__->load_components("InflateColumn::DateTime", "TimeStamp", "EncodedColumn", "Core");
 637
 638
 639 =head2 Modify the "password" Column to Use EncodedColumn
 640
 641 Open the file C<lib/MyApp/Schema/Result/Users.pm> and enter the following
 642 text below the "# DO NOT MODIFY THIS OR ANYTHING ABOVE!" line but above
 643 the closing "1;":
 644
 645     # Have the 'password' column use a SHA-1 hash and 10-character salt
 646     # with hex encoding; Generate the 'check_password" method
 647     __PACKAGE__->add_columns(
 648         'password' => {
 649             data_type           => "TEXT",
 650             size                => undef,
 651             encode_column       => 1,
 652             encode_class        => 'Digest',
 653             encode_args         => {salt_length => 10},
 654             encode_check_method => 'check_password',
 655         },
 656     );
 657
 658 This redefines the automatically generated definition for the password
 659 fields at the top of the Result Class file to now use EncodedColumn
 660 logic (C<encoded_column> is set to 1).  C<encode_class> can be set to
 661 either C<Digest> to use
 662 L<DBIx::Class::EncodedColumn::Digest|DBIx::Class::EncodedColumn::Digest>,
 663 or C<Crypt::Eksblowfish::Bcrypt> for
 664 L<DBIx::Class::EncodedColumn::Crypt::Eksblowfish::Bcrypt|DBIx::Class::EncodedColumn::Crypt::Eksblowfish::Bcrypt>.
 665 C<encode_args> is then used to customize the type of Digest you
 666 selected. Here we only specified the size of the salt to use, but
 667 we could have also modified the hashing algorithm ('SHA-256' is
 668 the default) and the format to use ('base64' is the default, but
 669 'hex' and 'binary' are other options).  To use these, you could
 670 change the C<encode_args> to something like:
 671
 672             encode_args         => {algorithm => 'SHA-1',
 673                                     format => 'hex',
 674                                     salt_length => 10},
 675
 676
 677 =head2 Load Hashed Passwords in the Database
 678
 679 Next, let's create a quick script to load some hashed and salted passwords
 680 into the C<password> column of our C<users> table.  Open the file
 681 C<set_hashed_passwords.pl> in your editor and enter the following text:
 682
 683     #!/usr/bin/perl
 684
 685     use strict;
 686     use warnings;
 687
 688     use MyApp::Schema;
 689
 690     my $schema = MyApp::Schema->connect('dbi:SQLite:myapp.db');
 691
 692     my @users = $schema->resultset('Users')->all;
 693
 694     foreach my $user (@users) {
 695         $user->password('mypass');
 696         $user->update;
 697     }
 698
 699 EncodedColumn lets us simple call C<$user->check_password($password)>
 700 to see if the user has supplied the correct password, or, as we show
 701 above, call C<$user->update($new_password)> to update the hashed
 702 password stored for this user.
 703
 704 Then run the following command:
 705
 706     $ perl -Ilib set_hashed_passwords.pl
 707
 708 We had to use the C<-Ilib> arguement to tell perl to look under the
 709 C<lib> directory for our C<MyApp::Schema> model.
 710
 711 Then dump the users table to verify that it worked:
 712
 713     $ sqlite3 myapp.db "select * from users"
 714     1|test01|38d3974fa9e9263099f7bc2574284b2f55473a9bM=fwpX2NR8|t01@na.com|Joe|Blow|1
 715     2|test02|6ed8586587e53e0d7509b1cfed5df08feadc68cbMJlnPyPt0I|t02@na.com|Jane|Doe|1
 716     3|test03|af929a151340c6aed4d54d7e2651795d1ad2e2f7UW8dHoGv9z|t03@na.com|No|Go|0
 717
 718 As you can see, the passwords are much harder to steal from the
 719 database.  Also note that this demonstrates how to use a DBIx::Class
 720 model outside of your web application -- a very useful feature in many
 721 situations.
 722
 723
 724 =head2 Enable Hashed and Salted Passwords
 725
 726 Edit C<lib/MyApp.pm> and update it to match the following text (the only change
 727 is to the C<password_type> field):
 728
 729     # Configure SimpleDB Authentication
 730     __PACKAGE__->config->{'Plugin::Authentication'} = {
 731             default => {
 732                 class           => 'SimpleDB',
 733                 user_model      => 'DB::Users',
 734                 password_type   => 'self_check',
 735             },
 736         };
 737
 738 The use of C<self_check> will cause
 739 Catalyst::Plugin::Authentication::Store::DBIC to call the
 740 C<check_password> method we enabled on our C<password> columns.
 741
 742
 743 =head2 Try Out the Hashed Passwords
 744
 745 Press C<Ctrl-C> to kill the previous server instance (if it's still
 746 running) and restart it:
 747
 748     $ script/myapp_server.pl
 749
 750 You should now be able to go to L<http://localhost:3000/books/list> and
 751 login as before.  When done, click the "logout" link on the login page
 752 (or point your browser at L<http://localhost:3000/logout>).
 753
 754
 755 =head1 USING THE SESSION FOR FLASH
 756
 757 As discussed in the previous chapter of the tutorial, C<flash> allows
 758 you to set variables in a way that is very similar to C<stash>, but it
 759 will remain set across multiple requests.  Once the value is read, it
 760 is cleared (unless reset).  Although C<flash> has nothing to do with
 761 authentication, it does leverage the same session plugins.  Now that
 762 those plugins are enabled, let's go back and update the "delete and
 763 redirect with query parameters" code seen at the end of the L<Basic
 764 CRUD|Catalyst::Manual::Tutorial::BasicCRUD> chapter of the tutorial to
 765 take advantage of C<flash>.
 766
 767 First, open C<lib/MyApp/Controller/Books.pm> and modify C<sub delete>
 768 to match the following (everything after the model search line of code
 769 has changed):
 770
 771     =head2 delete
 772
 773     Delete a book
 774
 775     =cut
 776
 777     sub delete :Chained('object') :PathPart('delete') :Args(0) {
 778         my ($self, $c) = @_;
 779
 780         # Use the book object saved by 'object' and delete it along
 781         # with related 'book_authors' entries
 782         $c->stash->{object}->delete;
 783
 784         # Use 'flash' to save information across requests until it's read
 785         $c->flash->{status_msg} = "Book deleted";
 786
 787         # Redirect the user back to the list page
 788         $c->response->redirect($c->uri_for($self->action_for('list')));
 789     }
 790
 791 Next, open C<root/src/wrapper.tt2> and update the TT code to pull from
 792 flash vs. the C<status_msg> query parameter:
 793
 794     ...
 795     <div id="content">
 796         [%# Status and error messages %]
 797         <span class="message">[% status_msg || c.flash.status_msg %]</span>
 798         <span class="error">[% error_msg %]</span>
 799         [%# This is where TT will stick all of your template's contents. -%]
 800         [% content %]
 801     </div><!-- end content -->
 802     ...
 803
 804 Although the sample above only shows the C<content> div, leave the
 805 rest of the file intact -- the only change we made to the C<wrapper.tt2>
 806 was to add "C<|| c.request.params.status_msg>" to the
 807 C<E<lt>span class="message"E<gt>> line.
 808
 809
 810 =head2 Try Out Flash
 811
 812 Restart the development server, log in, and then point your browser to
 813 L<http://localhost:3000/books/url_create/Test/1/4> to create an extra
 814 several books.  Click the "Return to list" link and delete one of the
 815 "Test" books you just added.  The C<flash> mechanism should retain our
 816 "Book deleted" status message across the redirect.
 817
 818 B<NOTE:> While C<flash> will save information across multiple requests,
 819 I<it does get cleared the first time it is read>.  In general, this is
 820 exactly what you want -- the C<flash> message will get displayed on
 821 the next screen where it's appropriate, but it won't "keep showing up"
 822 after that first time (unless you reset it).  Please refer to
 823 L<Catalyst::Plugin::Session|Catalyst::Plugin::Session> for additional
 824 information.
 825
 826
 827 =head2 Switch To Flash-To-Stash
 828
 829 Although the a use of flash above works well, the
 830 C<status_msg || c.flash.status_msg> statement is a little ugly. A nice
 831 alternative is to use the C<flash_to_stash> feature that automatically
 832 copies the content of flash to stash.  This makes your controller
 833 and template code work regardless of where it was directly access, a
 834 forward, or a redirect.  To enable C<flash_to_stash>, you can either
 835 set the value in C<lib/MyApp.pm> by changing the default
 836 C<__PACKAGE__-E<gt>config> setting to something like:
 837
 838     __PACKAGE__->config(
 839             name    => 'MyApp',
 840             session => {flash_to_stash => 1}
 841         );
 842
 843 B<or> add the following to C<myapp.conf>:
 844
 845     <session>
 846         flash_to_stash   1
 847     </session>
 848
 849 The C<__PACKAGE__-E<gt>config> option is probably preferable here
 850 since it's not something you will want to change at runtime without it
 851 possibly breaking some of your code.
 852
 853 Then edit C<root/src/wrapper.tt2> and change the C<status_msg> line
 854 to match the following:
 855
 856     <span class="message">[% status_msg %]</span>
 857
 858 Restart the development server and go to
 859 L<http://localhost:3000/books/list> in your browser.  Delete another
 860 of the "Test" books you added in the previous step.  Flash should still
 861 maintain the status message across the redirect even though you are no
 862 longer explicitly accessing C<c.flash>.
 863
 864
 865 =head1 AUTHOR
 866
 867 Kennedy Clark, C<hkclark@gmail.com>
 868
 869 Please report any errors, issues or suggestions to the author.  The
 870 most recent version of the Catalyst Tutorial can be found at
 871 L<http://dev.catalyst.perl.org/repos/Catalyst/Catalyst-Manual/5.70/trunk/lib/Catalyst/Manual/Tutorial/>.
 872
 873 Copyright 2006-2008, Kennedy Clark, under Creative Commons License
 874 (L<http://creativecommons.org/licenses/by-sa/3.0/us/>).