t/count/prefetch.t

   1 use strict;
   2 use warnings;
   3
   4 use lib qw(t/lib);
   5
   6 use Test::More;
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9
  10 my $schema = DBICTest->init_schema();
  11
  12 # collapsing prefetch
  13 {
  14   my $rs = $schema->resultset("Artist")
  15             ->search_related('cds',
  16                 { 'tracks.position' => [1,2] },
  17                 { prefetch => [qw/tracks artist/] },
  18             );
  19   is ($rs->all, 5, 'Correct number of objects');
  20   is ($rs->count, 5, 'Correct count');
  21
  22   is_same_sql_bind (
  23     $rs->count_rs->as_query,
  24     '(
  25       SELECT COUNT( * )
  26         FROM (
  27           SELECT cds.cdid
  28             FROM artist me
  29             JOIN cd cds ON cds.artist = me.artistid
  30             LEFT JOIN track tracks ON tracks.cd = cds.cdid
  31             JOIN artist artist ON artist.artistid = cds.artist
  32           WHERE tracks.position = ? OR tracks.position = ?
  33           GROUP BY cds.cdid
  34         ) count_subq
  35     )',
  36     [ map { [ 'tracks.position' => $_ ] } (1, 2) ],
  37   );
  38 }
  39
  40 # collapsing prefetch with distinct
  41 {
  42   my $first_cd = $schema->resultset('Artist')->first->cds->first;
  43   $first_cd->update ({
  44     genreid => $first_cd->create_related (
  45       genre => ({ name => 'vague genre' })
  46     )->id
  47   });
  48
  49   my $rs = $schema->resultset("Artist")->search(undef, {distinct => 1})
  50             ->search_related('cds')->search_related('genre',
  51                 { 'genre.name' => { '!=', 'foo' } },
  52                 { prefetch => q(cds) },
  53             );
  54   is ($rs->all, 1, 'Correct number of objects');
  55   is ($rs->count, 1, 'Correct count');
  56
  57   is_same_sql_bind (
  58     $rs->count_rs->as_query,
  59     '(
  60       SELECT COUNT( * )
  61         FROM (
  62           SELECT genre.genreid
  63             FROM artist me
  64             JOIN cd cds ON cds.artist = me.artistid
  65             JOIN genre genre ON genre.genreid = cds.genreid
  66             LEFT JOIN cd cds_2 ON cds_2.genreid = genre.genreid
  67           WHERE ( genre.name != ? )
  68           GROUP BY genre.genreid
  69         ) count_subq
  70     )',
  71     [ [ 'genre.name' => 'foo' ] ],
  72   );
  73 }
  74
  75 # non-collapsing prefetch (no multi prefetches)
  76 {
  77   my $rs = $schema->resultset("CD")
  78             ->search_related('tracks',
  79                 { position => [1,2] },
  80                 { prefetch => [qw/disc lyrics/] },
  81             );
  82   is ($rs->all, 10, 'Correct number of objects');
  83
  84
  85   is ($rs->count, 10, 'Correct count');
  86
  87   is_same_sql_bind (
  88     $rs->count_rs->as_query,
  89     '(
  90       SELECT COUNT( * )
  91         FROM cd me
  92         JOIN track tracks ON tracks.cd = me.cdid
  93         JOIN cd disc ON disc.cdid = tracks.cd
  94         LEFT JOIN lyrics lyrics ON lyrics.track_id = tracks.trackid
  95       WHERE position = ? OR position = ?
  96     )',
  97     [ map { [ position => $_ ] } (1, 2) ],
  98   );
  99 }
 100
 101 done_testing;