t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9
  10 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  11
  12 plan skip_all => <<EOM unless $dsn && $user;
  13 Set \$ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  14 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  15 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  16 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  17 'nonpkid_seq''. as well as following schemas: 'dbic_t_schema',
  18 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  19 EOM
  20
  21 ### load any test classes that are defined further down in the file via BEGIN blocks
  22
  23 our @test_classes; #< array that will be pushed into by test classes defined in this file
  24 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  25
  26 my $test_server_supports_insert_returning = do {
  27   my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  28   $s->storage->_determine_driver;
  29   $s->storage->_supports_insert_returning;
  30 };
  31
  32 my $schema;
  33
  34 for my $use_insert_returning ($test_server_supports_insert_returning
  35   ? (0,1)
  36   : (0)
  37 ) {
  38   no warnings qw/redefine once/;
  39   local *DBIx::Class::Storage::DBI::Pg::_supports_insert_returning = sub {
  40     $use_insert_returning
  41   };
  42
  43 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  44   {
  45     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  46
  47     ok (!$s->storage->_dbh, 'definitely not connected');
  48
  49     # Check that datetime_parser returns correctly before we explicitly connect.
  50     SKIP: {
  51         eval { require DateTime::Format::Pg };
  52         skip "DateTime::Format::Pg required", 2 if $@;
  53
  54         my $store = ref $s->storage;
  55         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  56
  57         my $parser = $s->storage->datetime_parser;
  58         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  59     }
  60
  61     ok (!$s->storage->_dbh, 'still not connected');
  62   }
  63   {
  64     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  65     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  66     ok (!$s->storage->_dbh, 'definitely not connected');
  67     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  68     ok (!$s->storage->_dbh, 'still not connected');
  69   }
  70
  71 ### connect, create postgres-specific test schema
  72
  73   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  74   $schema->storage->ensure_connected;
  75
  76   drop_test_schema($schema);
  77   create_test_schema($schema);
  78
  79 ### begin main tests
  80
  81 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
  82 # discovery
  83   run_apk_tests($schema); #< older set of auto-pk tests
  84   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
  85
  86 ### type_info tests
  87
  88   my $test_type_info = {
  89       'artistid' => {
  90           'data_type' => 'integer',
  91           'is_nullable' => 0,
  92           'size' => 4,
  93       },
  94       'name' => {
  95           'data_type' => 'character varying',
  96           'is_nullable' => 1,
  97           'size' => 100,
  98           'default_value' => undef,
  99       },
 100       'rank' => {
 101           'data_type' => 'integer',
 102           'is_nullable' => 0,
 103           'size' => 4,
 104           'default_value' => 13,
 105
 106       },
 107       'charfield' => {
 108           'data_type' => 'character',
 109           'is_nullable' => 1,
 110           'size' => 10,
 111           'default_value' => undef,
 112       },
 113       'arrayfield' => {
 114           'data_type' => 'integer[]',
 115           'is_nullable' => 1,
 116           'size' => undef,
 117           'default_value' => undef,
 118       },
 119   };
 120
 121   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 122   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 123   like($artistid_defval,
 124        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 125        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 126   is_deeply($type_info, $test_type_info,
 127             'columns_info_for - column data types');
 128
 129
 130
 131
 132 ####### Array tests
 133
 134   BEGIN {
 135     package DBICTest::Schema::ArrayTest;
 136     push @main::test_classes, __PACKAGE__;
 137
 138     use strict;
 139     use warnings;
 140     use base 'DBIx::Class::Core';
 141
 142     __PACKAGE__->table('dbic_t_schema.array_test');
 143     __PACKAGE__->add_columns(qw/id arrayfield/);
 144     __PACKAGE__->column_info_from_storage(1);
 145     __PACKAGE__->set_primary_key('id');
 146
 147   }
 148   SKIP: {
 149     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 150
 151     lives_ok {
 152       $schema->resultset('ArrayTest')->create({
 153         arrayfield => [1, 2],
 154       });
 155     } 'inserting arrayref as pg array data';
 156
 157     lives_ok {
 158       $schema->resultset('ArrayTest')->update({
 159         arrayfield => [3, 4],
 160       });
 161     } 'updating arrayref as pg array data';
 162
 163     $schema->resultset('ArrayTest')->create({
 164       arrayfield => [5, 6],
 165     });
 166
 167     my $count;
 168     lives_ok {
 169       $count = $schema->resultset('ArrayTest')->search({
 170         arrayfield => \[ '= ?' => [arrayfield => [3, 4]] ],   #Todo anything less ugly than this?
 171       })->count;
 172     } 'comparing arrayref to pg array data does not blow up';
 173     is($count, 1, 'comparing arrayref to pg array data gives correct result');
 174   }
 175
 176
 177
 178 ########## Case check
 179
 180   BEGIN {
 181     package DBICTest::Schema::Casecheck;
 182     push @main::test_classes, __PACKAGE__;
 183
 184     use strict;
 185     use warnings;
 186     use base 'DBIx::Class::Core';
 187
 188     __PACKAGE__->table('dbic_t_schema.casecheck');
 189     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 190     __PACKAGE__->column_info_from_storage(1);
 191     __PACKAGE__->set_primary_key('id');
 192   }
 193
 194   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 195   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 196
 197   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 198   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 199
 200   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 201   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 202
 203
 204 ## Test ResultSet->update
 205 my $artist = $schema->resultset('Artist')->first;
 206 my $cds = $artist->cds_unordered->search({
 207     year => { '!=' => 2010 }
 208 }, { prefetch => 'liner_notes' });
 209 TODO: {
 210     todo_skip 'update resultset with a prefetch over a might_have rel', 1;
 211     $cds->update({ year => '2010' });
 212 }
 213
 214
 215 ## Test SELECT ... FOR UPDATE
 216
 217   SKIP: {
 218       if(eval "require Sys::SigAction" && !$@) {
 219           Sys::SigAction->import( 'set_sig_handler' );
 220       }
 221       else {
 222         skip "Sys::SigAction is not available", 6;
 223       }
 224
 225       my ($timed_out, $artist2);
 226
 227       for my $t (
 228         {
 229           # Make sure that an error was raised, and that the update failed
 230           update_lock => 1,
 231           test_sub => sub {
 232             ok($timed_out, "update from second schema times out");
 233             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 234           },
 235         },
 236         {
 237           # Make sure that an error was NOT raised, and that the update succeeded
 238           update_lock => 0,
 239           test_sub => sub {
 240             ok(! $timed_out, "update from second schema DOES NOT timeout");
 241             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 242           },
 243         },
 244       ) {
 245         # create a new schema
 246         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 247         $schema2->source("Artist")->name("dbic_t_schema.artist");
 248
 249         $schema->txn_do( sub {
 250           my $rs = $schema->resultset('Artist')->search(
 251               {
 252                   artistid => 1
 253               },
 254               $t->{update_lock} ? { for => 'update' } : {}
 255           );
 256           ok ($rs->count, 'Count works');
 257
 258           my $artist = $rs->next;
 259           is($artist->artistid, 1, "select returns artistid = 1");
 260
 261           $timed_out = 0;
 262           eval {
 263               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 264               alarm(2);
 265               $artist2 = $schema2->resultset('Artist')->find(1);
 266               $artist2->name('fooey');
 267               $artist2->update;
 268               alarm(0);
 269           };
 270           $timed_out = $@ =~ /DBICTestTimeout/;
 271         });
 272
 273         $t->{test_sub}->();
 274       }
 275   }
 276
 277
 278 ######## other older Auto-pk tests
 279
 280   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 281   for (1..5) {
 282       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 283       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 284       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 285       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 286   }
 287   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 288   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 289
 290
 291 ######## test non-serial auto-pk
 292
 293   if ($schema->storage->_supports_insert_returning) {
 294     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 295     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 296     ok $row->id;
 297   }
 298
 299 ######## test with_deferred_fk_checks
 300
 301   $schema->source('CD')->name('dbic_t_schema.cd');
 302   $schema->source('Track')->name('dbic_t_schema.track');
 303   lives_ok {
 304     $schema->storage->with_deferred_fk_checks(sub {
 305       $schema->resultset('Track')->create({
 306         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 307       });
 308       $schema->resultset('CD')->create({
 309         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 310       });
 311     });
 312   } 'with_deferred_fk_checks code survived';
 313
 314   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 315      'code in with_deferred_fk_checks worked';
 316
 317   throws_ok {
 318     $schema->resultset('Track')->create({
 319       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 320     });
 321   } qr/constraint/i, 'with_deferred_fk_checks is off';
 322 }
 323
 324 done_testing;
 325
 326 END {
 327     return unless $schema;
 328     drop_test_schema($schema);
 329     eapk_drop_all( $schema)
 330 };
 331
 332
 333 ######### SUBROUTINES
 334
 335 sub create_test_schema {
 336     my $schema = shift;
 337     $schema->storage->dbh_do(sub {
 338       my (undef,$dbh) = @_;
 339
 340       local $dbh->{Warn} = 0;
 341
 342       my $std_artist_table = <<EOS;
 343 (
 344   artistid serial PRIMARY KEY
 345   , name VARCHAR(100)
 346   , rank INTEGER NOT NULL DEFAULT '13'
 347   , charfield CHAR(10)
 348   , arrayfield INTEGER[]
 349 )
 350 EOS
 351
 352       $dbh->do("CREATE SCHEMA dbic_t_schema");
 353       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 354
 355       $dbh->do(<<EOS);
 356 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 357   id timestamp default current_timestamp
 358 )
 359 EOS
 360       $dbh->do(<<EOS);
 361 CREATE TABLE dbic_t_schema.cd (
 362   cdid int PRIMARY KEY,
 363   artist int,
 364   title varchar(255),
 365   year varchar(4),
 366   genreid int,
 367   single_track int
 368 )
 369 EOS
 370       $dbh->do(<<EOS);
 371 CREATE TABLE dbic_t_schema.track (
 372   trackid int,
 373   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 374   position int,
 375   title varchar(255),
 376   last_updated_on date,
 377   last_updated_at date,
 378   small_dt date
 379 )
 380 EOS
 381
 382       $dbh->do(<<EOS);
 383 CREATE TABLE dbic_t_schema.sequence_test (
 384     pkid1 integer
 385     , pkid2 integer
 386     , nonpkid integer
 387     , name VARCHAR(100)
 388     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 389 )
 390 EOS
 391       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 392       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 393       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 394       $dbh->do(<<EOS);
 395 CREATE TABLE dbic_t_schema.casecheck (
 396     id serial PRIMARY KEY
 397     , "name" VARCHAR(1)
 398     , "NAME" VARCHAR(2)
 399     , "UC_NAME" VARCHAR(3)
 400 )
 401 EOS
 402       $dbh->do(<<EOS);
 403 CREATE TABLE dbic_t_schema.array_test (
 404     id serial PRIMARY KEY
 405     , arrayfield INTEGER[]
 406 )
 407 EOS
 408       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 409       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 410       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 411       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 412       $dbh->do('set search_path=dbic_t_schema,public');
 413       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 414       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 415       $dbh->do(<<EOS);
 416  CREATE TABLE dbic_t_schema_4.artist
 417  (
 418    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 419    , name VARCHAR(100)
 420    , rank INTEGER NOT NULL DEFAULT '13'
 421    , charfield CHAR(10)
 422    , arrayfield INTEGER[]
 423  );
 424 EOS
 425       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 426       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 427       $dbh->do(<<EOS);
 428  CREATE TABLE dbic_t_schema_5.artist
 429  (
 430    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 431    , name VARCHAR(100)
 432    , rank INTEGER NOT NULL DEFAULT '13'
 433    , charfield CHAR(10)
 434    , arrayfield INTEGER[]
 435  );
 436 EOS
 437       $dbh->do('set search_path=dbic_t_schema,public');
 438   });
 439 }
 440
 441
 442
 443 sub drop_test_schema {
 444     my ( $schema, $warn_exceptions ) = @_;
 445
 446     $schema->storage->dbh_do(sub {
 447         my (undef,$dbh) = @_;
 448
 449         local $dbh->{Warn} = 0;
 450
 451         for my $stat (
 452                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 453                       'DROP SEQUENCE public.artist_artistid_seq',
 454                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 455                       'DROP SCHEMA dbic_t_schema CASCADE',
 456                       'DROP SEQUENCE pkid1_seq',
 457                       'DROP SEQUENCE pkid2_seq',
 458                       'DROP SEQUENCE nonpkid_seq',
 459                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 460                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 461                      ) {
 462             eval { $dbh->do ($stat) };
 463             diag $@ if $@ && $warn_exceptions;
 464         }
 465     });
 466 }
 467
 468
 469 ###  auto-pk / last_insert_id / sequence discovery
 470 sub run_apk_tests {
 471     my $schema = shift;
 472
 473     # This is in Core now, but it's here just to test that it doesn't break
 474     $schema->class('Artist')->load_components('PK::Auto');
 475     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 476
 477     # test that auto-pk also works with the defined search path by
 478     # un-schema-qualifying the table name
 479     apk_t_set($schema,'artist');
 480
 481     my $unq_new;
 482     lives_ok {
 483         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 484     } 'insert into unqualified, shadowed table succeeds';
 485
 486     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 487
 488     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 489                          [qw| dbic_t_schema_3    1  |],
 490                          [qw| dbic_t_schema_4    2  |],
 491                          [qw| dbic_t_schema_5    1  |],
 492                        );
 493     foreach my $t ( @test_schemas ) {
 494         my ($sch_name, $start_num) = @$t;
 495         #test with dbic_t_schema_2
 496         apk_t_set($schema,"$sch_name.artist");
 497         my $another_new;
 498         lives_ok {
 499             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 500             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 501                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 502         } "$sch_name liid 1 did not die"
 503             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 504         lives_ok {
 505             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 506             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 507                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 508         } "$sch_name liid 2 did not die"
 509             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 510
 511     }
 512
 513     lives_ok {
 514         apk_t_set($schema,'dbic_t_schema.artist');
 515         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 516         is($new->artistid, 4, "Auto-PK worked");
 517         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 518         is($new->artistid, 5, "Auto-PK worked");
 519     } 'old auto-pk tests did not die either';
 520 }
 521
 522 # sets the artist table name and clears sequence name cache
 523 sub apk_t_set {
 524     my ( $s, $n ) = @_;
 525     $s->source("Artist")->name($n);
 526     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 527 }
 528
 529
 530 ######## EXTENDED AUTO-PK TESTS
 531
 532 my @eapk_id_columns;
 533 BEGIN {
 534   package DBICTest::Schema::ExtAPK;
 535   push @main::test_classes, __PACKAGE__;
 536
 537   use strict;
 538   use warnings;
 539   use base 'DBIx::Class::Core';
 540
 541   __PACKAGE__->table('apk');
 542
 543   @eapk_id_columns = qw( id1 id2 id3 id4 );
 544   __PACKAGE__->add_columns(
 545     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 546        @eapk_id_columns
 547   );
 548
 549   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 550                                        #the primary key
 551 }
 552
 553 my @eapk_schemas;
 554 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 555 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 556
 557 sub run_extended_apk_tests {
 558   my $schema = shift;
 559
 560   #save the search path and reset it at the end
 561   my $search_path_save = eapk_get_search_path($schema);
 562
 563   eapk_drop_all($schema);
 564   %seqs = ();
 565
 566   # make the test schemas and sequences
 567   $schema->storage->dbh_do(sub {
 568     my ( undef, $dbh ) = @_;
 569
 570     $dbh->do("CREATE SCHEMA $_")
 571         for @eapk_schemas;
 572
 573     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 574     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 575     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 576
 577     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 578     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 579     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 580
 581     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 582     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 583     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 584
 585     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 586   });
 587
 588   # clear our search_path cache
 589   $schema->storage->{_pg_search_path} = undef;
 590
 591   eapk_create( $schema,
 592                with_search_path => [0,1],
 593              );
 594   eapk_create( $schema,
 595                with_search_path => [1,0,'public'],
 596                nextval => "$eapk_schemas[5].fooseq",
 597              );
 598   eapk_create( $schema,
 599                with_search_path => ['public',0,1],
 600                qualify_table => 2,
 601              );
 602   eapk_create( $schema,
 603                with_search_path => [3,1,0,'public'],
 604                nextval => "$eapk_schemas[4].fooseq",
 605              );
 606   eapk_create( $schema,
 607                with_search_path => [3,1,0,'public'],
 608                nextval => "$eapk_schemas[3].fooseq",
 609                qualify_table => 4,
 610              );
 611
 612   eapk_poke( $schema );
 613   eapk_poke( $schema, 0 );
 614   eapk_poke( $schema, 2 );
 615   eapk_poke( $schema, 4 );
 616   eapk_poke( $schema, 1 );
 617   eapk_poke( $schema, 0 );
 618   eapk_poke( $schema, 1 );
 619   eapk_poke( $schema );
 620   eapk_poke( $schema, 4 );
 621   eapk_poke( $schema, 3 );
 622   eapk_poke( $schema, 1 );
 623   eapk_poke( $schema, 2 );
 624   eapk_poke( $schema, 0 );
 625
 626   # set our search path back
 627   eapk_set_search_path( $schema, @$search_path_save );
 628 }
 629
 630 # do a DBIC create on the apk table in the given schema number (which is an
 631 # index of @eapk_schemas)
 632
 633 sub eapk_poke {
 634   my ($s, $schema_num) = @_;
 635
 636   my $schema_name = defined $schema_num
 637       ? $eapk_schemas[$schema_num]
 638       : '';
 639
 640   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 641
 642   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 643   #< clear sequence name cache
 644   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 645       for @eapk_id_columns;
 646
 647   no warnings 'uninitialized';
 648   lives_ok {
 649     my $new;
 650     for my $inc (1,2,3) {
 651       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 652       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 653       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 654           or eapk_seq_diag($s,$schema_name);
 655       $new->discard_changes;
 656       is( $new->id1, 1 );
 657       for my $id ('id3','id4') {
 658         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 659         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 660             or eapk_seq_diag($s,$schema_name);
 661       }
 662     }
 663   } "create in schema '$schema_name' lives"
 664       or eapk_seq_diag($s,$schema_name);
 665 }
 666
 667 # print diagnostic info on which sequences were found in the ExtAPK
 668 # class
 669 sub eapk_seq_diag {
 670     my $s = shift;
 671     my $schema = shift || eapk_find_visible_schema($s);
 672
 673     diag "$schema.apk sequences: ",
 674         join(', ',
 675              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 676              @eapk_id_columns
 677             );
 678 }
 679
 680 # get the postgres search path as an arrayref
 681 sub eapk_get_search_path {
 682     my ( $s ) = @_;
 683     # cache the search path as ['schema','schema',...] in the storage
 684     # obj
 685
 686     return $s->storage->dbh_do(sub {
 687         my (undef, $dbh) = @_;
 688         my @search_path;
 689         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 690         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 691             unless( defined $1 and length $1 ) {
 692                 die "search path sanity check failed: '$1'";
 693             }
 694             push @search_path, $1;
 695         }
 696         \@search_path
 697     });
 698 }
 699 sub eapk_set_search_path {
 700     my ($s,@sp) = @_;
 701     my $sp = join ',',@sp;
 702     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 703 }
 704
 705 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 706 sub eapk_create {
 707     my ($schema, %a) = @_;
 708
 709     $schema->storage->dbh_do(sub {
 710         my (undef,$dbh) = @_;
 711
 712         my $searchpath_save;
 713         if ( $a{with_search_path} ) {
 714             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 715
 716             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 717
 718             $dbh->do("SET search_path = $search_path");
 719         }
 720
 721         my $table_name = $a{qualify_table}
 722             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 723             : 'apk';
 724         local $_[1]->{Warn} = 0;
 725
 726         my $id_def = $a{nextval}
 727             ? "integer not null default nextval('$a{nextval}'::regclass)"
 728             : 'serial';
 729         $dbh->do(<<EOS);
 730 CREATE TABLE $table_name (
 731   id1 serial
 732   , id2 $id_def
 733   , id3 serial primary key
 734   , id4 serial
 735 )
 736 EOS
 737
 738         if( $searchpath_save ) {
 739             $dbh->do("SET search_path = $searchpath_save");
 740         }
 741     });
 742 }
 743
 744 sub eapk_drop_all {
 745     my ( $schema, $warn_exceptions ) = @_;
 746
 747     $schema->storage->dbh_do(sub {
 748         my (undef,$dbh) = @_;
 749
 750         local $dbh->{Warn} = 0;
 751
 752         # drop the test schemas
 753         for (@eapk_schemas ) {
 754             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 755             diag $@ if $@ && $warn_exceptions;
 756         }
 757
 758
 759     });
 760 }
 761
 762 sub eapk_find_visible_schema {
 763     my ($s) = @_;
 764
 765     my ($schema) =
 766         $s->storage->dbh_do(sub {
 767             $_[1]->selectrow_array(<<EOS);
 768 SELECT n.nspname
 769 FROM pg_catalog.pg_namespace n
 770 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 771 WHERE c.relname = 'apk'
 772   AND pg_catalog.pg_table_is_visible(c.oid)
 773 EOS
 774         });
 775     return $schema;
 776 }