lib/Catalyst/Manual/Tutorial/06_Authorization.pod

   1 =head1 NAME
   2
   3 Catalyst::Manual::Tutorial::06_Authorization - Catalyst Tutorial - Chapter 6: Authorization
   4
   5
   6 =head1 OVERVIEW
   7
   8 This is B<Chapter 6 of 10> for the Catalyst tutorial.
   9
  10 L<Tutorial Overview|Catalyst::Manual::Tutorial>
  11
  12 =over 4
  13
  14 =item 1
  15
  16 L<Introduction|Catalyst::Manual::Tutorial::01_Intro>
  17
  18 =item 2
  19
  20 L<Catalyst Basics|Catalyst::Manual::Tutorial::02_CatalystBasics>
  21
  22 =item 3
  23
  24 L<More Catalyst Basics|Catalyst::Manual::Tutorial::03_MoreCatalystBasics>
  25
  26 =item 4
  27
  28 L<Basic CRUD|Catalyst::Manual::Tutorial::04_BasicCRUD>
  29
  30 =item 5
  31
  32 L<Authentication|Catalyst::Manual::Tutorial::05_Authentication>
  33
  34 =item 6
  35
  36 B<06_Authorization>
  37
  38 =item 7
  39
  40 L<Debugging|Catalyst::Manual::Tutorial::07_Debugging>
  41
  42 =item 8
  43
  44 L<Testing|Catalyst::Manual::Tutorial::08_Testing>
  45
  46 =item 9
  47
  48 L<Advanced CRUD|Catalyst::Manual::Tutorial::09_AdvancedCRUD>
  49
  50 =item 10
  51
  52 L<Appendices|Catalyst::Manual::Tutorial::10_Appendices>
  53
  54 =back
  55
  56
  57 =head1 DESCRIPTION
  58
  59 This chapter of the tutorial adds role-based authorization to the
  60 existing authentication implemented in
  61 L<Chapter 5|Catalyst::Manual::Tutorial::05_Authentication>.  It provides
  62 simple examples of how to use roles in both TT templates and controller
  63 actions.  The first half looks at basic authorization concepts. The
  64 second half looks at how moving your authorization code to your model
  65 can simplify your code and make things easier to maintain.
  66
  67 Source code for the tutorial in included in the F</root/Final> directory
  68 of the Tutorial Virtual machine (one subdirectory per chapter).  There
  69 are also instructions for downloading the code in
  70 L<Catalyst::Manual::Tutorial::01_Intro>.
  71
  72
  73 =head1 BASIC AUTHORIZATION
  74
  75 In this section you learn the basics of how authorization works under
  76 Catalyst.
  77
  78
  79 =head2 Update Plugins to Include Support for Authorization
  80
  81 Edit C<lib/MyApp.pm> and add C<Authorization::Roles> to the list:
  82 ***TODO: remove stacktrace?
  83
  84     # Load plugins
  85     use Catalyst qw/
  86         -Debug
  87         ConfigLoader
  88         Static::Simple
  89
  90         StackTrace
  91
  92         Authentication
  93         Authorization::Roles
  94
  95         Session
  96         Session::Store::File
  97         Session::State::Cookie
  98
  99         StatusMessage
 100     /;
 101
 102 Once again, include this additional plugin as a new dependency in the
 103 Makefile.PL file like this:
 104
 105     requires 'Catalyst::Plugin::Authorization::Roles';
 106
 107
 108 =head2 Add Role-Specific Logic to the "Book List" Template
 109
 110 Open C<root/src/books/list.tt2> in your editor and add the following
 111 lines to the bottom of the file:
 112
 113     ...
 114     <p>Hello [% c.user.username %], you have the following roles:</p>
 115
 116     <ul>
 117       [% # Dump list of roles -%]
 118       [% FOR role = c.user.roles %]<li>[% role %]</li>[% END %]
 119     </ul>
 120
 121     <p>
 122     [% # Add some simple role-specific logic to template %]
 123     [% # Use $c->check_user_roles() to check authz -%]
 124     [% IF c.check_user_roles('user') %]
 125       [% # Give normal users a link for 'logout' %]
 126       <a href="[% c.uri_for('/logout') %]">User Logout</a>
 127     [% END %]
 128
 129     [% # Can also use $c->user->check_roles() to check authz -%]
 130     [% IF c.check_user_roles('admin') %]
 131       [% # Give admin users a link for 'create' %]
 132       <a href="[% c.uri_for(c.controller.action_for('form_create')) %]">Admin Create</a>
 133     [% END %]
 134     </p>
 135
 136 This code displays a different combination of links depending on the
 137 roles assigned to the user.
 138
 139
 140 =head2 Limit Books::add to 'admin' Users
 141
 142 C<IF> statements in TT templates simply control the output that is sent
 143 to the user's browser; it provides no real enforcement (if users know or
 144 guess the appropriate URLs, they are still perfectly free to hit any
 145 action within your application).  We need to enhance the controller
 146 logic to wrap restricted actions with role-validation logic.
 147
 148 For example, we might want to restrict the "formless create" action to
 149 admin-level users by editing C<lib/MyApp/Controller/Books.pm> and
 150 updating C<url_create> to match the following code:
 151
 152     =head2 url_create
 153
 154     Create a book with the supplied title and rating,
 155     with manual authorization
 156
 157     =cut
 158
 159     sub url_create :Chained('base') :PathPart('url_create') :Args(3) {
 160         # In addition to self & context, get the title, rating & author_id args
 161         # from the URL.  Note that Catalyst automatically puts extra information
 162         # after the "/<controller_name>/<action_name/" into @_
 163         my ($self, $c, $title, $rating, $author_id) = @_;
 164
 165         # Check the user's roles
 166         if ($c->check_user_roles('admin')) {
 167             # Call create() on the book model object. Pass the table
 168             # columns/field values we want to set as hash values
 169             my $book = $c->model('DB::Book')->create({
 170                     title   => $title,
 171                     rating  => $rating
 172                 });
 173
 174             # Add a record to the join table for this book, mapping to
 175             # appropriate author
 176             $book->add_to_book_authors({author_id => $author_id});
 177             # Note: Above is a shortcut for this:
 178             # $book->create_related('book_authors', {author_id => $author_id});
 179
 180             # Assign the Book object to the stash and set template
 181             $c->stash(book     => $book,
 182                       template => 'books/create_done.tt2');
 183         } else {
 184             # Provide very simple feedback to the user.
 185             $c->response->body('Unauthorized!');
 186         }
 187     }
 188
 189
 190 To add authorization, we simply wrap the main code of this method in an
 191 C<if> statement that calls C<check_user_roles>.  If the user does not
 192 have the appropriate permissions, they receive an "Unauthorized!"
 193 message.  Note that we intentionally chose to display the message this
 194 way to demonstrate that TT templates will not be used if the response
 195 body has already been set.  In reality you would probably want to use a
 196 technique that maintains the visual continuity of your template layout
 197 (for example, using L<Catalyst::Plugin::StateMessage> as shown in the
 198 L<last chapter|Catalyst::Manual::Tutorial::05_Authentication> to
 199 redirect to an "unauthorized" page).
 200
 201 B<TIP>: If you want to keep your existing C<url_create> method, you can
 202 create a new copy and comment out the original by making it look like a
 203 Pod comment.  For example, put something like C<=begin> before
 204 C<sub add : Local {> and C<=end> after the closing C<}>.
 205
 206
 207 =head2 Try Out Authentication And Authorization
 208
 209 Make sure the development server is running:
 210
 211     $ script/myapp_server.pl -r
 212
 213 Now trying going to L<http://localhost:3000/books/list> and you should
 214 be taken to the login page (you might have to C<Shift+Reload> or
 215 C<Ctrl+Reload> your browser and/or click the "User Logout" link on the
 216 book list page).  Try logging in with both C<test01> and C<test02> (both
 217 use a password of C<mypass>) and notice how the roles information
 218 updates at the bottom of the "Book List" page. Also try the "User
 219 Logout" link on the book list page.
 220
 221 Now the "url_create" URL will work if you are already logged in as user
 222 C<test01>, but receive an authorization failure if you are logged in as
 223 C<test02>.  Try:
 224
 225     http://localhost:3000/books/url_create/test/1/6
 226
 227 while logged in as each user.  Use one of the "logout" links (or go to
 228 L<http://localhost:3000/logout> in your browser directly) when you are
 229 done.
 230
 231
 232 =head1 ENABLE MODEL-BASED AUTHORIZATION
 233
 234 Hopefully it's fairly obvious that adding detailed permission checking
 235 logic to our controllers and view templates isn't a very clean or
 236 scalable way to build role-based permissions into out application.  As
 237 with many other aspects of MVC web development, the goal is to have your
 238 controllers and views be an "thin" as possible, with all of the "fancy
 239 business logic" built into your model.
 240
 241 For example, let's add a method to our C<Books.pm> Result Class to check
 242 if a user is allowed to delete a book.  Open
 243 C<lib/MyApp/Schema/Result/Book.pm> and add the following method (be sure
 244 to add it below the "C<DO NOT MODIFY ...>" line):
 245
 246     =head2 delete_allowed_by
 247
 248     Can the specified user delete the current book?
 249
 250     =cut
 251
 252     sub delete_allowed_by {
 253         my ($self, $user) = @_;
 254
 255         # Only allow delete if user has 'admin' role
 256         return $user->has_role('admin');
 257     }
 258
 259 Here we call a C<has_role> method on our user object, so we should add
 260 this method to our Result Class.  Open
 261 C<lib/MyApp/Schema/Result/User.pm> and add the following method below
 262 the "C<DO NOT MODIFY ...>" line:
 263
 264     =head2 has_role
 265
 266     Check if a user has the specified role
 267
 268     =cut
 269
 270     use Perl6::Junction qw/any/;
 271     sub has_role {
 272         my ($self, $role) = @_;
 273
 274         # Does this user posses the required role?
 275         return any(map { $_->role } $self->roles) eq $role;
 276     }
 277
 278 Let's also add C<Perl6::Junction> to the requirements listed in
 279 Makefile.PL:
 280
 281     requires 'Perl6::Junction';
 282
 283 B<Note:> Feel free to use C<grep> in lieu of C<Perl6::Junction::any> if
 284 you prefer.  Also, please don't let the use of the C<Perl6::Junction>
 285 module above lead you to believe that Catalyst is somehow dependent on
 286 Perl 6... we are simply using that module for its
 287 L<easy-to-read|http://blogs.perl.org/users/marc_sebastian_jakobs/2009/11/my-favorite-module-of-the-month-perl6junction.html>
 288 C<any> function.
 289
 290 Now we need to add some enforcement inside our controller.  Open
 291 C<lib/MyApp/Controller/Books.pm> and update the C<delete> method to
 292 match the following code:
 293
 294     =head2 delete
 295
 296     Delete a book
 297
 298     =cut
 299
 300     sub delete :Chained('object') :PathPart('delete') :Args(0) {
 301         my ($self, $c) = @_;
 302
 303         # Check permissions
 304         $c->detach('/error_noperms')
 305             unless $c->stash->{object}->delete_allowed_by($c->user->get_object);
 306
 307         # Use the book object saved by 'object' and delete it along
 308         # with related 'book_authors' entries
 309         $c->stash->{object}->delete;
 310
 311         # Redirect the user back to the list page
 312         $c->response->redirect($c->uri_for($self->action_for('list'),
 313             {mid => $c->set_status_msg("Deleted book $id")}));
 314     }
 315
 316 Here, we C<detach> to an error page if the user is lacking the
 317 appropriate permissions.  For this to work, we need to make arrangements
 318 for the '/error_noperms' action to work.  Open
 319 C<lib/MyApp/Controller/Root.pm> and add this method:
 320
 321     =head2 error_noperms
 322
 323     Permissions error screen
 324
 325     =cut
 326
 327     sub error_noperms :Chained('/') :PathPart('error_noperms') :Args(0) {
 328         my ($self, $c) = @_;
 329
 330         $c->stash(template => 'error_noperms.tt2');
 331     }
 332
 333 And also add the template file by putting the following text into
 334 C<root/src/error_noperms.tt2>:
 335
 336     <span class="error">Permission Denied</span>
 337
 338 Log in as C<test01> and create several new books using the C<url_create>
 339 feature:
 340
 341     http://localhost:3000/books/url_create/Test/1/4
 342
 343 Then, while still logged in as C<test01>, click the "Delete" link next
 344 to one of these books.  The book should be removed and you should see
 345 the usual green "Book deleted" message.  Next, click the "User Logout"
 346 link and log back in as C<test02>.  Now try deleting one of the books.
 347 You should be taken to the red "Permission Denied" message on our error
 348 page.
 349
 350 Use one of the 'Logout' links (or go to the
 351 L<http://localhost:3000/logout> URL directly) when you are done.
 352
 353
 354 =head1 AUTHOR
 355
 356 Kennedy Clark, C<hkclark@gmail.com>
 357
 358 Feel free to contact the author for any errors or suggestions, but the
 359 best way to report issues is via the CPAN RT Bug system at
 360 <https://rt.cpan.org/Public/Dist/Display.html?Name=Catalyst-Manual>.
 361
 362 The most recent version of the Catalyst Tutorial can be found at
 363 L<http://dev.catalyst.perl.org/repos/Catalyst/Catalyst-Manual/5.80/trunk/lib/Catalyst/Manual/Tutorial/>.
 364
 365 Copyright 2006-2010, Kennedy Clark, under the
 366 Creative Commons Attribution Share-Alike License Version 3.0
 367 (L<http://creativecommons.org/licenses/by-sa/3.0/us/>).