t/53lean_startup.t

   1 # Use a require override instead of @INC munging (less common)
   2 # Do the override as early as possible so that CORE::require doesn't get compiled away
   3 # We will replace $req_override in a bit
   4
   5 my $test_hook;
   6 BEGIN {
   7   $test_hook = sub {}; # noop at first
   8   *CORE::GLOBAL::require = sub {
   9     $test_hook->(@_);
  10     CORE::require($_[0]);
  11   };
  12 }
  13
  14 use strict;
  15 use warnings;
  16 use Test::More;
  17
  18 BEGIN {
  19   my $core_modules = { map { $_ => 1 } qw/
  20     strict
  21     warnings
  22     vars
  23
  24     base
  25     parent
  26     mro
  27     overload
  28
  29     B
  30     locale
  31
  32     namespace::clean
  33     Try::Tiny
  34     Sub::Name
  35
  36     Scalar::Util
  37     List::Util
  38     Hash::Merge
  39
  40     DBI
  41     SQL::Abstract
  42
  43     Carp
  44
  45     Class::Accessor::Grouped
  46     Class::C3::Componentised
  47   /, $] < 5.010 ? 'MRO::Compat' : () };
  48
  49   $test_hook = sub {
  50
  51     my $req = $_[0];
  52     $req =~ s/\.pm$//;
  53     $req =~ s/\//::/g;
  54
  55     return if $req =~ /^DBIx::Class|^DBICTest::Schema/;
  56
  57     my $up = 1;
  58     my @caller;
  59     do { @caller = caller($up++) } while (
  60       @caller and (
  61         $caller[0] =~ /^ (?: base | parent | Class::C3::Componentised | Module::Inspector) $/x
  62           or
  63         $caller[1] =~ / \( eval \s \d+ \) /x
  64       )
  65     );
  66
  67     if ( $caller[0] =~ /^DBIx::Class/) {
  68       fail ("Unexpected require of '$req' by $caller[0] ($caller[1] line $caller[2])")
  69         unless $core_modules->{$req};
  70     }
  71   };
  72 }
  73
  74 use lib 't/lib';
  75 use DBICTest;
  76
  77 # these envvars bring in more stuff
  78 delete $ENV{$_} for qw/
  79   DBICTEST_SQLT_DEPLOY
  80   DBIC_TRACE
  81 /;
  82
  83 my $schema = DBICTest->init_schema;
  84 is ($schema->resultset('Artist')->next->name, 'Caterwauler McCrae');
  85
  86 done_testing;