t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  11
  12 my $TESTS = 37 + 2;
  13
  14 if (not ($dsn && $user)) {
  15   plan skip_all =>
  16     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
  17     "\nWarning: This test drops and creates the tables " .
  18     "'artist' and 'bindtype_test'";
  19 } else {
  20   plan tests => $TESTS*2;
  21 }
  22
  23 my @storage_types = (
  24   'DBI::Sybase',
  25   'DBI::Sybase::NoBindVars',
  26 );
  27 my $schema;
  28 my $storage_idx = -1;
  29
  30 sub get_schema {
  31   DBICTest::Schema->connect($dsn, $user, $pass, {
  32     on_connect_call => [
  33       [ blob_setup => log_on_update => 1 ], # this is a safer option
  34     ],
  35   });
  36 }
  37
  38 for my $storage_type (@storage_types) {
  39   $storage_idx++;
  40
  41   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  42     DBICTest::Schema->storage_type("::$storage_type");
  43   }
  44
  45   $schema = get_schema();
  46
  47   $schema->storage->ensure_connected;
  48
  49   if ($storage_idx == 0 &&
  50       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::NoBindVars')) {
  51 # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  52       my $tb = Test::More->builder;
  53       $tb->skip('no placeholders') for 1..$TESTS;
  54       next;
  55   }
  56
  57   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  58
  59   $schema->storage->_dbh->disconnect;
  60   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  61
  62   $schema->storage->dbh_do (sub {
  63       my ($storage, $dbh) = @_;
  64       eval { $dbh->do("DROP TABLE artist") };
  65       $dbh->do(<<'SQL');
  66 CREATE TABLE artist (
  67    artistid INT IDENTITY PRIMARY KEY,
  68    name VARCHAR(100),
  69    rank INT DEFAULT 13 NOT NULL,
  70    charfield CHAR(10) NULL
  71 )
  72 SQL
  73   });
  74
  75   my %seen_id;
  76
  77 # so we start unconnected
  78   $schema->storage->disconnect;
  79
  80 # test primary key handling
  81   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  82   ok($new->artistid > 0, "Auto-PK worked");
  83
  84   $seen_id{$new->artistid}++;
  85
  86 # check redispatch to storage-specific insert when auto-detected storage
  87   if ($storage_type eq 'DBI::Sybase') {
  88     DBICTest::Schema->storage_type('::DBI');
  89     $schema = get_schema();
  90   }
  91
  92   $new = $schema->resultset('Artist')->create({ name => 'Artist 1' });
  93   is ( $seen_id{$new->artistid}, undef, 'id for Artist 1 is unique' );
  94   $seen_id{$new->artistid}++;
  95
  96 # inserts happen in a txn, so we make sure it still works inside a txn too
  97   $schema->txn_begin;
  98
  99   for (2..6) {
 100     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 101     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
 102     $seen_id{$new->artistid}++;
 103   }
 104
 105   $schema->txn_commit;
 106
 107 # test simple count
 108   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
 109
 110 # test LIMIT support
 111   my $it = $schema->resultset('Artist')->search({
 112     artistid => { '>' => 0 }
 113   }, {
 114     rows => 3,
 115     order_by => 'artistid',
 116   });
 117
 118   is( $it->count, 3, "LIMIT count ok" );
 119
 120   is( $it->next->name, "foo", "iterator->next ok" );
 121   $it->next;
 122   is( $it->next->name, "Artist 2", "iterator->next ok" );
 123   is( $it->next, undef, "next past end of resultset ok" );
 124
 125 # now try with offset
 126   $it = $schema->resultset('Artist')->search({}, {
 127     rows => 3,
 128     offset => 3,
 129     order_by => 'artistid',
 130   });
 131
 132   is( $it->count, 3, "LIMIT with offset count ok" );
 133
 134   is( $it->next->name, "Artist 3", "iterator->next ok" );
 135   $it->next;
 136   is( $it->next->name, "Artist 5", "iterator->next ok" );
 137   is( $it->next, undef, "next past end of resultset ok" );
 138
 139 # now try a grouped count
 140   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 141     for (1..6);
 142
 143   $it = $schema->resultset('Artist')->search({}, {
 144     group_by => 'name'
 145   });
 146
 147   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 148
 149 # do an identity insert (which should happen with no txn when using
 150 # placeholders.)
 151   {
 152     no warnings 'redefine';
 153     my @debug_out;
 154     local *DBIx::Class::Storage::DBI::_query_start = sub {
 155       push @debug_out, $_[1];
 156     };
 157
 158     my $txn_used = 0;
 159     my $txn_commit = \&DBIx::Class::Storage::DBI::txn_commit;
 160     local *DBIx::Class::Storage::DBI::txn_commit = sub {
 161       $txn_used = 1;
 162       goto &$txn_commit;
 163     };
 164
 165     $schema->resultset('Artist')
 166       ->create({ artistid => 999, name => 'mtfnpy' });
 167
 168     ok((grep /IDENTITY_INSERT/i, @debug_out), 'IDENTITY_INSERT');
 169
 170     SKIP: {
 171       skip 'not testing lack of txn on IDENTITY_INSERT with NoBindVars', 1
 172         if $storage_type =~ /NoBindVars/i;
 173
 174       is $txn_used, 0, 'no txn on insert with IDENTITY_INSERT';
 175     }
 176   }
 177
 178 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 179   SKIP: {
 180     skip 'TEXT/IMAGE support does not work with FreeTDS', 12
 181       if $schema->storage->using_freetds;
 182
 183     my $dbh = $schema->storage->dbh;
 184     {
 185       local $SIG{__WARN__} = sub {};
 186       eval { $dbh->do('DROP TABLE bindtype_test') };
 187
 188       $dbh->do(qq[
 189         CREATE TABLE bindtype_test
 190         (
 191           id    INT   IDENTITY PRIMARY KEY,
 192           bytea INT   NULL,
 193           blob  IMAGE NULL,
 194           clob  TEXT  NULL
 195         )
 196       ],{ RaiseError => 1, PrintError => 0 });
 197     }
 198
 199     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 200     $binstr{'large'} = $binstr{'small'} x 1024;
 201
 202     my $maxloblen = length $binstr{'large'};
 203
 204     if (not $schema->storage->using_freetds) {
 205       $dbh->{'LongReadLen'} = $maxloblen * 2;
 206     } else {
 207       $dbh->do("set textsize ".($maxloblen * 2));
 208     }
 209
 210     my $rs = $schema->resultset('BindType');
 211     my $last_id;
 212
 213     foreach my $type (qw(blob clob)) {
 214       foreach my $size (qw(small large)) {
 215         no warnings 'uninitialized';
 216
 217         my $created = eval { $rs->create( { $type => $binstr{$size} } ) };
 218         ok(!$@, "inserted $size $type without dying");
 219         diag $@ if $@;
 220
 221         $last_id = $created->id if $created;
 222
 223         my $got = eval {
 224           $rs->find($last_id)->$type
 225         };
 226         diag $@ if $@;
 227         ok($got eq $binstr{$size}, "verified inserted $size $type");
 228       }
 229     }
 230
 231     # blob insert with explicit PK
 232     # also a good opportunity to test IDENTITY_INSERT
 233     {
 234       local $SIG{__WARN__} = sub {};
 235       eval { $dbh->do('DROP TABLE bindtype_test') };
 236
 237       $dbh->do(qq[
 238         CREATE TABLE bindtype_test
 239         (
 240           id    INT   IDENTITY PRIMARY KEY,
 241           bytea INT   NULL,
 242           blob  IMAGE NULL,
 243           clob  TEXT  NULL
 244         )
 245       ],{ RaiseError => 1, PrintError => 0 });
 246     }
 247     my $created = eval { $rs->create( { id => 1, blob => $binstr{large} } ) };
 248     ok(!$@, "inserted large blob without dying with manual PK");
 249     diag $@ if $@;
 250
 251     my $got = eval {
 252       $rs->find(1)->blob
 253     };
 254     diag $@ if $@;
 255     ok($got eq $binstr{large}, "verified inserted large blob with manual PK");
 256
 257     # try a blob update
 258     my $new_str = $binstr{large} . 'mtfnpy';
 259
 260     # check redispatch to storage-specific update when auto-detected storage
 261     if ($storage_type eq 'DBI::Sybase') {
 262       DBICTest::Schema->storage_type('::DBI');
 263       $schema = get_schema();
 264     }
 265
 266     eval { $rs->search({ id => 1 })->update({ blob => $new_str }) };
 267     ok !$@, 'updated blob successfully';
 268     diag $@ if $@;
 269     $got = eval {
 270       $rs->find(1)->blob
 271     };
 272     diag $@ if $@;
 273     ok($got eq $new_str, "verified updated blob");
 274   }
 275
 276 # test MONEY column support
 277   $schema->storage->dbh_do (sub {
 278       my ($storage, $dbh) = @_;
 279       eval { $dbh->do("DROP TABLE money_test") };
 280       $dbh->do(<<'SQL');
 281 CREATE TABLE money_test (
 282    id INT IDENTITY PRIMARY KEY,
 283    amount MONEY NULL
 284 )
 285 SQL
 286   });
 287
 288   my $rs = $schema->resultset('Money');
 289
 290   my $row;
 291   lives_ok {
 292     $row = $rs->create({ amount => 100 });
 293   } 'inserted a money value';
 294
 295   is eval { $rs->find($row->id)->amount }, 100, 'money value round-trip';
 296
 297   lives_ok {
 298     $row->update({ amount => 200 });
 299   } 'updated a money value';
 300
 301   is eval { $rs->find($row->id)->amount },
 302     200, 'updated money value round-trip';
 303
 304   lives_ok {
 305     $row->update({ amount => undef });
 306   } 'updated a money value to NULL';
 307
 308   my $null_amount = eval { $rs->find($row->id)->amount };
 309   ok(
 310     (($null_amount == undef) && (not $@)),
 311     'updated money value to NULL round-trip'
 312   );
 313   diag $@ if $@;
 314 }
 315
 316 # clean up our mess
 317 END {
 318   if (my $dbh = eval { $schema->storage->_dbh }) {
 319     eval { $dbh->do("DROP TABLE $_") }
 320       for qw/artist bindtype_test money_test/;
 321   }
 322 }