t/71mysql.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6
   7 use DBI::Const::GetInfoType;
   8 use Scalar::Util qw/weaken/;
   9 use DBIx::Class::Optional::Dependencies ();
  10
  11 use lib qw(t/lib);
  12 use DBICTest;
  13 use DBIC::SqlMakerTest;
  14
  15 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_mysql')
  16   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_mysql');
  17
  18 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_MYSQL_${_}" } qw/DSN USER PASS/};
  19
  20 #warn "$dsn $user $pass";
  21
  22 plan skip_all => 'Set $ENV{DBICTEST_MYSQL_DSN}, _USER and _PASS to run this test'
  23   unless ($dsn && $user);
  24
  25 my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  26
  27 my $dbh = $schema->storage->dbh;
  28
  29 $dbh->do("DROP TABLE IF EXISTS artist;");
  30
  31 $dbh->do("CREATE TABLE artist (artistid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100), rank INTEGER NOT NULL DEFAULT '13', charfield CHAR(10));");
  32
  33 $dbh->do("DROP TABLE IF EXISTS cd;");
  34
  35 $dbh->do("CREATE TABLE cd (cdid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, artist INTEGER, title TEXT, year DATE, genreid INTEGER, single_track INTEGER);");
  36
  37 $dbh->do("DROP TABLE IF EXISTS producer;");
  38
  39 $dbh->do("CREATE TABLE producer (producerid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name TEXT);");
  40
  41 $dbh->do("DROP TABLE IF EXISTS cd_to_producer;");
  42
  43 $dbh->do("CREATE TABLE cd_to_producer (cd INTEGER,producer INTEGER);");
  44
  45 $dbh->do("DROP TABLE IF EXISTS owners;");
  46
  47 $dbh->do("CREATE TABLE owners (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100) NOT NULL);");
  48
  49 $dbh->do("DROP TABLE IF EXISTS books;");
  50
  51 $dbh->do("CREATE TABLE books (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, source VARCHAR(100) NOT NULL, owner integer NOT NULL, title varchar(100) NOT NULL,  price integer);");
  52
  53 #'dbi:mysql:host=localhost;database=dbic_test', 'dbic_test', '');
  54
  55 # make sure sqlt_type overrides work (::Storage::DBI::mysql does this)
  56 {
  57   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  58
  59   ok (!$schema->storage->_dbh, 'definitely not connected');
  60   is ($schema->storage->sqlt_type, 'MySQL', 'sqlt_type correct pre-connection');
  61 }
  62
  63 # This is in Core now, but it's here just to test that it doesn't break
  64 $schema->class('Artist')->load_components('PK::Auto');
  65
  66 # test primary key handling
  67 my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  68 ok($new->artistid, "Auto-PK worked");
  69
  70 # test LIMIT support
  71 for (1..6) {
  72     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  73 }
  74 my $it = $schema->resultset('Artist')->search( {},
  75     { rows => 3,
  76       offset => 2,
  77       order_by => 'artistid' }
  78 );
  79 is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 7 artists
  80 is( $it->next->name, "Artist 2", "iterator->next ok" );
  81 $it->next;
  82 $it->next;
  83 is( $it->next, undef, "next past end of resultset ok" );
  84
  85 # Limit with select-lock
  86 lives_ok {
  87   $schema->txn_do (sub {
  88     isa_ok (
  89       $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  90       'DBICTest::Schema::Artist',
  91     );
  92   });
  93 } 'Limited FOR UPDATE select works';
  94
  95 # shared-lock
  96 lives_ok {
  97   $schema->txn_do (sub {
  98     isa_ok (
  99       $schema->resultset('Artist')->find({artistid => 1}, {for => 'shared'}),
 100       'DBICTest::Schema::Artist',
 101     );
 102   });
 103 } 'LOCK IN SHARE MODE select works';
 104
 105 my $test_type_info = {
 106     'artistid' => {
 107         'data_type' => 'INT',
 108         'is_nullable' => 0,
 109         'size' => 11,
 110         'default_value' => undef,
 111     },
 112     'name' => {
 113         'data_type' => 'VARCHAR',
 114         'is_nullable' => 1,
 115         'size' => 100,
 116         'default_value' => undef,
 117     },
 118     'rank' => {
 119         'data_type' => 'INT',
 120         'is_nullable' => 0,
 121         'size' => 11,
 122         'default_value' => 13,
 123     },
 124     'charfield' => {
 125         'data_type' => 'CHAR',
 126         'is_nullable' => 1,
 127         'size' => 10,
 128         'default_value' => undef,
 129     },
 130 };
 131
 132 $schema->populate ('Owners', [
 133   [qw/id  name  /],
 134   [qw/1   wiggle/],
 135   [qw/2   woggle/],
 136   [qw/3   boggle/],
 137 ]);
 138
 139 $schema->populate ('BooksInLibrary', [
 140   [qw/source  owner title   /],
 141   [qw/Library 1     secrets1/],
 142   [qw/Eatery  1     secrets2/],
 143   [qw/Library 2     secrets3/],
 144 ]);
 145
 146 #
 147 # try a distinct + prefetch on tables with identically named columns
 148 # (mysql doesn't seem to like subqueries with equally named columns)
 149 #
 150
 151 {
 152   # try a ->has_many direction (due to a 'multi' accessor the select/group_by group is collapsed)
 153   my $owners = $schema->resultset ('Owners')->search (
 154     { 'books.id' => { '!=', undef }},
 155     { prefetch => 'books', distinct => 1 }
 156   );
 157   my $owners2 = $schema->resultset ('Owners')->search ({ id => { -in => $owners->get_column ('me.id')->as_query }});
 158   for ($owners, $owners2) {
 159     is ($_->all, 2, 'Prefetched grouped search returns correct number of rows');
 160     is ($_->count, 2, 'Prefetched grouped search returns correct count');
 161   }
 162
 163   # try a ->belongs_to direction (no select collapse)
 164   my $books = $schema->resultset ('BooksInLibrary')->search (
 165     { 'owner.name' => 'wiggle' },
 166     { prefetch => 'owner', distinct => 1 }
 167   );
 168   my $books2 = $schema->resultset ('BooksInLibrary')->search ({ id => { -in => $books->get_column ('me.id')->as_query }});
 169   for ($books, $books2) {
 170     is ($_->all, 1, 'Prefetched grouped search returns correct number of rows');
 171     is ($_->count, 1, 'Prefetched grouped search returns correct count');
 172   }
 173 }
 174
 175 SKIP: {
 176     my $mysql_version = $dbh->get_info( $GetInfoType{SQL_DBMS_VER} );
 177     skip "Cannot determine MySQL server version", 1 if !$mysql_version;
 178
 179     my ($v1, $v2, $v3) = $mysql_version =~ /^(\d+)\.(\d+)(?:\.(\d+))?/;
 180     skip "Cannot determine MySQL server version", 1 if !$v1 || !defined($v2);
 181
 182     $v3 ||= 0;
 183
 184     if( ($v1 < 5) || ($v1 == 5 && $v2 == 0 && $v3 <= 3) ) {
 185         $test_type_info->{charfield}->{data_type} = 'VARCHAR';
 186     }
 187
 188     my $type_info = $schema->storage->columns_info_for('artist');
 189     is_deeply($type_info, $test_type_info, 'columns_info_for - column data types');
 190 }
 191
 192 my $cd = $schema->resultset ('CD')->create ({});
 193 my $producer = $schema->resultset ('Producer')->create ({});
 194 lives_ok { $cd->set_producers ([ $producer ]) } 'set_relationship doesnt die';
 195
 196 {
 197   my $artist = $schema->resultset('Artist')->next;
 198   my $cd = $schema->resultset('CD')->next;
 199   $cd->set_from_related ('artist', $artist);
 200   $cd->update;
 201
 202   my $rs = $schema->resultset('CD')->search ({}, { prefetch => 'artist' });
 203
 204   lives_ok sub {
 205     my $cd = $rs->next;
 206     is ($cd->artist->name, $artist->name, 'Prefetched artist');
 207   }, 'join does not throw (mysql 3 test)';
 208
 209   # induce a jointype override, make sure it works even if we don't have mysql3
 210   local $schema->storage->sql_maker->{_default_jointype} = 'inner';
 211   is_same_sql_bind (
 212     $rs->as_query,
 213     '(
 214       SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
 215              artist.artistid, artist.name, artist.rank, artist.charfield
 216         FROM cd me
 217         INNER JOIN artist artist ON artist.artistid = me.artist
 218     )',
 219     [],
 220     'overriden default join type works',
 221   );
 222 }
 223
 224 {
 225   # Test support for straight joins
 226   my $cdsrc = $schema->source('CD');
 227   my $artrel_info = $cdsrc->relationship_info ('artist');
 228   $cdsrc->add_relationship(
 229     'straight_artist',
 230     $artrel_info->{class},
 231     $artrel_info->{cond},
 232     { %{$artrel_info->{attrs}}, join_type => 'straight' },
 233   );
 234   is_same_sql_bind (
 235     $cdsrc->resultset->search({}, { prefetch => 'straight_artist' })->as_query,
 236     '(
 237       SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
 238              straight_artist.artistid, straight_artist.name, straight_artist.rank, straight_artist.charfield
 239         FROM cd me
 240         STRAIGHT_JOIN artist straight_artist ON straight_artist.artistid = me.artist
 241     )',
 242     [],
 243     'straight joins correctly supported for mysql'
 244   );
 245 }
 246
 247 ## Can we properly deal with the null search problem?
 248 ##
 249 ## Only way is to do a SET SQL_AUTO_IS_NULL = 0; on connect
 250 ## But I'm not sure if we should do this or not (Ash, 2008/06/03)
 251 #
 252 # There is now a built-in function to do this, test that everything works
 253 # with it (ribasushi, 2009/07/03)
 254
 255 NULLINSEARCH: {
 256     my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, { on_connect_call => 'set_strict_mode' });
 257
 258     $ansi_schema->resultset('Artist')->create ({ name => 'last created artist' });
 259
 260     ok my $artist1_rs = $ansi_schema->resultset('Artist')->search({artistid=>6666})
 261       => 'Created an artist resultset of 6666';
 262
 263     is $artist1_rs->count, 0
 264       => 'Got no returned rows';
 265
 266     ok my $artist2_rs = $ansi_schema->resultset('Artist')->search({artistid=>undef})
 267       => 'Created an artist resultset of undef';
 268
 269     is $artist2_rs->count, 0
 270       => 'got no rows';
 271
 272     my $artist = $artist2_rs->single;
 273
 274     is $artist => undef
 275       => 'Nothing Found!';
 276 }
 277
 278 # check for proper grouped counts
 279 {
 280   my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, {
 281     on_connect_call => 'set_strict_mode',
 282     quote_char => '`',
 283   });
 284   my $rs = $ansi_schema->resultset('CD');
 285
 286   my $years;
 287   $years->{$_->year|| scalar keys %$years}++ for $rs->all;  # NULL != NULL, thus the keys eval
 288
 289   lives_ok ( sub {
 290     is (
 291       $rs->search ({}, { group_by => 'year'})->count,
 292       scalar keys %$years,
 293       'grouped count correct',
 294     );
 295   }, 'Grouped count does not throw');
 296
 297   lives_ok( sub {
 298     $ansi_schema->resultset('Owners')->search({}, {
 299       join => 'books', group_by => [ 'me.id', 'books.id' ]
 300     })->count();
 301   }, 'count on grouped columns with the same name does not throw');
 302
 303
 304 }
 305
 306 ZEROINSEARCH: {
 307   my $cds_per_year = {
 308     2001 => 2,
 309     2002 => 1,
 310     2005 => 3,
 311   };
 312
 313   my $rs = $schema->resultset ('CD');
 314   $rs->delete;
 315   for my $y (keys %$cds_per_year) {
 316     for my $c (1 .. $cds_per_year->{$y} ) {
 317       $rs->create ({ title => "CD $y-$c", artist => 1, year => "$y-01-01" });
 318     }
 319   }
 320
 321   is ($rs->count, 6, 'CDs created successfully');
 322
 323   $rs = $rs->search ({}, {
 324     select => [ \ 'YEAR(year)' ], as => ['y'], distinct => 1,
 325   });
 326
 327   is_deeply (
 328     [ sort ($rs->get_column ('y')->all) ],
 329     [ sort keys %$cds_per_year ],
 330     'Years group successfully',
 331   );
 332
 333   $rs->create ({ artist => 1, year => '0-1-1', title => 'Jesus Rap' });
 334
 335   is_deeply (
 336     [ sort $rs->get_column ('y')->all ],
 337     [ 0, sort keys %$cds_per_year ],
 338     'Zero-year groups successfully',
 339   );
 340
 341   # convoluted search taken verbatim from list
 342   my $restrict_rs = $rs->search({ -and => [
 343     year => { '!=', 0 },
 344     year => { '!=', undef }
 345   ]});
 346
 347   is_deeply (
 348     [ $restrict_rs->get_column('y')->all ],
 349     [ $rs->get_column ('y')->all ],
 350     'Zero year was correctly excluded from resultset',
 351   );
 352 }
 353
 354 # make sure find hooks determine driver
 355 {
 356   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 357   $schema->resultset("Artist")->find(4);
 358   isa_ok($schema->storage->sql_maker, 'DBIx::Class::SQLMaker::MySQL');
 359 }
 360
 361 # make sure the mysql_auto_reconnect buggery is avoided
 362 {
 363   local $ENV{MOD_PERL} = 'boogiewoogie';
 364   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 365   ok (! $schema->storage->_get_dbh->{mysql_auto_reconnect}, 'mysql_auto_reconnect unset regardless of ENV' );
 366
 367   # Make sure hardcore forking action still works even if mysql_auto_reconnect
 368   # is true (test inspired by ether)
 369
 370   my $schema_autorecon = DBICTest::Schema->connect($dsn, $user, $pass, { mysql_auto_reconnect => 1 });
 371   my $orig_dbh = $schema_autorecon->storage->_get_dbh;
 372   weaken $orig_dbh;
 373
 374   ok ($orig_dbh, 'Got weak $dbh ref');
 375   ok ($orig_dbh->{mysql_auto_reconnect}, 'mysql_auto_reconnect is properly set if explicitly requested' );
 376
 377   my $rs = $schema_autorecon->resultset('Artist');
 378
 379   my $pid = fork();
 380   if (! defined $pid ) {
 381     die "fork() failed: $!"
 382   }
 383   elsif ($pid) {
 384     # sanity check
 385     $schema_autorecon->storage->dbh_do(sub {
 386       is ($_[1], $orig_dbh, 'Storage holds correct $dbh in parent');
 387     });
 388
 389     # kill our $dbh
 390     $schema_autorecon->storage->_dbh(undef);
 391
 392     TODO: {
 393       local $TODO = "Perl $] is known to leak like a sieve"
 394         if DBIx::Class::_ENV_::PEEPEENESS();
 395
 396       ok (! defined $orig_dbh, 'Parent $dbh handle is gone');
 397     }
 398   }
 399   else {
 400     # wait for parent to kill its $dbh
 401     sleep 1;
 402
 403     #simulate a  subtest to not confuse the parent TAP emission
 404     Test::More->builder->reset;
 405     Test::More->builder->plan('no_plan');
 406     Test::More->builder->_indent(' ' x 4);
 407
 408     # try to do something dbic-esque
 409     $rs->create({ name => "Hardcore Forker $$" });
 410
 411
 412     TODO: {
 413       local $TODO = "Perl $] is known to leak like a sieve"
 414         if DBIx::Class::_ENV_::PEEPEENESS();
 415
 416       ok (! defined $orig_dbh, 'DBIC operation triggered reconnect - old $dbh is gone');
 417     }
 418
 419     exit 0;
 420   }
 421
 422   wait;
 423   ok(!$?, 'Child subtests passed');
 424
 425   ok ($rs->find({ name => "Hardcore Forker $pid" }), 'Expected row created');
 426 }
 427
 428 done_testing;