t/count/prefetch.t

   1 use strict;
   2 use warnings;
   3
   4 use lib qw(t/lib);
   5
   6 use Test::More;
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9
  10 my $schema = DBICTest->init_schema();
  11
  12 # collapsing prefetch
  13 {
  14   my $rs = $schema->resultset("Artist")
  15             ->search_related('cds',
  16                 { 'tracks.position' => [1,2] },
  17                 { prefetch => [qw/tracks artist/] },
  18             );
  19   is ($rs->all, 5, 'Correct number of objects');
  20   is ($rs->count, 5, 'Correct count');
  21
  22   is_same_sql_bind (
  23     $rs->count_rs->as_query,
  24     '(
  25       SELECT COUNT( * )
  26         FROM (
  27           SELECT cds.cdid
  28             FROM artist me
  29             JOIN cd cds ON cds.artist = me.artistid
  30             LEFT JOIN track tracks ON tracks.cd = cds.cdid
  31             JOIN artist artist ON artist.artistid = cds.artist
  32           WHERE tracks.position = ? OR tracks.position = ?
  33           GROUP BY cds.cdid
  34         ) count_subq
  35     )',
  36     [ map { [ 'tracks.position' => $_ ] } (1, 2) ],
  37   );
  38 }
  39
  40 # collapsing prefetch with distinct
  41 {
  42   my $rs = $schema->resultset("Artist")->search(undef, {distinct => 1})
  43             ->search_related('cds')->search_related('genre',
  44                 { 'genre.name' => 'emo' },
  45                 { prefetch => q(cds) },
  46             );
  47   is ($rs->all, 1, 'Correct number of objects');
  48   is ($rs->count, 1, 'Correct count');
  49
  50   is_same_sql_bind (
  51     $rs->count_rs->as_query,
  52     '(
  53       SELECT COUNT( * )
  54         FROM (
  55           SELECT genre.genreid
  56             FROM artist me
  57             JOIN cd cds ON cds.artist = me.artistid
  58             JOIN genre genre ON genre.genreid = cds.genreid
  59             LEFT JOIN cd cds_2 ON cds_2.genreid = genre.genreid
  60           WHERE ( genre.name = ? )
  61           GROUP BY genre.genreid
  62         ) count_subq
  63     )',
  64     [ [ 'genre.name' => 'emo' ] ],
  65   );
  66 }
  67
  68 # non-collapsing prefetch (no multi prefetches)
  69 {
  70   my $rs = $schema->resultset("CD")
  71             ->search_related('tracks',
  72                 { position => [1,2] },
  73                 { prefetch => [qw/disc lyrics/] },
  74             );
  75   is ($rs->all, 10, 'Correct number of objects');
  76
  77
  78   is ($rs->count, 10, 'Correct count');
  79
  80   is_same_sql_bind (
  81     $rs->count_rs->as_query,
  82     '(
  83       SELECT COUNT( * )
  84         FROM cd me
  85         JOIN track tracks ON tracks.cd = me.cdid
  86         JOIN cd disc ON disc.cdid = tracks.cd
  87         LEFT JOIN lyrics lyrics ON lyrics.track_id = tracks.trackid
  88       WHERE position = ? OR position = ?
  89     )',
  90     [ map { [ position => $_ ] } (1, 2) ],
  91   );
  92 }
  93
  94 done_testing;