lib/strictures.pm

   1 package strictures;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 use constant _PERL_LT_5_8_4 => ($] < 5.008004) ? 1 : 0;
   7
   8 our $VERSION = '1.004001'; # 1.4.1
   9
  10 sub VERSION {
  11   for ($_[1]) {
  12     last unless defined && !ref && int != 1;
  13     die "Major version specified as $_ - this is strictures version 1";
  14   }
  15   # disable this since Foo->VERSION(undef) correctly returns the version
  16   # and that can happen either if our caller passes undef explicitly or
  17   # because the for above autovivified $_[1] - I could make it stop but
  18   # it's pointless since we don't want to blow up if the caller does
  19   # something valid either.
  20   no warnings 'uninitialized';
  21   shift->SUPER::VERSION(@_);
  22 }
  23
  24 my $extras_load_warned;
  25
  26 our $Smells_Like_VCS = (-e '.git' || -e '.svn'
  27   || (-e '../../dist.ini' && (-e '../../.git' || -e '../../.svn')));
  28
  29 sub import {
  30   strict->import;
  31   warnings->import(FATAL => 'all');
  32
  33   my $extra_tests = do {
  34     if (exists $ENV{PERL_STRICTURES_EXTRA}) {
  35       if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
  36         die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
  37           . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
  38       }
  39       $ENV{PERL_STRICTURES_EXTRA};
  40     } elsif (! _PERL_LT_5_8_4) {
  41       !!((caller)[1] =~ /^(?:t|xt|lib|blib)/
  42          and $Smells_Like_VCS)
  43     }
  44   };
  45   if ($extra_tests) {
  46     my @failed;
  47     if (eval { require indirect; 1 }) {
  48       indirect->unimport(':fatal');
  49     } else {
  50       push @failed, 'indirect';
  51     }
  52     if (eval { require multidimensional; 1 }) {
  53       multidimensional->unimport;
  54     } else {
  55       push @failed, 'multidimensional';
  56     }
  57     if (eval { require bareword::filehandles; 1 }) {
  58       bareword::filehandles->unimport;
  59     } else {
  60       push @failed, 'bareword::filehandles';
  61     }
  62     if (@failed and not $extras_load_warned++) {
  63       my $failed = join ' ', @failed;
  64       warn <<EOE;
  65 strictures.pm extra testing active but couldn't load all modules. Missing were:
  66
  67   $failed
  68
  69 Extra testing is auto-enabled in checkouts only, so if you're the author
  70 of a strictures using module you need to run:
  71
  72   cpan indirect multidimensional bareword::filehandles
  73
  74 but these modules are not required by your users.
  75 EOE
  76     }
  77   }
  78 }
  79
  80 1;
  81
  82 __END__
  83 =head1 NAME
  84
  85 strictures - turn on strict and make all warnings fatal
  86
  87 =head1 SYNOPSIS
  88
  89   use strictures 1;
  90
  91 is equivalent to
  92
  93   use strict;
  94   use warnings FATAL => 'all';
  95
  96 except when called from a file which matches:
  97
  98   (caller)[1] =~ /^(?:t|xt|lib|blib)/
  99
 100 and when either '.git' or '.svn' is present in the current directory (with
 101 the intention of only forcing extra tests on the author side) - or when '.git'
 102 or '.svn' is present two directories up along with 'dist.ini' (which would
 103 indicate we are in a 'dzil test' operation, via L<Dist::Zilla>) -
 104 or when the PERL_STRICTURES_EXTRA environment variable is set, in which case
 105
 106   use strictures 1;
 107
 108 is equivalent to
 109
 110   use strict;
 111   use warnings FATAL => 'all';
 112   no indirect 'fatal';
 113   no multidimensional;
 114   no bareword::filehandles;
 115
 116 Note that _EXTRA may at some point add even more tests, with only a minor
 117 version increase, but any changes to the effect of 'use strictures' in
 118 normal mode will involve a major version bump.
 119
 120 If any of the extra testing modules are not present, strictures will
 121 complain loudly, once, via warn(), and then shut up. But you really
 122 should consider installing them, they're all great anti-footgun tools.
 123
 124 =head1 DESCRIPTION
 125
 126 I've been writing the equivalent of this module at the top of my code for
 127 about a year now. I figured it was time to make it shorter.
 128
 129 Things like the importer in 'use Moose' don't help me because they turn
 130 warnings on but don't make them fatal - which from my point of view is
 131 useless because I want an exception to tell me my code isn't warnings clean.
 132
 133 Any time I see a warning from my code, that indicates a mistake.
 134
 135 Any time my code encounters a mistake, I want a crash - not spew to STDERR
 136 and then unknown (and probably undesired) subsequent behaviour.
 137
 138 I also want to ensure that obvious coding mistakes, like indirect object
 139 syntax (and not so obvious mistakes that cause things to accidentally compile
 140 as such) get caught, but not at the cost of an XS dependency and not at the
 141 cost of blowing things up on another machine.
 142
 143 Therefore, strictures turns on additional checking, but only when it thinks
 144 it's running in a test file in a VCS checkout - though if this causes
 145 undesired behaviour this can be overridden by setting the
 146 PERL_STRICTURES_EXTRA environment variable.
 147
 148 If additional useful author side checks come to mind, I'll add them to the
 149 _EXTRA code path only - this will result in a minor version increase (i.e.
 150 1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
 151 this code will result in a subversion increas (i.e. 1.000000 to 1.000001
 152 (1.0.1)).
 153
 154 If the behaviour of 'use strictures' in normal mode changes in any way, that
 155 will constitute a major version increase - and the code already checks
 156 when its version is tested to ensure that
 157
 158   use strictures 1;
 159
 160 will continue to only introduce the current set of strictures even if 2.0 is
 161 installed.
 162
 163 =head1 METHODS
 164
 165 =head2 import
 166
 167 This method does the setup work described above in L</DESCRIPTION>
 168
 169 =head2 VERSION
 170
 171 This method traps the strictures->VERSION(1) call produced by a use line
 172 with a version number on it and does the version check.
 173
 174 =head1 COMMUNITY AND SUPPORT
 175
 176 =head2 IRC channel
 177
 178 irc.perl.org #toolchain
 179
 180 (or bug 'mst' in query on there or freenode)
 181
 182 =head2 Git repository
 183
 184 Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:
 185
 186   git clone git://git.shadowcat.co.uk/p5sagit/strictures.git
 187
 188 =head1 AUTHOR
 189
 190 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 191
 192 =head1 CONTRIBUTORS
 193
 194 None required yet. Maybe this module is perfect (hahahahaha ...).
 195
 196 =head1 COPYRIGHT
 197
 198 Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
 199 as listed above.
 200
 201 =head1 LICENSE
 202
 203 This library is free software and may be distributed under the same terms
 204 as perl itself.
 205
 206 =cut