t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use DBIx::Class::Optional::Dependencies ();
   8 use lib qw(t/lib);
   9 use DBICTest;
  10
  11 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  12   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  13
  14 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  15
  16 plan skip_all => <<'EOM' unless $dsn && $user;
  17 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  18 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  19 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  20 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  21 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  22 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  23 EOM
  24
  25 ### load any test classes that are defined further down in the file via BEGIN blocks
  26
  27 our @test_classes; #< array that will be pushed into by test classes defined in this file
  28 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  29
  30 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  31   {
  32     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  33
  34     ok (!$s->storage->_dbh, 'definitely not connected');
  35
  36     # Check that datetime_parser returns correctly before we explicitly connect.
  37     SKIP: {
  38         skip (
  39           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  40           2
  41         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  42
  43         my $store = ref $s->storage;
  44         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  45
  46         my $parser = $s->storage->datetime_parser;
  47         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  48     }
  49
  50     ok (!$s->storage->_dbh, 'still not connected');
  51   }
  52
  53   {
  54     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  55     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  56     ok (!$s->storage->_dbh, 'definitely not connected');
  57     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  58     ok (!$s->storage->_dbh, 'still not connected');
  59   }
  60
  61 # test LIMIT support
  62 {
  63   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  64   drop_test_schema($schema);
  65   create_test_schema($schema);
  66   for (1..6) {
  67     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  68   }
  69   my $it = $schema->resultset('Artist')->search( {},
  70     { rows => 3,
  71       offset => 2,
  72       order_by => 'artistid' }
  73   );
  74   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  75   is( $it->next->name, "Artist 3", "iterator->next ok" );
  76   $it->next;
  77   $it->next;
  78   $it->next;
  79   is( $it->next, undef, "next past end of resultset ok" );
  80
  81   # Limit with select-lock
  82   lives_ok {
  83     $schema->txn_do (sub {
  84       isa_ok (
  85         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  86         'DBICTest::Schema::Artist',
  87       );
  88     });
  89   } 'Limited FOR UPDATE select works';
  90 }
  91
  92 # check if we indeed do support stuff
  93 my $test_server_supports_insert_returning = do {
  94
  95   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  96   die "Unparseable Pg server version: $si->{dbms_version}\n"
  97     unless $si->{normalized_dbms_version};
  98
  99   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
 100 };
 101 is (
 102   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 103   $test_server_supports_insert_returning,
 104   'insert returning capability guessed correctly'
 105 );
 106
 107 my $schema;
 108 for my $use_insert_returning ($test_server_supports_insert_returning
 109   ? (0,1)
 110   : (0)
 111 ) {
 112
 113   no warnings qw/once redefine/;
 114   my $old_connection = DBICTest::Schema->can('connection');
 115   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 116     my $s = shift->$old_connection(@_);
 117     $s->storage->_use_insert_returning ($use_insert_returning);
 118     $s;
 119   };
 120
 121 ### test capability override
 122   {
 123     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 124
 125     ok (!$s->storage->_dbh, 'definitely not connected');
 126
 127     ok (
 128       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 129       'insert returning capability set correctly',
 130     );
 131     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 132   }
 133
 134 ### connect, create postgres-specific test schema
 135
 136   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 137   $schema->storage->ensure_connected;
 138
 139   drop_test_schema($schema);
 140   create_test_schema($schema);
 141
 142 ### begin main tests
 143
 144 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 145 # discovery
 146   run_apk_tests($schema); #< older set of auto-pk tests
 147   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 148
 149 ### type_info tests
 150
 151   my $test_type_info = {
 152       'artistid' => {
 153           'data_type' => 'integer',
 154           'is_nullable' => 0,
 155           'size' => 4,
 156       },
 157       'name' => {
 158           'data_type' => 'character varying',
 159           'is_nullable' => 1,
 160           'size' => 100,
 161           'default_value' => undef,
 162       },
 163       'rank' => {
 164           'data_type' => 'integer',
 165           'is_nullable' => 0,
 166           'size' => 4,
 167           'default_value' => 13,
 168
 169       },
 170       'charfield' => {
 171           'data_type' => 'character',
 172           'is_nullable' => 1,
 173           'size' => 10,
 174           'default_value' => undef,
 175       },
 176       'arrayfield' => {
 177           'data_type' => 'integer[]',
 178           'is_nullable' => 1,
 179           'size' => undef,
 180           'default_value' => undef,
 181       },
 182   };
 183
 184   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 185   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 186   like($artistid_defval,
 187        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 188        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 189   is_deeply($type_info, $test_type_info,
 190             'columns_info_for - column data types');
 191
 192
 193
 194
 195 ####### Array tests
 196
 197   BEGIN {
 198     package DBICTest::Schema::ArrayTest;
 199     push @main::test_classes, __PACKAGE__;
 200
 201     use strict;
 202     use warnings;
 203     use base 'DBICTest::BaseResult';
 204
 205     __PACKAGE__->table('dbic_t_schema.array_test');
 206     __PACKAGE__->add_columns(qw/id arrayfield/);
 207     __PACKAGE__->column_info_from_storage(1);
 208     __PACKAGE__->set_primary_key('id');
 209
 210   }
 211   SKIP: {
 212     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 213
 214     my $arr_rs = $schema->resultset('ArrayTest');
 215
 216     lives_ok {
 217       $arr_rs->create({
 218         arrayfield => [1, 2],
 219       });
 220     } 'inserting arrayref as pg array data';
 221
 222     lives_ok {
 223       $arr_rs->update({
 224         arrayfield => [3, 4],
 225       });
 226     } 'updating arrayref as pg array data';
 227
 228     $arr_rs->create({
 229       arrayfield => [5, 6],
 230     });
 231
 232     lives_ok {
 233       $schema->populate('ArrayTest', [
 234         [ qw/arrayfield/ ],
 235         [ [0,0]          ],
 236       ]);
 237     } 'inserting arrayref using void ctx populate';
 238
 239     # Search using arrays
 240     lives_ok {
 241       is_deeply (
 242         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 243         [3,4],
 244         'Array value matches'
 245       );
 246     } 'searching by arrayref';
 247
 248     lives_ok {
 249       is_deeply (
 250         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 251         [3,4],,
 252         'Array value matches explicit equal'
 253       );
 254     } 'searching by arrayref (explicit equal sign)';
 255
 256     lives_ok {
 257       is_deeply (
 258         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 259         [3,4],
 260         'Array value matches greater than'
 261       );
 262     } 'searching by arrayref (greater than)';
 263
 264     lives_ok {
 265       is (
 266         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 267         1,
 268         'Greater than search found [5,6]',
 269       );
 270     } 'searching by arrayref (greater than)';
 271
 272     # Find using arrays
 273     lives_ok {
 274       is_deeply (
 275         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 276         [3,4],
 277         'Array value matches implicit equal'
 278       );
 279     } 'find by arrayref';
 280
 281     lives_ok {
 282       is_deeply (
 283         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 284         [3,4],
 285         'Array value matches explicit equal'
 286       );
 287     } 'find by arrayref (equal)';
 288
 289     # test inferred condition for creation
 290     for my $cond (
 291       { -value => [3,4] },
 292       \[ '= ?' => [arrayfield => [3, 4]] ],
 293     ) {
 294       local $TODO = 'No introspection of complex conditions :(';
 295       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 296
 297       my $row = $arr_rs_cond->create({});
 298       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 299       $row->discard_changes;
 300       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 301     }
 302   }
 303
 304 ########## Case check
 305
 306   BEGIN {
 307     package DBICTest::Schema::Casecheck;
 308     push @main::test_classes, __PACKAGE__;
 309
 310     use strict;
 311     use warnings;
 312     use base 'DBIx::Class::Core';
 313
 314     __PACKAGE__->table('dbic_t_schema.casecheck');
 315     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 316     __PACKAGE__->column_info_from_storage(1);
 317     __PACKAGE__->set_primary_key('id');
 318   }
 319
 320   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 321   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 322
 323   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 324   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 325
 326   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 327   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 328
 329
 330 ## Test ResultSet->update
 331 my $artist = $schema->resultset('Artist')->first;
 332 my $cds = $artist->cds_unordered->search({
 333     year => { '!=' => 2010 }
 334 }, { prefetch => 'liner_notes' });
 335 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 336
 337 ## Test SELECT ... FOR UPDATE
 338
 339   SKIP: {
 340       my ($timed_out, $artist2);
 341
 342       for my $t (
 343         {
 344           # Make sure that an error was raised, and that the update failed
 345           update_lock => 1,
 346           test_sub => sub {
 347             ok($timed_out, "update from second schema times out");
 348             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 349           },
 350         },
 351         {
 352           # Make sure that an error was NOT raised, and that the update succeeded
 353           update_lock => 0,
 354           test_sub => sub {
 355             ok(! $timed_out, "update from second schema DOES NOT timeout");
 356             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 357           },
 358         },
 359       ) {
 360         # create a new schema
 361         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 362         $schema2->source("Artist")->name("dbic_t_schema.artist");
 363
 364         $schema->txn_do( sub {
 365           my $rs = $schema->resultset('Artist')->search(
 366               {
 367                   artistid => 1
 368               },
 369               $t->{update_lock} ? { for => 'update' } : {}
 370           );
 371           ok ($rs->count, 'Count works');
 372
 373           my $artist = $rs->next;
 374           is($artist->artistid, 1, "select returns artistid = 1");
 375
 376           $timed_out = 0;
 377           eval {
 378               # can not use %SIG assignment directly - we need sigaction below
 379               # localization to a block still works however
 380               local $SIG{ALRM};
 381
 382               POSIX::sigaction( POSIX::SIGALRM() => POSIX::SigAction->new(
 383                 sub { die "DBICTestTimeout" },
 384               ));
 385
 386               $artist2 = $schema2->resultset('Artist')->find(1);
 387               $artist2->name('fooey');
 388
 389               # FIXME - this needs to go away in lieu of a non-retrying runner
 390               # ( i.e. after solving RT#47005 )
 391               local *DBIx::Class::Storage::DBI::_ping = sub { 1 }, DBIx::Class::_ENV_::OLD_MRO && Class::C3->reinitialize()
 392                 if DBIx::Class::_Util::modver_gt_or_eq( 'DBD::Pg' => '3.5.0' );
 393
 394               alarm(1);
 395               $artist2->update;
 396               alarm(0);
 397           };
 398           $timed_out = $@ =~ /DBICTestTimeout/;
 399         });
 400
 401         $t->{test_sub}->();
 402       }
 403   }
 404
 405
 406 ######## other older Auto-pk tests
 407
 408   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 409   for (1..5) {
 410       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 411       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 412       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 413       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 414   }
 415   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 416   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 417
 418
 419 ######## test non-serial auto-pk
 420
 421   if ($schema->storage->_use_insert_returning) {
 422     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 423     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 424     ok $row->id;
 425   }
 426
 427 ######## test with_deferred_fk_checks
 428
 429   $schema->source('CD')->name('dbic_t_schema.cd');
 430   $schema->source('Track')->name('dbic_t_schema.track');
 431   lives_ok {
 432     $schema->storage->with_deferred_fk_checks(sub {
 433       $schema->resultset('Track')->create({
 434         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 435       });
 436       $schema->resultset('CD')->create({
 437         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 438       });
 439     });
 440   } 'with_deferred_fk_checks code survived';
 441
 442   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 443      'code in with_deferred_fk_checks worked';
 444
 445   throws_ok {
 446     $schema->resultset('Track')->create({
 447       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 448     });
 449   } qr/constraint/i, 'with_deferred_fk_checks is off';
 450 }
 451
 452 done_testing;
 453
 454 END {
 455     return unless $schema;
 456     drop_test_schema($schema);
 457     eapk_drop_all($schema);
 458     undef $schema;
 459 };
 460
 461
 462 ######### SUBROUTINES
 463
 464 sub create_test_schema {
 465     my $schema = shift;
 466     $schema->storage->dbh_do(sub {
 467       my (undef,$dbh) = @_;
 468
 469       local $dbh->{Warn} = 0;
 470
 471       my $std_artist_table = <<EOS;
 472 (
 473   artistid serial PRIMARY KEY
 474   , name VARCHAR(100)
 475   , rank INTEGER NOT NULL DEFAULT '13'
 476   , charfield CHAR(10)
 477   , arrayfield INTEGER[]
 478 )
 479 EOS
 480
 481       $dbh->do("CREATE SCHEMA dbic_t_schema");
 482       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 483
 484       $dbh->do(<<EOS);
 485 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 486   id timestamp default current_timestamp
 487 )
 488 EOS
 489       $dbh->do(<<EOS);
 490 CREATE TABLE dbic_t_schema.cd (
 491   cdid int PRIMARY KEY,
 492   artist int,
 493   title varchar(255),
 494   year varchar(4),
 495   genreid int,
 496   single_track int
 497 )
 498 EOS
 499       $dbh->do(<<EOS);
 500 CREATE TABLE dbic_t_schema.track (
 501   trackid int,
 502   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 503   position int,
 504   title varchar(255),
 505   last_updated_on date,
 506   last_updated_at date
 507 )
 508 EOS
 509
 510       $dbh->do(<<EOS);
 511 CREATE TABLE dbic_t_schema.sequence_test (
 512     pkid1 integer
 513     , pkid2 integer
 514     , nonpkid integer
 515     , name VARCHAR(100)
 516     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 517 )
 518 EOS
 519       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 520       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 521       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 522       $dbh->do(<<EOS);
 523 CREATE TABLE dbic_t_schema.casecheck (
 524     id serial PRIMARY KEY
 525     , "name" VARCHAR(1)
 526     , "NAME" VARCHAR(2)
 527     , "UC_NAME" VARCHAR(3)
 528 )
 529 EOS
 530       $dbh->do(<<EOS);
 531 CREATE TABLE dbic_t_schema.array_test (
 532     id serial PRIMARY KEY
 533     , arrayfield INTEGER[]
 534 )
 535 EOS
 536       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 537       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 538       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 539       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 540       $dbh->do('set search_path=dbic_t_schema,public');
 541       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 542       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 543       $dbh->do(<<EOS);
 544  CREATE TABLE dbic_t_schema_4.artist
 545  (
 546    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 547    , name VARCHAR(100)
 548    , rank INTEGER NOT NULL DEFAULT '13'
 549    , charfield CHAR(10)
 550    , arrayfield INTEGER[]
 551  );
 552 EOS
 553       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 554       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 555       $dbh->do(<<EOS);
 556  CREATE TABLE dbic_t_schema_5.artist
 557  (
 558    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 559    , name VARCHAR(100)
 560    , rank INTEGER NOT NULL DEFAULT '13'
 561    , charfield CHAR(10)
 562    , arrayfield INTEGER[]
 563  );
 564 EOS
 565       $dbh->do('set search_path=dbic_t_schema,public');
 566   });
 567 }
 568
 569
 570
 571 sub drop_test_schema {
 572     my ( $schema, $warn_exceptions ) = @_;
 573
 574     $schema->storage->dbh_do(sub {
 575         my (undef,$dbh) = @_;
 576
 577         local $dbh->{Warn} = 0;
 578
 579         for my $stat (
 580                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 581                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 582                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 583                       'DROP SCHEMA dbic_t_schema CASCADE',
 584                       'DROP SEQUENCE pkid1_seq CASCADE',
 585                       'DROP SEQUENCE pkid2_seq CASCADE',
 586                       'DROP SEQUENCE nonpkid_seq CASCADE',
 587                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 588                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 589                      ) {
 590             eval { $dbh->do ($stat) };
 591             diag $@ if $@ && $warn_exceptions;
 592         }
 593     });
 594 }
 595
 596
 597 ###  auto-pk / last_insert_id / sequence discovery
 598 sub run_apk_tests {
 599     my $schema = shift;
 600
 601     # This is in Core now, but it's here just to test that it doesn't break
 602     $schema->class('Artist')->load_components('PK::Auto');
 603     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 604
 605     # test that auto-pk also works with the defined search path by
 606     # un-schema-qualifying the table name
 607     apk_t_set($schema,'artist');
 608
 609     my $unq_new;
 610     lives_ok {
 611         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 612     } 'insert into unqualified, shadowed table succeeds';
 613
 614     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 615
 616     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 617                          [qw| dbic_t_schema_3    1  |],
 618                          [qw| dbic_t_schema_4    2  |],
 619                          [qw| dbic_t_schema_5    1  |],
 620                        );
 621     foreach my $t ( @test_schemas ) {
 622         my ($sch_name, $start_num) = @$t;
 623         #test with dbic_t_schema_2
 624         apk_t_set($schema,"$sch_name.artist");
 625         my $another_new;
 626         lives_ok {
 627             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 628             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 629                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 630         } "$sch_name liid 1 did not die"
 631             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 632         lives_ok {
 633             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 634             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 635                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 636         } "$sch_name liid 2 did not die"
 637             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 638
 639     }
 640
 641     lives_ok {
 642         apk_t_set($schema,'dbic_t_schema.artist');
 643         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 644         is($new->artistid, 4, "Auto-PK worked");
 645         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 646         is($new->artistid, 5, "Auto-PK worked");
 647     } 'old auto-pk tests did not die either';
 648 }
 649
 650 # sets the artist table name and clears sequence name cache
 651 sub apk_t_set {
 652     my ( $s, $n ) = @_;
 653     $s->source("Artist")->name($n);
 654     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 655 }
 656
 657
 658 ######## EXTENDED AUTO-PK TESTS
 659
 660 my @eapk_id_columns;
 661 BEGIN {
 662   package DBICTest::Schema::ExtAPK;
 663   push @main::test_classes, __PACKAGE__;
 664
 665   use strict;
 666   use warnings;
 667   use base 'DBIx::Class::Core';
 668
 669   __PACKAGE__->table('apk');
 670
 671   @eapk_id_columns = qw( id1 id2 id3 id4 );
 672   __PACKAGE__->add_columns(
 673     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 674        @eapk_id_columns
 675   );
 676
 677   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 678                                        #the primary key
 679 }
 680
 681 my @eapk_schemas;
 682 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 683 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 684
 685 sub run_extended_apk_tests {
 686   my $schema = shift;
 687
 688   #save the search path and reset it at the end
 689   my $search_path_save = eapk_get_search_path($schema);
 690
 691   eapk_drop_all($schema);
 692   %seqs = ();
 693
 694   # make the test schemas and sequences
 695   $schema->storage->dbh_do(sub {
 696     my ( undef, $dbh ) = @_;
 697
 698     $dbh->do("CREATE SCHEMA $_")
 699         for @eapk_schemas;
 700
 701     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 702     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 703     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 704
 705     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 706     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 707     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 708
 709     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 710     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 711     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 712
 713     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 714   });
 715
 716   # clear our search_path cache
 717   $schema->storage->{_pg_search_path} = undef;
 718
 719   eapk_create( $schema,
 720                with_search_path => [0,1],
 721              );
 722   eapk_create( $schema,
 723                with_search_path => [1,0,'public'],
 724                nextval => "$eapk_schemas[5].fooseq",
 725              );
 726   eapk_create( $schema,
 727                with_search_path => ['public',0,1],
 728                qualify_table => 2,
 729              );
 730   eapk_create( $schema,
 731                with_search_path => [3,1,0,'public'],
 732                nextval => "$eapk_schemas[4].fooseq",
 733              );
 734   eapk_create( $schema,
 735                with_search_path => [3,1,0,'public'],
 736                nextval => "$eapk_schemas[3].fooseq",
 737                qualify_table => 4,
 738              );
 739
 740   eapk_poke( $schema );
 741   eapk_poke( $schema, 0 );
 742   eapk_poke( $schema, 2 );
 743   eapk_poke( $schema, 4 );
 744   eapk_poke( $schema, 1 );
 745   eapk_poke( $schema, 0 );
 746   eapk_poke( $schema, 1 );
 747   eapk_poke( $schema );
 748   eapk_poke( $schema, 4 );
 749   eapk_poke( $schema, 3 );
 750   eapk_poke( $schema, 1 );
 751   eapk_poke( $schema, 2 );
 752   eapk_poke( $schema, 0 );
 753
 754   # set our search path back
 755   eapk_set_search_path( $schema, @$search_path_save );
 756 }
 757
 758 # do a DBIC create on the apk table in the given schema number (which is an
 759 # index of @eapk_schemas)
 760
 761 sub eapk_poke {
 762   my ($s, $schema_num) = @_;
 763
 764   my $schema_name = defined $schema_num
 765       ? $eapk_schemas[$schema_num]
 766       : '';
 767
 768   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 769
 770   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 771   #< clear sequence name cache
 772   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 773       for @eapk_id_columns;
 774
 775   no warnings 'uninitialized';
 776   lives_ok {
 777     my $new;
 778     for my $inc (1,2,3) {
 779       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 780       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 781       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 782           or eapk_seq_diag($s,$schema_name);
 783       $new->discard_changes;
 784       is( $new->id1, 1 );
 785       for my $id ('id3','id4') {
 786         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 787         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 788             or eapk_seq_diag($s,$schema_name);
 789       }
 790     }
 791   } "create in schema '$schema_name' lives"
 792       or eapk_seq_diag($s,$schema_name);
 793 }
 794
 795 # print diagnostic info on which sequences were found in the ExtAPK
 796 # class
 797 sub eapk_seq_diag {
 798     my $s = shift;
 799     my $schema = shift || eapk_find_visible_schema($s);
 800
 801     diag "$schema.apk sequences: ",
 802         join(', ',
 803              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 804              @eapk_id_columns
 805             );
 806 }
 807
 808 # get the postgres search path as an arrayref
 809 sub eapk_get_search_path {
 810     my ( $s ) = @_;
 811     # cache the search path as ['schema','schema',...] in the storage
 812     # obj
 813
 814     return $s->storage->dbh_do(sub {
 815         my (undef, $dbh) = @_;
 816         my @search_path;
 817         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 818         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 819             unless( defined $1 and length $1 ) {
 820                 die "search path sanity check failed: '$1'";
 821             }
 822             push @search_path, $1;
 823         }
 824         \@search_path
 825     });
 826 }
 827 sub eapk_set_search_path {
 828     my ($s,@sp) = @_;
 829     my $sp = join ',',@sp;
 830     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 831 }
 832
 833 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 834 sub eapk_create {
 835     my ($schema, %a) = @_;
 836
 837     $schema->storage->dbh_do(sub {
 838         my (undef,$dbh) = @_;
 839
 840         my $searchpath_save;
 841         if ( $a{with_search_path} ) {
 842             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 843
 844             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 845
 846             $dbh->do("SET search_path = $search_path");
 847         }
 848
 849         my $table_name = $a{qualify_table}
 850             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 851             : 'apk';
 852         local $_[1]->{Warn} = 0;
 853
 854         my $id_def = $a{nextval}
 855             ? "integer not null default nextval('$a{nextval}'::regclass)"
 856             : 'serial';
 857         $dbh->do(<<EOS);
 858 CREATE TABLE $table_name (
 859   id1 serial
 860   , id2 $id_def
 861   , id3 serial primary key
 862   , id4 serial
 863 )
 864 EOS
 865
 866         if( $searchpath_save ) {
 867             $dbh->do("SET search_path = $searchpath_save");
 868         }
 869     });
 870 }
 871
 872 sub eapk_drop_all {
 873     my ( $schema, $warn_exceptions ) = @_;
 874
 875     $schema->storage->dbh_do(sub {
 876         my (undef,$dbh) = @_;
 877
 878         local $dbh->{Warn} = 0;
 879
 880         # drop the test schemas
 881         for (@eapk_schemas ) {
 882             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 883             diag $@ if $@ && $warn_exceptions;
 884         }
 885
 886
 887     });
 888 }
 889
 890 sub eapk_find_visible_schema {
 891     my ($s) = @_;
 892
 893     my ($schema) =
 894         $s->storage->dbh_do(sub {
 895             $_[1]->selectrow_array(<<EOS);
 896 SELECT n.nspname
 897 FROM pg_catalog.pg_namespace n
 898 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 899 WHERE c.relname = 'apk'
 900   AND pg_catalog.pg_table_is_visible(c.oid)
 901 EOS
 902         });
 903     return $schema;
 904 }