t/admin/02ddl.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7
   8 use Path::Class;
   9
  10 use lib qw(t/lib);
  11 use DBICTest;
  12 use DBIx::Class::_Util 'sigwarn_silencer';
  13
  14 BEGIN {
  15     require DBIx::Class;
  16     plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for('admin')
  17       unless DBIx::Class::Optional::Dependencies->req_ok_for('admin');
  18
  19     plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for('deploy')
  20       unless DBIx::Class::Optional::Dependencies->req_ok_for('deploy');
  21 }
  22
  23 use_ok 'DBIx::Class::Admin';
  24
  25 # lock early
  26 DBICTest->init_schema(no_deploy => 1, no_populate => 1);
  27
  28 my $db_fn = DBICTest->_sqlite_dbfilename;
  29 my @connect_info = (
  30   "dbi:SQLite:$db_fn",
  31   undef,
  32   undef,
  33   { on_connect_do => 'PRAGMA synchronous = OFF' },
  34 );
  35 my $ddl_dir = dir(qw/t var/, "admin_ddl-$$");
  36
  37 { # create the schema
  38
  39 #  make sure we are  clean
  40 clean_dir($ddl_dir);
  41
  42
  43 my $admin = DBIx::Class::Admin->new(
  44   schema_class=> "DBICTest::Schema",
  45   sql_dir=> $ddl_dir,
  46   connect_info => \@connect_info,
  47 );
  48 isa_ok ($admin, 'DBIx::Class::Admin', 'create the admin object');
  49 lives_ok { $admin->create('MySQL'); } 'Can create MySQL sql';
  50 lives_ok { $admin->create('SQLite'); } 'Can Create SQLite sql';
  51 lives_ok {
  52   local $SIG{__WARN__} = sigwarn_silencer( qr/no such table.+DROP TABLE/s );
  53   $admin->deploy()
  54 } 'Can Deploy schema';
  55 }
  56
  57 { # upgrade schema
  58
  59 clean_dir($ddl_dir);
  60 require DBICVersion_v1;
  61
  62 my $admin = DBIx::Class::Admin->new(
  63   schema_class => 'DBICVersion::Schema',
  64   sql_dir =>  $ddl_dir,
  65   connect_info => \@connect_info,
  66 );
  67
  68 my $schema = $admin->schema();
  69
  70 lives_ok { $admin->create($schema->storage->sqlt_type(), {add_drop_table=>0}); } 'Can create DBICVersionOrig sql in ' . $schema->storage->sqlt_type;
  71 lives_ok { $admin->deploy(  ) } 'Can Deploy schema';
  72
  73 # connect to now deployed schema
  74 lives_ok { $schema = DBICVersion::Schema->connect(@{$schema->storage->connect_info()}); } 'Connect to deployed Database';
  75
  76 is($schema->get_db_version, $DBICVersion::Schema::VERSION, 'Schema deployed and versions match');
  77
  78
  79 require DBICVersion_v2;
  80 DBICVersion::Schema->upgrade_directory (undef);  # so that we can test use of $ddl_dir
  81
  82 $admin = DBIx::Class::Admin->new(
  83   schema_class => 'DBICVersion::Schema',
  84   sql_dir =>  $ddl_dir,
  85   connect_info => \@connect_info
  86 );
  87
  88 lives_ok { $admin->create($schema->storage->sqlt_type(), {}, "1.0" ); } 'Can create diff for ' . $schema->storage->sqlt_type;
  89 {
  90   local $SIG{__WARN__} = sigwarn_silencer( qr/DB version .+? is lower than the schema version/ );
  91   lives_ok { $admin->upgrade() } 'upgrade the schema';
  92   dies_ok { $admin->deploy } 'cannot deploy installed schema, should upgrade instead';
  93 }
  94
  95 is($schema->get_db_version, $DBICVersion::Schema::VERSION, 'Schema and db versions match');
  96
  97 }
  98
  99 { # install
 100
 101 clean_dir($ddl_dir);
 102
 103 my $admin = DBIx::Class::Admin->new(
 104   schema_class  => 'DBICVersion::Schema',
 105   sql_dir      => $ddl_dir,
 106   _confirm    => 1,
 107   connect_info  => \@connect_info,
 108 );
 109
 110 $admin->version("3.0");
 111 lives_ok { $admin->install(); } 'install schema version 3.0';
 112 is($admin->schema->get_db_version, "3.0", 'db thinks its version 3.0');
 113 dies_ok { $admin->install("4.0"); } 'cannot install to allready existing version';
 114
 115 $admin->force(1);
 116 warnings_exist ( sub {
 117   lives_ok { $admin->install("4.0") } 'can force install to allready existing version'
 118 }, qr/Forcing install may not be a good idea/, 'Force warning emitted' );
 119 is($admin->schema->get_db_version, "4.0", 'db thinks its version 4.0');
 120 }
 121
 122 sub clean_dir {
 123   my ($dir) = @_;
 124   $dir->rmtree if -d $dir;
 125   unlink $db_fn;
 126 }
 127
 128 END {
 129   clean_dir($ddl_dir);
 130 }
 131
 132 done_testing;