t/000_recipes/004_company.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7
   8 BEGIN {
   9     eval "use Regexp::Common; use Locale::US;";
  10     plan skip_all => "Regexp::Common & Locale::US required for this test" if $@;
  11     plan tests => 66;
  12 }
  13
  14 use Test::Exception;
  15 use Scalar::Util 'isweak';
  16
  17 BEGIN {
  18     use_ok('Moose');
  19 }
  20
  21 {
  22     package Address;
  23     use Moose;
  24     use Moose::Util::TypeConstraints;
  25
  26     use Locale::US;
  27     use Regexp::Common 'zip';
  28
  29     my $STATES = Locale::US->new;
  30
  31     subtype USState
  32         => as Str
  33         => where {
  34             (exists $STATES->{code2state}{uc($_)} || exists $STATES->{state2code}{uc($_)})
  35         };
  36
  37     subtype USZipCode
  38         => as Value
  39         => where {
  40             /^$RE{zip}{US}{-extended => 'allow'}$/
  41         };
  42
  43     has 'street'   => (is => 'rw', isa => 'Str');
  44     has 'city'     => (is => 'rw', isa => 'Str');
  45     has 'state'    => (is => 'rw', isa => 'USState');
  46     has 'zip_code' => (is => 'rw', isa => 'USZipCode');
  47
  48     __PACKAGE__->meta->make_immutable(debug => 0);
  49 }{
  50
  51     package Company;
  52     use Moose;
  53     use Moose::Util::TypeConstraints;
  54
  55     has 'name'      => (is => 'rw', isa => 'Str', required => 1);
  56     has 'address'   => (is => 'rw', isa => 'Address');
  57     has 'employees' => (is => 'rw', isa => 'ArrayRef[Employee]');
  58
  59     sub BUILD {
  60         my ($self, $params) = @_;
  61         if ($params->{employees}) {
  62             foreach my $employee (@{$params->{employees}}) {
  63                 $employee->company($self);
  64             }
  65         }
  66     }
  67
  68     sub get_employee_count { scalar @{(shift)->employees} }
  69
  70     after 'employees' => sub {
  71         my ($self, $employees) = @_;
  72         # if employees is defined, it
  73         # has already been type checked
  74         if (defined $employees) {
  75             # make sure each gets the
  76             # weak ref to the company
  77             foreach my $employee (@{$employees}) {
  78                 $employee->company($self);
  79             }
  80         }
  81     };
  82
  83     __PACKAGE__->meta->make_immutable(debug => 0);
  84 }{
  85
  86     package Person;
  87     use Moose;
  88
  89     has 'first_name'     => (is => 'rw', isa => 'Str', required => 1);
  90     has 'last_name'      => (is => 'rw', isa => 'Str', required => 1);
  91     has 'middle_initial' => (is => 'rw', isa => 'Str', predicate => 'has_middle_initial');
  92     has 'address'        => (is => 'rw', isa => 'Address');
  93
  94     sub full_name {
  95         my $self = shift;
  96         return $self->first_name .
  97               ($self->has_middle_initial ? ' ' . $self->middle_initial . '. ' : ' ') .
  98                $self->last_name;
  99     }
 100
 101     __PACKAGE__->meta->make_immutable(debug => 0);
 102 }{
 103
 104     package Employee;
 105     use Moose;
 106
 107     extends 'Person';
 108
 109     has 'title'   => (is => 'rw', isa => 'Str', required => 1);
 110     has 'company' => (is => 'rw', isa => 'Company', weak_ref => 1);
 111
 112     override 'full_name' => sub {
 113         my $self = shift;
 114         super() . ', ' . $self->title
 115     };
 116
 117     __PACKAGE__->meta->make_immutable(debug => 0);
 118 }
 119
 120 my $ii;
 121 lives_ok {
 122     $ii = Company->new({
 123         name    => 'Infinity Interactive',
 124         address => Address->new(
 125             street   => '565 Plandome Rd., Suite 307',
 126             city     => 'Manhasset',
 127             state    => 'NY',
 128             zip_code => '11030'
 129         ),
 130         employees => [
 131             Employee->new(
 132                 first_name     => 'Jeremy',
 133                 last_name      => 'Shao',
 134                 title          => 'President / Senior Consultant',
 135                 address        => Address->new(city => 'Manhasset', state => 'NY')
 136             ),
 137             Employee->new(
 138                 first_name     => 'Tommy',
 139                 last_name      => 'Lee',
 140                 title          => 'Vice President / Senior Developer',
 141                 address        => Address->new(city => 'New York', state => 'NY')
 142             ),
 143             Employee->new(
 144                 first_name     => 'Stevan',
 145                 middle_initial => 'C',
 146                 last_name      => 'Little',
 147                 title          => 'Senior Developer',
 148                 address        => Address->new(city => 'Madison', state => 'CT')
 149             ),
 150         ]
 151     });
 152 } '... created the entire company successfully';
 153 isa_ok($ii, 'Company');
 154
 155 is($ii->name, 'Infinity Interactive', '... got the right name for the company');
 156
 157 isa_ok($ii->address, 'Address');
 158 is($ii->address->street, '565 Plandome Rd., Suite 307', '... got the right street address');
 159 is($ii->address->city, 'Manhasset', '... got the right city');
 160 is($ii->address->state, 'NY', '... got the right state');
 161 is($ii->address->zip_code, 11030, '... got the zip code');
 162
 163 is($ii->get_employee_count, 3, '... got the right employee count');
 164
 165 # employee #1
 166
 167 isa_ok($ii->employees->[0], 'Employee');
 168 isa_ok($ii->employees->[0], 'Person');
 169
 170 is($ii->employees->[0]->first_name, 'Jeremy', '... got the right first name');
 171 is($ii->employees->[0]->last_name, 'Shao', '... got the right last name');
 172 ok(!$ii->employees->[0]->has_middle_initial, '... no middle initial');
 173 is($ii->employees->[0]->middle_initial, undef, '... got the right middle initial value');
 174 is($ii->employees->[0]->full_name, 'Jeremy Shao, President / Senior Consultant', '... got the right full name');
 175 is($ii->employees->[0]->title, 'President / Senior Consultant', '... got the right title');
 176 is($ii->employees->[0]->company, $ii, '... got the right company');
 177 ok(isweak($ii->employees->[0]->{company}), '... the company is a weak-ref');
 178
 179 isa_ok($ii->employees->[0]->address, 'Address');
 180 is($ii->employees->[0]->address->city, 'Manhasset', '... got the right city');
 181 is($ii->employees->[0]->address->state, 'NY', '... got the right state');
 182
 183 # employee #2
 184
 185 isa_ok($ii->employees->[1], 'Employee');
 186 isa_ok($ii->employees->[1], 'Person');
 187
 188 is($ii->employees->[1]->first_name, 'Tommy', '... got the right first name');
 189 is($ii->employees->[1]->last_name, 'Lee', '... got the right last name');
 190 ok(!$ii->employees->[1]->has_middle_initial, '... no middle initial');
 191 is($ii->employees->[1]->middle_initial, undef, '... got the right middle initial value');
 192 is($ii->employees->[1]->full_name, 'Tommy Lee, Vice President / Senior Developer', '... got the right full name');
 193 is($ii->employees->[1]->title, 'Vice President / Senior Developer', '... got the right title');
 194 is($ii->employees->[1]->company, $ii, '... got the right company');
 195 ok(isweak($ii->employees->[1]->{company}), '... the company is a weak-ref');
 196
 197 isa_ok($ii->employees->[1]->address, 'Address');
 198 is($ii->employees->[1]->address->city, 'New York', '... got the right city');
 199 is($ii->employees->[1]->address->state, 'NY', '... got the right state');
 200
 201 # employee #3
 202
 203 isa_ok($ii->employees->[2], 'Employee');
 204 isa_ok($ii->employees->[2], 'Person');
 205
 206 is($ii->employees->[2]->first_name, 'Stevan', '... got the right first name');
 207 is($ii->employees->[2]->last_name, 'Little', '... got the right last name');
 208 ok($ii->employees->[2]->has_middle_initial, '... got middle initial');
 209 is($ii->employees->[2]->middle_initial, 'C', '... got the right middle initial value');
 210 is($ii->employees->[2]->full_name, 'Stevan C. Little, Senior Developer', '... got the right full name');
 211 is($ii->employees->[2]->title, 'Senior Developer', '... got the right title');
 212 is($ii->employees->[2]->company, $ii, '... got the right company');
 213 ok(isweak($ii->employees->[2]->{company}), '... the company is a weak-ref');
 214
 215 isa_ok($ii->employees->[2]->address, 'Address');
 216 is($ii->employees->[2]->address->city, 'Madison', '... got the right city');
 217 is($ii->employees->[2]->address->state, 'CT', '... got the right state');
 218
 219 # create new company
 220
 221 my $new_company = Company->new(name => 'Infinity Interactive International');
 222 isa_ok($new_company, 'Company');
 223
 224 my $ii_employees = $ii->employees;
 225 foreach my $employee (@$ii_employees) {
 226     is($employee->company, $ii, '... has the ii company');
 227 }
 228
 229 $new_company->employees($ii_employees);
 230
 231 foreach my $employee (@{$new_company->employees}) {
 232     is($employee->company, $new_company, '... has the different company now');
 233 }
 234
 235 ## check some error conditions for the subtypes
 236
 237 dies_ok {
 238     Address->new(street => {}),
 239 } '... we die correctly with bad args';
 240
 241 dies_ok {
 242     Address->new(city => {}),
 243 } '... we die correctly with bad args';
 244
 245 dies_ok {
 246     Address->new(state => 'British Columbia'),
 247 } '... we die correctly with bad args';
 248
 249 lives_ok {
 250     Address->new(state => 'Connecticut'),
 251 } '... we live correctly with good args';
 252
 253 dies_ok {
 254     Address->new(zip_code => 'AF5J6$'),
 255 } '... we die correctly with bad args';
 256
 257 lives_ok {
 258     Address->new(zip_code => '06443'),
 259 } '... we live correctly with good args';
 260
 261 dies_ok {
 262     Company->new(),
 263 } '... we die correctly without good args';
 264
 265 lives_ok {
 266     Company->new(name => 'Foo'),
 267 } '... we live correctly without good args';
 268
 269 dies_ok {
 270     Company->new(name => 'Foo', employees => [ Person->new ]),
 271 } '... we die correctly with good args';
 272
 273 lives_ok {
 274     Company->new(name => 'Foo', employees => []),
 275 } '... we live correctly with good args';
 276