t/89inflate_datetime.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 {
   9   local $SIG{__WARN__} = sub { warn @_ if $_[0] !~ /extra \=\> .+? has been deprecated/ };
  10   DBICTest::Schema->load_classes('EventTZDeprecated');
  11   DBICTest::Schema->load_classes('EventTZPg');
  12 }
  13
  14 my $schema = DBICTest->init_schema();
  15
  16 plan tests => 57;
  17
  18 SKIP: {
  19   eval { require DateTime::Format::MySQL };
  20   skip "Need DateTime::Format::MySQL for inflation tests", 50  if $@;
  21
  22
  23 # inflation test
  24 my $event = $schema->resultset("Event")->find(1);
  25
  26 isa_ok($event->starts_at, 'DateTime', 'DateTime returned');
  27
  28 # klunky, but makes older Test::More installs happy
  29 my $starts = $event->starts_at;
  30 is("$starts", '2006-04-25T22:24:33', 'Correct date/time');
  31
  32 ok(my $row =
  33   $schema->resultset('Event')->search({ starts_at => $starts })->single);
  34 is(eval { $row->id }, 1, 'DT in search');
  35
  36 ok($row =
  37   $schema->resultset('Event')->search({ starts_at => { '>=' => $starts } })->single);
  38 is(eval { $row->id }, 1, 'DT in search with condition');
  39
  40 # create using DateTime
  41 my $created = $schema->resultset('Event')->create({
  42     starts_at => DateTime->new(year=>2006, month=>6, day=>18),
  43     created_on => DateTime->new(year=>2006, month=>6, day=>23)
  44 });
  45 my $created_start = $created->starts_at;
  46
  47 isa_ok($created->starts_at, 'DateTime', 'DateTime returned');
  48 is("$created_start", '2006-06-18T00:00:00', 'Correct date/time');
  49
  50 ## timestamp field
  51 isa_ok($event->created_on, 'DateTime', 'DateTime returned');
  52
  53 ## varchar fields
  54 isa_ok($event->varchar_date, 'DateTime', 'DateTime returned');
  55 isa_ok($event->varchar_datetime, 'DateTime', 'DateTime returned');
  56
  57 ## skip inflation field
  58 isnt(ref($event->skip_inflation), 'DateTime', 'No DateTime returned for skip inflation column');
  59
  60 # klunky, but makes older Test::More installs happy
  61 my $createo = $event->created_on;
  62 is("$createo", '2006-06-22T21:00:05', 'Correct date/time');
  63
  64 my $created_cron = $created->created_on;
  65
  66 isa_ok($created->created_on, 'DateTime', 'DateTime returned');
  67 is("$created_cron", '2006-06-23T00:00:00', 'Correct date/time');
  68
  69
  70 # Test "timezone" parameter
  71
  72 foreach my $tbl (qw/EventTZ EventTZDeprecated/) {
  73   my $event_tz = $schema->resultset($tbl)->create({
  74       starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
  75       created_on => DateTime->new(year=>2006, month=>1, day=>31,
  76           hour => 13, minute => 34, second => 56, time_zone => "America/New_York" ),
  77   });
  78
  79   is ($event_tz->starts_at->day_name, "Montag", 'Locale de_DE loaded: day_name');
  80   is ($event_tz->starts_at->month_name, "Dezember", 'Locale de_DE loaded: month_name');
  81   is ($event_tz->created_on->day_name, "Tuesday", 'Default locale loaded: day_name');
  82   is ($event_tz->created_on->month_name, "January", 'Default locale loaded: month_name');
  83
  84   my $starts_at = $event_tz->starts_at;
  85   is("$starts_at", '2007-12-31T00:00:00', 'Correct date/time using timezone');
  86
  87   my $created_on = $event_tz->created_on;
  88   is("$created_on", '2006-01-31T12:34:56', 'Correct timestamp using timezone');
  89   is($event_tz->created_on->time_zone->name, "America/Chicago", "Correct timezone");
  90
  91   my $loaded_event = $schema->resultset($tbl)->find( $event_tz->id );
  92
  93   isa_ok($loaded_event->starts_at, 'DateTime', 'DateTime returned');
  94   $starts_at = $loaded_event->starts_at;
  95   is("$starts_at", '2007-12-31T00:00:00', 'Loaded correct date/time using timezone');
  96   is($starts_at->time_zone->name, 'America/Chicago', 'Correct timezone');
  97
  98   isa_ok($loaded_event->created_on, 'DateTime', 'DateTime returned');
  99   $created_on = $loaded_event->created_on;
 100   is("$created_on", '2006-01-31T12:34:56', 'Loaded correct timestamp using timezone');
 101   is($created_on->time_zone->name, 'America/Chicago', 'Correct timezone');
 102
 103   # Test floating timezone warning
 104   # We expect one warning
 105   SKIP: {
 106       skip "ENV{DBIC_FLOATING_TZ_OK} was set, skipping", 1 if $ENV{DBIC_FLOATING_TZ_OK};
 107       local $SIG{__WARN__} = sub {
 108           like(
 109               shift,
 110               qr/You're using a floating timezone, please see the documentation of DBIx::Class::InflateColumn::DateTime for an explanation/,
 111               'Floating timezone warning'
 112           );
 113       };
 114       my $event_tz_floating = $schema->resultset($tbl)->create({
 115           starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 116           created_on => DateTime->new(year=>2006, month=>1, day=>31,
 117               hour => 13, minute => 34, second => 56, ),
 118       });
 119       delete $SIG{__WARN__};
 120   };
 121
 122   # This should fail to set
 123   my $prev_str = "$created_on";
 124   $loaded_event->update({ created_on => '0000-00-00' });
 125   is("$created_on", $prev_str, "Don't update invalid dates");
 126
 127   my $invalid = $schema->resultset('Event')->create({
 128       starts_at  => '0000-00-00',
 129       created_on => $created_on
 130   });
 131
 132   is( $invalid->get_column('starts_at'), '0000-00-00', "Invalid date stored" );
 133   is( $invalid->starts_at, undef, "Inflate to undef" );
 134
 135   $invalid->created_on('0000-00-00');
 136   $invalid->update;
 137
 138   {
 139       local $@;
 140       eval { $invalid->created_on };
 141       like( $@, qr/invalid date format/i, "Invalid date format exception");
 142   }
 143 }
 144
 145 ## varchar field using inflate_date => 1
 146 my $varchar_date = $event->varchar_date;
 147 is("$varchar_date", '2006-07-23T00:00:00', 'Correct date/time');
 148
 149 ## varchar field using inflate_datetime => 1
 150 my $varchar_datetime = $event->varchar_datetime;
 151 is("$varchar_datetime", '2006-05-22T19:05:07', 'Correct date/time');
 152
 153 ## skip inflation field
 154 my $skip_inflation = $event->skip_inflation;
 155 is ("$skip_inflation", '2006-04-21 18:04:06', 'Correct date/time');
 156
 157 } # Skip if no MySQL DT::Formatter
 158
 159 SKIP: {
 160   eval { require DateTime::Format::Pg };
 161   skip ('Need DateTime::Format::Pg for timestamp inflation tests', 3) if $@;
 162
 163   my $event = $schema->resultset("EventTZPg")->find(1);
 164   $event->update({created_on => '2009-01-15 17:00:00+00'});
 165   $event->discard_changes;
 166   isa_ok($event->created_on, "DateTime") or diag $event->created_on;
 167   is($event->created_on->time_zone->name, "America/Chicago", "Timezone changed");
 168   # Time zone difference -> -6hours
 169   is($event->created_on->iso8601, "2009-01-15T11:00:00", "Time with TZ correct");
 170 }