t/070_native_traits/013_array_coerce.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6
   7 {
   8
   9     package Foo;
  10     use Moose;
  11     use Moose::Util::TypeConstraints;
  12
  13     subtype 'UCArray', as 'ArrayRef[Str]', where {
  14         !grep {/[a-z]/} @{$_};
  15     };
  16
  17     coerce 'UCArray', from 'ArrayRef[Str]', via {
  18         [ map { uc $_ } @{$_} ];
  19     };
  20
  21     has array => (
  22         traits  => ['Array'],
  23         is      => 'rw',
  24         isa     => 'UCArray',
  25         coerce  => 1,
  26         handles => {
  27             push_array => 'push',
  28             set_array  => 'set',
  29         },
  30     );
  31
  32     our @TriggerArgs;
  33
  34     has lazy => (
  35         traits  => ['Array'],
  36         is      => 'rw',
  37         isa     => 'UCArray',
  38         coerce  => 1,
  39         lazy    => 1,
  40         default => sub { ['a'] },
  41         handles => {
  42             push_lazy => 'push',
  43             set_lazy  => 'set',
  44         },
  45         trigger => sub { @TriggerArgs = @_ },
  46         clearer => 'clear_lazy',
  47     );
  48 }
  49
  50 my $foo = Foo->new;
  51
  52 {
  53     $foo->array( [qw( A B C )] );
  54
  55     $foo->push_array('d');
  56
  57     is_deeply(
  58         $foo->array, [qw( A B C D )],
  59         'push coerces the array'
  60     );
  61
  62     $foo->set_array( 1 => 'x' );
  63
  64     is_deeply(
  65         $foo->array, [qw( A X C D )],
  66         'set coerces the array'
  67     );
  68 }
  69
  70 {
  71     $foo->push_lazy('d');
  72
  73     is_deeply(
  74         $foo->lazy, [qw( A D )],
  75         'push coerces the array - lazy'
  76     );
  77
  78     is_deeply(
  79         \@Foo::TriggerArgs,
  80         [ $foo, [qw( A D )], ['A'] ],
  81         'trigger receives expected arguments'
  82     );
  83
  84     $foo->set_lazy( 2 => 'f' );
  85
  86     is_deeply(
  87         $foo->lazy, [qw( A D F )],
  88         'set coerces the array - lazy'
  89     );
  90
  91     is_deeply(
  92         \@Foo::TriggerArgs,
  93         [ $foo, [qw( A D F )], [qw( A D )] ],
  94         'trigger receives expected arguments'
  95     );
  96 }
  97
  98 {
  99     package Thing;
 100     use Moose;
 101
 102     has thing => (
 103         is => 'ro', isa => 'Str',
 104     );
 105 }
 106
 107 {
 108     package Bar;
 109     use Moose;
 110     use Moose::Util::TypeConstraints;
 111
 112     class_type 'Thing';
 113
 114     coerce 'Thing'
 115         => from 'Str'
 116         => via { Thing->new(thing => $_) };
 117
 118     subtype 'ArrayRefOfThings'
 119         => as 'ArrayRef[Thing]';
 120
 121     coerce 'ArrayRefOfThings'
 122         => from 'ArrayRef[Str]'
 123         => via { [ map { Thing->new(thing => $_) } @$_ ] };
 124
 125     coerce 'ArrayRefOfThings'
 126         => from 'Str'
 127         => via { [ Thing->new(thing => $_) ] };
 128
 129     coerce 'ArrayRefOfThings'
 130         => from 'Thing'
 131         => via { [ $_ ] };
 132
 133     has array => (
 134         traits  => ['Array'],
 135         is      => 'rw',
 136         isa     => 'ArrayRefOfThings',
 137         coerce  => 1,
 138         handles => {
 139             push_array => 'push',
 140             set_array  => 'set',
 141             get_array  => 'get',
 142         },
 143     );
 144 }
 145
 146 TODO: {
 147     my $bar = Bar->new( array => [qw( a b c )] );
 148
 149     todo_skip 'coercion in push dies here!', 1;
 150
 151     $bar->push_array('d');
 152
 153     is( $bar->get_array(3)->thing, 'd', 'push coerces the array' );
 154 }
 155
 156 done_testing;