t/51threads.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5
   6 use Config;
   7 BEGIN {
   8     plan skip_all => 'Your perl does not support ithreads'
   9         if !$Config{useithreads};
  10 }
  11
  12 BEGIN {
  13     plan skip_all => 'Minimum of perl 5.8.3 required for thread tests (DBD::Pg mandated)'
  14         if $] < '5.008003';
  15 }
  16
  17 use threads;
  18 use Test::Exception;
  19 use lib qw(t/lib);
  20
  21 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  22 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  23       . ' (note: creates and drops a table named artist!)' unless ($dsn && $user);
  24
  25 # README: If you set the env var to a number greater than 10,
  26 #   we will use that many children
  27 my $num_children = $ENV{DBICTEST_THREAD_STRESS} || 1;
  28 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  29    $num_children = 10;
  30 }
  31
  32 use_ok('DBICTest::Schema');
  33
  34 diag "\n\nIt is ok if you see series of 'Attempt to free unreferenced scalar: ...' warnings during this test\n "
  35   if $] < '5.008005';
  36
  37 my $schema = DBICTest::Schema->connection($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  38
  39 my $parent_rs;
  40
  41 lives_ok (sub {
  42     my $dbh = $schema->storage->dbh;
  43
  44     {
  45         local $SIG{__WARN__} = sub {};
  46         eval { $dbh->do("DROP TABLE cd") };
  47         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  48     }
  49
  50     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  51     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  52
  53     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  54     $parent_rs->next;
  55 }, 'populate successfull');
  56
  57 my @children;
  58 while(@children < $num_children) {
  59
  60     my $newthread = async {
  61         my $tid = threads->tid;
  62
  63         my $child_rs = $schema->resultset('CD')->search({ year => 1901 });
  64         my $row = $parent_rs->next;
  65         if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  66             $schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  67         }
  68         sleep(3);
  69     };
  70     die "Thread creation failed: $! $@" if !defined $newthread;
  71     push(@children, $newthread);
  72 }
  73
  74 ok(1, "past spawning");
  75
  76 {
  77     $_->join for(@children);
  78 }
  79
  80 ok(1, "past joining");
  81
  82 while(@children) {
  83     my $child = pop(@children);
  84     my $tid = $child->tid;
  85     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  86     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  87 }
  88
  89 ok(1, "Made it to the end");
  90
  91 $schema->storage->dbh->do("DROP TABLE cd");
  92
  93 done_testing;