t/070_native_traits/013_array_coerce.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6
   7 {
   8
   9     package Foo;
  10     use Moose;
  11     use Moose::Util::TypeConstraints;
  12
  13     subtype 'UCArray', as 'ArrayRef[Str]', where {
  14         !grep {/[a-z]/} @{$_};
  15     };
  16
  17     coerce 'UCArray', from 'ArrayRef[Str]', via {
  18         [ map { uc $_ } @{$_} ];
  19     };
  20
  21     has array => (
  22         traits  => ['Array'],
  23         is      => 'rw',
  24         isa     => 'UCArray',
  25         coerce  => 1,
  26         handles => {
  27             push_array => 'push',
  28             set_array  => 'set',
  29         },
  30     );
  31
  32     our @TriggerArgs;
  33
  34     has lazy => (
  35         traits  => ['Array'],
  36         is      => 'rw',
  37         isa     => 'UCArray',
  38         coerce  => 1,
  39         lazy    => 1,
  40         default => sub { ['a'] },
  41         handles => {
  42             push_lazy => 'push',
  43             set_lazy  => 'set',
  44         },
  45         trigger => sub { @TriggerArgs = @_ },
  46         clearer => 'clear_lazy',
  47     );
  48 }
  49
  50 my $foo = Foo->new;
  51
  52 {
  53     $foo->array( [qw( A B C )] );
  54
  55     $foo->push_array('d');
  56
  57     is_deeply(
  58         $foo->array, [qw( A B C D )],
  59         'push coerces the array'
  60     );
  61
  62     $foo->set_array( 1 => 'x' );
  63
  64     is_deeply(
  65         $foo->array, [qw( A X C D )],
  66         'set coerces the array'
  67     );
  68 }
  69
  70 {
  71     $foo->push_lazy('d');
  72
  73     is_deeply(
  74         $foo->lazy, [qw( A D )],
  75         'push coerces the array - lazy'
  76     );
  77
  78     is_deeply(
  79         \@Foo::TriggerArgs,
  80         [ $foo, [qw( A D )], ['A'] ],
  81         'trigger receives expected arguments'
  82     );
  83
  84     $foo->set_lazy( 2 => 'f' );
  85
  86     is_deeply(
  87         $foo->lazy, [qw( A D F )],
  88         'set coerces the array - lazy'
  89     );
  90
  91     is_deeply(
  92         \@Foo::TriggerArgs,
  93         [ $foo, [qw( A D F )], [qw( A D )] ],
  94         'trigger receives expected arguments'
  95     );
  96 }
  97
  98 {
  99     package Thing;
 100     use Moose;
 101
 102     has thing => (
 103         is  => 'ro',
 104         isa => 'Str',
 105     );
 106 }
 107
 108 {
 109     package Bar;
 110     use Moose;
 111     use Moose::Util::TypeConstraints;
 112
 113     class_type 'Thing';
 114
 115     coerce 'Thing'
 116         => from 'Str'
 117         => via { Thing->new( thing => $_ ) };
 118
 119     subtype 'ArrayRefOfThings'
 120         => as 'ArrayRef[Thing]'
 121         => where { scalar(@$_) < 5 };
 122
 123     coerce 'ArrayRefOfThings'
 124         => from 'ArrayRef[Str]'
 125         => via { [ map { Thing->new( thing => $_ ) } @{$_} ] };
 126
 127     coerce 'ArrayRefOfThings'
 128         => from 'Str'
 129         => via { [ Thing->new( thing => $_ ) ] };
 130
 131     has array => (
 132         traits  => ['Array'],
 133         is      => 'rw',
 134         isa     => 'ArrayRefOfThings',
 135         coerce  => 1,
 136         handles => {
 137             push_array => 'push',
 138             set_array  => 'set',
 139             get_array  => 'get',
 140         },
 141     );
 142 }
 143
 144 TODO: {
 145     my $bar = Bar->new( array => [qw( a b c )] );
 146
 147     todo_skip 'coercion in push dies here!', 2;
 148
 149     $bar->push_array('d');
 150
 151     is( $bar->get_array(3)->thing, 'd', 'push coerces the array' );
 152
 153     dies_ok { $bar->push_array('e') }
 154         'the type constraint prohibits arrays of length 5';
 155 }
 156
 157 done_testing;