t/030_roles/003_apply_role.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8
   9 {
  10     package FooRole;
  11     use Moose::Role;
  12
  13     our $VERSION = 23;
  14
  15     has 'bar' => ( is => 'rw', isa => 'FooClass' );
  16     has 'baz' => ( is => 'ro' );
  17
  18     sub goo {'FooRole::goo'}
  19     sub foo {'FooRole::foo'}
  20
  21     override 'boo' => sub { 'FooRole::boo -> ' . super() };
  22
  23     around 'blau' => sub {
  24         my $c = shift;
  25         'FooRole::blau -> ' . $c->();
  26     };
  27 }
  28
  29 {
  30     package BarRole;
  31     use Moose::Role;
  32     sub woot {'BarRole::woot'}
  33 }
  34
  35 {
  36     package BarClass;
  37     use Moose;
  38
  39     sub boo {'BarClass::boo'}
  40     sub foo {'BarClass::foo'}    # << the role overrides this ...
  41 }
  42
  43 {
  44     package FooClass;
  45     use Moose;
  46
  47     extends 'BarClass';
  48
  49     ::throws_ok { with 'FooRole' => { -version => 42 } }
  50         qr/FooRole version 42 required--this is only version 23/,
  51         'applying role with unsatisfied version requirement';
  52
  53     ::lives_ok { with 'FooRole' => { -version => 13 } }
  54         'applying role with satisfied version requirement';
  55
  56     sub blau {'FooClass::blau'}    # << the role wraps this ...
  57
  58     sub goo {'FooClass::goo'}      # << overrides the one from the role ...
  59 }
  60
  61 {
  62     package FooBarClass;
  63     use Moose;
  64
  65     extends 'FooClass';
  66     with 'FooRole', 'BarRole';
  67 }
  68
  69 my $foo_class_meta = FooClass->meta;
  70 isa_ok( $foo_class_meta, 'Moose::Meta::Class' );
  71
  72 my $foobar_class_meta = FooBarClass->meta;
  73 isa_ok( $foobar_class_meta, 'Moose::Meta::Class' );
  74
  75 dies_ok {
  76     $foo_class_meta->does_role();
  77 }
  78 '... does_role requires a role name';
  79
  80 dies_ok {
  81     $foo_class_meta->add_role();
  82 }
  83 '... apply_role requires a role';
  84
  85 dies_ok {
  86     $foo_class_meta->add_role( bless( {} => 'Fail' ) );
  87 }
  88 '... apply_role requires a role';
  89
  90 ok( $foo_class_meta->does_role('FooRole'),
  91     '... the FooClass->meta does_role FooRole' );
  92 ok( !$foo_class_meta->does_role('OtherRole'),
  93     '... the FooClass->meta !does_role OtherRole' );
  94
  95 ok( $foobar_class_meta->does_role('FooRole'),
  96     '... the FooBarClass->meta does_role FooRole' );
  97 ok( $foobar_class_meta->does_role('BarRole'),
  98     '... the FooBarClass->meta does_role BarRole' );
  99 ok( !$foobar_class_meta->does_role('OtherRole'),
 100     '... the FooBarClass->meta !does_role OtherRole' );
 101
 102 foreach my $method_name (qw(bar baz foo boo blau goo)) {
 103     ok( $foo_class_meta->has_method($method_name),
 104         '... FooClass has the method ' . $method_name );
 105     ok( $foobar_class_meta->has_method($method_name),
 106         '... FooBarClass has the method ' . $method_name );
 107 }
 108
 109 ok( !$foo_class_meta->has_method('woot'),
 110     '... FooClass lacks the method woot' );
 111 ok( $foobar_class_meta->has_method('woot'),
 112     '... FooBarClass has the method woot' );
 113
 114 foreach my $attr_name (qw(bar baz)) {
 115     ok( $foo_class_meta->has_attribute($attr_name),
 116         '... FooClass has the attribute ' . $attr_name );
 117     ok( $foobar_class_meta->has_attribute($attr_name),
 118         '... FooBarClass has the attribute ' . $attr_name );
 119 }
 120
 121 can_ok( 'FooClass', 'does' );
 122 ok( FooClass->does('FooRole'),    '... the FooClass does FooRole' );
 123 ok( !FooClass->does('BarRole'),   '... the FooClass does not do BarRole' );
 124 ok( !FooClass->does('OtherRole'), '... the FooClass does not do OtherRole' );
 125
 126 can_ok( 'FooBarClass', 'does' );
 127 ok( FooBarClass->does('FooRole'), '... the FooClass does FooRole' );
 128 ok( FooBarClass->does('BarRole'), '... the FooBarClass does FooBarRole' );
 129 ok( !FooBarClass->does('OtherRole'),
 130     '... the FooBarClass does not do OtherRole' );
 131
 132 my $foo = FooClass->new();
 133 isa_ok( $foo, 'FooClass' );
 134
 135 my $foobar = FooBarClass->new();
 136 isa_ok( $foobar, 'FooBarClass' );
 137
 138 is( $foo->goo,    'FooClass::goo', '... got the right value of goo' );
 139 is( $foobar->goo, 'FooRole::goo',  '... got the right value of goo' );
 140
 141 is( $foo->boo, 'FooRole::boo -> BarClass::boo',
 142     '... got the right value from ->boo' );
 143 is( $foobar->boo, 'FooRole::boo -> FooRole::boo -> BarClass::boo',
 144     '... got the right value from ->boo (double wrapped)' );
 145
 146 is( $foo->blau, 'FooRole::blau -> FooClass::blau',
 147     '... got the right value from ->blau' );
 148 is( $foobar->blau, 'FooRole::blau -> FooRole::blau -> FooClass::blau',
 149     '... got the right value from ->blau' );
 150
 151 foreach my $foo ( $foo, $foobar ) {
 152     can_ok( $foo, 'does' );
 153     ok( $foo->does('FooRole'), '... an instance of FooClass does FooRole' );
 154     ok( !$foo->does('OtherRole'),
 155         '... and instance of FooClass does not do OtherRole' );
 156
 157     can_ok( $foobar, 'does' );
 158     ok( $foobar->does('FooRole'),
 159         '... an instance of FooBarClass does FooRole' );
 160     ok( $foobar->does('BarRole'),
 161         '... an instance of FooBarClass does BarRole' );
 162     ok( !$foobar->does('OtherRole'),
 163         '... and instance of FooBarClass does not do OtherRole' );
 164
 165     for my $method (qw/bar baz foo boo goo blau/) {
 166         can_ok( $foo, $method );
 167     }
 168
 169     is( $foo->foo, 'FooRole::foo', '... got the right value of foo' );
 170
 171     ok( !defined( $foo->baz ), '... $foo->baz is undefined' );
 172     ok( !defined( $foo->bar ), '... $foo->bar is undefined' );
 173
 174     dies_ok {
 175         $foo->baz(1);
 176     }
 177     '... baz is a read-only accessor';
 178
 179     dies_ok {
 180         $foo->bar(1);
 181     }
 182     '... bar is a read-write accessor with a type constraint';
 183
 184     my $foo2 = FooClass->new();
 185     isa_ok( $foo2, 'FooClass' );
 186
 187     lives_ok {
 188         $foo->bar($foo2);
 189     }
 190     '... bar is a read-write accessor with a type constraint';
 191
 192     is( $foo->bar, $foo2, '... got the right value for bar now' );
 193 }
 194
 195 done_testing;