t/storage/debug.t

   1 use strict;
   2 use warnings;
   3 no warnings 'once';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIC::DebugObj;
  10 use DBIC::SqlMakerTest;
  11 use Path::Class qw/file/;
  12
  13 my $schema = DBICTest->init_schema();
  14
  15 my $lfn = file('t/var/sql.log');
  16 unlink $lfn or die $!
  17   if -e $lfn;
  18
  19 # make sure we are testing the vanilla debugger and not ::PrettyPrint
  20 $schema->storage->debugobj(DBIx::Class::Storage::Statistics->new);
  21
  22 ok ( $schema->storage->debug(1), 'debug' );
  23 $schema->storage->debugfh($lfn->openw);
  24 $schema->storage->debugfh->autoflush(1);
  25 $schema->resultset('CD')->count;
  26
  27 my @loglines = $lfn->slurp;
  28 is (@loglines, 1, 'one line of log');
  29 like($loglines[0], qr/^SELECT COUNT/, 'File log via debugfh success');
  30
  31 $schema->storage->debugfh(undef);
  32
  33 {
  34   local $ENV{DBIC_TRACE} = "=$lfn";
  35   unlink $lfn;
  36
  37   $schema->resultset('CD')->count;
  38
  39   my $schema2 = DBICTest->init_schema(no_deploy => 1);
  40   $schema2->storage->_do_query('SELECT 1'); # _do_query() logs via standard mechanisms
  41
  42   my @loglines = $lfn->slurp;
  43   is(@loglines, 2, '2 lines of log');
  44   like($loglines[0], qr/^SELECT COUNT/, 'Env log from schema1 success');
  45   like($loglines[1], qr/^SELECT 1:/, 'Env log from schema2 success');
  46
  47   $schema->storage->debugobj->debugfh(undef)
  48 }
  49
  50 open(STDERRCOPY, '>&STDERR');
  51 close(STDERR);
  52 dies_ok {
  53   $schema->resultset('CD')->search({})->count;
  54 } 'Died on closed FH';
  55
  56 open(STDERR, '>&STDERRCOPY');
  57
  58 # test trace output correctness for bind params
  59 {
  60     my ($sql, @bind);
  61     $schema->storage->debugobj(DBIC::DebugObj->new(\$sql, \@bind));
  62
  63     my @cds = $schema->resultset('CD')->search( { artist => 1, cdid => { -between => [ 1, 3 ] }, } );
  64     is_same_sql_bind(
  65         $sql, \@bind,
  66         "SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track FROM cd me WHERE ( artist = ? AND (cdid BETWEEN ? AND ?) )",
  67         [qw/'1' '1' '3'/],
  68         'got correct SQL with all bind parameters (debugcb)'
  69     );
  70
  71     @cds = $schema->resultset('CD')->search( { artist => 1, cdid => { -between => [ 1, 3 ] }, } );
  72     is_same_sql_bind(
  73         $sql, \@bind,
  74         "SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track FROM cd me WHERE ( artist = ? AND (cdid BETWEEN ? AND ?) )", ["'1'", "'1'", "'3'"],
  75         'got correct SQL with all bind parameters (debugobj)'
  76     );
  77 }
  78
  79 done_testing;