t/storage/reconnect.t

   1 use strict;
   2 use warnings;
   3
   4 use FindBin;
   5 use File::Copy 'move';
   6 use Test::More;
   7 use Test::Exception;
   8 use lib qw(t/lib);
   9 use DBICTest;
  10
  11 my $db_orig = DBICTest->_sqlite_dbfilename;
  12 my $db_tmp  = "$db_orig.tmp";
  13
  14 # Set up the "usual" sqlite for DBICTest
  15 my $schema = DBICTest->init_schema( sqlite_use_file => 1 );
  16
  17 # Make sure we're connected by doing something
  18 my @art = $schema->resultset("Artist")->search({ }, { order_by => { -desc => 'name' }});
  19 cmp_ok(@art, '==', 3, "Three artists returned");
  20
  21 # Disconnect the dbh, and be sneaky about it
  22 # Also test if DBD::SQLite finaly knows how to ->disconnect properly
  23 {
  24   my $w;
  25   local $SIG{__WARN__} = sub { $w = shift };
  26   $schema->storage->_dbh->disconnect;
  27   ok ($w !~ /active statement handles/, 'SQLite can disconnect properly');
  28 }
  29
  30 # Try the operation again - What should happen here is:
  31 #   1. S::DBI blindly attempts the SELECT, which throws an exception
  32 #   2. It catches the exception, checks ->{Active}/->ping, sees the disconnected state...
  33 #   3. Reconnects, and retries the operation
  34 #   4. Success!
  35 my @art_two = $schema->resultset("Artist")->search({ }, { order_by => { -desc => 'name' }});
  36 cmp_ok(@art_two, '==', 3, "Three artists returned");
  37
  38 ### Now, disconnect the dbh, and move the db file;
  39 # create a new one full of garbage, prevent SQLite from connecting.
  40 $schema->storage->_dbh->disconnect;
  41 move( $db_orig, $db_tmp )
  42   or die "failed to move $db_orig to $db_tmp: $!";
  43 open my $db_file, '>', $db_orig;
  44 print $db_file 'THIS IS NOT A REAL DATABASE';
  45 close $db_file;
  46
  47 ### Try the operation again... it should fail, since there's no valid db
  48 {
  49   # Catch the DBI connection error
  50   local $SIG{__WARN__} = sub {};
  51   throws_ok {
  52     my @art_three = $schema->resultset("Artist")->search( {}, { order_by => { -desc => 'name' } } );
  53   }  qr/not a database/, 'The operation failed';
  54 }
  55
  56 ok (! $schema->storage->connected, 'We are not connected' );
  57
  58 ### Now, move the db file back to the correct name
  59 unlink($db_orig) or die "could not delete $db_orig: $!";
  60 move( $db_tmp, $db_orig )
  61   or die "could not move $db_tmp to $db_orig: $!";
  62
  63 ### Try the operation again... this time, it should succeed
  64 my @art_four;
  65 lives_ok {
  66     @art_four = $schema->resultset("Artist")->search( {}, { order_by => { -desc => 'name' } } );
  67 } 'The operation succeeded';
  68 cmp_ok( @art_four, '==', 3, "Three artists returned" );
  69
  70 # check that reconnection contexts are preserved in txn_do / dbh_do
  71
  72 my $args = [1, 2, 3];
  73
  74 my $ctx_map = {
  75   VOID => {
  76     invoke => sub { shift->(); 1 },
  77     wa => undef,
  78   },
  79   SCALAR => {
  80     invoke => sub { my $foo = shift->() },
  81     wa => '',
  82   },
  83   LIST => {
  84     invoke => sub { my @foo = shift->() },
  85     wa => 1,
  86   },
  87 };
  88
  89 for my $ctx (keys %$ctx_map) {
  90
  91   # start disconnected and then connected
  92   $schema->storage->disconnect;
  93   for (1, 2) {
  94     my $disarmed;
  95
  96     $ctx_map->{$ctx}{invoke}->(sub { $schema->txn_do(sub {
  97       is_deeply (\@_, $args, 'Args propagated correctly' );
  98
  99       is (wantarray(), $ctx_map->{$ctx}{wa}, "Correct $ctx context");
 100
 101       # this will cause a retry
 102       $schema->storage->_dbh->disconnect unless $disarmed++;
 103
 104       isa_ok ($schema->resultset('Artist')->next, 'DBICTest::Artist');
 105     }, @$args) });
 106   }
 107 };
 108
 109 done_testing;