t/60core.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8 use Test::Warn;
   9
  10 use DBICTest ':DiffSQL';
  11
  12 my $schema = DBICTest->init_schema();
  13
  14 my @art = $schema->resultset("Artist")->search({ }, { order_by => 'name DESC'});
  15
  16 is(@art, 3, "Three artists returned");
  17
  18 my $art = $art[0];
  19
  20 is($art->name, 'We Are Goth', "Correct order too");
  21
  22 $art->name('We Are In Rehab');
  23
  24 is($art->name, 'We Are In Rehab', "Accessor update ok");
  25
  26 my %dirty = $art->get_dirty_columns();
  27 is(scalar(keys(%dirty)), 1, '1 dirty column');
  28 ok(grep($_ eq 'name', keys(%dirty)), 'name is dirty');
  29
  30 is($art->get_column("name"), 'We Are In Rehab', 'And via get_column');
  31
  32 ok($art->update, 'Update run');
  33
  34 my %not_dirty = $art->get_dirty_columns();
  35 is(scalar(keys(%not_dirty)), 0, 'Nothing is dirty');
  36
  37 throws_ok ( sub {
  38   my $ret = $art->make_column_dirty('name2');
  39 }, qr/No such column 'name2'/, 'Failed to make non-existent column dirty');
  40
  41 $art->make_column_dirty('name');
  42 my %fake_dirty = $art->get_dirty_columns();
  43 is(scalar(keys(%fake_dirty)), 1, '1 fake dirty column');
  44 ok(grep($_ eq 'name', keys(%fake_dirty)), 'name is fake dirty');
  45
  46 ok($art->update, 'Update run');
  47
  48 my $record_jp = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => 'cds' })->next;
  49
  50 ok($record_jp, "prefetch on same rel okay");
  51
  52 my $record_fn = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search({'cds.cdid' => '1'}, {join => 'artist_undirected_maps'})->next;
  53
  54 ok($record_fn, "funny join is okay");
  55
  56 @art = $schema->resultset("Artist")->search({ name => 'We Are In Rehab' });
  57
  58 is(@art, 1, "Changed artist returned by search");
  59
  60 is($art[0]->artistid, 3,'Correct artist too');
  61
  62 lives_ok (sub { $art->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
  63
  64 @art = $schema->resultset("Artist")->search({ });
  65
  66 is(@art, 2, 'And then there were two');
  67
  68 is($art->in_storage, 0, "It knows it's dead");
  69
  70 lives_ok { $art->update } 'No changes so update should be OK';
  71
  72 dies_ok ( sub { $art->delete }, "Can't delete twice");
  73
  74 is($art->name, 'We Are In Rehab', 'But the object is still live');
  75
  76 $art->insert;
  77
  78 ok($art->in_storage, "Re-created");
  79
  80 @art = $schema->resultset("Artist")->search({ });
  81
  82 is(@art, 3, 'And now there are three again');
  83
  84 my $new = $schema->resultset("Artist")->create({ artistid => 4 });
  85
  86 is($new->artistid, 4, 'Create produced record ok');
  87
  88 @art = $schema->resultset("Artist")->search({ });
  89
  90 is(@art, 4, "Oh my god! There's four of them!");
  91
  92 $new->set_column('name' => 'Man With A Fork');
  93
  94 is($new->name, 'Man With A Fork', 'set_column ok');
  95
  96 $new->discard_changes;
  97
  98 ok(!defined $new->name, 'Discard ok');
  99
 100 $new->name('Man With A Spoon');
 101
 102 $new->update;
 103
 104 my $new_again = $schema->resultset("Artist")->find(4);
 105
 106 is($new_again->name, 'Man With A Spoon', 'Retrieved correctly');
 107
 108 is($new_again->ID, 'DBICTest::Artist|artist|artistid=4', 'unique object id generated correctly');
 109
 110 # test that store_column is called once for create() for non sequence columns
 111 {
 112   ok(my $artist = $schema->resultset('Artist')->create({name => 'store_column test'}));
 113   is($artist->name, 'X store_column test'); # used to be 'X X store...'
 114
 115   # call store_column even though the column doesn't seem to be dirty
 116   $artist->name($artist->name);
 117   is($artist->name, 'X X store_column test');
 118   ok($artist->is_column_changed('name'), 'changed column marked as dirty');
 119
 120   $artist->delete;
 121 }
 122
 123 # deprecation of rolled-out search
 124 warnings_exist {
 125   $schema->resultset('Artist')->search_rs(id => 4)
 126 } qr/\Qsearch( %condition ) is deprecated/, 'Deprecation warning on ->search( %condition )';
 127
 128 # this has been warning for 4 years, killing
 129 throws_ok {
 130   $schema->resultset('Artist')->find(artistid => 4);
 131 } qr|expects either a column/value hashref, or a list of values corresponding to the columns of the specified unique constraint|;
 132
 133 is($schema->resultset("Artist")->count, 4, 'count ok');
 134
 135 # test find on an unresolvable condition
 136 is(
 137   $schema->resultset('Artist')->find({ artistid => [ -and => 1, 2 ]}),
 138   undef
 139 );
 140
 141
 142 # test find_or_new
 143 {
 144   my $existing_obj = $schema->resultset('Artist')->find_or_new({
 145     artistid => 4,
 146   });
 147
 148   is($existing_obj->name, 'Man With A Spoon', 'find_or_new: found existing artist');
 149   ok($existing_obj->in_storage, 'existing artist is in storage');
 150
 151   my $new_obj = $schema->resultset('Artist')->find_or_new({
 152     artistid => 5,
 153     name     => 'find_or_new',
 154   });
 155
 156   is($new_obj->name, 'find_or_new', 'find_or_new: instantiated a new artist');
 157   is($new_obj->in_storage, 0, 'new artist is not in storage');
 158 }
 159
 160 my $cd = $schema->resultset("CD")->find(1);
 161 my %cols = $cd->get_columns;
 162
 163 is(keys %cols, 6, 'get_columns number of columns ok');
 164
 165 is($cols{title}, 'Spoonful of bees', 'get_columns values ok');
 166
 167 %cols = ( title => 'Forkful of bees', year => 2005);
 168 $cd->set_columns(\%cols);
 169
 170 is($cd->title, 'Forkful of bees', 'set_columns ok');
 171
 172 is($cd->year, 2005, 'set_columns ok');
 173
 174 $cd->discard_changes;
 175
 176 # check whether ResultSource->columns returns columns in order originally supplied
 177 my @cd = $schema->source("CD")->columns;
 178
 179 is_deeply( \@cd, [qw/cdid artist title year genreid single_track/], 'column order');
 180
 181 $cd = $schema->resultset("CD")->search({ title => 'Spoonful of bees' }, { columns => ['title'] })->next;
 182 is($cd->title, 'Spoonful of bees', 'subset of columns returned correctly');
 183
 184 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 185
 186 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 187 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 188
 189 # check if new syntax +columns also works for this
 190 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ { name => 'artist.name' } ], join => [ 'artist' ] })->find(1);
 191
 192 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 193 is($cd->get_column('name'), 'Caterwauler McCrae', 'Additional column returned');
 194
 195 # check if new syntax for +columns select specifiers works for this
 196 $cd = $schema->resultset("CD")->search(undef, { '+columns' => [ {artist_name => 'artist.name'} ], join => [ 'artist' ] })->find(1);
 197
 198 is($cd->title, 'Spoonful of bees', 'Correct CD returned with include');
 199 is($cd->get_column('artist_name'), 'Caterwauler McCrae', 'Additional column returned');
 200
 201 # update_or_insert
 202 $new = $schema->resultset("Track")->new( {
 203   trackid => 100,
 204   cd => 1,
 205   title => 'Insert or Update',
 206   last_updated_on => '1973-07-19 12:01:02'
 207 } );
 208 $new->update_or_insert;
 209 ok($new->in_storage, 'update_or_insert insert ok');
 210
 211 throws_ok (sub {
 212   $schema->class("Track")->load_components('DoesNotExist');
 213 }, qr!Can't locate DBIx/Class/DoesNotExist.pm!, 'exception on nonexisting component');
 214
 215 is($schema->class("Artist")->field_name_for->{name}, 'artist name', 'mk_classdata usage ok');
 216
 217 my $search = [ { 'tags.tag' => 'Cheesy' }, { 'tags.tag' => 'Blue' } ];
 218
 219 my $or_rs = $schema->resultset("CD")->search_rs($search, { join => 'tags',
 220                                                   order_by => 'cdid' });
 221 is($or_rs->all, 5, 'Joined search with OR returned correct number of rows');
 222 is($or_rs->count, 5, 'Search count with OR ok');
 223
 224 my $collapsed_or_rs = $or_rs->search ({}, { distinct => 1 }); # induce collapse
 225 is ($collapsed_or_rs->all, 4, 'Collapsed joined search with OR returned correct number of rows');
 226 is ($collapsed_or_rs->count, 4, 'Collapsed search count with OR ok');
 227
 228 # make sure sure distinct on a grouped rs is warned about
 229 {
 230   my $cd_rs = $schema->resultset ('CD')
 231                 ->search ({}, { distinct => 1, group_by => 'title' });
 232   warnings_exist (sub {
 233     $cd_rs->next;
 234   }, qr/Useless use of distinct/, 'UUoD warning');
 235 }
 236
 237 {
 238   my $tcount = $schema->resultset('Track')->search(
 239     {},
 240     {
 241       select => [ qw/position title/ ],
 242       distinct => 1,
 243     }
 244   );
 245   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 246
 247   $tcount = $schema->resultset('Track')->search(
 248     {},
 249     {
 250       columns => [ qw/position title/ ],
 251       distinct => 1,
 252     }
 253   );
 254   is($tcount->count, 13, 'multiple column COUNT DISTINCT ok');
 255
 256   $tcount = $schema->resultset('Track')->search(
 257     {},
 258     {
 259        group_by => [ qw/position title/ ]
 260     }
 261   );
 262   is($tcount->count, 13, 'multiple column COUNT DISTINCT using column syntax ok');
 263 }
 264
 265 my $tag_rs = $schema->resultset('Tag')->search(
 266                [ { 'me.tag' => 'Cheesy' }, { 'me.tag' => 'Blue' } ]);
 267
 268 my $rel_rs = $tag_rs->search_related('cd', {}, { order_by => 'cd.cdid'} );
 269
 270 is($rel_rs->count, 5, 'Related search ok');
 271
 272 is($or_rs->next->cdid, $rel_rs->next->cdid, 'Related object ok');
 273 $or_rs->reset;
 274 $rel_rs->reset;
 275
 276 # at this point there should be no active statements
 277 # (finish() was called everywhere, either explicitly via
 278 # reset() or on DESTROY)
 279 for (keys %{$schema->storage->dbh->{CachedKids}}) {
 280   fail("Unreachable cached statement still active: $_")
 281     if $schema->storage->dbh->{CachedKids}{$_}->FETCH('Active');
 282 }
 283
 284 my $tag = $schema->resultset('Tag')->search(
 285   [ { 'me.tag' => 'Blue' } ],
 286   { columns => 'tagid' }
 287 )->next;
 288
 289 ok($tag->has_column_loaded('tagid'), 'Has tagid loaded');
 290 ok(!$tag->has_column_loaded('tag'), 'Has not tag loaded');
 291
 292 ok($schema->storage(), 'Storage available');
 293
 294 {
 295   my $rs = $schema->resultset("Artist")->search({
 296     -and => [
 297       artistid => { '>=', 1 },
 298       artistid => { '<', 3 }
 299     ]
 300   });
 301
 302   $rs->update({ rank => 6134 });
 303
 304   my $art;
 305
 306   $art = $schema->resultset("Artist")->find(1);
 307   is($art->rank, 6134, 'updated first artist rank');
 308
 309   $art = $schema->resultset("Artist")->find(2);
 310   is($art->rank, 6134, 'updated second artist rank');
 311 }
 312
 313 # test source_name
 314 {
 315   # source_name should be set for normal modules
 316   is($schema->source('CD')->source_name, 'CD', 'source_name is set to moniker');
 317
 318   # test the result source that sets source_name explictly
 319   ok($schema->source('SourceNameArtists'), 'SourceNameArtists result source exists');
 320
 321   my @artsn = $schema->resultset('SourceNameArtists')->search({}, { order_by => 'name DESC' });
 322   is(@artsn, 4, "Four artists returned");
 323
 324   # make sure subclasses that don't set source_name are ok
 325   ok($schema->source('ArtistSubclass'), 'ArtistSubclass exists');
 326 }
 327
 328 my $newbook = $schema->resultset( 'Bookmark' )->find(1);
 329
 330 lives_ok (sub { my $newlink = $newbook->link}, "stringify to false value doesn't cause error");
 331
 332 # test cascade_delete through many_to_many relations
 333 {
 334   my $art_del = $schema->resultset("Artist")->find({ artistid => 1 });
 335   lives_ok (sub { $art_del->delete }, 'Cascading delete on Ordered has_many works' );  # real test in ordered.t
 336   is( $schema->resultset("CD")->search({artist => 1}), 0, 'Cascading through has_many top level.');
 337   is( $schema->resultset("CD_to_Producer")->search({cd => 1}), 0, 'Cascading through has_many children.');
 338 }
 339
 340 # test column_info
 341 {
 342   $schema->source("Artist")->{_columns}{'artistid'} = {};
 343   $schema->source("Artist")->column_info_from_storage(1);
 344
 345   my $typeinfo = $schema->source("Artist")->column_info('artistid');
 346   is($typeinfo->{data_type}, 'INTEGER', 'column_info ok');
 347   $schema->source("Artist")->column_info('artistid');
 348   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 349 }
 350
 351 # test columns_info
 352 {
 353   $schema->source("Artist")->{_columns}{'artistid'} = {};
 354   $schema->source("Artist")->column_info_from_storage(1);
 355   $schema->source("Artist")->{_columns_info_loaded} = 0;
 356
 357   my @undef_default = DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE
 358     ? ()
 359     : ( default_value => undef )
 360   ;
 361
 362   is_deeply (
 363     $schema->source('Artist')->columns_info,
 364     {
 365       artistid => {
 366         data_type => "INTEGER",
 367         @undef_default,
 368         is_nullable => 0,
 369         size => undef
 370       },
 371       charfield => {
 372         data_type => "char",
 373         @undef_default,
 374         is_nullable => 1,
 375         size => 10
 376       },
 377       name => {
 378         data_type => "varchar",
 379         @undef_default,
 380         is_nullable => 1,
 381         is_numeric => 0,
 382         size => 100
 383       },
 384       rank => {
 385         data_type => "integer",
 386         default_value => 13,
 387         is_nullable => 0,
 388         size => undef
 389       },
 390     },
 391     'columns_info works',
 392   );
 393
 394   ok($schema->source("Artist")->{_columns_info_loaded} == 1, 'Columns info loaded flag set');
 395
 396   is_deeply (
 397     $schema->source('Artist')->columns_info([qw/artistid rank/]),
 398     {
 399       artistid => {
 400         data_type => "INTEGER",
 401         @undef_default,
 402         is_nullable => 0,
 403         size => undef
 404       },
 405       rank => {
 406         data_type => "integer",
 407         default_value => 13,
 408         is_nullable => 0,
 409         size => undef
 410       },
 411     },
 412     'limited columns_info works',
 413   );
 414 }
 415
 416 # test source_info
 417 {
 418   my $expected = {
 419     "source_info_key_A" => "source_info_value_A",
 420     "source_info_key_B" => "source_info_value_B",
 421     "source_info_key_C" => "source_info_value_C",
 422   };
 423
 424   my $sinfo = $schema->source("Artist")->source_info;
 425
 426   is_deeply($sinfo, $expected, 'source_info data works');
 427 }
 428
 429 # test remove_columns
 430 {
 431   is_deeply(
 432     [$schema->source('CD')->columns],
 433     [qw/cdid artist title year genreid single_track/],
 434     'initial columns',
 435   );
 436
 437   $schema->source('CD')->remove_columns('coolyear'); #should not delete year
 438   is_deeply(
 439     [$schema->source('CD')->columns],
 440     [qw/cdid artist title year genreid single_track/],
 441     'nothing removed when removing a non-existent column',
 442   );
 443
 444   $schema->source('CD')->remove_columns('genreid', 'year');
 445   is_deeply(
 446     [$schema->source('CD')->columns],
 447     [qw/cdid artist title single_track/],
 448     'removed two columns',
 449   );
 450
 451   my $priv_columns = $schema->source('CD')->_columns;
 452   ok(! exists $priv_columns->{'year'}, 'year purged from _columns');
 453   ok(! exists $priv_columns->{'genreid'}, 'genreid purged from _columns');
 454 }
 455
 456 # test resultsource->table return value when setting
 457 {
 458     my $class = $schema->class('Event');
 459     my $table = $class->table($class->table);
 460     is($table, $class->table, '->table($table) returns $table');
 461 }
 462
 463 #make sure insert doesn't use set_column
 464 {
 465   my $en_row = $schema->resultset('Encoded')->new_result({encoded => 'wilma'});
 466   is($en_row->encoded, 'amliw', 'new encodes');
 467   $en_row->insert;
 468   is($en_row->encoded, 'amliw', 'insert does not encode again');
 469 }
 470
 471 #make sure multicreate encoding still works
 472 {
 473   my $empl_rs = $schema->resultset('Employee');
 474
 475   my $empl = $empl_rs->create ({
 476     name => 'Secret holder',
 477     secretkey => {
 478       encoded => 'CAN HAZ',
 479     },
 480   });
 481   is($empl->secretkey->encoded, 'ZAH NAC', 'correctly encoding on multicreate');
 482
 483   my $empl2 = $empl_rs->create ({
 484     name => 'Same secret holder',
 485     secretkey => {
 486       encoded => 'CAN HAZ',
 487     },
 488   });
 489   is($empl2->secretkey->encoded, 'ZAH NAC', 'correctly encoding on preexisting multicreate');
 490
 491   $empl_rs->create ({
 492     name => 'cat1',
 493     secretkey => {
 494       encoded => 'CHEEZBURGER',
 495       keyholders => [
 496         {
 497           name => 'cat2',
 498         },
 499         {
 500           name => 'cat3',
 501         },
 502       ],
 503     },
 504   });
 505
 506   is($empl_rs->find({name => 'cat1'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl1');
 507   is($empl_rs->find({name => 'cat2'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl2');
 508   is($empl_rs->find({name => 'cat3'})->secretkey->encoded, 'REGRUBZEEHC', 'correct secret in database for empl3');
 509
 510 }
 511
 512 # make sure that obsolete handle-based source tracking continues to work for the time being
 513 {
 514   my $handle = $schema->source('Artist')->handle;
 515
 516   my $rowdata = { $schema->resultset('Artist')->next->get_columns };
 517
 518   my $rs = DBIx::Class::ResultSet->new($handle);
 519   my $rs_result = $rs->next;
 520   isa_ok( $rs_result, 'DBICTest::Artist' );
 521   is_deeply (
 522     { $rs_result->get_columns },
 523     $rowdata,
 524     'Correct columns retrieved (rset/source link healthy)'
 525   );
 526
 527   my $row = DBICTest::Artist->new({ -source_handle => $handle });
 528   is_deeply(
 529     { $row->get_columns },
 530     {},
 531     'No columns yet'
 532   );
 533
 534   # store_column to fool the _orig_ident tracker
 535   $row->store_column('artistid', $rowdata->{artistid});
 536   $row->in_storage(1);
 537
 538   $row->discard_changes;
 539   is_deeply(
 540     { $row->get_columns },
 541     $rowdata,
 542     'Storage refetch successful'
 543   );
 544 }
 545
 546 # test to make sure that calling ->new() on a resultset object gives
 547 # us a row object
 548 {
 549     my $new_artist = $schema->resultset('Artist')->new({});
 550     isa_ok( $new_artist, 'DBIx::Class::Row', '$rs->new gives a row object' );
 551 }
 552
 553
 554 # make sure we got rid of the compat shims
 555 SKIP: {
 556     my $remove_version = 0.083;
 557     skip "Remove in $remove_version", 3 if $DBIx::Class::VERSION < $remove_version;
 558
 559     for (qw/compare_relationship_keys pk_depends_on resolve_condition/) {
 560       ok (! DBIx::Class::ResultSource->can ($_), "$_ no longer provided by DBIx::Class::ResultSource, removed before $remove_version");
 561     }
 562 }
 563
 564 #------------------------------
 565 # READ THIS BEFORE "FIXING"
 566 #------------------------------
 567 #
 568 # make sure we got rid of discard_changes mess - this is a mess and a source
 569 # of great confusion. Here I simply die if the methods are available, which
 570 # is wrong on its own (we *have* to provide some sort of back-compat, even
 571 # if with warnings). Here is how I envision things should actually be. Also
 572 # note that a lot of the deprecation can be started today (i.e. the switch
 573 # from get_from_storage to copy_from_storage). So:
 574 #
 575 # $row->discard_changes =>
 576 #   warning, and delegation to reload_from_storage
 577 #
 578 # $row->reload_from_storage =>
 579 #   does what discard changes did in 0.08 - issues a query to the db
 580 #   and repopulates all column slots, regardless of dirty states etc.
 581 #
 582 # $row->revert_changes =>
 583 #   does what discard_changes should have done initially (before it became
 584 #   a dual-purpose call). In order to make this work we will have to
 585 #   augment $row to carry its own initial-state, much like svn has a
 586 #   copy of the current checkout in contrast to cvs.
 587 #
 588 # my $db_row = $row->get_from_storage =>
 589 #   warns and delegates to an improved name copy_from_storage, with the
 590 #   same semantics
 591 #
 592 # my $db_row = $row->copy_from_storage =>
 593 #   a much better/descriptive name than get_from_storage
 594 #
 595 #------------------------------
 596 # READ THIS BEFORE "FIXING"
 597 #------------------------------
 598 #
 599 SKIP: {
 600     skip "Something needs to be done before 0.09", 2 if $DBIx::Class::VERSION < 0.09;
 601
 602     my $row = $schema->resultset ('Artist')->next;
 603
 604     for (qw/discard_changes get_from_storage/) {
 605       ok (! $row->can ($_), "$_ needs *some* sort of facelift before 0.09 ships - current state of affairs is unacceptable");
 606     }
 607 }
 608
 609 throws_ok { $schema->resultset} qr/resultset\(\) expects a source name/, 'resultset with no argument throws exception';
 610
 611 throws_ok { $schema->source('Artist')->result_class->new( 'bugger' ) } qr/must be a hashref/;
 612
 613 done_testing;