t/admin/10script.t

   1 # vim: filetype=perl
   2 use strict;
   3 use warnings;
   4
   5 use Test::More;
   6 use Config;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 BEGIN {
  11     require DBIx::Class;
  12     plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for('admin_script')
  13       unless DBIx::Class::Optional::Dependencies->req_ok_for('admin_script');
  14 }
  15
  16 $ENV{PATH} = '';
  17 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  18
  19 my @json_backends = qw/XS JSON DWIW/;
  20
  21 # test the script is setting @INC properly
  22 test_exec (qw|-It/lib/testinclude --schema=DBICTestAdminInc --connect=[] --insert|);
  23 cmp_ok ( $? >> 8, '==', 70, 'Correct exit code from connecting a custom INC schema' );
  24
  25 # test that config works properly
  26 {
  27   no warnings 'qw';
  28   test_exec(qw|-It/lib/testinclude --schema=DBICTestConfig --create --connect=["klaatu","barada","nikto"]|);
  29   cmp_ok( $? >> 8, '==', 71, 'Correct schema loaded via config' ) || exit;
  30 }
  31
  32 # test that config-file works properly
  33 test_exec(qw|-It/lib/testinclude --schema=DBICTestConfig --config=t/lib/admincfgtest.json --config-stanza=Model::Gort --deploy|);
  34 cmp_ok ($? >> 8, '==', 71, 'Correct schema loaded via testconfig');
  35
  36 for my $js (@json_backends) {
  37
  38     eval {JSON::Any->import ($js) };
  39     SKIP: {
  40         skip ("JSON backend $js is not available, skip testing", 1) if $@;
  41
  42         $ENV{JSON_ANY_ORDER} = $js;
  43         eval { test_dbicadmin () };
  44         diag $@ if $@;
  45     }
  46 }
  47
  48 done_testing();
  49
  50 sub test_dbicadmin {
  51     my $schema = DBICTest->init_schema( sqlite_use_file => 1 );  # reinit a fresh db for every run
  52
  53     my $employees = $schema->resultset('Employee');
  54
  55     test_exec( default_args(), qw|--op=insert --set={"name":"Matt"}| );
  56     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: insert count" );
  57
  58     my $employee = $employees->find(1);
  59     ok( ($employee->name() eq 'Matt'), "$ENV{JSON_ANY_ORDER}: insert valid" );
  60
  61     test_exec( default_args(), qw|--op=update --set={"name":"Trout"}| );
  62     $employee = $employees->find(1);
  63     ok( ($employee->name() eq 'Trout'), "$ENV{JSON_ANY_ORDER}: update" );
  64
  65     test_exec( default_args(), qw|--op=insert --set={"name":"Aran"}| );
  66
  67     SKIP: {
  68         skip ("MSWin32 doesn't support -| either", 1) if $^O eq 'MSWin32';
  69
  70         my ($perl) = $^X =~ /(.*)/;
  71
  72         open(my $fh, "-|",  ( $perl, 'script/dbicadmin', default_args(), qw|--op=select --attrs={"order_by":"name"}| ) ) or die $!;
  73         my $data = do { local $/; <$fh> };
  74         close($fh);
  75         if (!ok( ($data=~/Aran.*Trout/s), "$ENV{JSON_ANY_ORDER}: select with attrs" )) {
  76           diag ("data from select is $data")
  77         };
  78     }
  79
  80     test_exec( default_args(), qw|--op=delete --where={"name":"Trout"}| );
  81     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: delete" );
  82 }
  83
  84 sub default_args {
  85   my $dbname = DBICTest->_sqlite_dbfilename;
  86   return (
  87     qw|--quiet --schema=DBICTest::Schema --class=Employee|,
  88     qq|--connect=["dbi:SQLite:dbname=$dbname","","",{"AutoCommit":1}]|,
  89     qw|--force -I testincludenoniterference|,
  90   );
  91 }
  92
  93 # Why do we need this crap? Apparently MSWin32 can not pass through quotes properly
  94 # (sometimes it will and sometimes not, depending on what compiler was used to build
  95 # perl). So we go the extra mile to escape all the quotes. We can't also use ' instead
  96 # of ", because JSON::XS (proudly) does not support "malformed JSON" as the author
  97 # calls it. Bleh.
  98 #
  99 sub test_exec {
 100   my ($perl) = $^X =~ /(.*)/;
 101
 102   my @args = ('script/dbicadmin', @_);
 103
 104   if ( $^O eq 'MSWin32' ) {
 105     $perl = qq|"$perl"|;    # execution will fail if $^X contains paths
 106     for (@args) {
 107       $_ =~ s/"/\\"/g;
 108     }
 109   }
 110
 111   system ($perl, @args);
 112 }