t/66relationship.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 my $schema = DBICTest->init_schema();
   9
  10 plan tests => 58;
  11
  12 # has_a test
  13 my $cd = $schema->resultset("CD")->find(4);
  14 my ($artist) = ($INC{'DBICTest/HelperRels'}
  15                   ? $cd->artist
  16                   : $cd->search_related('artist'));
  17 is($artist->name, 'Random Boy Band', 'has_a search_related ok');
  18
  19 # has_many test with an order_by clause defined
  20 $artist = $schema->resultset("Artist")->find(1);
  21 my @cds = ($INC{'DBICTest/HelperRels'}
  22              ? $artist->cds
  23              : $artist->search_related('cds'));
  24 is( $cds[1]->title, 'Spoonful of bees', 'has_many search_related with order_by ok' );
  25
  26 # search_related with additional abstract query
  27 @cds = ($INC{'DBICTest/HelperRels'}
  28           ? $artist->cds({ title => { like => '%of%' } })
  29           : $artist->search_related('cds', { title => { like => '%of%' } } )
  30        );
  31 is( $cds[1]->title, 'Forkful of bees', 'search_related with abstract query ok' );
  32
  33 # creating a related object
  34 if ($INC{'DBICTest/HelperRels.pm'}) {
  35   $artist->add_to_cds({ title => 'Big Flop', year => 2005 });
  36 } else {
  37   $artist->create_related( 'cds', {
  38       title => 'Big Flop',
  39       year => 2005,
  40   } );
  41 }
  42
  43 is( ($artist->search_related('cds'))[3]->title, 'Big Flop', 'create_related ok' );
  44
  45 my( $rs_from_list ) = $artist->search_related_rs('cds');
  46 is( ref($rs_from_list), 'DBIx::Class::ResultSet', 'search_related_rs in list context returns rs' );
  47
  48 ( $rs_from_list ) = $artist->cds_rs();
  49 is( ref($rs_from_list), 'DBIx::Class::ResultSet', 'relation_rs in list context returns rs' );
  50
  51 # count_related
  52 is( $artist->count_related('cds'), 4, 'count_related ok' );
  53
  54 # set_from_related
  55 my $track = $schema->resultset("Track")->create( {
  56   trackid => 1,
  57   cd => 3,
  58   position => 98,
  59   title => 'Hidden Track'
  60 } );
  61 $track->set_from_related( cd => $cd );
  62
  63 is($track->disc->cdid, 4, 'set_from_related ok, including alternative accessor' );
  64
  65 $track->set_from_related( cd => undef );
  66
  67 ok( !defined($track->cd), 'set_from_related with undef ok');
  68
  69
  70 # update_from_related, the same as set_from_related, but it calls update afterwards
  71 $track = $schema->resultset("Track")->create( {
  72   trackid => 2,
  73   cd => 3,
  74   position => 99,
  75   title => 'Hidden Track 2'
  76 } );
  77 $track->update_from_related( cd => $cd );
  78
  79 my $t_cd = ($schema->resultset("Track")->search( cd => 4, position => 99 ))[0]->cd;
  80
  81 is( $t_cd->cdid, 4, 'update_from_related ok' );
  82
  83 # find_or_create_related with an existing record
  84 $cd = $artist->find_or_create_related( 'cds', { title => 'Big Flop' } );
  85 is( $cd->year, 2005, 'find_or_create_related on existing record ok' );
  86
  87 # find_or_create_related creating a new record
  88 $cd = $artist->find_or_create_related( 'cds', {
  89   title => 'Greatest Hits',
  90   year => 2006,
  91 } );
  92 is( $cd->title, 'Greatest Hits', 'find_or_create_related new record ok' );
  93
  94 @cds = $artist->search_related('cds');
  95 is( ($artist->search_related('cds'))[4]->title, 'Greatest Hits', 'find_or_create_related new record search ok' );
  96
  97 $artist->delete_related( cds => { title => 'Greatest Hits' });
  98 cmp_ok( $schema->resultset("CD")->search( title => 'Greatest Hits' ), '==', 0, 'delete_related ok' );
  99
 100 # find_or_new_related with an existing record
 101 $cd = $artist->find_or_new_related( 'cds', { title => 'Big Flop' } );
 102 is( $cd->year, 2005, 'find_or_new_related on existing record ok' );
 103 ok( $cd->in_storage, 'find_or_new_related on existing record: is in_storage' );
 104
 105 # find_or_new_related instantiating a new record
 106 $cd = $artist->find_or_new_related( 'cds', {
 107   title => 'Greatest Hits 2: Louder Than Ever',
 108   year => 2007,
 109 } );
 110 is( $cd->title, 'Greatest Hits 2: Louder Than Ever', 'find_or_new_related new record ok' );
 111 ok( ! $cd->in_storage, 'find_or_new_related on a new record: not in_storage' );
 112
 113 # print STDERR Data::Dumper::Dumper($cd->get_columns);
 114 # $cd->result_source->schema->storage->debug(1);
 115 $cd->artist(undef);
 116 my $newartist = $cd->find_or_new_related( 'artist', {
 117   name => 'Random Boy Band Two',
 118   artistid => 200,
 119 } );
 120 $cd->result_source->schema->storage->debug(0);
 121
 122 is($newartist->name, 'Random Boy Band Two', 'find_or_new_related new artist record with id');
 123 is($newartist->id, 200, 'find_or_new_related new artist id set');
 124
 125
 126 SKIP: {
 127   skip "relationship checking needs fixing", 1;
 128   # try to add a bogus relationship using the wrong cols
 129   eval {
 130       DBICTest::Schema::Artist->add_relationship(
 131           tracks => 'DBICTest::Schema::Track',
 132           { 'foreign.cd' => 'self.cdid' }
 133       );
 134   };
 135   like($@, qr/Unknown column/, 'failed when creating a rel with invalid key, ok');
 136 }
 137
 138 # another bogus relationship using no join condition
 139 eval {
 140     DBICTest::Schema::Artist->add_relationship( tracks => 'DBICTest::Track' );
 141 };
 142 like($@, qr/join condition/, 'failed when creating a rel without join condition, ok');
 143
 144 # many_to_many helper tests
 145 $cd = $schema->resultset("CD")->find(1);
 146 my @producers = $cd->producers();
 147 is( $producers[0]->name, 'Matt S Trout', 'many_to_many ok' );
 148 is( $cd->producers_sorted->next->name, 'Bob The Builder',
 149     'sorted many_to_many ok' );
 150 is( $cd->producers_sorted(producerid => 3)->next->name, 'Fred The Phenotype',
 151     'sorted many_to_many with search condition ok' );
 152
 153 $cd = $schema->resultset('CD')->find(2);
 154 my $prod_rs = $cd->producers();
 155 my $prod_before_count = $schema->resultset('Producer')->count;
 156 is( $prod_rs->count, 0, "CD doesn't yet have any producers" );
 157 my $prod = $schema->resultset('Producer')->find(1);
 158 $cd->add_to_producers($prod);
 159 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($obj) count ok' );
 160 is( $prod_rs->first->name, 'Matt S Trout',
 161     'many_to_many add_to_$rel($obj) ok' );
 162 $cd->remove_from_producers($prod);
 163 is( $schema->resultset('Producer')->find(1)->name, 'Matt S Trout',
 164     "producer object exists after remove of link" );
 165 is( $prod_rs->count, 0, 'many_to_many remove_from_$rel($obj) ok' );
 166 $cd->add_to_producers({ name => 'Testy McProducer' });
 167 is( $schema->resultset('Producer')->count, $prod_before_count+1,
 168     'add_to_$rel($hash) inserted a new producer' );
 169 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($hash) count ok' );
 170 is( $prod_rs->first->name, 'Testy McProducer',
 171     'many_to_many add_to_$rel($hash) ok' );
 172 $cd->add_to_producers({ name => 'Jack Black' });
 173 is( $prod_rs->count(), 2, 'many_to_many add_to_$rel($hash) count ok' );
 174 $cd->set_producers($schema->resultset('Producer')->all);
 175 is( $cd->producers->count(), $prod_before_count+2,
 176     'many_to_many set_$rel(@objs) count ok' );
 177 $cd->set_producers($schema->resultset('Producer')->find(1));
 178 is( $cd->producers->count(), 1, 'many_to_many set_$rel($obj) count ok' );
 179 $cd->set_producers([$schema->resultset('Producer')->all]);
 180 is( $cd->producers->count(), $prod_before_count+2,
 181     'many_to_many set_$rel(\@objs) count ok' );
 182 $cd->set_producers([$schema->resultset('Producer')->find(1)]);
 183 is( $cd->producers->count(), 1, 'many_to_many set_$rel([$obj]) count ok' );
 184
 185 eval { $cd->remove_from_producers({ fake => 'hash' }); };
 186 like( $@, qr/needs an object/, 'remove_from_$rel($hash) dies correctly' );
 187
 188 eval { $cd->add_to_producers(); };
 189 like( $@, qr/needs an object or hashref/,
 190       'add_to_$rel(undef) dies correctly' );
 191
 192 # many_to_many stresstest
 193 my $twokey = $schema->resultset('TwoKeys')->find(1,1);
 194 my $fourkey = $schema->resultset('FourKeys')->find(1,2,3,4);
 195
 196 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 197 $twokey->add_to_fourkeys($fourkey, { autopilot => 'engaged' });
 198 my $got_fourkey = $twokey->fourkeys({ sensors => 'online' })->first;
 199 is( $twokey->fourkeys->count, 1, 'twokey has one fourkey' );
 200 is( $got_fourkey->$_, $fourkey->$_,
 201     'fourkeys row has the correct value for column '.$_ )
 202   for (qw(foo bar hello goodbye sensors));
 203 $twokey->remove_from_fourkeys($fourkey);
 204 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 205 is( $twokey->fourkeys_to_twokeys->count, 0,
 206     'twokey has no links to fourkey' );
 207
 208
 209 # test undirected many-to-many relationship (e.g. "related artists")
 210 my $undir_maps = $schema->resultset("Artist")->find(1)->artist_undirected_maps;
 211 is($undir_maps->count, 1, 'found 1 undirected map for artist 1');
 212
 213 $undir_maps = $schema->resultset("Artist")->find(2)->artist_undirected_maps;
 214 is($undir_maps->count, 1, 'found 1 undirected map for artist 2');
 215
 216 my $mapped_rs = $undir_maps->search_related('mapped_artists');
 217
 218 my @art = $mapped_rs->all;
 219
 220 cmp_ok(@art, '==', 2, "Both artist returned from map");
 221
 222 my $searched = $mapped_rs->search({'mapped_artists.artistid' => {'!=', undef}});
 223
 224 cmp_ok($searched->count, '==', 2, "Both artist returned from map after adding another condition");
 225
 226 # check join through cascaded has_many relationships
 227 $artist = $schema->resultset("Artist")->find(1);
 228 my $trackset = $artist->cds->search_related('tracks');
 229 # LEFT join means we also see the trackless additional album...
 230 cmp_ok($trackset->count, '==', 11, "Correct number of tracks for artist");
 231
 232 # now see about updating eveything that belongs to artist 2 to artist 3
 233 $artist = $schema->resultset("Artist")->find(2);
 234 my $nartist = $schema->resultset("Artist")->find(3);
 235 cmp_ok($artist->cds->count, '==', 1, "Correct orig #cds for artist");
 236 cmp_ok($nartist->cds->count, '==', 1, "Correct orig #cds for artist");
 237 $artist->cds->update({artist => $nartist->id});
 238 cmp_ok($artist->cds->count, '==', 0, "Correct new #cds for artist");
 239 cmp_ok($nartist->cds->count, '==', 2, "Correct new #cds for artist");
 240