t/71mysql.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6
   7 use DBI::Const::GetInfoType;
   8 use Scalar::Util qw/weaken/;
   9 use DBIx::Class::Optional::Dependencies ();
  10
  11 use lib qw(t/lib);
  12 use DBICTest;
  13 use DBIC::SqlMakerTest;
  14
  15 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_mysql')
  16   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_mysql');
  17
  18 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_MYSQL_${_}" } qw/DSN USER PASS/};
  19
  20 plan skip_all => 'Set $ENV{DBICTEST_MYSQL_DSN}, _USER and _PASS to run this test'
  21   unless ($dsn && $user);
  22
  23 my $schema = DBICTest::Schema->connect($dsn, $user, $pass, { quote_names => 1 });
  24
  25 my $dbh = $schema->storage->dbh;
  26
  27 $dbh->do("DROP TABLE IF EXISTS artist;");
  28
  29 $dbh->do("CREATE TABLE artist (artistid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100), rank INTEGER NOT NULL DEFAULT '13', charfield CHAR(10));");
  30
  31 $dbh->do("DROP TABLE IF EXISTS cd;");
  32
  33 $dbh->do("CREATE TABLE cd (cdid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, artist INTEGER, title TEXT, year DATE, genreid INTEGER, single_track INTEGER);");
  34
  35 $dbh->do("DROP TABLE IF EXISTS producer;");
  36
  37 $dbh->do("CREATE TABLE producer (producerid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name TEXT);");
  38
  39 $dbh->do("DROP TABLE IF EXISTS cd_to_producer;");
  40
  41 $dbh->do("CREATE TABLE cd_to_producer (cd INTEGER,producer INTEGER);");
  42
  43 $dbh->do("DROP TABLE IF EXISTS owners;");
  44
  45 $dbh->do("CREATE TABLE owners (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100) NOT NULL);");
  46
  47 $dbh->do("DROP TABLE IF EXISTS books;");
  48
  49 $dbh->do("CREATE TABLE books (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, source VARCHAR(100) NOT NULL, owner integer NOT NULL, title varchar(100) NOT NULL,  price integer);");
  50
  51 #'dbi:mysql:host=localhost;database=dbic_test', 'dbic_test', '');
  52
  53 # make sure sqlt_type overrides work (::Storage::DBI::mysql does this)
  54 {
  55   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  56
  57   ok (!$schema->storage->_dbh, 'definitely not connected');
  58   is ($schema->storage->sqlt_type, 'MySQL', 'sqlt_type correct pre-connection');
  59 }
  60
  61 # This is in Core now, but it's here just to test that it doesn't break
  62 $schema->class('Artist')->load_components('PK::Auto');
  63
  64 # test primary key handling
  65 my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  66 ok($new->artistid, "Auto-PK worked");
  67
  68 # test LIMIT support
  69 for (1..6) {
  70     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  71 }
  72 my $it = $schema->resultset('Artist')->search( {},
  73     { rows => 3,
  74       offset => 2,
  75       order_by => 'artistid' }
  76 );
  77 is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 7 artists
  78 is( $it->next->name, "Artist 2", "iterator->next ok" );
  79 $it->next;
  80 $it->next;
  81 is( $it->next, undef, "next past end of resultset ok" );
  82
  83 # Limit with select-lock
  84 lives_ok {
  85   $schema->txn_do (sub {
  86     isa_ok (
  87       $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  88       'DBICTest::Schema::Artist',
  89     );
  90   });
  91 } 'Limited FOR UPDATE select works';
  92
  93 # shared-lock
  94 lives_ok {
  95   $schema->txn_do (sub {
  96     isa_ok (
  97       $schema->resultset('Artist')->find({artistid => 1}, {for => 'shared'}),
  98       'DBICTest::Schema::Artist',
  99     );
 100   });
 101 } 'LOCK IN SHARE MODE select works';
 102
 103 my $test_type_info = {
 104     'artistid' => {
 105         'data_type' => 'INT',
 106         'is_nullable' => 0,
 107         'size' => 11,
 108         'default_value' => undef,
 109     },
 110     'name' => {
 111         'data_type' => 'VARCHAR',
 112         'is_nullable' => 1,
 113         'size' => 100,
 114         'default_value' => undef,
 115     },
 116     'rank' => {
 117         'data_type' => 'INT',
 118         'is_nullable' => 0,
 119         'size' => 11,
 120         'default_value' => 13,
 121     },
 122     'charfield' => {
 123         'data_type' => 'CHAR',
 124         'is_nullable' => 1,
 125         'size' => 10,
 126         'default_value' => undef,
 127     },
 128 };
 129
 130 $schema->populate ('Owners', [
 131   [qw/id  name  /],
 132   [qw/1   wiggle/],
 133   [qw/2   woggle/],
 134   [qw/3   boggle/],
 135 ]);
 136
 137 $schema->populate ('BooksInLibrary', [
 138   [qw/source  owner title   /],
 139   [qw/Library 1     secrets1/],
 140   [qw/Eatery  1     secrets2/],
 141   [qw/Library 2     secrets3/],
 142 ]);
 143
 144 #
 145 # try a distinct + prefetch on tables with identically named columns
 146 # (mysql doesn't seem to like subqueries with equally named columns)
 147 #
 148
 149 {
 150   # try a ->has_many direction (due to a 'multi' accessor the select/group_by group is collapsed)
 151   my $owners = $schema->resultset ('Owners')->search (
 152     { 'books.id' => { '!=', undef }},
 153     { prefetch => 'books', distinct => 1 }
 154   );
 155   my $owners2 = $schema->resultset ('Owners')->search ({ id => { -in => $owners->get_column ('me.id')->as_query }});
 156   for ($owners, $owners2) {
 157     is ($_->all, 2, 'Prefetched grouped search returns correct number of rows');
 158     is ($_->count, 2, 'Prefetched grouped search returns correct count');
 159   }
 160
 161   # try a ->belongs_to direction (no select collapse)
 162   my $books = $schema->resultset ('BooksInLibrary')->search (
 163     { 'owner.name' => 'wiggle' },
 164     { prefetch => 'owner', distinct => 1 }
 165   );
 166   my $books2 = $schema->resultset ('BooksInLibrary')->search ({ id => { -in => $books->get_column ('me.id')->as_query }});
 167   for ($books, $books2) {
 168     is ($_->all, 1, 'Prefetched grouped search returns correct number of rows');
 169     is ($_->count, 1, 'Prefetched grouped search returns correct count');
 170   }
 171 }
 172
 173 SKIP: {
 174     my $norm_version = $schema->storage->_server_info->{normalized_dbms_version}
 175       or skip "Cannot determine MySQL server version", 1;
 176
 177     if ($norm_version < 5.000003_01) {
 178         $test_type_info->{charfield}->{data_type} = 'VARCHAR';
 179     }
 180
 181     my $type_info = $schema->storage->columns_info_for('artist');
 182     is_deeply($type_info, $test_type_info, 'columns_info_for - column data types');
 183 }
 184
 185 my $cd = $schema->resultset ('CD')->create ({});
 186 my $producer = $schema->resultset ('Producer')->create ({});
 187 lives_ok { $cd->set_producers ([ $producer ]) } 'set_relationship doesnt die';
 188
 189 {
 190   my $artist = $schema->resultset('Artist')->next;
 191   my $cd = $schema->resultset('CD')->next;
 192   $cd->set_from_related ('artist', $artist);
 193   $cd->update;
 194
 195   my $rs = $schema->resultset('CD')->search ({}, { prefetch => 'artist' });
 196
 197   lives_ok sub {
 198     my $cd = $rs->next;
 199     is ($cd->artist->name, $artist->name, 'Prefetched artist');
 200   }, 'join does not throw (mysql 3 test)';
 201
 202   # induce a jointype override, make sure it works even if we don't have mysql3
 203   local $schema->storage->sql_maker->{_default_jointype} = 'inner';
 204   is_same_sql_bind (
 205     $rs->as_query,
 206     '(
 207       SELECT `me`.`cdid`, `me`.`artist`, `me`.`title`, `me`.`year`, `me`.`genreid`, `me`.`single_track`,
 208              `artist`.`artistid`, `artist`.`name`, `artist`.`rank`, `artist`.`charfield`
 209         FROM cd `me`
 210         INNER JOIN `artist` `artist` ON `artist`.`artistid` = `me`.`artist`
 211     )',
 212     [],
 213     'overridden default join type works',
 214   );
 215 }
 216
 217 {
 218   # Test support for straight joins
 219   my $cdsrc = $schema->source('CD');
 220   my $artrel_info = $cdsrc->relationship_info ('artist');
 221   $cdsrc->add_relationship(
 222     'straight_artist',
 223     $artrel_info->{class},
 224     $artrel_info->{cond},
 225     { %{$artrel_info->{attrs}}, join_type => 'straight' },
 226   );
 227   is_same_sql_bind (
 228     $cdsrc->resultset->search({}, { prefetch => 'straight_artist' })->as_query,
 229     '(
 230       SELECT `me`.`cdid`, `me`.`artist`, `me`.`title`, `me`.`year`, `me`.`genreid`, `me`.`single_track`,
 231              `straight_artist`.`artistid`, `straight_artist`.`name`, `straight_artist`.`rank`, `straight_artist`.`charfield`
 232         FROM cd `me`
 233         STRAIGHT_JOIN `artist` `straight_artist` ON `straight_artist`.`artistid` = `me`.`artist`
 234     )',
 235     [],
 236     'straight joins correctly supported for mysql'
 237   );
 238 }
 239
 240 ## Can we properly deal with the null search problem?
 241 ##
 242 ## Only way is to do a SET SQL_AUTO_IS_NULL = 0; on connect
 243 ## But I'm not sure if we should do this or not (Ash, 2008/06/03)
 244 #
 245 # There is now a built-in function to do this, test that everything works
 246 # with it (ribasushi, 2009/07/03)
 247
 248 NULLINSEARCH: {
 249     my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, { on_connect_call => 'set_strict_mode' });
 250
 251     $ansi_schema->resultset('Artist')->create ({ name => 'last created artist' });
 252
 253     ok my $artist1_rs = $ansi_schema->resultset('Artist')->search({artistid=>6666})
 254       => 'Created an artist resultset of 6666';
 255
 256     is $artist1_rs->count, 0
 257       => 'Got no returned rows';
 258
 259     ok my $artist2_rs = $ansi_schema->resultset('Artist')->search({artistid=>undef})
 260       => 'Created an artist resultset of undef';
 261
 262     is $artist2_rs->count, 0
 263       => 'got no rows';
 264
 265     my $artist = $artist2_rs->single;
 266
 267     is $artist => undef,
 268       => 'Nothing Found!';
 269 }
 270
 271 # check for proper grouped counts
 272 {
 273   my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, {
 274     on_connect_call => 'set_strict_mode',
 275     quote_char => '`',
 276   });
 277   my $rs = $ansi_schema->resultset('CD');
 278
 279   my $years;
 280   $years->{$_->year|| scalar keys %$years}++ for $rs->all;  # NULL != NULL, thus the keys eval
 281
 282   lives_ok ( sub {
 283     is (
 284       $rs->search ({}, { group_by => 'year'})->count,
 285       scalar keys %$years,
 286       'grouped count correct',
 287     );
 288   }, 'Grouped count does not throw');
 289
 290   lives_ok( sub {
 291     $ansi_schema->resultset('Owners')->search({}, {
 292       join => 'books', group_by => [ 'me.id', 'books.id' ]
 293     })->count();
 294   }, 'count on grouped columns with the same name does not throw');
 295 }
 296
 297 # a more contrived^Wcomplicated self-referential double-subquery test
 298 {
 299   my $rs = $schema->resultset('Artist')->search({ name => { -like => 'baby_%' } });
 300
 301   $rs->populate([map { [$_] } ('name', map { "baby_$_" } (1..10) ) ]);
 302
 303   my ($count_sql, @count_bind) = @${$rs->count_rs->as_query};
 304
 305   my $complex_rs = $schema->resultset('Artist')->search(
 306     { artistid => {
 307       -in => $rs->get_column('artistid')
 308                   ->as_query
 309     } },
 310   );
 311
 312   $complex_rs->update({ name => \[ "CONCAT( `name`, '_bell_out_of_', $count_sql )", @count_bind ] });
 313
 314   for (1..10) {
 315     is (
 316       $schema->resultset('Artist')->search({ name => "baby_${_}_bell_out_of_10" })->count,
 317       1,
 318       "Correctly updated babybell $_",
 319     );
 320   }
 321
 322   is ($rs->count, 10, '10 artists present');
 323
 324   my $orig_debug = $schema->storage->debug;
 325   $schema->storage->debug(1);
 326   my $query_count;
 327   $schema->storage->debugcb(sub { $query_count++ });
 328
 329   $query_count = 0;
 330   $complex_rs->delete;
 331
 332   is ($query_count, 1, 'One delete query fired');
 333   is ($rs->count, 0, '10 Artists correctly deleted');
 334
 335   $rs->create({
 336     name => 'baby_with_cd',
 337     cds => [ { title => 'babeeeeee', year => 2013 } ],
 338   });
 339   is ($rs->count, 1, 'Artist with cd created');
 340
 341   $query_count = 0;
 342   $schema->resultset('CD')->search_related('artist',
 343     { 'artist.name' => { -like => 'baby_with_%' } }
 344   )->delete;
 345   is ($query_count, 1, 'And one more delete query fired');
 346   is ($rs->count, 0, 'Artist with cd deleted');
 347
 348   $schema->storage->debugcb(undef);
 349   $schema->storage->debug($orig_debug);
 350 }
 351
 352 ZEROINSEARCH: {
 353   my $cds_per_year = {
 354     2001 => 2,
 355     2002 => 1,
 356     2005 => 3,
 357   };
 358
 359   my $rs = $schema->resultset ('CD');
 360   $rs->delete;
 361   for my $y (keys %$cds_per_year) {
 362     for my $c (1 .. $cds_per_year->{$y} ) {
 363       $rs->create ({ title => "CD $y-$c", artist => 1, year => "$y-01-01" });
 364     }
 365   }
 366
 367   is ($rs->count, 6, 'CDs created successfully');
 368
 369   $rs = $rs->search ({}, {
 370     select => [ \ 'YEAR(year)' ], as => ['y'], distinct => 1,
 371   });
 372
 373   is_deeply (
 374     [ sort ($rs->get_column ('y')->all) ],
 375     [ sort keys %$cds_per_year ],
 376     'Years group successfully',
 377   );
 378
 379   $rs->create ({ artist => 1, year => '0-1-1', title => 'Jesus Rap' });
 380
 381   is_deeply (
 382     [ sort $rs->get_column ('y')->all ],
 383     [ 0, sort keys %$cds_per_year ],
 384     'Zero-year groups successfully',
 385   );
 386
 387   # convoluted search taken verbatim from list
 388   my $restrict_rs = $rs->search({ -and => [
 389     year => { '!=', 0 },
 390     year => { '!=', undef }
 391   ]});
 392
 393   is_deeply (
 394     [ $restrict_rs->get_column('y')->all ],
 395     [ $rs->get_column ('y')->all ],
 396     'Zero year was correctly excluded from resultset',
 397   );
 398 }
 399
 400 # make sure find hooks determine driver
 401 {
 402   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 403   $schema->resultset("Artist")->find(4);
 404   isa_ok($schema->storage->sql_maker, 'DBIx::Class::SQLMaker::MySQL');
 405 }
 406
 407 # make sure the mysql_auto_reconnect buggery is avoided
 408 {
 409   local $ENV{MOD_PERL} = 'boogiewoogie';
 410   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 411   ok (! $schema->storage->_get_dbh->{mysql_auto_reconnect}, 'mysql_auto_reconnect unset regardless of ENV' );
 412
 413   # Make sure hardcore forking action still works even if mysql_auto_reconnect
 414   # is true (test inspired by ether)
 415
 416   my $schema_autorecon = DBICTest::Schema->connect($dsn, $user, $pass, { mysql_auto_reconnect => 1 });
 417   my $orig_dbh = $schema_autorecon->storage->_get_dbh;
 418   weaken $orig_dbh;
 419
 420   ok ($orig_dbh, 'Got weak $dbh ref');
 421   ok ($orig_dbh->{mysql_auto_reconnect}, 'mysql_auto_reconnect is properly set if explicitly requested' );
 422
 423   my $rs = $schema_autorecon->resultset('Artist');
 424
 425   my ($parent_in, $child_out);
 426   pipe( $parent_in, $child_out ) or die "Pipe open failed: $!";
 427   my $pid = fork();
 428   if (! defined $pid ) {
 429     die "fork() failed: $!"
 430   }
 431   elsif ($pid) {
 432     close $child_out;
 433
 434     # sanity check
 435     $schema_autorecon->storage->dbh_do(sub {
 436       is ($_[1], $orig_dbh, 'Storage holds correct $dbh in parent');
 437     });
 438
 439     # kill our $dbh
 440     $schema_autorecon->storage->_dbh(undef);
 441
 442     {
 443       local $TODO = "Perl $] is known to leak like a sieve"
 444         if DBIx::Class::_ENV_::PEEPEENESS;
 445
 446       ok (! defined $orig_dbh, 'Parent $dbh handle is gone');
 447     }
 448   }
 449   else {
 450     close $parent_in;
 451
 452     #simulate a  subtest to not confuse the parent TAP emission
 453     my $tb = Test::More->builder;
 454     $tb->reset;
 455     for (qw/output failure_output todo_output/) {
 456       close $tb->$_;
 457       open ($tb->$_, '>&', $child_out);
 458     }
 459
 460     # wait for parent to kill its $dbh
 461     sleep 1;
 462
 463     # try to do something dbic-esque
 464     $rs->create({ name => "Hardcore Forker $$" });
 465
 466     {
 467       local $TODO = "Perl $] is known to leak like a sieve"
 468         if DBIx::Class::_ENV_::PEEPEENESS;
 469
 470       ok (! defined $orig_dbh, 'DBIC operation triggered reconnect - old $dbh is gone');
 471     }
 472
 473     done_testing;
 474     exit 0;
 475   }
 476
 477   while (my $ln = <$parent_in>) {
 478     print "   $ln";
 479   }
 480   wait;
 481   ok(!$?, 'Child subtests passed');
 482
 483   ok ($rs->find({ name => "Hardcore Forker $pid" }), 'Expected row created');
 484 }
 485
 486 done_testing;