xt/optional_deps.t

   1 use strict;
   2 use warnings;
   3 no warnings qw/once/;
   4
   5 my ($inc_before, $inc_after);
   6 # DBIx::Class::Optional::Dependencies queries $ENV at compile time
   7 # to build the optional requirements
   8 BEGIN {
   9   $ENV{DBICTEST_PG_DSN} = '1';
  10   delete $ENV{DBICTEST_ORA_DSN};
  11
  12   require Carp;   # Carp is not used in the test, but in OptDeps, load for proper %INC comparison
  13
  14   $inc_before = [ keys %INC ];
  15   require DBIx::Class::Optional::Dependencies;
  16   $inc_after = [ keys %INC ];
  17 }
  18
  19 use Test::More;
  20 use Test::Exception;
  21 use Scalar::Util; # load before we break require()
  22
  23 ok ( (! grep { $_ =~ m|DBIx/Class| } @$inc_before ), 'Nothing DBIC related was loaded before inc-test')
  24   unless $ENV{PERL5OPT}; # a defined PERL5OPT may inject extra deps crashing this test
  25
  26 is_deeply (
  27   [ sort @$inc_after],
  28   [ sort (@$inc_before, 'DBIx/Class/Optional/Dependencies.pm') ],
  29   'Nothing loaded other than DBIx::Class::OptDeps',
  30 );
  31
  32 my $sqlt_dep = DBIx::Class::Optional::Dependencies->req_list_for ('deploy');
  33 is_deeply (
  34   [ keys %$sqlt_dep ],
  35   [ 'SQL::Translator' ],
  36   'Correct deploy() dependency list',
  37 );
  38
  39 # make module loading impossible, regardless of actual libpath contents
  40 {
  41   local @INC = (sub { die('Optional Dep Test') } );
  42
  43   ok (
  44     ! DBIx::Class::Optional::Dependencies->req_ok_for ('deploy'),
  45     'deploy() deps missing',
  46   );
  47
  48   like (
  49     DBIx::Class::Optional::Dependencies->req_missing_for ('deploy'),
  50     qr/^SQL::Translator \>\= \d/,
  51     'expected missing string contents',
  52   );
  53
  54   like (
  55     DBIx::Class::Optional::Dependencies->req_errorlist_for ('deploy')->{'SQL::Translator'},
  56     qr/Optional Dep Test/,
  57     'custom exception found in errorlist',
  58   );
  59 }
  60
  61 #make it so module appears loaded
  62 $INC{'SQL/Translator.pm'} = 1;
  63 $SQL::Translator::VERSION = 999;
  64
  65 ok (
  66   ! DBIx::Class::Optional::Dependencies->req_ok_for ('deploy'),
  67   'deploy() deps missing cached properly',
  68 );
  69
  70 #reset cache
  71 %DBIx::Class::Optional::Dependencies::req_availability_cache = ();
  72
  73
  74 ok (
  75   DBIx::Class::Optional::Dependencies->req_ok_for ('deploy'),
  76   'deploy() deps present',
  77 );
  78
  79 is (
  80   DBIx::Class::Optional::Dependencies->req_missing_for ('deploy'),
  81   '',
  82   'expected null missing string',
  83 );
  84
  85 is_deeply (
  86   DBIx::Class::Optional::Dependencies->req_errorlist_for ('deploy'),
  87   {},
  88   'expected empty errorlist',
  89 );
  90
  91 # test multiple times to find autovivification bugs
  92 for (1..2) {
  93   throws_ok {
  94     DBIx::Class::Optional::Dependencies->req_list_for();
  95   } qr/\Qreq_list_for() expects a requirement group name/,
  96   "req_list_for without groupname throws exception on run $_";
  97
  98   throws_ok {
  99     DBIx::Class::Optional::Dependencies->req_list_for('');
 100   } qr/\Qreq_list_for() expects a requirement group name/,
 101   "req_list_for with empty groupname throws exception on run $_";
 102
 103   throws_ok {
 104     DBIx::Class::Optional::Dependencies->req_list_for('invalid_groupname');
 105   } qr/Requirement group 'invalid_groupname' does not exist/,
 106   "req_list_for with invalid groupname throws exception on run $_";
 107 }
 108
 109 is_deeply(
 110   DBIx::Class::Optional::Dependencies->req_list_for('rdbms_pg'),
 111   {
 112     'DBD::Pg' => '0',
 113   }, 'optional dependencies for deploying to Postgres ok');
 114
 115 is_deeply(
 116   DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_pg'),
 117   {
 118     'DBD::Pg'        => '2.009002',
 119   }, 'optional dependencies for testing Postgres with ENV var ok');
 120
 121 is_deeply(
 122   DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_oracle'),
 123   {}, 'optional dependencies for testing Oracle without ENV var ok');
 124
 125 done_testing;