lib/Catalyst/Manual/Tutorial/Authentication.pod

   1 =head1 NAME
   2
   3 Catalyst::Manual::Tutorial::Authentication - Catalyst Tutorial - Chapter 5: Authentication
   4
   5
   6 =head1 OVERVIEW
   7
   8 This is B<Chapter 5 of 10> for the Catalyst tutorial.
   9
  10 L<Tutorial Overview|Catalyst::Manual::Tutorial>
  11
  12 =over 4
  13
  14 =item 1
  15
  16 L<Introduction|Catalyst::Manual::Tutorial::Intro>
  17
  18 =item 2
  19
  20 L<Catalyst Basics|Catalyst::Manual::Tutorial::CatalystBasics>
  21
  22 =item 3
  23
  24 L<More Catalyst Basics|Catalyst::Manual::Tutorial::MoreCatalystBasics>
  25
  26 =item 4
  27
  28 L<Basic CRUD|Catalyst::Manual::Tutorial::BasicCRUD>
  29
  30 =item 5
  31
  32 B<Authentication>
  33
  34 =item 6
  35
  36 L<Authorization|Catalyst::Manual::Tutorial::Authorization>
  37
  38 =item 7
  39
  40 L<Debugging|Catalyst::Manual::Tutorial::Debugging>
  41
  42 =item 8
  43
  44 L<Testing|Catalyst::Manual::Tutorial::Testing>
  45
  46 =item 9
  47
  48 L<Advanced CRUD|Catalyst::Manual::Tutorial::AdvancedCRUD>
  49
  50 =item 10
  51
  52 L<Appendices|Catalyst::Manual::Tutorial::Appendices>
  53
  54 =back
  55
  56
  57 =head1 DESCRIPTION
  58
  59 Now that we finally have a simple yet functional application, we can
  60 focus on providing authentication (with authorization coming next in
  61 Chapter 6).
  62
  63 This chapter of the tutorial is divided into two main sections: 1) basic,
  64 cleartext authentication and 2) hash-based authentication.
  65
  66 You can checkout the source code for this example from the catalyst
  67 subversion repository as per the instructions in
  68 L<Catalyst::Manual::Tutorial::Intro|Catalyst::Manual::Tutorial::Intro>.
  69
  70
  71 =head1 BASIC AUTHENTICATION
  72
  73 This section explores how to add authentication logic to a Catalyst
  74 application.
  75
  76
  77 =head2 Add Users and Roles to the Database
  78
  79 First, we add both user and role information to the database (we will
  80 add the role information here although it will not be used until the
  81 authorization section, Chapter 6).  Create a new SQL script file by opening
  82 C<myapp02.sql> in your editor and insert:
  83
  84     --
  85     -- Add users and roles tables, along with a many-to-many join table
  86     --
  87     CREATE TABLE users (
  88             id            INTEGER PRIMARY KEY,
  89             username      TEXT,
  90             password      TEXT,
  91             email_address TEXT,
  92             first_name    TEXT,
  93             last_name     TEXT,
  94             active        INTEGER
  95     );
  96     CREATE TABLE roles (
  97             id   INTEGER PRIMARY KEY,
  98             role TEXT
  99     );
 100     CREATE TABLE user_roles (
 101             user_id INTEGER,
 102             role_id INTEGER,
 103             PRIMARY KEY (user_id, role_id)
 104     );
 105     --
 106     -- Load up some initial test data
 107     --
 108     INSERT INTO users VALUES (1, 'test01', 'mypass', 't01@na.com', 'Joe',  'Blow', 1);
 109     INSERT INTO users VALUES (2, 'test02', 'mypass', 't02@na.com', 'Jane', 'Doe',  1);
 110     INSERT INTO users VALUES (3, 'test03', 'mypass', 't03@na.com', 'No',   'Go',   0);
 111     INSERT INTO roles VALUES (1, 'user');
 112     INSERT INTO roles VALUES (2, 'admin');
 113     INSERT INTO user_roles VALUES (1, 1);
 114     INSERT INTO user_roles VALUES (1, 2);
 115     INSERT INTO user_roles VALUES (2, 1);
 116     INSERT INTO user_roles VALUES (3, 1);
 117
 118 Then load this into the C<myapp.db> database with the following command:
 119
 120     $ sqlite3 myapp.db < myapp02.sql
 121
 122
 123 =head2 Add User and Role Information to DBIC Schema
 124
 125 Although we could manually edit the DBIC schema information to include
 126 the new tables added in the previous step, let's use the C<create=static>
 127 option on the DBIC model helper to do most of the work for us:
 128
 129     $ script/myapp_create.pl model DB DBIC::Schema MyApp::Schema \
 130         create=static components=TimeStamp dbi:SQLite:myapp.db
 131      exists "/root/dev/MyApp/script/../lib/MyApp/Model"
 132      exists "/root/dev/MyApp/script/../t"
 133     Dumping manual schema for MyApp::Schema to directory /root/dev/MyApp/script/../lib ...
 134     Schema dump completed.
 135      exists "/root/dev/MyApp/script/../lib/MyApp/Model/DB.pm"
 136     $
 137     $ ls lib/MyApp/Schema/Result
 138     Authors.pm  BookAuthors.pm  Books.pm  Roles.pm  UserRoles.pm  Users.pm
 139
 140 Notice how the helper has added three new table-specific result source
 141 files to the C<lib/MyApp/Schema/Result> directory.  And, more
 142 importantly, even if there were changes to the existing result source
 143 files, those changes would have only been written above the C<# DO NOT
 144 MODIFY THIS OR ANYTHING ABOVE!> comment and your hand-edited
 145 enhancements would have been preserved.
 146
 147 Speaking of "hand-edit ted enhancements," we should now add
 148 relationship information to the three new result source files.  Edit
 149 each of these files and add the following information between the C<#
 150 DO NOT MODIFY THIS OR ANYTHING ABOVE!> comment and the closing C<1;>:
 151
 152 C<lib/MyApp/Schema/Result/Users.pm>:
 153
 154     #
 155     # Set relationships:
 156     #
 157
 158     # has_many():
 159     #   args:
 160     #     1) Name of relationship, DBIC will create accessor with this name
 161     #     2) Name of the model class referenced by this relationship
 162     #     3) Column name in *foreign* table (aka, foreign key in peer table)
 163     __PACKAGE__->has_many(map_user_role => 'MyApp::Schema::Result::UserRoles', 'user_id');
 164
 165     # many_to_many():
 166     #   args:
 167     #     1) Name of relationship, DBIC will create accessor with this name
 168     #     2) Name of has_many() relationship this many_to_many() is shortcut for
 169     #     3) Name of belongs_to() relationship in model class of has_many() above
 170     #   You must already have the has_many() defined to use a many_to_many().
 171     __PACKAGE__->many_to_many(roles => 'map_user_role', 'role');
 172
 173
 174 C<lib/MyApp/Schema/Result/Roles.pm>:
 175
 176     #
 177     # Set relationships:
 178     #
 179
 180     # has_many():
 181     #   args:
 182     #     1) Name of relationship, DBIC will create accessor with this name
 183     #     2) Name of the model class referenced by this relationship
 184     #     3) Column name in *foreign* table (aka, foreign key in peer table)
 185     __PACKAGE__->has_many(map_user_role => 'MyApp::Schema::Result::UserRoles', 'role_id');
 186
 187
 188 C<lib/MyApp/Schema/Result/UserRoles.pm>:
 189
 190     #
 191     # Set relationships:
 192     #
 193
 194     # belongs_to():
 195     #   args:
 196     #     1) Name of relationship, DBIC will create accessor with this name
 197     #     2) Name of the model class referenced by this relationship
 198     #     3) Column name in *this* table
 199     __PACKAGE__->belongs_to(user => 'MyApp::Schema::Result::Users', 'user_id');
 200
 201     # belongs_to():
 202     #   args:
 203     #     1) Name of relationship, DBIC will create accessor with this name
 204     #     2) Name of the model class referenced by this relationship
 205     #     3) Column name in *this* table
 206     __PACKAGE__->belongs_to(role => 'MyApp::Schema::Result::Roles', 'role_id');
 207
 208
 209 The code for these three sets of updates is obviously very similar to
 210 the edits we made to the C<Books>, C<Authors>, and C<BookAuthors>
 211 classes created in Chapter 3.
 212
 213 Note that we do not need to make any change to the
 214 C<lib/MyApp/Schema.pm> schema file.  It simply tells DBIC to load all
 215 of the Result Class and ResultSet Class files it finds in below the
 216 C<lib/MyApp/Schema> directory, so it will automatically pick up our
 217 new table information.
 218
 219
 220 =head2 Sanity-Check Reload of Development Server
 221
 222 We aren't ready to try out the authentication just yet; we only want
 223 to do a quick check to be sure our model loads correctly.  Press
 224 C<Ctrl-C> to kill the previous server instance (if it's still running)
 225 and restart it:
 226
 227     $ script/myapp_server.pl
 228
 229 Look for the three new model objects in the startup debug output:
 230
 231     ...
 232      .-------------------------------------------------------------------+----------.
 233     | Class                                                             | Type     |
 234     +-------------------------------------------------------------------+----------+
 235     | MyApp::Controller::Books                                          | instance |
 236     | MyApp::Controller::Root                                           | instance |
 237     | MyApp::Model::DB                                                  | instance |
 238     | MyApp::Model::DB::Author                                          | class    |
 239     | MyApp::Model::DB::Books                                           | class    |
 240     | MyApp::Model::DB::BookAuthors                                     | class    |
 241     | MyApp::Model::DB::Roles                                           | class    |
 242     | MyApp::Model::DB::Users                                           | class    |
 243     | MyApp::Model::DB::UserRoles                                       | class    |
 244     | MyApp::View::TT                                                   | instance |
 245     '-------------------------------------------------------------------+----------'
 246     ...
 247
 248 Again, notice that your "Result Class" classes have been "re-loaded"
 249 by Catalyst under C<MyApp::Model>.
 250
 251
 252 =head2 Include Authentication and Session Plugins
 253
 254 Edit C<lib/MyApp.pm> and update it as follows (everything below
 255 C<StackTrace> is new):
 256
 257     # Load plugins
 258     use Catalyst qw/-Debug
 259                 ConfigLoader
 260                 Static::Simple
 261
 262                 StackTrace
 263
 264                 Authentication
 265
 266                 Session
 267                 Session::Store::FastMmap
 268                 Session::State::Cookie
 269                 /;
 270
 271 B<Note:> As discussed in MoreCatalystBasics, different versions of
 272 C<Catalyst::Devel> have used a variety of methods to load the plugins.
 273 You can put the plugins in the C<use Catalyst> statement if you prefer.
 274
 275 The C<Authentication> plugin supports Authentication while the
 276 C<Session> plugins are required to maintain state across multiple HTTP
 277 requests.
 278
 279 Note that the only required Authentication class is the main one. This
 280 is a change that occurred in version 0.09999_01 of the
 281 C<Authentication> plugin. You B<do not need> to specify a particular
 282 Authentication::Store or Authentication::Credential plugin. Instead,
 283 indicate the Store and Credential you want to use in your application
 284 configuration (see below).
 285
 286 Note that there are several options for
 287 L<Session::Store|Catalyst::Plugin::Session::Store>
 288 (L<Session::Store::FastMmap|Catalyst::Plugin::Session::Store::FastMmap>
 289 is generally a good choice if you are on Unix; try
 290 L<Session::Store::File|Catalyst::Plugin::Session::Store::File> if you
 291 are on Win32) -- consult
 292 L<Session::Store|Catalyst::Plugin::Session::Store> and its subclasses
 293 for additional information and options (for example to use a database-
 294 backed session store).
 295
 296
 297 =head2 Configure Authentication
 298
 299 There are a variety of way to provide configuration information to
 300 L<Catalyst::Plugin::Authentication|Catalyst::Plugin::Authentication>.
 301 Here we will use
 302 L<Catalyst::Authentication::Realm::SimpleDB|Catalyst::Authentication::Realm::SimpleDB>
 303 because it automatically sets a reasonable set of defaults for us. Open
 304 C<lib/MyApp.pm> and place the following text above the call to
 305 C<__PACKAGE__-E<gt>setup();>:
 306
 307     # Configure SimpleDB Authentication
 308     __PACKAGE__->config->{'Plugin::Authentication'} = {
 309             default => {
 310                 class           => 'SimpleDB',
 311                 user_model      => 'DB::Users',
 312                 password_type   => 'clear',
 313             },
 314         };
 315
 316 We could have placed this configuration in C<myapp.conf>, but placing
 317 it in C<lib/MyApp.pm> is probably a better place since it's not likely
 318 something that users of your application will want to change during
 319 deployment (or you could use a mixture: leave C<class> and
 320 C<user_model> defined in C<lib/MyApp.pm> as we show above, but place
 321 C<password_type> in C<myapp.conf> to allow the type of password to be
 322 easily modified during deployment).  We will stick with putting
 323 all of the authentication-related configuration in C<lib/MyApp.pm>
 324 for the tutorial, but if you wish to use C<myapp.conf>, just convert
 325 to the following code:
 326
 327     <Plugin::Authentication>
 328         use_session 1
 329         <default>
 330             password_type self_check
 331             user_model    DB::Users
 332             class         SimpleDB
 333         </default>
 334     </Plugin::Authentication>
 335
 336 B<TIP:> Here is a short script that will dump the contents of
 337 C<MyApp->config> to L<Config::General|Config::General> format in
 338 C<myapp.conf>:
 339
 340     $ perl -Ilib -e 'use MyApp; use Config::General;
 341         Config::General->new->save_file("myapp.conf", MyApp->config);'
 342
 343
 344 =head2 Add Login and Logout Controllers
 345
 346 Use the Catalyst create script to create two stub controller files:
 347
 348     $ script/myapp_create.pl controller Login
 349     $ script/myapp_create.pl controller Logout
 350
 351 You could easily use a single controller here.  For example, you could
 352 have a C<User> controller with both C<login> and C<logout> actions.
 353 Remember, Catalyst is designed to be very flexible, and leaves such
 354 matters up to you, the designer and programmer.
 355
 356 Then open C<lib/MyApp/Controller/Login.pm>, locate the
 357 C<sub index :Path :Args(0)> method (or C<sub index : Private> if you
 358 are using an older version of Catalyst) that was automatically
 359 inserted by the helpers when we created the Login controller above,
 360 and update the definition of C<sub index> to match:
 361
 362     =head2 index
 363
 364     Login logic
 365
 366     =cut
 367
 368     sub index :Path :Args(0) {
 369         my ($self, $c) = @_;
 370
 371         # Get the username and password from form
 372         my $username = $c->request->params->{username} || "";
 373         my $password = $c->request->params->{password} || "";
 374
 375         # If the username and password values were found in form
 376         if ($username && $password) {
 377             # Attempt to log the user in
 378             if ($c->authenticate({ username => $username,
 379                                    password => $password  } )) {
 380                 # If successful, then let them use the application
 381                 $c->response->redirect($c->uri_for(
 382                     $c->controller('Books')->action_for('list')));
 383                 return;
 384             } else {
 385                 # Set an error message
 386                 $c->stash->{error_msg} = "Bad username or password.";
 387             }
 388         }
 389
 390         # If either of above don't work out, send to the login page
 391         $c->stash->{template} = 'login.tt2';
 392     }
 393
 394 This controller fetches the C<username> and C<password> values from the
 395 login form and attempts to authenticate the user.  If successful, it
 396 redirects the user to the book list page.  If the login fails, the user
 397 will stay at the login page and receive an error message.  If the
 398 C<username> and C<password> values are not present in the form, the
 399 user will be taken to the empty login form.
 400
 401 Note that we could have used something like "C<sub default :Path>",
 402 however, it is generally recommended (partly for historical reasons,
 403 and partly for code clarity) only to use C<default> in
 404 C<MyApp::Controller::Root>, and then mainly to generate the 404 not
 405 found page for the application.
 406
 407 Instead, we are using "C<sub somename :Path :Args(0) {...}>" here to
 408 specifically match the URL C</login>. C<Path> actions (aka, "literal
 409 actions") create URI matches relative to the namespace of the
 410 controller where they are defined.  Although C<Path> supports
 411 arguments that allow relative and absolute paths to be defined, here
 412 we use an empty C<Path> definition to match on just the name of the
 413 controller itself.  The method name, C<index>, is arbitrary. We make
 414 the match even more specific with the C<:Args(0)> action modifier --
 415 this forces the match on I<only> C</login>, not
 416 C</login/somethingelse>.
 417
 418 Next, update the corresponding method in
 419 C<lib/MyApp/Controller/Logout.pm> to match:
 420
 421     =head2 index
 422
 423     Logout logic
 424
 425     =cut
 426
 427     sub index :Path :Args(0) {
 428         my ($self, $c) = @_;
 429
 430         # Clear the user's state
 431         $c->logout;
 432
 433         # Send the user to the starting point
 434         $c->response->redirect($c->uri_for('/'));
 435     }
 436
 437 As with the login controller, be sure to delete the
 438 C<$c-E<gt>response-E<gt>body('Matched MyApp::Controller::Logout in Logout.');>
 439 line of the C<sub index>.
 440
 441
 442 =head2 Add a Login Form TT Template Page
 443
 444 Create a login form by opening C<root/src/login.tt2> and inserting:
 445
 446     [% META title = 'Login' %]
 447
 448     <!-- Login form -->
 449     <form method="post" action="[% c.uri_for('/login') %]">
 450       <table>
 451         <tr>
 452           <td>Username:</td>
 453           <td><input type="text" name="username" size="40" /></td>
 454         </tr>
 455         <tr>
 456           <td>Password:</td>
 457           <td><input type="password" name="password" size="40" /></td>
 458         </tr>
 459         <tr>
 460           <td colspan="2"><input type="submit" name="submit" value="Submit" /></td>
 461         </tr>
 462       </table>
 463     </form>
 464
 465
 466 =head2 Add Valid User Check
 467
 468 We need something that provides enforcement for the authentication
 469 mechanism -- a I<global> mechanism that prevents users who have not
 470 passed authentication from reaching any pages except the login page.
 471 This is generally done via an C<auto> action/method (prior to Catalyst
 472 v5.66, this sort of thing would go in C<MyApp.pm>, but starting in
 473 v5.66, the preferred location is C<lib/MyApp/Controller/Root.pm>).
 474
 475 Edit the existing C<lib/MyApp/Controller/Root.pm> class file and insert
 476 the following method:
 477
 478     =head2 auto
 479
 480     Check if there is a user and, if not, forward to login page
 481
 482     =cut
 483
 484     # Note that 'auto' runs after 'begin' but before your actions and that
 485     # 'auto's "chain" (all from application path to most specific class are run)
 486     # See the 'Actions' section of 'Catalyst::Manual::Intro' for more info.
 487     sub auto : Private {
 488         my ($self, $c) = @_;
 489
 490         # Allow unauthenticated users to reach the login page.  This
 491         # allows unauthenticated users to reach any action in the Login
 492         # controller.  To lock it down to a single action, we could use:
 493         #   if ($c->action eq $c->controller('Login')->action_for('index'))
 494         # to only allow unauthenticated access to the 'index' action we
 495         # added above.
 496         if ($c->controller eq $c->controller('Login')) {
 497             return 1;
 498         }
 499
 500         # If a user doesn't exist, force login
 501         if (!$c->user_exists) {
 502             # Dump a log message to the development server debug output
 503             $c->log->debug('***Root::auto User not found, forwarding to /login');
 504             # Redirect the user to the login page
 505             $c->response->redirect($c->uri_for('/login'));
 506             # Return 0 to cancel 'post-auto' processing and prevent use of application
 507             return 0;
 508         }
 509
 510         # User found, so return 1 to continue with processing after this 'auto'
 511         return 1;
 512     }
 513
 514 As discussed in
 515 L<Catalyst::Manual::Tutorial::MoreCatalystBasics/CREATE A CATALYST CONTROLLER>,
 516 every C<auto> method from the application/root controller down to the
 517 most specific controller will be called.  By placing the
 518 authentication enforcement code inside the C<auto> method of
 519 C<lib/MyApp/Controller/Root.pm> (or C<lib/MyApp.pm>), it will be
 520 called for I<every> request that is received by the entire
 521 application.
 522
 523
 524 =head2 Displaying Content Only to Authenticated Users
 525
 526 Let's say you want to provide some information on the login page that
 527 changes depending on whether the user has authenticated yet.  To do
 528 this, open C<root/src/login.tt2> in your editor and add the following
 529 lines to the bottom of the file:
 530
 531     ...
 532     <p>
 533     [%
 534        # This code illustrates how certain parts of the TT
 535        # template will only be shown to users who have logged in
 536     %]
 537     [% IF c.user_exists %]
 538         Please Note: You are already logged in as '[% c.user.username %]'.
 539         You can <a href="[% c.uri_for('/logout') %]">logout</a> here.
 540     [% ELSE %]
 541         You need to log in to use this application.
 542     [% END %]
 543     [%#
 544        Note that this whole block is a comment because the "#" appears
 545        immediate after the "[%" (with no spaces in between).  Although it
 546        can be a handy way to temporarily "comment out" a whole block of
 547        TT code, it's probably a little too subtle for use in "normal"
 548        comments.
 549     %]
 550     </p>
 551
 552 Although most of the code is comments, the middle few lines provide a
 553 "you are already logged in" reminder if the user returns to the login
 554 page after they have already authenticated.  For users who have not yet
 555 authenticated, a "You need to log in..." message is displayed (note the
 556 use of an IF-THEN-ELSE construct in TT).
 557
 558
 559 =head2 Try Out Authentication
 560
 561 Press C<Ctrl-C> to kill the previous server instance (if it's still
 562 running) and restart it:
 563
 564     $ script/myapp_server.pl
 565
 566 B<IMPORTANT NOTE:> If you are having issues with authentication on
 567 Internet Explorer, be sure to check the system clocks on both your
 568 server and client machines.  Internet Explorer is very picky about
 569 timestamps for cookies.  You can quickly sync a Debian system by
 570 installing the "ntpdate" package:
 571
 572     sudo aptitude -y install ntpdate
 573
 574 And then run the following command:
 575
 576     sudo ntpdate-debian
 577
 578 Or, depending on your firewall configuration:
 579
 580     sudo ntpdate-debian -u
 581
 582 Note: NTP can be a little more finicky about firewalls because it uses
 583 UDP vs. the more common TCP that you see with most Internet protocols.
 584 Worse case, you might have to manually set the time on your development
 585 box instead of using NTP.
 586
 587 Now trying going to L<http://localhost:3000/books/list> and you should
 588 be redirected to the login page, hitting Shift+Reload or Ctrl+Reload
 589 if necessary (the "You are already logged in" message should I<not>
 590 appear -- if it does, click the C<logout> button and try again). Note
 591 the C<***Root::auto User not found...> debug message in the
 592 development server output.  Enter username C<test01> and password
 593 C<mypass>, and you should be taken to the Book List page.
 594
 595 Open C<root/src/books/list.tt2> and add the following lines to the
 596 bottom (below the closing </table> tag):
 597
 598     <p>
 599       <a href="[% c.uri_for('/login') %]">Login</a>
 600       <a href="[% c.uri_for(c.controller.action_for('form_create')) %]">Create</a>
 601     </p>
 602
 603 Reload your browser and you should now see a "Login" and "Create" links
 604 at the bottom of the page (as mentioned earlier, you can update template
 605 files without reloading the development server).  Click the first link
 606 to return to the login page.  This time you I<should> see the "You are
 607 already logged in" message.
 608
 609 Finally, click the C<You can logout here> link on the C</login> page.
 610 You should stay at the login page, but the message should change to "You
 611 need to log in to use this application."
 612
 613
 614 =head1 USING PASSWORD HASHES
 615
 616 In this section we increase the security of our system by converting
 617 from cleartext passwords to SHA-1 password hashes that include a
 618 random "salt" value to make them extremely difficult to crack with
 619 dictionary and "rainbow table" attacks.
 620
 621 B<Note:> This section is optional.  You can skip it and the rest of the
 622 tutorial will function normally.
 623
 624 Be aware that even with the techniques shown in this section, the browser
 625 still transmits the passwords in cleartext to your application.  We are
 626 just avoiding the I<storage> of cleartext passwords in the database by
 627 using a salted SHA-1 hash. If you are concerned about cleartext passwords
 628 between the browser and your application, consider using SSL/TLS, made
 629 easy with the Catalyst plugin Catalyst::Plugin:RequireSSL.
 630
 631
 632 =head2 Install DBIx::Class::EncodedColumn
 633
 634 L<DBIx::Class::EncodedColumn|DBIx::Class::EncodedColumn> provides features
 635 that can greatly simplify the maintenance of passwords.  It's currently
 636 not available as a .deb package in the normal Debian repositories, so let's
 637 install it directly from CPAN:
 638
 639     $ sudo cpan DBIx::Class::EncodedColumn
 640
 641
 642 =head2 Re-Run the DBIC::Schema Model Helper to Include DBIx::Class::EncodedColumn
 643
 644 Next, we can re-run the model helper to have it include
 645 L<DBIx::Class::EncodedColumn|DBIx::Class::EncodedColumn> in all of the
 646 Result Classes it generates for us.  Simply use the same command we
 647 saw in Chapters 3 and 4, but add C<,EncodedColumn> to the C<components>
 648 argument:
 649
 650     $ script/myapp_create.pl model DB DBIC::Schema MyApp::Schema \
 651         create=static components=TimeStamp,EncodedColumn dbi:SQLite:myapp.db
 652
 653 If you then open one of the Result Classes, you will see that it
 654 includes EncodedColumn in the C<load_components> line.  Take a look at
 655 C<lib/MyApp/Schema/Result/Users.pm> since that's the main class where we
 656 want to use hashed and salted passwords:
 657
 658     __PACKAGE__->load_components("InflateColumn::DateTime", "TimeStamp", "EncodedColumn", "Core");
 659
 660
 661 =head2 Modify the "password" Column to Use EncodedColumn
 662
 663 Open the file C<lib/MyApp/Schema/Result/Users.pm> and enter the following
 664 text below the "# DO NOT MODIFY THIS OR ANYTHING ABOVE!" line but above
 665 the closing "1;":
 666
 667     # Have the 'password' column use a SHA-1 hash and 10-character salt
 668     # with hex encoding; Generate the 'check_password" method
 669     __PACKAGE__->add_columns(
 670         'password' => {
 671             data_type           => "TEXT",
 672             size                => undef,
 673             encode_column       => 1,
 674             encode_class        => 'Digest',
 675             encode_args         => {salt_length => 10},
 676             encode_check_method => 'check_password',
 677         },
 678     );
 679
 680 This redefines the automatically generated definition for the password
 681 fields at the top of the Result Class file to now use EncodedColumn
 682 logic (C<encoded_column> is set to 1).  C<encode_class> can be set to
 683 either C<Digest> to use
 684 L<DBIx::Class::EncodedColumn::Digest|DBIx::Class::EncodedColumn::Digest>,
 685 or C<Crypt::Eksblowfish::Bcrypt> for
 686 L<DBIx::Class::EncodedColumn::Crypt::Eksblowfish::Bcrypt|DBIx::Class::EncodedColumn::Crypt::Eksblowfish::Bcrypt>.
 687 C<encode_args> is then used to customize the type of Digest you
 688 selected. Here we only specified the size of the salt to use, but
 689 we could have also modified the hashing algorithm ('SHA-256' is
 690 the default) and the format to use ('base64' is the default, but
 691 'hex' and 'binary' are other options).  To use these, you could
 692 change the C<encode_args> to something like:
 693
 694             encode_args         => {algorithm => 'SHA-1',
 695                                     format => 'hex',
 696                                     salt_length => 10},
 697
 698
 699 =head2 Load Hashed Passwords in the Database
 700
 701 Next, let's create a quick script to load some hashed and salted passwords
 702 into the C<password> column of our C<users> table.  Open the file
 703 C<set_hashed_passwords.pl> in your editor and enter the following text:
 704
 705     #!/usr/bin/perl
 706
 707     use strict;
 708     use warnings;
 709
 710     use MyApp::Schema;
 711
 712     my $schema = MyApp::Schema->connect('dbi:SQLite:myapp.db');
 713
 714     my @users = $schema->resultset('Users')->all;
 715
 716     foreach my $user (@users) {
 717         $user->password('mypass');
 718         $user->update;
 719     }
 720
 721 EncodedColumn lets us simple call C<$user->check_password($password)>
 722 to see if the user has supplied the correct password, or, as we show
 723 above, call C<$user->update($new_password)> to update the hashed
 724 password stored for this user.
 725
 726 Then run the following command:
 727
 728     $ perl -Ilib set_hashed_passwords.pl
 729
 730 We had to use the C<-Ilib> arguement to tell perl to look under the
 731 C<lib> directory for our C<MyApp::Schema> model.
 732
 733 Then dump the users table to verify that it worked:
 734
 735     $ sqlite3 myapp.db "select * from users"
 736     1|test01|38d3974fa9e9263099f7bc2574284b2f55473a9bM=fwpX2NR8|t01@na.com|Joe|Blow|1
 737     2|test02|6ed8586587e53e0d7509b1cfed5df08feadc68cbMJlnPyPt0I|t02@na.com|Jane|Doe|1
 738     3|test03|af929a151340c6aed4d54d7e2651795d1ad2e2f7UW8dHoGv9z|t03@na.com|No|Go|0
 739
 740 As you can see, the passwords are much harder to steal from the
 741 database.  Also note that this demonstrates how to use a DBIx::Class
 742 model outside of your web application -- a very useful feature in many
 743 situations.
 744
 745
 746 =head2 Enable Hashed and Salted Passwords
 747
 748 Edit C<lib/MyApp.pm> and update it to match the following text (the only change
 749 is to the C<password_type> field):
 750
 751     # Configure SimpleDB Authentication
 752     __PACKAGE__->config->{'Plugin::Authentication'} = {
 753             default => {
 754                 class           => 'SimpleDB',
 755                 user_model      => 'DB::Users',
 756                 password_type   => 'self_check',
 757             },
 758         };
 759
 760 The use of C<self_check> will cause
 761 Catalyst::Plugin::Authentication::Store::DBIC to call the
 762 C<check_password> method we enabled on our C<password> columns.
 763
 764
 765 =head2 Try Out the Hashed Passwords
 766
 767 Press C<Ctrl-C> to kill the previous server instance (if it's still
 768 running) and restart it:
 769
 770     $ script/myapp_server.pl
 771
 772 You should now be able to go to L<http://localhost:3000/books/list> and
 773 login as before.  When done, click the "logout" link on the login page
 774 (or point your browser at L<http://localhost:3000/logout>).
 775
 776
 777 =head1 USING THE SESSION FOR FLASH
 778
 779 As discussed in the previous chapter of the tutorial, C<flash> allows
 780 you to set variables in a way that is very similar to C<stash>, but it
 781 will remain set across multiple requests.  Once the value is read, it
 782 is cleared (unless reset).  Although C<flash> has nothing to do with
 783 authentication, it does leverage the same session plugins.  Now that
 784 those plugins are enabled, let's go back and update the "delete and
 785 redirect with query parameters" code seen at the end of the L<Basic
 786 CRUD|Catalyst::Manual::Tutorial::BasicCRUD> chapter of the tutorial to
 787 take advantage of C<flash>.
 788
 789 First, open C<lib/MyApp/Controller/Books.pm> and modify C<sub delete>
 790 to match the following (everything after the model search line of code
 791 has changed):
 792
 793     =head2 delete
 794
 795     Delete a book
 796
 797     =cut
 798
 799     sub delete :Chained('object') :PathPart('delete') :Args(0) {
 800         my ($self, $c) = @_;
 801
 802         # Use the book object saved by 'object' and delete it along
 803         # with related 'book_authors' entries
 804         $c->stash->{object}->delete;
 805
 806         # Use 'flash' to save information across requests until it's read
 807         $c->flash->{status_msg} = "Book deleted";
 808
 809         # Redirect the user back to the list page
 810         $c->response->redirect($c->uri_for($self->action_for('list')));
 811     }
 812
 813 Next, open C<root/src/wrapper.tt2> and update the TT code to pull from
 814 flash vs. the C<status_msg> query parameter:
 815
 816     ...
 817     <div id="content">
 818         [%# Status and error messages %]
 819         <span class="message">[% status_msg || c.flash.status_msg %]</span>
 820         <span class="error">[% error_msg %]</span>
 821         [%# This is where TT will stick all of your template's contents. -%]
 822         [% content %]
 823     </div><!-- end content -->
 824     ...
 825
 826 Although the sample above only shows the C<content> div, leave the
 827 rest of the file intact -- the only change we made to the C<wrapper.tt2>
 828 was to add "C<|| c.request.params.status_msg>" to the
 829 C<E<lt>span class="message"E<gt>> line.
 830
 831
 832 =head2 Try Out Flash
 833
 834 Restart the development server, log in, and then point your browser to
 835 L<http://localhost:3000/books/url_create/Test/1/4> to create an extra
 836 several books.  Click the "Return to list" link and delete one of the
 837 "Test" books you just added.  The C<flash> mechanism should retain our
 838 "Book deleted" status message across the redirect.
 839
 840 B<NOTE:> While C<flash> will save information across multiple requests,
 841 I<it does get cleared the first time it is read>.  In general, this is
 842 exactly what you want -- the C<flash> message will get displayed on
 843 the next screen where it's appropriate, but it won't "keep showing up"
 844 after that first time (unless you reset it).  Please refer to
 845 L<Catalyst::Plugin::Session|Catalyst::Plugin::Session> for additional
 846 information.
 847
 848
 849 =head2 Switch To Flash-To-Stash
 850
 851 Although the a use of flash above works well, the
 852 C<status_msg || c.flash.status_msg> statement is a little ugly. A nice
 853 alternative is to use the C<flash_to_stash> feature that automatically
 854 copies the content of flash to stash.  This makes your controller
 855 and template code work regardless of where it was directly access, a
 856 forward, or a redirect.  To enable C<flash_to_stash>, you can either
 857 set the value in C<lib/MyApp.pm> by changing the default
 858 C<__PACKAGE__-E<gt>config> setting to something like:
 859
 860     __PACKAGE__->config(
 861             name    => 'MyApp',
 862             session => {flash_to_stash => 1}
 863         );
 864
 865 B<or> add the following to C<myapp.conf>:
 866
 867     <session>
 868         flash_to_stash   1
 869     </session>
 870
 871 The C<__PACKAGE__-E<gt>config> option is probably preferable here
 872 since it's not something you will want to change at runtime without it
 873 possibly breaking some of your code.
 874
 875 Then edit C<root/src/wrapper.tt2> and change the C<status_msg> line
 876 to match the following:
 877
 878     <span class="message">[% status_msg %]</span>
 879
 880 Restart the development server and go to
 881 L<http://localhost:3000/books/list> in your browser.  Delete another
 882 of the "Test" books you added in the previous step.  Flash should still
 883 maintain the status message across the redirect even though you are no
 884 longer explicitly accessing C<c.flash>.
 885
 886
 887 =head1 AUTHOR
 888
 889 Kennedy Clark, C<hkclark@gmail.com>
 890
 891 Please report any errors, issues or suggestions to the author.  The
 892 most recent version of the Catalyst Tutorial can be found at
 893 L<http://dev.catalyst.perl.org/repos/Catalyst/Catalyst-Manual/5.70/trunk/lib/Catalyst/Manual/Tutorial/>.
 894
 895 Copyright 2006-2008, Kennedy Clark, under Creative Commons License
 896 (L<http://creativecommons.org/licenses/by-sa/3.0/us/>).