t/inflate/datetime_mysql.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBICTest::Schema;
   9
  10 {
  11   local $SIG{__WARN__} = sub { warn @_ if $_[0] !~ /extra \=\> .+? has been deprecated/ };
  12   DBICTest::Schema->load_classes('EventTZ');
  13   DBICTest::Schema->load_classes('EventTZDeprecated');
  14 }
  15
  16 eval { require DateTime::Format::MySQL };
  17 plan $@
  18   ? ( skip_all => "Need DateTime::Format::MySQL for inflation tests")
  19   : ( tests => 33 )
  20 ;
  21
  22 my $schema = DBICTest->init_schema();
  23
  24 # Test "timezone" parameter
  25 foreach my $tbl (qw/EventTZ EventTZDeprecated/) {
  26   my $event_tz = $schema->resultset($tbl)->create({
  27       starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
  28       created_on => DateTime->new(year=>2006, month=>1, day=>31,
  29           hour => 13, minute => 34, second => 56, time_zone => "America/New_York" ),
  30   });
  31
  32   is ($event_tz->starts_at->day_name, "Montag", 'Locale de_DE loaded: day_name');
  33   is ($event_tz->starts_at->month_name, "Dezember", 'Locale de_DE loaded: month_name');
  34   is ($event_tz->created_on->day_name, "Tuesday", 'Default locale loaded: day_name');
  35   is ($event_tz->created_on->month_name, "January", 'Default locale loaded: month_name');
  36
  37   my $starts_at = $event_tz->starts_at;
  38   is("$starts_at", '2007-12-31T00:00:00', 'Correct date/time using timezone');
  39
  40   my $created_on = $event_tz->created_on;
  41   is("$created_on", '2006-01-31T12:34:56', 'Correct timestamp using timezone');
  42   is($event_tz->created_on->time_zone->name, "America/Chicago", "Correct timezone");
  43
  44   my $loaded_event = $schema->resultset($tbl)->find( $event_tz->id );
  45
  46   isa_ok($loaded_event->starts_at, 'DateTime', 'DateTime returned');
  47   $starts_at = $loaded_event->starts_at;
  48   is("$starts_at", '2007-12-31T00:00:00', 'Loaded correct date/time using timezone');
  49   is($starts_at->time_zone->name, 'America/Chicago', 'Correct timezone');
  50
  51   isa_ok($loaded_event->created_on, 'DateTime', 'DateTime returned');
  52   $created_on = $loaded_event->created_on;
  53   is("$created_on", '2006-01-31T12:34:56', 'Loaded correct timestamp using timezone');
  54   is($created_on->time_zone->name, 'America/Chicago', 'Correct timezone');
  55
  56   # Test floating timezone warning
  57   # We expect one warning
  58   SKIP: {
  59       skip "ENV{DBIC_FLOATING_TZ_OK} was set, skipping", 1 if $ENV{DBIC_FLOATING_TZ_OK};
  60       local $SIG{__WARN__} = sub {
  61           like(
  62               shift,
  63               qr/You're using a floating timezone, please see the documentation of DBIx::Class::InflateColumn::DateTime for an explanation/,
  64               'Floating timezone warning'
  65           );
  66       };
  67       my $event_tz_floating = $schema->resultset($tbl)->create({
  68           starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
  69           created_on => DateTime->new(year=>2006, month=>1, day=>31,
  70               hour => 13, minute => 34, second => 56, ),
  71       });
  72       delete $SIG{__WARN__};
  73   };
  74
  75   # This should fail to set
  76   my $prev_str = "$created_on";
  77   $loaded_event->update({ created_on => '0000-00-00' });
  78   is("$created_on", $prev_str, "Don't update invalid dates");
  79 }
  80
  81 # Test invalid DT
  82 my $invalid = $schema->resultset('EventTZ')->create({
  83   starts_at  => '0000-00-00',
  84   created_on => DateTime->now,
  85 });
  86
  87 is( $invalid->get_column('starts_at'), '0000-00-00', "Invalid date stored" );
  88 is( $invalid->starts_at, undef, "Inflate to undef" );
  89
  90 $invalid->created_on('0000-00-00');
  91 $invalid->update;
  92
  93 throws_ok (
  94   sub { $invalid->created_on },
  95   qr/invalid date format/i,
  96   "Invalid date format exception"
  97 );