t/51threadtxn.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Config;
   5
   6 # README: If you set the env var to a number greater than 10,
   7 #   we will use that many children
   8
   9 BEGIN {
  10     plan skip_all => 'Your perl does not support ithreads'
  11         if !$Config{useithreads};
  12 }
  13
  14 BEGIN {
  15     plan skip_all => 'Minimum of perl 5.8.3 required for thread tests (DBD::Pg mandated)'
  16         if $] < '5.008003';
  17 }
  18
  19
  20 use threads;
  21 use lib qw(t/lib);
  22
  23 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  24 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  25       . ' (note: creates and drops a table named artist!)' unless ($dsn && $user);
  26
  27
  28 my $num_children = $ENV{DBICTEST_THREAD_STRESS} || 1;
  29 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  30    $num_children = 10;
  31 }
  32
  33 use_ok('DBICTest::Schema');
  34
  35 diag "\n\nIt is ok if you see series of 'Attempt to free unreferenced scalar: ...' warnings during this test\n "
  36   if $] < '5.008005';
  37
  38 my $schema = DBICTest::Schema->connection($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  39
  40 my $parent_rs;
  41
  42 eval {
  43     my $dbh = $schema->storage->dbh;
  44
  45     {
  46         local $SIG{__WARN__} = sub {};
  47         eval { $dbh->do("DROP TABLE cd") };
  48         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  49     }
  50
  51     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  52     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  53
  54     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  55     $parent_rs->next;
  56 };
  57 ok(!$@) or diag "Creation eval failed: $@";
  58
  59 my @children;
  60 while(@children < $num_children) {
  61
  62     my $newthread = async {
  63         my $tid = threads->tid;
  64         # my $dbh = $schema->storage->dbh;
  65
  66         $schema->txn_do(sub {
  67             my $child_rs = $schema->resultset('CD')->search({ year => 1901 });
  68             my $row = $parent_rs->next;
  69             if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  70                 $schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  71             }
  72         });
  73         sleep(3);
  74     };
  75     die "Thread creation failed: $! $@" if !defined $newthread;
  76     push(@children, $newthread);
  77 }
  78
  79 ok(1, "past spawning");
  80
  81 {
  82     $_->join for(@children);
  83 }
  84
  85 ok(1, "past joining");
  86
  87 while(@children) {
  88     my $child = pop(@children);
  89     my $tid = $child->tid;
  90     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  91     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  92 }
  93
  94 ok(1, "Made it to the end");
  95
  96 $schema->storage->dbh->do("DROP TABLE cd");
  97
  98 done_testing;