t/60core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9
  10 my $schema = DBICTest->init_schema();
  11
  12 plan tests => 103;
  13
  14 eval { require DateTime::Format::SQLite };
  15 my $NO_DTFM = $@ ? 1 : 0;
  16
  17 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  18
  19 is(@art, 3, "Three artists returned");
  20
  21 my $art = $art[0];
  22
  23 is($art->name, 'We Are Goth', "Correct order too");
  24
  25 $art->name('We Are In Rehab');
  26
  27 is($art->name, 'We Are In Rehab', "Accessor update ok");
  28
  29 my %dirty = $art->get_dirty_columns();
  30 is(scalar(keys(%dirty)), 1, '1 dirty column');
  31 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  32
  33 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  34
  35 ok($art->update, 'Update run');
  36
  37 my %not_dirty = $art->get_dirty_columns();
  38 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  39
  40 eval {
  41   my $ret = $art->make_column_dirty('name2');
  42 };
  43 ok(defined($@), 'Failed to make non-existent column dirty');
  44 $art->make_column_dirty('name');
  45 my %fake_dirty = $art->get_dirty_columns();
  46 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  47 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  48
  49 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  50
  51 ok($record_jp, "prefetch on same rel okay");
  52
  53 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  54
  55 ok($record_fn, "funny join is okay");
  56
  57 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  58
  59 is(@art, 1, "Changed artist returned by search");
  60
  61 is($art[0]->artistid, 3,'Correct artist too');
  62
  63 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  64
  65 @art = $schema->resultset("Artist")->search({ });
  66
  67 is(@art, 2, 'And then there were two');
  68
  69 ok(!$art->in_storage, "It knows it's dead");
  70
  71 dies_ok ( sub { $art->delete }, "Can't delete twice");
  72
  73 is($art->name, 'We Are In Rehab', 'But the object is still live');
  74
  75 $art->insert;
  76
  77 ok($art->in_storage, "Re-created");
  78
  79 @art = $schema->resultset("Artist")->search({ });
  80
  81 is(@art, 3, 'And now there are three again');
  82
  83 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  84
  85 is($new->artistid, 4, 'Create produced record ok');
  86
  87 @art = $schema->resultset("Artist")->search({ });
  88
  89 is(@art, 4, "Oh my god! There's four of them!");
  90
  91 $new->set_column('name' => 'Man With A Fork');
  92
  93 is($new->name, 'Man With A Fork', 'set_column ok');
  94
  95 $new->discard_changes;
  96
  97 ok(!defined $new->name, 'Discard ok');
  98
  99 $new->name('Man With A Spoon');
 100
 101 $new->update;
 102
 103 my $new_again = $schema->resultset("Artist")->find(4);
 104
 105 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 106
 107 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 108
 109 # Test backwards compatibility
 110 {
 111   my $warnings = '';
 112   local $SIG{__WARN__} = sub { $warnings .= $_[0] };
 113
 114   my $artist_by_hash = $schema->resultset('Artist')->find(artistid => 4);
 115   is($artist_by_hash->name, 'Man With A Spoon', 'Retrieved correctly');
 116   is($artist_by_hash->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 117   like($warnings, qr/deprecated/, 'warned about deprecated find usage');
 118 }
 119
 120 is($schema->resultset("Artist")->count, 4, 'count ok');
 121
 122 # test find_or_new
 123 {
 124   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 125     artistid => 4,
 126   });
 127
 128   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 129   ok($existing_obj->in_storage, 'existing artist is in storage');
 130
 131   my $new_obj = $schema->resultset('Artist')->find_or_new({
 132     artistid => 5,
 133     name     => 'find_or_new',
 134   });
 135
 136   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 137   ok(! $new_obj->in_storage, 'new artist is not in storage');
 138 }
 139
 140 my $cd = $schema->resultset("CD")->find(1);
 141 my %cols = $cd->get_columns;
 142
 143 is(keys %cols, 6, 'get_columns number of columns ok');
 144
 145 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 146
 147 %cols = ( title => 'Forkful of bees', year => 2005);
 148 $cd->set_columns(\%cols);
 149
 150 is($cd->title, 'Forkful of bees', 'set_columns ok');
 151
 152 is($cd->year, 2005, 'set_columns ok');
 153
 154 $cd->discard_changes;
 155
 156 # check whether ResultSource->columns returns columns in order originally supplied
 157 my @cd = $schema->source("CD")->columns;
 158
 159 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 160
 161 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 162 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 163
 164 $cd = $schema->resultset("CD")->search(undef, { include_columns => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 165
 166 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 167 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 168
 169 # check if new syntax +columns also works for this
 170 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ 'artist.name' ], join => [ 'artist' ] })->find(1);
 171
 172 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 173 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 174
 175 # check if new syntax for +columns select specifiers works for this
 176 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 177
 178 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 179 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 180
 181 # update_or_insert
 182 $new = $schema->resultset("Track")->new( {
 183   trackid => 100,
 184   cd => 1,
 185   title => 'Insert or Update',
 186   last_updated_on => '1973-07-19 12:01:02'
 187 } );
 188 $new->update_or_insert;
 189 ok($new->in_storage, 'update_or_insert insert ok');
 190
 191 # test in update mode
 192 $new->title('Insert or Update - updated');
 193 $new->update_or_insert;
 194 is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 195
 196 # get_inflated_columns w/relation and accessor alias
 197 SKIP: {
 198     skip "This test requires DateTime::Format::SQLite", 8 if $NO_DTFM;
 199
 200     isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 201     my %tdata = $new->get_inflated_columns;
 202     is($tdata{'trackid'}, 100, 'got id');
 203     isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 204     is($tdata{'cd'}->id, 1, 'cd object is id 1');
 205     is(
 206         $tdata{'position'},
 207         $schema->resultset ('Track')->search ({cd => 1})->count,
 208         'Ordered assigned proper position',
 209     );
 210     is($tdata{'title'}, 'Insert or Update - updated');
 211     is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 212     isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 213 }
 214
 215 eval { $schema->class("Track")->load_components('DoesNotExist'); };
 216
 217 ok $@, $@;
 218
 219 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 220
 221 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 222
 223 my( $or_rs ) = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 224                                                   order_by => 'cdid' });
 225 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 226 is($or_rs->count, 5, 'Search count with OR ok');
 227
 228 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 229 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 230 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 231
 232 {
 233   my $tcount = $schema->resultset('Track')->search(
 234     {},
 235     {
 236       select => [ qw/position title/ ],
 237       distinct => 1,
 238     }
 239   );
 240   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 241
 242   $tcount = $schema->resultset('Track')->search(
 243     {},
 244     {
 245       columns => [ qw/position title/ ],
 246       distinct => 1,
 247     }
 248   );
 249   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 250
 251   $tcount = $schema->resultset('Track')->search(
 252     {},
 253     {
 254        group_by => [ qw/position title/ ]
 255     }
 256   );
 257   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 258 }
 259
 260 my $tag_rs = $schema->resultset('Tag')->search(
 261                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 262
 263 my $rel_rs = $tag_rs->search_related('cd');
 264
 265 is($rel_rs->count, 5, 'Related search ok');
 266
 267 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 268 $or_rs->reset;
 269 $rel_rs->reset;
 270
 271 my $tag = $schema->resultset('Tag')->search(
 272                [ { 'me.tag' => 'Blue' } ], { cols=>[qw/tagid/] } )->next;
 273
 274 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 275 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 276
 277 ok($schema->storage(), 'Storage available');
 278
 279 {
 280   my $rs = $schema->resultset("Artist")->search({
 281     -and => [
 282       artistid => { '>=', 1 },
 283       artistid => { '<', 3 }
 284     ]
 285   });
 286
 287   $rs->update({ name => 'Test _cond_for_update_delete' });
 288
 289   my $art;
 290
 291   $art = $schema->resultset("Artist")->find(1);
 292   is($art->name, 'Test _cond_for_update_delete', 'updated first artist name');
 293
 294   $art = $schema->resultset("Artist")->find(2);
 295   is($art->name, 'Test _cond_for_update_delete', 'updated second artist name');
 296 }
 297
 298 # test source_name
 299 {
 300   # source_name should be set for normal modules
 301   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 302
 303   # test the result source that sets source_name explictly
 304   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 305
 306   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 307   is(@artsn, 4, "Four artists returned");
 308
 309   # make sure subclasses that don't set source_name are ok
 310   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 311 }
 312
 313 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 314
 315 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 316
 317 # test cascade_delete through many_to_many relations
 318 {
 319   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 320   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 321   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 322   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 323 }
 324
 325 # test column_info
 326 {
 327   $schema->source("Artist")->{_columns}{'artistid'} = {};
 328   $schema->source("Artist")->column_info_from_storage(1);
 329
 330   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 331   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 332   $schema->source("Artist")->column_info('artistid');
 333   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info flag set');
 334 }
 335
 336 # test source_info
 337 {
 338   my $expected = {
 339     "source_info_key_A" => "source_info_value_A",
 340     "source_info_key_B" => "source_info_value_B",
 341     "source_info_key_C" => "source_info_value_C",
 342   };
 343
 344   my $sinfo = $schema->source("Artist")->source_info;
 345
 346   is_deeply($sinfo, $expected, 'source_info data works');
 347 }
 348
 349 # test remove_columns
 350 {
 351   is_deeply(
 352     [$schema->source('CD')->columns],
 353     [qw/cdid artist title year genreid single_track/],
 354     'initial columns',
 355   );
 356
 357   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 358   is_deeply(
 359     [$schema->source('CD')->columns],
 360     [qw/cdid artist title year genreid single_track/],
 361     'nothing removed when removing a non-existent column',
 362   );
 363
 364   $schema->source('CD')->remove_columns('genreid', 'year');
 365   is_deeply(
 366     [$schema->source('CD')->columns],
 367     [qw/cdid artist title single_track/],
 368     'removed two columns',
 369   );
 370
 371   my $priv_columns = $schema->source('CD')->_columns;
 372   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 373   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 374 }
 375
 376 # test get_inflated_columns with objects
 377 SKIP: {
 378     skip "This test requires DateTime::Format::SQLite", 5 if $NO_DTFM;
 379     my $event = $schema->resultset('Event')->search->first;
 380     my %edata = $event->get_inflated_columns;
 381     is($edata{'id'}, $event->id, 'got id');
 382     isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 383     isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 384     is($edata{'starts_at'}, $event->starts_at, 'got start date');
 385     is($edata{'created_on'}, $event->created_on, 'got created date');
 386 }
 387
 388 # test resultsource->table return value when setting
 389 {
 390     my $class = $schema->class('Event');
 391     my $table = $class->table($class->table);
 392     is($table, $class->table, '->table($table) returns $table');
 393 }
 394
 395 #make sure insert doesn't use set_column
 396 {
 397   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 398   is($en_row->encoded, 'amliw', 'new encodes');
 399   $en_row->insert;
 400   is($en_row->encoded, 'amliw', 'insert does not encode again');
 401 }
 402
 403 # make sure we got rid of the compat shims
 404 SKIP: {
 405     skip "Remove in 0.09", 5 if $DBIx::Class::VERSION < 0.09;
 406
 407     for (qw/compare_relationship_keys pk_depends_on resolve_condition resolve_join resolve_prefetch/) {
 408       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource");
 409     }
 410 }