t/71mysql.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7
   8 use DBI::Const::GetInfoType;
   9 use Scalar::Util qw/weaken/;
  10 use DBIx::Class::Optional::Dependencies ();
  11
  12 use lib qw(t/lib);
  13 use DBICTest;
  14 use DBIC::SqlMakerTest;
  15
  16 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_mysql')
  17   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_mysql');
  18
  19 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_MYSQL_${_}" } qw/DSN USER PASS/};
  20
  21 plan skip_all => 'Set $ENV{DBICTEST_MYSQL_DSN}, _USER and _PASS to run this test'
  22   unless ($dsn && $user);
  23
  24 my $schema = DBICTest::Schema->connect($dsn, $user, $pass, { quote_names => 1 });
  25
  26 my $dbh = $schema->storage->dbh;
  27
  28 $dbh->do("DROP TABLE IF EXISTS artist;");
  29
  30 $dbh->do("CREATE TABLE artist (artistid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100), rank INTEGER NOT NULL DEFAULT '13', charfield CHAR(10));");
  31
  32 $dbh->do("DROP TABLE IF EXISTS cd;");
  33
  34 $dbh->do("CREATE TABLE cd (cdid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, artist INTEGER, title TEXT, year DATE, genreid INTEGER, single_track INTEGER);");
  35
  36 $dbh->do("DROP TABLE IF EXISTS producer;");
  37
  38 $dbh->do("CREATE TABLE producer (producerid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name TEXT);");
  39
  40 $dbh->do("DROP TABLE IF EXISTS cd_to_producer;");
  41
  42 $dbh->do("CREATE TABLE cd_to_producer (cd INTEGER,producer INTEGER);");
  43
  44 $dbh->do("DROP TABLE IF EXISTS owners;");
  45
  46 $dbh->do("CREATE TABLE owners (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100) NOT NULL);");
  47
  48 $dbh->do("DROP TABLE IF EXISTS books;");
  49
  50 $dbh->do("CREATE TABLE books (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, source VARCHAR(100) NOT NULL, owner integer NOT NULL, title varchar(100) NOT NULL,  price integer);");
  51
  52 #'dbi:mysql:host=localhost;database=dbic_test', 'dbic_test', '');
  53
  54 # make sure sqlt_type overrides work (::Storage::DBI::mysql does this)
  55 {
  56   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  57
  58   ok (!$schema->storage->_dbh, 'definitely not connected');
  59   is ($schema->storage->sqlt_type, 'MySQL', 'sqlt_type correct pre-connection');
  60 }
  61
  62 # This is in Core now, but it's here just to test that it doesn't break
  63 $schema->class('Artist')->load_components('PK::Auto');
  64
  65 # test primary key handling
  66 my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  67 ok($new->artistid, "Auto-PK worked");
  68
  69 # test LIMIT support
  70 for (1..6) {
  71     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  72 }
  73 my $it = $schema->resultset('Artist')->search( {},
  74     { rows => 3,
  75       offset => 2,
  76       order_by => 'artistid' }
  77 );
  78 is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 7 artists
  79 is( $it->next->name, "Artist 2", "iterator->next ok" );
  80 $it->next;
  81 $it->next;
  82 is( $it->next, undef, "next past end of resultset ok" );
  83
  84 # Limit with select-lock
  85 lives_ok {
  86   $schema->txn_do (sub {
  87     isa_ok (
  88       $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  89       'DBICTest::Schema::Artist',
  90     );
  91   });
  92 } 'Limited FOR UPDATE select works';
  93
  94 # shared-lock
  95 lives_ok {
  96   $schema->txn_do (sub {
  97     isa_ok (
  98       $schema->resultset('Artist')->find({artistid => 1}, {for => 'shared'}),
  99       'DBICTest::Schema::Artist',
 100     );
 101   });
 102 } 'LOCK IN SHARE MODE select works';
 103
 104 my $test_type_info = {
 105     'artistid' => {
 106         'data_type' => 'INT',
 107         'is_nullable' => 0,
 108         'size' => 11,
 109         'default_value' => undef,
 110     },
 111     'name' => {
 112         'data_type' => 'VARCHAR',
 113         'is_nullable' => 1,
 114         'size' => 100,
 115         'default_value' => undef,
 116     },
 117     'rank' => {
 118         'data_type' => 'INT',
 119         'is_nullable' => 0,
 120         'size' => 11,
 121         'default_value' => 13,
 122     },
 123     'charfield' => {
 124         'data_type' => 'CHAR',
 125         'is_nullable' => 1,
 126         'size' => 10,
 127         'default_value' => undef,
 128     },
 129 };
 130
 131 $schema->populate ('Owners', [
 132   [qw/id  name  /],
 133   [qw/1   wiggle/],
 134   [qw/2   woggle/],
 135   [qw/3   boggle/],
 136 ]);
 137
 138 $schema->populate ('BooksInLibrary', [
 139   [qw/source  owner title   /],
 140   [qw/Library 1     secrets1/],
 141   [qw/Eatery  1     secrets2/],
 142   [qw/Library 2     secrets3/],
 143 ]);
 144
 145 #
 146 # try a distinct + prefetch on tables with identically named columns
 147 # (mysql doesn't seem to like subqueries with equally named columns)
 148 #
 149
 150 {
 151   # try a ->has_many direction (due to a 'multi' accessor the select/group_by group is collapsed)
 152   my $owners = $schema->resultset ('Owners')->search (
 153     { 'books.id' => { '!=', undef }},
 154     { prefetch => 'books', distinct => 1 }
 155   );
 156   my $owners2 = $schema->resultset ('Owners')->search ({ id => { -in => $owners->get_column ('me.id')->as_query }});
 157   for ($owners, $owners2) {
 158     is ($_->all, 2, 'Prefetched grouped search returns correct number of rows');
 159     is ($_->count, 2, 'Prefetched grouped search returns correct count');
 160   }
 161
 162   # try a ->belongs_to direction (no select collapse)
 163   my $books = $schema->resultset ('BooksInLibrary')->search (
 164     { 'owner.name' => 'wiggle' },
 165     { prefetch => 'owner', distinct => 1 }
 166   );
 167   my $books2 = $schema->resultset ('BooksInLibrary')->search ({ id => { -in => $books->get_column ('me.id')->as_query }});
 168   for ($books, $books2) {
 169     is ($_->all, 1, 'Prefetched grouped search returns correct number of rows');
 170     is ($_->count, 1, 'Prefetched grouped search returns correct count');
 171   }
 172 }
 173
 174 SKIP: {
 175     my $norm_version = $schema->storage->_server_info->{normalized_dbms_version}
 176       or skip "Cannot determine MySQL server version", 1;
 177
 178     if ($norm_version < 5.000003_01) {
 179         $test_type_info->{charfield}->{data_type} = 'VARCHAR';
 180     }
 181
 182     my $type_info = $schema->storage->columns_info_for('artist');
 183     is_deeply($type_info, $test_type_info, 'columns_info_for - column data types');
 184 }
 185
 186 my $cd = $schema->resultset ('CD')->create ({});
 187 my $producer = $schema->resultset ('Producer')->create ({});
 188 lives_ok { $cd->set_producers ([ $producer ]) } 'set_relationship doesnt die';
 189
 190 {
 191   my $artist = $schema->resultset('Artist')->next;
 192   my $cd = $schema->resultset('CD')->next;
 193   $cd->set_from_related ('artist', $artist);
 194   $cd->update;
 195
 196   my $rs = $schema->resultset('CD')->search ({}, { prefetch => 'artist' });
 197
 198   lives_ok sub {
 199     my $cd = $rs->next;
 200     is ($cd->artist->name, $artist->name, 'Prefetched artist');
 201   }, 'join does not throw (mysql 3 test)';
 202
 203   # induce a jointype override, make sure it works even if we don't have mysql3
 204   local $schema->storage->sql_maker->{_default_jointype} = 'inner';
 205   is_same_sql_bind (
 206     $rs->as_query,
 207     '(
 208       SELECT `me`.`cdid`, `me`.`artist`, `me`.`title`, `me`.`year`, `me`.`genreid`, `me`.`single_track`,
 209              `artist`.`artistid`, `artist`.`name`, `artist`.`rank`, `artist`.`charfield`
 210         FROM cd `me`
 211         INNER JOIN `artist` `artist` ON `artist`.`artistid` = `me`.`artist`
 212     )',
 213     [],
 214     'overridden default join type works',
 215   );
 216 }
 217
 218 ## Can we properly deal with the null search problem?
 219 ##
 220 ## Only way is to do a SET SQL_AUTO_IS_NULL = 0; on connect
 221 ## But I'm not sure if we should do this or not (Ash, 2008/06/03)
 222 #
 223 # There is now a built-in function to do this, test that everything works
 224 # with it (ribasushi, 2009/07/03)
 225
 226 NULLINSEARCH: {
 227     my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, { on_connect_call => 'set_strict_mode' });
 228
 229     $ansi_schema->resultset('Artist')->create ({ name => 'last created artist' });
 230
 231     ok my $artist1_rs = $ansi_schema->resultset('Artist')->search({artistid=>6666})
 232       => 'Created an artist resultset of 6666';
 233
 234     is $artist1_rs->count, 0
 235       => 'Got no returned rows';
 236
 237     ok my $artist2_rs = $ansi_schema->resultset('Artist')->search({artistid=>undef})
 238       => 'Created an artist resultset of undef';
 239
 240     is $artist2_rs->count, 0
 241       => 'got no rows';
 242
 243     my $artist = $artist2_rs->single;
 244
 245     is $artist => undef,
 246       => 'Nothing Found!';
 247 }
 248
 249 # check for proper grouped counts
 250 {
 251   my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, {
 252     on_connect_call => 'set_strict_mode',
 253     quote_char => '`',
 254   });
 255   my $rs = $ansi_schema->resultset('CD');
 256
 257   my $years;
 258   $years->{$_->year|| scalar keys %$years}++ for $rs->all;  # NULL != NULL, thus the keys eval
 259
 260   lives_ok ( sub {
 261     is (
 262       $rs->search ({}, { group_by => 'year'})->count,
 263       scalar keys %$years,
 264       'grouped count correct',
 265     );
 266   }, 'Grouped count does not throw');
 267
 268   lives_ok( sub {
 269     $ansi_schema->resultset('Owners')->search({}, {
 270       join => 'books', group_by => [ 'me.id', 'books.id' ]
 271     })->count();
 272   }, 'count on grouped columns with the same name does not throw');
 273 }
 274
 275 # a more contrived^Wcomplicated self-referential double-subquery test
 276 {
 277   my $rs = $schema->resultset('Artist')->search({ name => { -like => 'baby_%' } });
 278
 279   $rs->populate([map { [$_] } ('name', map { "baby_$_" } (1..10) ) ]);
 280
 281   my ($count_sql, @count_bind) = @${$rs->count_rs->as_query};
 282
 283   my $complex_rs = $schema->resultset('Artist')->search(
 284     { artistid => {
 285       -in => $rs->get_column('artistid')
 286                   ->as_query
 287     } },
 288   );
 289
 290   $complex_rs->update({ name => \[ "CONCAT( `name`, '_bell_out_of_', $count_sql )", @count_bind ] });
 291
 292   for (1..10) {
 293     is (
 294       $schema->resultset('Artist')->search({ name => "baby_${_}_bell_out_of_10" })->count,
 295       1,
 296       "Correctly updated babybell $_",
 297     );
 298   }
 299
 300   is ($rs->count, 10, '10 artists present');
 301
 302   my $orig_debug = $schema->storage->debug;
 303   $schema->storage->debug(1);
 304   my $query_count;
 305   $schema->storage->debugcb(sub { $query_count++ });
 306
 307   $query_count = 0;
 308   $complex_rs->delete;
 309
 310   is ($query_count, 1, 'One delete query fired');
 311   is ($rs->count, 0, '10 Artists correctly deleted');
 312
 313   $rs->create({
 314     name => 'baby_with_cd',
 315     cds => [ { title => 'babeeeeee', year => 2013 } ],
 316   });
 317   is ($rs->count, 1, 'Artist with cd created');
 318
 319   $query_count = 0;
 320   $schema->resultset('CD')->search_related('artist',
 321     { 'artist.name' => { -like => 'baby_with_%' } }
 322   )->delete;
 323   is ($query_count, 1, 'And one more delete query fired');
 324   is ($rs->count, 0, 'Artist with cd deleted');
 325
 326   $schema->storage->debugcb(undef);
 327   $schema->storage->debug($orig_debug);
 328 }
 329
 330 ZEROINSEARCH: {
 331   my $cds_per_year = {
 332     2001 => 2,
 333     2002 => 1,
 334     2005 => 3,
 335   };
 336
 337   my $rs = $schema->resultset ('CD');
 338   $rs->delete;
 339   for my $y (keys %$cds_per_year) {
 340     for my $c (1 .. $cds_per_year->{$y} ) {
 341       $rs->create ({ title => "CD $y-$c", artist => 1, year => "$y-01-01" });
 342     }
 343   }
 344
 345   is ($rs->count, 6, 'CDs created successfully');
 346
 347   $rs = $rs->search ({}, {
 348     select => [ \ 'YEAR(year)' ], as => ['y'], distinct => 1,
 349   });
 350
 351   my $y_rs = $rs->get_column ('y');
 352
 353   warnings_exist { is_deeply (
 354     [ sort ($y_rs->all) ],
 355     [ sort keys %$cds_per_year ],
 356     'Years group successfully',
 357   ) } qr/
 358     \QUse of distinct => 1 while selecting anything other than a column \E
 359     \Qdeclared on the primary ResultSource is deprecated\E
 360   /x, 'deprecation warning';
 361
 362
 363   $rs->create ({ artist => 1, year => '0-1-1', title => 'Jesus Rap' });
 364
 365   is_deeply (
 366     [ sort $y_rs->all ],
 367     [ 0, sort keys %$cds_per_year ],
 368     'Zero-year groups successfully',
 369   );
 370
 371   # convoluted search taken verbatim from list
 372   my $restrict_rs = $rs->search({ -and => [
 373     year => { '!=', 0 },
 374     year => { '!=', undef }
 375   ]});
 376
 377   warnings_exist { is_deeply (
 378     [ $restrict_rs->get_column('y')->all ],
 379     [ $y_rs->all ],
 380     'Zero year was correctly excluded from resultset',
 381   ) } qr/
 382     \QUse of distinct => 1 while selecting anything other than a column \E
 383     \Qdeclared on the primary ResultSource is deprecated\E
 384   /x, 'deprecation warning';
 385 }
 386
 387 # make sure find hooks determine driver
 388 {
 389   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 390   $schema->resultset("Artist")->find(4);
 391   isa_ok($schema->storage->sql_maker, 'DBIx::Class::SQLMaker::MySQL');
 392 }
 393
 394 # make sure the mysql_auto_reconnect buggery is avoided
 395 {
 396   local $ENV{MOD_PERL} = 'boogiewoogie';
 397   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 398   ok (! $schema->storage->_get_dbh->{mysql_auto_reconnect}, 'mysql_auto_reconnect unset regardless of ENV' );
 399
 400   # Make sure hardcore forking action still works even if mysql_auto_reconnect
 401   # is true (test inspired by ether)
 402
 403   my $schema_autorecon = DBICTest::Schema->connect($dsn, $user, $pass, { mysql_auto_reconnect => 1 });
 404   my $orig_dbh = $schema_autorecon->storage->_get_dbh;
 405   weaken $orig_dbh;
 406
 407   ok ($orig_dbh, 'Got weak $dbh ref');
 408   ok ($orig_dbh->{mysql_auto_reconnect}, 'mysql_auto_reconnect is properly set if explicitly requested' );
 409
 410   my $rs = $schema_autorecon->resultset('Artist');
 411
 412   my ($parent_in, $child_out);
 413   pipe( $parent_in, $child_out ) or die "Pipe open failed: $!";
 414   my $pid = fork();
 415   if (! defined $pid ) {
 416     die "fork() failed: $!"
 417   }
 418   elsif ($pid) {
 419     close $child_out;
 420
 421     # sanity check
 422     $schema_autorecon->storage->dbh_do(sub {
 423       is ($_[1], $orig_dbh, 'Storage holds correct $dbh in parent');
 424     });
 425
 426     # kill our $dbh
 427     $schema_autorecon->storage->_dbh(undef);
 428
 429     {
 430       local $TODO = "Perl $] is known to leak like a sieve"
 431         if DBIx::Class::_ENV_::PEEPEENESS;
 432
 433       ok (! defined $orig_dbh, 'Parent $dbh handle is gone');
 434     }
 435   }
 436   else {
 437     close $parent_in;
 438
 439     #simulate a  subtest to not confuse the parent TAP emission
 440     my $tb = Test::More->builder;
 441     $tb->reset;
 442     for (qw/output failure_output todo_output/) {
 443       close $tb->$_;
 444       open ($tb->$_, '>&', $child_out);
 445     }
 446
 447     # wait for parent to kill its $dbh
 448     sleep 1;
 449
 450     # try to do something dbic-esque
 451     $rs->create({ name => "Hardcore Forker $$" });
 452
 453     {
 454       local $TODO = "Perl $] is known to leak like a sieve"
 455         if DBIx::Class::_ENV_::PEEPEENESS;
 456
 457       ok (! defined $orig_dbh, 'DBIC operation triggered reconnect - old $dbh is gone');
 458     }
 459
 460     done_testing;
 461     exit 0;
 462   }
 463
 464   while (my $ln = <$parent_in>) {
 465     print "   $ln";
 466   }
 467   wait;
 468   ok(!$?, 'Child subtests passed');
 469
 470   ok ($rs->find({ name => "Hardcore Forker $pid" }), 'Expected row created');
 471 }
 472
 473 done_testing;