xt/extra/dbicadmin.t

   1 BEGIN {
   2   # just in case the user env has stuff in it
   3   delete $ENV{JSON_ANY_ORDER};
   4   delete $ENV{DBICTEST_VERSION_WARNS_INDISCRIMINATELY};
   5
   6   do "./t/lib/ANFANG.pm" or die ( $@ || $! )
   7 }
   8
   9 use strict;
  10 use warnings;
  11
  12 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_admin_script';
  13
  14 use Test::More;
  15 use Config;
  16
  17 use DBICTest;
  18
  19 $ENV{PATH} = '';
  20 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  21
  22 my @json_backends = qw(DWIW PP JSON CPANEL XS);
  23
  24 # test the script is setting @INC properly
  25 test_exec (qw|-It/lib/testinclude --schema=DBICTestAdminInc --connect=[] --insert|);
  26 cmp_ok ( $? >> 8, '==', 70, 'Correct exit code from connecting a custom INC schema' );
  27
  28 # test that config works properly
  29 {
  30   no warnings 'qw';
  31   test_exec(qw|-It/lib/testinclude --schema=DBICTestConfig --create --connect=["klaatu","barada","nikto"]|);
  32   cmp_ok( $? >> 8, '==', 71, 'Correct schema loaded via config' ) || exit;
  33 }
  34
  35 # test that config-file works properly
  36 test_exec(qw|-It/lib/testinclude --schema=DBICTestConfig --config=t/lib/admincfgtest.json --config-stanza=Model::Gort --deploy|);
  37 cmp_ok ($? >> 8, '==', 71, 'Correct schema loaded via testconfig');
  38
  39 for my $js (@json_backends) {
  40
  41     SKIP: {
  42         eval {JSON::Any->import ($js); 1 }
  43           or skip ("JSON backend $js is not available, skip testing", 1);
  44
  45         local $ENV{JSON_ANY_ORDER} = $js;
  46         eval { test_dbicadmin () };
  47         diag $@ if $@;
  48     }
  49 }
  50
  51 done_testing();
  52
  53 sub test_dbicadmin {
  54     my $schema = DBICTest->init_schema( sqlite_use_file => 1 );  # reinit a fresh db for every run
  55
  56     my $employees = $schema->resultset('Employee');
  57
  58     test_exec( default_args(), qw|--op=insert --set={"name":"Matt"}| );
  59     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: insert count" );
  60
  61     my $employee = $employees->find(1);
  62     ok( ($employee->name() eq 'Matt'), "$ENV{JSON_ANY_ORDER}: insert valid" );
  63
  64     test_exec( default_args(), qw|--op=update --set={"name":"Trout"}| );
  65     $employee = $employees->find(1);
  66     ok( ($employee->name() eq 'Trout'), "$ENV{JSON_ANY_ORDER}: update" );
  67
  68     test_exec( default_args(), qw|--op=insert --set={"name":"Aran"}| );
  69
  70     SKIP: {
  71         skip ("MSWin32 doesn't support -|", 1) if $^O eq 'MSWin32';
  72
  73         my ($perl) = $^X =~ /(.*)/;
  74
  75         open(my $fh, "-|",  ( $perl, '-MANFANG', 'script/dbicadmin', default_args(), qw|--op=select --attrs={"order_by":"name"}| ) ) or die $!;
  76         my $data = do { local $/; <$fh> };
  77         close($fh);
  78         if (!ok( ($data=~/Aran.*Trout/s), "$ENV{JSON_ANY_ORDER}: select with attrs" )) {
  79           diag ("data from select is $data")
  80         };
  81     }
  82
  83     test_exec( default_args(), qw|--op=delete --where={"name":"Trout"}| );
  84     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: delete" );
  85 }
  86
  87 sub default_args {
  88   my $dsn = JSON::Any->encode([
  89     'dbi:SQLite:dbname=' . DBICTest->_sqlite_dbfilename,
  90     '',
  91     '',
  92     { AutoCommit => 1 },
  93   ]);
  94
  95   return (
  96     qw|--quiet --schema=DBICTest::Schema --class=Employee|,
  97     qq|--connect=$dsn|,
  98     qw|--force -I testincludenoniterference|,
  99   );
 100 }
 101
 102 sub test_exec {
 103   my ($perl) = $^X =~ /(.*)/;
 104
 105   my @args = ($perl, '-MANFANG', 'script/dbicadmin', @_);
 106
 107   if ($^O eq 'MSWin32') {
 108     require Win32::ShellQuote; # included in test optdeps
 109     @args = Win32::ShellQuote::quote_system_list(@args);
 110   }
 111
 112   system @args;
 113 }