t/050_metaclasses/004_moose_for_meta.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8
   9
  10 =pod
  11
  12 This test demonstrates the ability to extend
  13 Moose meta-level classes using Moose itself.
  14
  15 =cut
  16
  17 {
  18     package My::Meta::Class;
  19     use Moose;
  20
  21     extends 'Moose::Meta::Class';
  22
  23     around 'create_anon_class' => sub {
  24         my $next = shift;
  25         my ($self, %options) = @_;
  26         $options{superclasses} = [ 'Moose::Object' ]
  27             unless exists $options{superclasses};
  28         $next->($self, %options);
  29     };
  30 }
  31
  32 my $anon = My::Meta::Class->create_anon_class();
  33 isa_ok($anon, 'My::Meta::Class');
  34 isa_ok($anon, 'Moose::Meta::Class');
  35 isa_ok($anon, 'Class::MOP::Class');
  36
  37 is_deeply(
  38     [ $anon->superclasses ],
  39     [ 'Moose::Object' ],
  40     '... got the default superclasses');
  41
  42 {
  43     package My::Meta::Attribute::DefaultReadOnly;
  44     use Moose;
  45
  46     extends 'Moose::Meta::Attribute';
  47
  48     around 'new' => sub {
  49         my $next = shift;
  50         my ($self, $name, %options) = @_;
  51         $options{is} = 'ro'
  52             unless exists $options{is};
  53         $next->($self, $name, %options);
  54     };
  55 }
  56
  57 {
  58     my $attr = My::Meta::Attribute::DefaultReadOnly->new('foo');
  59     isa_ok($attr, 'My::Meta::Attribute::DefaultReadOnly');
  60     isa_ok($attr, 'Moose::Meta::Attribute');
  61     isa_ok($attr, 'Class::MOP::Attribute');
  62
  63     ok($attr->has_reader, '... the attribute has a reader (as expected)');
  64     ok(!$attr->has_writer, '... the attribute does not have a writer (as expected)');
  65     ok(!$attr->has_accessor, '... the attribute does not have an accessor (as expected)');
  66 }
  67
  68 {
  69     my $attr = My::Meta::Attribute::DefaultReadOnly->new('foo', (is => 'rw'));
  70     isa_ok($attr, 'My::Meta::Attribute::DefaultReadOnly');
  71     isa_ok($attr, 'Moose::Meta::Attribute');
  72     isa_ok($attr, 'Class::MOP::Attribute');
  73
  74     ok(!$attr->has_reader, '... the attribute does not have a reader (as expected)');
  75     ok(!$attr->has_writer, '... the attribute does not have a writer (as expected)');
  76     ok($attr->has_accessor, '... the attribute does have an accessor (as expected)');
  77 }
  78
  79 done_testing;