t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9 {
  10   package DBICTest::Schema::Casecheck;
  11
  12   use strict;
  13   use warnings;
  14   use base 'DBIx::Class';
  15
  16   __PACKAGE__->load_components(qw/Core/);
  17   __PACKAGE__->table('testschema.casecheck');
  18   __PACKAGE__->add_columns(qw/id name NAME uc_name storecolumn/);
  19   __PACKAGE__->column_info_from_storage(1);
  20   __PACKAGE__->set_primary_key('id');
  21
  22   sub store_column {
  23     my ($self, $name, $value) = @_;
  24     $value = '#'.$value if($name eq "storecolumn");
  25     $self->maybe::next::method($name, $value);
  26   }
  27 }
  28
  29 {
  30   package DBICTest::Schema::ArrayTest;
  31
  32   use strict;
  33   use warnings;
  34   use base 'DBIx::Class';
  35
  36   __PACKAGE__->load_components(qw/Core/);
  37   __PACKAGE__->table('testschema.array_test');
  38   __PACKAGE__->add_columns(qw/id arrayfield/);
  39   __PACKAGE__->column_info_from_storage(1);
  40   __PACKAGE__->set_primary_key('id');
  41
  42 }
  43
  44 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  45
  46 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test '.
  47   '(note: This test drops and creates tables called \'artist\', \'casecheck\', \'array_test\' and \'sequence_test\''.
  48   ' as well as following sequences: \'pkid1_seq\', \'pkid2_seq\' and \'nonpkid_seq\''.
  49   ' as well as following schemas: \'testschema\'!)'
  50     unless ($dsn && $user);
  51
  52
  53 plan tests => 39;
  54
  55 DBICTest::Schema->load_classes( 'Casecheck', 'ArrayTest' );
  56 my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  57
  58 # Check that datetime_parser returns correctly before we explicitly connect.
  59 SKIP: {
  60     eval { require DateTime::Format::Pg };
  61     skip "DateTime::Format::Pg required", 2 if $@;
  62
  63     my $store = ref $schema->storage;
  64     is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  65
  66     my $parser = $schema->storage->datetime_parser;
  67     is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  68 }
  69
  70 my $dbh = $schema->storage->dbh;
  71 $schema->source("Artist")->name("testschema.artist");
  72 $schema->source("SequenceTest")->name("testschema.sequence_test");
  73 {
  74     local $SIG{__WARN__} = sub {};
  75     $dbh->do("CREATE SCHEMA testschema;");
  76     $dbh->do("CREATE TABLE testschema.artist (artistid serial PRIMARY KEY, name VARCHAR(100), rank INTEGER NOT NULL DEFAULT '13', charfield CHAR(10), arrayfield INTEGER[]);");
  77     $dbh->do("CREATE TABLE testschema.sequence_test (pkid1 integer, pkid2 integer, nonpkid integer, name VARCHAR(100), CONSTRAINT pk PRIMARY KEY(pkid1, pkid2));");
  78     $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
  79     $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
  80     $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
  81     ok ( $dbh->do('CREATE TABLE testschema.casecheck (id serial PRIMARY KEY, "name" VARCHAR(1), "NAME" VARCHAR(2), "UC_NAME" VARCHAR(3), "storecolumn" VARCHAR(10));'), 'Creation of casecheck table');
  82     ok ( $dbh->do('CREATE TABLE testschema.array_test (id serial PRIMARY KEY, arrayfield INTEGER[]);'), 'Creation of array_test table');
  83 }
  84
  85 # store_column is called once for create() for non sequence columns
  86
  87 ok(my $storecolumn = $schema->resultset('Casecheck')->create({'storecolumn' => 'a'}));
  88
  89 is($storecolumn->storecolumn, '#a'); # was '##a'
  90
  91
  92 # This is in Core now, but it's here just to test that it doesn't break
  93 $schema->class('Artist')->load_components('PK::Auto');
  94
  95 my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  96
  97 is($new->artistid, 1, "Auto-PK worked");
  98
  99 $new = $schema->resultset('Artist')->create({ name => 'bar' });
 100
 101 is($new->artistid, 2, "Auto-PK worked");
 102
 103 my $test_type_info = {
 104     'artistid' => {
 105         'data_type' => 'integer',
 106         'is_nullable' => 0,
 107         'size' => 4,
 108     },
 109     'name' => {
 110         'data_type' => 'character varying',
 111         'is_nullable' => 1,
 112         'size' => 100,
 113         'default_value' => undef,
 114     },
 115     'rank' => {
 116         'data_type' => 'integer',
 117         'is_nullable' => 0,
 118         'size' => 4,
 119         'default_value' => 13,
 120
 121     },
 122     'charfield' => {
 123         'data_type' => 'character',
 124         'is_nullable' => 1,
 125         'size' => 10,
 126         'default_value' => undef,
 127     },
 128     'arrayfield' => {
 129         'data_type' => 'integer[]',
 130         'is_nullable' => 1,
 131         'size' => undef,
 132         'default_value' => undef,
 133     },
 134 };
 135
 136
 137 my $type_info = $schema->storage->columns_info_for('testschema.artist');
 138 my $artistid_defval = delete $type_info->{artistid}->{default_value};
 139 like($artistid_defval,
 140      qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 141      'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 142 is_deeply($type_info, $test_type_info,
 143           'columns_info_for - column data types');
 144
 145 {
 146   lives_ok {
 147     $schema->resultset('ArrayTest')->create({
 148       arrayfield => [1, 2],
 149     });
 150   } 'inserting arrayref as pg array data';
 151
 152   lives_ok {
 153     $schema->resultset('ArrayTest')->update({
 154       arrayfield => [3, 4],
 155     });
 156   } 'updating arrayref as pg array data';
 157
 158   $schema->resultset('ArrayTest')->create({
 159     arrayfield => [5, 6],
 160   });
 161
 162   my $count;
 163   lives_ok {
 164     $count = $schema->resultset('ArrayTest')->search({
 165       arrayfield => \[ '= ?' => [arrayfield => [3, 4]] ],   #Todo anything less ugly than this?
 166     })->count;
 167   } 'comparing arrayref to pg array data does not blow up';
 168   is($count, 1, 'comparing arrayref to pg array data gives correct result');
 169 }
 170
 171
 172 my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 173 is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 174
 175 my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 176 is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 177
 178 my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 179 is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 180
 181 # Test SELECT ... FOR UPDATE
 182 my $HaveSysSigAction = eval "require Sys::SigAction" && !$@;
 183 if ($HaveSysSigAction) {
 184     Sys::SigAction->import( 'set_sig_handler' );
 185 }
 186
 187 SKIP: {
 188     skip "Sys::SigAction is not available", 3 unless $HaveSysSigAction;
 189     # create a new schema
 190     my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 191     $schema2->source("Artist")->name("testschema.artist");
 192
 193     $schema->txn_do( sub {
 194         my $artist = $schema->resultset('Artist')->search(
 195             {
 196                 artistid => 1
 197             },
 198             {
 199                 for => 'update'
 200             }
 201         )->first;
 202         is($artist->artistid, 1, "select for update returns artistid = 1");
 203
 204         my $artist_from_schema2;
 205         my $error_ok = 0;
 206         eval {
 207             my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 208             alarm(2);
 209             $artist_from_schema2 = $schema2->resultset('Artist')->find(1);
 210             $artist_from_schema2->name('fooey');
 211             $artist_from_schema2->update;
 212             alarm(0);
 213         };
 214         if (my $e = $@) {
 215             $error_ok = $e =~ /DBICTestTimeout/;
 216         }
 217
 218         # Make sure that an error was raised, and that the update failed
 219         ok($error_ok, "update from second schema times out");
 220         ok($artist_from_schema2->is_column_changed('name'), "'name' column is still dirty from second schema");
 221     });
 222 }
 223
 224 SKIP: {
 225     skip "Sys::SigAction is not available", 3 unless $HaveSysSigAction;
 226     # create a new schema
 227     my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 228     $schema2->source("Artist")->name("testschema.artist");
 229
 230     $schema->txn_do( sub {
 231         my $artist = $schema->resultset('Artist')->search(
 232             {
 233                 artistid => 1
 234             },
 235         )->first;
 236         is($artist->artistid, 1, "select for update returns artistid = 1");
 237
 238         my $artist_from_schema2;
 239         my $error_ok = 0;
 240         eval {
 241             my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 242             alarm(2);
 243             $artist_from_schema2 = $schema2->resultset('Artist')->find(1);
 244             $artist_from_schema2->name('fooey');
 245             $artist_from_schema2->update;
 246             alarm(0);
 247         };
 248         if (my $e = $@) {
 249             $error_ok = $e =~ /DBICTestTimeout/;
 250         }
 251
 252         # Make sure that an error was NOT raised, and that the update succeeded
 253         ok(! $error_ok, "update from second schema DOES NOT timeout");
 254         ok(! $artist_from_schema2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 255     });
 256 }
 257
 258 for (1..5) {
 259     my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 260     is($st->pkid1, $_, "Oracle Auto-PK without trigger: First primary key");
 261     is($st->pkid2, $_ + 9, "Oracle Auto-PK without trigger: Second primary key");
 262     is($st->nonpkid, $_ + 19, "Oracle Auto-PK without trigger: Non-primary key");
 263 }
 264 my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 265 is($st->pkid1, 55, "Oracle Auto-PK without trigger: First primary key set manually");
 266
 267
 268 END {
 269     if($dbh) {
 270         $dbh->do("DROP TABLE testschema.artist;");
 271         $dbh->do("DROP TABLE testschema.casecheck;");
 272         $dbh->do("DROP TABLE testschema.sequence_test;");
 273         $dbh->do("DROP TABLE testschema.array_test;");
 274         $dbh->do("DROP SEQUENCE pkid1_seq");
 275         $dbh->do("DROP SEQUENCE pkid2_seq");
 276         $dbh->do("DROP SEQUENCE nonpkid_seq");
 277         $dbh->do("DROP SCHEMA testschema;");
 278     }
 279 }