t/52leaks.t

   1 # work around brain damage in PPerl (yes, it has to be a global)
   2 $SIG{__WARN__} = sub {
   3   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   4 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   5
   6 # the persistent environments run with this flag first to see if
   7 # we will run at all (e.g. it will fail if $^X doesn't match)
   8 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
   9
  10 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  11 # We will replace $bless_override only if we are in author mode
  12 my $bless_override;
  13 BEGIN {
  14   $bless_override = sub {
  15     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  16   };
  17   *CORE::GLOBAL::bless = sub { goto $bless_override };
  18 }
  19
  20 use strict;
  21 use warnings;
  22 use Test::More;
  23
  24 my $TB = Test::More->builder;
  25 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  26   # without this explicit close older TBs warn in END after a ->reset
  27   if ($TB->VERSION < 1.005) {
  28     close ($TB->$_) for (qw/output failure_output todo_output/);
  29   }
  30
  31   # if I do not do this, I get happy sigpipes on new TB, no idea why
  32   # (the above close-and-forget doesn't work - new TB does *not* reopen
  33   # its handles automatically anymore)
  34   else {
  35     for (qw/failure_output todo_output/) {
  36       close $TB->$_;
  37       open ($TB->$_, '>&', *STDERR);
  38     }
  39
  40     close $TB->output;
  41     open ($TB->output, '>&', *STDOUT);
  42   }
  43
  44   # so done_testing can work on every persistent pass
  45   $TB->reset;
  46 }
  47
  48 use lib qw(t/lib);
  49 use DBICTest::RunMode;
  50 use DBICTest::Util::LeakTracer qw(populate_weakregistry assert_empty_weakregistry visit_refs hrefaddr);
  51 use Scalar::Util qw(weaken);
  52 use DBIx::Class;
  53 BEGIN {
  54   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  55     if DBIx::Class::_ENV_::PEEPEENESS;
  56 }
  57
  58 # this is what holds all weakened refs to be checked for leakage
  59 my $weak_registry = {};
  60
  61 # whether or to invoke IC::DT
  62 my $has_dt;
  63
  64 # Skip the heavy-duty leak tracing when just doing an install
  65 unless (DBICTest::RunMode->is_plain) {
  66
  67   # redefine the bless override so that we can catch each and every object created
  68   no warnings qw/redefine once/;
  69   no strict qw/refs/;
  70
  71   $bless_override = sub {
  72
  73     my $obj = CORE::bless(
  74       $_[0], (@_ > 1) ? $_[1] : do {
  75         my ($class, $fn, $line) = caller();
  76         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  77           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  78         $class;
  79       }
  80     );
  81
  82     # unicode is tricky, and now we happen to invoke it early via a
  83     # regex in connection()
  84     return $obj if (ref $obj) =~ /^utf8/;
  85
  86     # Test Builder is now making a new object for every pass/fail (que bloat?)
  87     # and as such we can't really store any of its objects (since it will
  88     # re-populate the registry while checking it, ewwww!)
  89     return $obj if (ref $obj) =~ /^TB2::/;
  90
  91     # populate immediately to avoid weird side effects
  92     return populate_weakregistry ($weak_registry, $obj );
  93   };
  94
  95   require Try::Tiny;
  96   for my $func (qw/try catch finally/) {
  97     my $orig = \&{"Try::Tiny::$func"};
  98     *{"Try::Tiny::$func"} = sub (&;@) {
  99       populate_weakregistry( $weak_registry, $_[0] );
 100       goto $orig;
 101     }
 102   }
 103
 104   # Some modules are known to install singletons on-load
 105   # Load them and empty the registry
 106
 107   # this loads the DT armada
 108   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for('test_dt_sqlite');
 109
 110   require Errno;
 111   require DBI;
 112   require DBD::SQLite;
 113   require FileHandle;
 114   require Moo;
 115
 116   %$weak_registry = ();
 117 }
 118
 119 {
 120   use_ok ('DBICTest');
 121
 122   my $schema = DBICTest->init_schema;
 123   my $rs = $schema->resultset ('Artist');
 124   my $storage = $schema->storage;
 125
 126   ok ($storage->connected, 'we are connected');
 127
 128   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 129   ok ($row_obj, 'row from db');
 130
 131   # txn_do to invoke more codepaths
 132   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 133
 134     my $artist = $schema->resultset('Artist')->create ({
 135       name => 'foo artist',
 136       cds => [{
 137         title => 'foo cd',
 138         year => 1984,
 139         tracks => [
 140           { title => 't1' },
 141           { title => 't2' },
 142         ],
 143         genre => { name => 'mauve' },
 144       }],
 145     });
 146
 147     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 148
 149     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 150
 151     return ($artist, $pg, $pg_wcount);
 152   });
 153
 154   # more codepaths - error handling in txn_do
 155   {
 156     eval { $schema->txn_do ( sub {
 157       $storage->_dbh->begin_work;
 158       fail ('how did we get so far?!');
 159     } ) };
 160
 161     eval { $schema->txn_do ( sub {
 162       $schema->txn_do ( sub {
 163         die "It's called EXCEPTION";
 164         fail ('how did we get so far?!');
 165       } );
 166       fail ('how did we get so far?!');
 167     } ) };
 168     like( $@, qr/It\'s called EXCEPTION/, 'Exception correctly propagated in nested txn_do' );
 169   }
 170
 171   # dbh_do codepath
 172   my ($rs_bind_circref, $cond_rowobj) = $schema->storage->dbh_do ( sub {
 173     my $row = $_[0]->schema->resultset('Artist')->new({});
 174     my $rs = $_[0]->schema->resultset('Artist')->search({
 175       name => $row,  # this is deliberately bogus, see FIXME below!
 176     });
 177     return ($rs, $row);
 178   });
 179
 180   is ($pager->next_page, 3, 'There is one more page available');
 181
 182   # based on 66 per 10 pages
 183   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 184
 185   # do some population (invokes some extra codepaths)
 186   # also exercise the guard code and the manual txn control
 187   {
 188     my $guard = $schema->txn_scope_guard;
 189     # populate with bindvars
 190     $rs->populate([{ name => 'James Bound' }]);
 191     $guard->commit;
 192
 193     $schema->txn_begin;
 194     # populate mixed
 195     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 196     $schema->txn_commit;
 197
 198     $schema->txn_begin;
 199     # and without bindvars
 200     $rs->populate([{ name => \ '"James Unbound"' }]);
 201     $schema->txn_rollback;
 202   }
 203
 204   # prefetching
 205   my $cds_rs = $schema->resultset('CD');
 206   my $cds_with_artist = $cds_rs->search({}, { prefetch => 'artist' });
 207   my $cds_with_tracks = $cds_rs->search({}, { prefetch => 'tracks' });
 208   my $cds_with_stuff = $cds_rs->search({}, { prefetch => [ 'genre', { artist => { cds => { tracks => 'cd_single' } } } ] });
 209
 210   # implicit pref
 211   my $cds_with_impl_artist = $cds_rs->search({}, { columns => [qw/me.title artist.name/], join => 'artist' });
 212
 213   # get_column
 214   my $getcol_rs = $cds_rs->get_column('me.cdid');
 215   my $pref_getcol_rs = $cds_with_stuff->get_column('me.cdid');
 216
 217   # fire the column getters
 218   my @throwaway = $pref_getcol_rs->all;
 219
 220   my $base_collection = {
 221     resultset => $rs,
 222
 223     pref_precursor => $cds_rs,
 224
 225     pref_rs_single => $cds_with_artist,
 226     pref_rs_multi => $cds_with_tracks,
 227     pref_rs_nested => $cds_with_stuff,
 228
 229     pref_rs_implicit => $cds_with_impl_artist,
 230
 231     pref_row_single => $cds_with_artist->next,
 232     pref_row_multi => $cds_with_tracks->next,
 233     pref_row_nested => $cds_with_stuff->next,
 234
 235     # even though this does not leak Storable croaks on it :(((
 236     #pref_row_implicit => $cds_with_impl_artist->next,
 237
 238     get_column_rs_plain => $getcol_rs,
 239     get_column_rs_pref => $pref_getcol_rs,
 240
 241     # twice so that we make sure only one H::M object spawned
 242     chained_resultset => $rs->search_rs ({}, { '+columns' => [ 'foo' ] } ),
 243     chained_resultset2 => $rs->search_rs ({}, { '+columns' => [ 'bar' ] } ),
 244
 245     row_object => $row_obj,
 246
 247     mc_row_object => $mc_row_obj,
 248
 249     result_source => $rs->result_source,
 250
 251     result_source_handle => $rs->result_source->handle,
 252
 253     pager_explicit_count => $pager_explicit_count,
 254
 255     leaky_resultset => $rs_bind_circref,
 256     leaky_resultset_cond => $cond_rowobj,
 257   };
 258
 259   # this needs to fire, even if it can't find anything
 260   # see FIXME below
 261   $rs_bind_circref->next;
 262
 263   require Storable;
 264   %$base_collection = (
 265     %$base_collection,
 266     refrozen => Storable::dclone( $base_collection ),
 267     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 268     pref_row_implicit => $cds_with_impl_artist->next,
 269     schema => $schema,
 270     storage => $storage,
 271     sql_maker => $storage->sql_maker,
 272     dbh => $storage->_dbh,
 273     fresh_pager => $rs->page(5)->pager,
 274     pager => $pager,
 275   );
 276
 277   # FIXME - ideally this kind of collector ought to be global, but attempts
 278   # with an invasive debugger-based tracer did not quite work out... yet
 279   # Manually scan the innards of everything we have in the base collection
 280   # we assembled so far (skip the DT madness below) *recursively*
 281   #
 282   # Only do this when we do have the bits to look inside CVs properly,
 283   # without it we are liable to pick up object defaults that are locked
 284   # in method closures
 285   if (DBICTest::Util::LeakTracer::CV_TRACING) {
 286     visit_refs(
 287       refs => [ $base_collection ],
 288       action => sub {
 289         populate_weakregistry ($weak_registry, $_[0]);
 290         1;  # true means "keep descending"
 291       },
 292     );
 293   }
 294
 295   if ($has_dt) {
 296     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 297
 298     my $now = DateTime->now;
 299     for (1..5) {
 300       $base_collection->{"icdt_row_$_"} = $rs->create({
 301         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 302         starts_at => $now->clone->add(days => $_),
 303       });
 304     }
 305
 306     # re-search
 307     my @dummy = $rs->all;
 308   }
 309
 310   # dbh's are created in XS space, so pull them separately
 311   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 312     $base_collection->{"DBI handle $_"} = $_;
 313   }
 314
 315   populate_weakregistry ($weak_registry, $base_collection->{$_}, "basic $_")
 316     for keys %$base_collection;
 317 }
 318
 319 # check that "phantom-chaining" works - we never lose track of the original $schema
 320 # and have access to the entire tree without leaking anything
 321 {
 322   my $phantom;
 323   for (
 324     sub { DBICTest->init_schema( sqlite_use_file => 0 ) },
 325     sub { shift->source('Artist') },
 326     sub { shift->resultset },
 327     sub { shift->result_source },
 328     sub { shift->schema },
 329     sub { shift->resultset('Artist') },
 330     sub { shift->find_or_create({ name => 'detachable' }) },
 331     sub { shift->result_source },
 332     sub { shift->schema },
 333     sub { shift->clone },
 334     sub { shift->resultset('CD') },
 335     sub { shift->next },
 336     sub { shift->artist },
 337     sub { shift->search_related('cds') },
 338     sub { shift->next },
 339     sub { shift->search_related('artist') },
 340     sub { shift->result_source },
 341     sub { shift->resultset },
 342     sub { shift->create({ name => 'detached' }) },
 343     sub { shift->update({ name => 'reattached' }) },
 344     sub { shift->discard_changes },
 345     sub { shift->delete },
 346     sub { shift->insert },
 347   ) {
 348     $phantom = populate_weakregistry ( $weak_registry, scalar $_->($phantom) );
 349   }
 350
 351   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 352   is( $phantom->name, 'reattached', 'Still correct name' );
 353 }
 354
 355 # Naturally we have some exceptions
 356 my $cleared;
 357 for my $addr (keys %$weak_registry) {
 358   my $names = join "\n", keys %{$weak_registry->{$addr}{slot_names}};
 359
 360   if ($names =~ /^Test::Builder/m) {
 361     # T::B 2.0 has result objects and other fancyness
 362     delete $weak_registry->{$addr};
 363   }
 364   elsif ($names =~ /^Hash::Merge/m) {
 365     # only clear one object of a specific behavior - more would indicate trouble
 366     delete $weak_registry->{$addr}
 367       unless $cleared->{hash_merge_singleton}{$weak_registry->{$addr}{weakref}{behavior}}++;
 368   }
 369 }
 370
 371 # FIXME !!!
 372 # There is an actual strong circular reference taking place here, but because
 373 # half of it is in XS, so it is a bit harder to track down (it stumps D::FR)
 374 # (our tracker does not yet do it, but it'd be nice)
 375 # The problem is:
 376 #
 377 # $cond_object --> result_source --> schema --> storage --> $dbh --> {CachedKids}
 378 #          ^                                                           /
 379 #           \-------- bound value on prepared/cached STH  <-----------/
 380 #
 381 {
 382   my @circreffed;
 383
 384   for my $r (map
 385     { $_->{weakref} }
 386     grep
 387       { $_->{slot_names}{'basic leaky_resultset_cond'} }
 388       values %$weak_registry
 389   ) {
 390     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 391     ok(! defined $r, 'Self-referential RS conditions no longer leak!')
 392       or push @circreffed, $r;
 393   }
 394
 395   if (@circreffed) {
 396     is (scalar @circreffed, 1, 'One resultset expected to leak');
 397
 398     # this is useless on its own, it is to showcase the circref-diag
 399     # and eventually test it when it is operational
 400     local $TODO = 'Needs Data::Entangled or somesuch - see RT#82942';
 401     while (@circreffed) {
 402       weaken (my $r = shift @circreffed);
 403
 404       populate_weakregistry( (my $mini_registry = {}), $r );
 405       assert_empty_weakregistry( $mini_registry );
 406
 407       $r->result_source(undef);
 408     }
 409   }
 410 }
 411
 412 assert_empty_weakregistry ($weak_registry);
 413
 414 # we got so far without a failure - this is a good thing
 415 # now let's try to rerun this script under a "persistent" environment
 416 # this is ugly and dirty but we do not yet have a Test::Embedded or
 417 # similar
 418
 419 # set up -I
 420 require Config;
 421 $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 422 ($ENV{PATH}) = $ENV{PATH} =~ /(.+)/;
 423
 424
 425 my $persistence_tests = {
 426   PPerl => {
 427     cmd => [qw/pperl --prefork=1/, __FILE__],
 428   },
 429   'CGI::SpeedyCGI' => {
 430     cmd => [qw/speedy -- -t5/, __FILE__],
 431   },
 432 };
 433
 434 # scgi is smart and will auto-reap after -t amount of seconds
 435 # pperl needs an actual killer :(
 436 $persistence_tests->{PPerl}{termcmd} = [
 437   $persistence_tests->{PPerl}{cmd}[0],
 438   '--kill',
 439   @{$persistence_tests->{PPerl}{cmd}}[ 1 .. $#{$persistence_tests->{PPerl}{cmd}} ],
 440 ];
 441
 442 SKIP: {
 443   skip 'Test already in a persistent loop', 1
 444     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 445
 446   skip 'Main test failed - skipping persistent env tests', 1
 447     unless $TB->is_passing;
 448
 449   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 450
 451   require IPC::Open2;
 452
 453   for my $type (keys %$persistence_tests) { SKIP: {
 454     unless (eval "require $type") {
 455       # Don't terminate what we didn't start
 456       delete $persistence_tests->{$type}{termcmd};
 457       skip "$type module not found", 1;
 458     }
 459
 460     my @cmd = @{$persistence_tests->{$type}{cmd}};
 461
 462     # since PPerl is racy and sucks - just prime the "server"
 463     {
 464       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 465       system(@cmd);
 466       sleep 1;
 467
 468       # see if the thing actually runs, if not - might as well bail now
 469       skip "Something is wrong with $type ($!)", 1
 470         if system(@cmd);
 471     }
 472
 473     for (1,2,3) {
 474       note ("Starting run in persistent env ($type pass $_)");
 475       IPC::Open2::open2(my $out, undef, @cmd);
 476       my @out_lines;
 477       while (my $ln = <$out>) {
 478         next if $ln =~ /^\s*$/;
 479         push @out_lines, "   $ln";
 480         last if $ln =~ /^\d+\.\.\d+$/;  # this is persistence, we need to terminate reading on our end
 481       }
 482       print $_ for @out_lines;
 483       close $out;
 484       wait;
 485       ok (!$?, "Run in persistent env ($type pass $_): exit $?");
 486       ok (scalar @out_lines, "Run in persistent env ($type pass $_): got output");
 487     }
 488
 489     ok (! system (@{$persistence_tests->{$type}{termcmd}}), "killed $type server instance")
 490       if $persistence_tests->{$type}{termcmd};
 491   }}
 492 }
 493
 494 done_testing;
 495
 496 # just an extra precaution in case we blew away from the SKIP - since there are no
 497 # PID files to go by (man does pperl really suck :(
 498 END {
 499   unless ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
 500     close $_ for (*STDIN, *STDOUT, *STDERR);
 501     local $?; # otherwise test will inherit $? of the system()
 502     system (@{$persistence_tests->{PPerl}{termcmd}})
 503       if $persistence_tests->{PPerl}{termcmd};
 504   }
 505 }