t/53lean_startup.t

   1 # Use a require override instead of @INC munging (less common)
   2 # Do the override as early as possible so that CORE::require doesn't get compiled away
   3
   4 my ($initial_inc_contents, $expected_dbic_deps, $require_sites);
   5 BEGIN {
   6   # these envvars *will* bring in more stuff than the baseline
   7   delete @ENV{qw(DBICTEST_SQLT_DEPLOY DBIC_TRACE)};
   8
   9   unshift @INC, 't/lib';
  10   require DBICTest::Util::OverrideRequire;
  11
  12   DBICTest::Util::OverrideRequire::override_global_require( sub {
  13     my $res = $_[0]->();
  14
  15     my $req = $_[1];
  16     $req =~ s/\.pm$//;
  17     $req =~ s/\//::/g;
  18
  19     my $up = 0;
  20     my @caller;
  21     do { @caller = caller($up++) } while (
  22       @caller and (
  23         # exclude our test suite, known "module require-rs" and eval frames
  24         $caller[1] =~ /^ t [\/\\] /x
  25           or
  26         $caller[0] =~ /^ (?: base | parent | Class::C3::Componentised | Module::Inspector | Module::Runtime ) $/x
  27           or
  28         $caller[3] eq '(eval)',
  29       )
  30     );
  31
  32     push @{$require_sites->{$req}}, "$caller[1] line $caller[2]"
  33       if @caller;
  34
  35     return $res if $req =~ /^DBIx::Class|^DBICTest::/;
  36
  37     # exclude everything where the current namespace does not match the called function
  38     # (this works around very weird XS-induced require callstack corruption)
  39     if (
  40       !$initial_inc_contents->{$req}
  41         and
  42       !$expected_dbic_deps->{$req}
  43         and
  44       @caller
  45         and
  46       $caller[0] =~ /^DBIx::Class/
  47         and
  48       (caller($up))[3] =~ /\Q$caller[0]/
  49     ) {
  50       CORE::require('Test/More.pm');
  51       Test::More::fail ("Unexpected require of '$req' by $caller[0] ($caller[1] line $caller[2])");
  52
  53       if ($ENV{TEST_VERBOSE}) {
  54         CORE::require('DBICTest/Util.pm');
  55         Test::More::diag( 'Require invoked' .  DBICTest::Util::stacktrace() );
  56       }
  57     }
  58
  59     return $res;
  60   });
  61 }
  62
  63 use strict;
  64 use warnings;
  65 use Test::More;
  66
  67 use lib 't/dqlib';
  68
  69 BEGIN {
  70   plan skip_all => 'A defined PERL5OPT may inject extra deps crashing this test'
  71     if $ENV{PERL5OPT};
  72
  73   plan skip_all => 'Dependency load patterns are radically different before perl 5.10'
  74     if $] < 5.010;
  75
  76   # add what we loaded so far
  77   for (keys %INC) {
  78     my $mod = $_;
  79     $mod =~ s/\.pm$//;
  80     $mod =~ s!\/!::!g;
  81     $initial_inc_contents->{$mod} = 1;
  82   }
  83 }
  84
  85 #######
  86 ### This is where the test starts
  87 #######
  88
  89 # checking base schema load, no storage no connection
  90 {
  91   register_lazy_loadable_requires(qw(
  92     B
  93     constant
  94     overload
  95
  96     base
  97     Devel::GlobalDestruction
  98     mro
  99
 100     Carp
 101     namespace::clean
 102     Try::Tiny
 103     Sub::Name
 104
 105     Scalar::Util
 106     List::Util
 107     Data::Compare
 108
 109     Class::Accessor::Grouped
 110     Class::C3::Componentised
 111
 112     Module::Runtime
 113     Data::Query::Constants
 114     Data::Query::ExprHelpers
 115   ));
 116
 117   require DBICTest::Schema;
 118   assert_no_missing_expected_requires();
 119 }
 120
 121 # check schema/storage instantiation with no connect
 122 {
 123   register_lazy_loadable_requires(qw(
 124     Moo
 125     Sub::Quote
 126     Context::Preserve
 127   ));
 128
 129   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 130   ok (! $s->storage->connected, 'no connection');
 131   assert_no_missing_expected_requires();
 132 }
 133
 134 # do something (deploy, insert)
 135 {
 136   register_lazy_loadable_requires(qw(
 137     DBI
 138     SQL::Abstract
 139     Hash::Merge
 140   ));
 141
 142   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 143   $s->storage->dbh_do(sub {
 144     $_[1]->do('CREATE TABLE artist (
 145       "artistid" INTEGER PRIMARY KEY NOT NULL,
 146       "name" varchar(100),
 147       "rank" integer NOT NULL DEFAULT 13,
 148       "charfield" char(10)
 149     )');
 150   });
 151
 152   my $art = $s->resultset('Artist')->create({ name => \[ '?' => 'foo'], rank => 42 });
 153   $art->discard_changes;
 154   $art->update({ rank => 69, name => 'foo' });
 155   assert_no_missing_expected_requires();
 156 }
 157
 158 # and do full populate() as well, just in case - shouldn't add new stuff
 159 {
 160   local $ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER};
 161   require DBICTest;
 162   my $s = DBICTest->init_schema;
 163   is ($s->resultset('Artist')->find(1)->name, 'Caterwauler McCrae');
 164   assert_no_missing_expected_requires();
 165 }
 166
 167 done_testing;
 168
 169 sub register_lazy_loadable_requires {
 170   local $Test::Builder::Level = $Test::Builder::Level + 1;
 171
 172   for my $mod (@_) {
 173     (my $modfn = "$mod.pm") =~ s!::!\/!g;
 174     fail(join "\n",
 175       "Module $mod already loaded by require site(s):",
 176       (map { "\t$_" } @{$require_sites->{$mod}}),
 177       '',
 178     ) if $INC{$modfn} and !$initial_inc_contents->{$mod};
 179
 180     $expected_dbic_deps->{$mod}++
 181   }
 182 }
 183
 184 # check if anything we were expecting didn't actually load
 185 sub assert_no_missing_expected_requires {
 186   my $nl;
 187   for my $mod (keys %$expected_dbic_deps) {
 188     (my $modfn = "$mod.pm") =~ s/::/\//g;
 189     unless ($INC{$modfn}) {
 190       my $err = sprintf "Expected DBIC core dependency '%s' never loaded - %s needs adjustment", $mod, __FILE__;
 191       if (DBICTest::RunMode->is_smoker or DBICTest::RunMode->is_author) {
 192         fail ($err)
 193       }
 194       else {
 195         diag "\n" unless $nl->{$mod}++;
 196         diag $err;
 197       }
 198     }
 199   }
 200   pass(sprintf 'All modules expected at %s line %s loaded by DBIC: %s',
 201     __FILE__,
 202     (caller(0))[2],
 203     join (', ', sort keys %$expected_dbic_deps ),
 204   ) unless $nl;
 205 }