lib/SQL/Translator/Schema/Table.pm

   1 package SQL::Translator::Schema::Table;
   2
   3 # ----------------------------------------------------------------------
   4 # $Id: Table.pm,v 1.6 2003-06-06 00:10:32 kycl4rk Exp $
   5 # ----------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =pod
  24
  25 =head1 NAME
  26
  27 SQL::Translator::Schema::Table - SQL::Translator table object
  28
  29 =head1 SYNOPSIS
  30
  31   use SQL::Translator::Schema::Table;
  32   my $table = SQL::Translator::Schema::Table->new( name => 'foo' );
  33
  34 =head1 DESCSIPTION
  35
  36 C<SQL::Translator::Schema::Table> is the table object.
  37
  38 =head1 METHODS
  39
  40 =cut
  41
  42 use strict;
  43 use Class::Base;
  44 use SQL::Translator::Utils 'parse_list_arg';
  45 use SQL::Translator::Schema::Constants;
  46 use SQL::Translator::Schema::Constraint;
  47 use SQL::Translator::Schema::Field;
  48 use SQL::Translator::Schema::Index;
  49
  50 use base 'Class::Base';
  51 use vars qw( $VERSION $FIELD_ORDER );
  52
  53 $VERSION = 1.00;
  54
  55 # ----------------------------------------------------------------------
  56 sub init {
  57
  58 =pod
  59
  60 =head2 new
  61
  62 Object constructor.
  63
  64   my $table  =  SQL::Translator::Schema::Table->new(
  65       schema => $schema,
  66       name   => 'foo',
  67   );
  68
  69 =cut
  70
  71     my ( $self, $config ) = @_;
  72
  73     for my $arg ( qw[ schema name ] ) {
  74         next unless defined $config->{ $arg };
  75         $self->$arg( $config->{ $arg } ) or return;
  76     }
  77
  78     return $self;
  79 }
  80
  81 # ----------------------------------------------------------------------
  82 sub add_constraint {
  83
  84 =pod
  85
  86 =head2 add_constraint
  87
  88 Add a constraint to the table.  Returns the newly created
  89 C<SQL::Translator::Schema::Constraint> object.
  90
  91   my $c1 = $table->add_constraint(
  92       name        => 'pk',
  93       type        => PRIMARY_KEY,
  94       fields      => [ 'foo_id' ],
  95   );
  96
  97   my $c2 = SQL::Translator::Schema::Constraint->new( name => 'uniq' );
  98   $c2    = $table->add_constraint( $constraint );
  99
 100 =cut
 101
 102     my $self             = shift;
 103     my $constraint_class = 'SQL::Translator::Schema::Constraint';
 104     my $constraint;
 105
 106     if ( UNIVERSAL::isa( $_[0], $constraint_class ) ) {
 107         $constraint = shift;
 108         $constraint->table( $self );
 109     }
 110     else {
 111         my %args = @_;
 112         $args{'table'} = $self;
 113         $constraint = $constraint_class->new( \%args ) or
 114             return $self->error( $constraint_class->error );
 115     }
 116
 117     #
 118     # If we're trying to add a PK when one is already defined,
 119     # then just add the fields to the existing definition.
 120     #
 121     my $ok = 0;
 122     my $pk = $self->primary_key;
 123     if ( $pk && $constraint->type eq PRIMARY_KEY ) {
 124         $self->primary_key( $constraint->fields );
 125         $constraint = $pk;
 126     }
 127     else {
 128         my @field_names = $constraint->fields;
 129         $ok = 1;
 130
 131         for my $c (
 132             grep { $_->type eq $constraint->type }
 133             $self->get_constraints
 134         ) {
 135             my %fields = map { $_, 1 } $c->fields;
 136             for my $field_name ( @field_names ) {
 137                 if ( $fields{ $field_name } ) {
 138                     $constraint = $c;
 139                     $ok = 0;
 140                     last;
 141                 }
 142             }
 143             last unless $ok;
 144         }
 145     }
 146
 147     if ( $ok ) {
 148         push @{ $self->{'constraints'} }, $constraint;
 149     }
 150
 151     return $constraint;
 152 }
 153
 154 # ----------------------------------------------------------------------
 155 sub add_index {
 156
 157 =pod
 158
 159 =head2 add_index
 160
 161 Add an index to the table.  Returns the newly created
 162 C<SQL::Translator::Schema::Index> object.
 163
 164   my $i1 = $table->add_index(
 165       name   => 'name',
 166       fields => [ 'name' ],
 167       type   => 'normal',
 168   );
 169
 170   my $i2 = SQL::Translator::Schema::Index->new( name => 'id' );
 171   $i2    = $table->add_index( $index );
 172
 173 =cut
 174
 175     my $self        = shift;
 176     my $index_class = 'SQL::Translator::Schema::Index';
 177     my $index;
 178
 179     if ( UNIVERSAL::isa( $_[0], $index_class ) ) {
 180         $index = shift;
 181         $index->table( $self );
 182     }
 183     else {
 184         my %args = @_;
 185         $args{'table'} = $self;
 186         $index = $index_class->new( \%args ) or return
 187             $self->error( $index_class->error );
 188     }
 189
 190     push @{ $self->{'indices'} }, $index;
 191     return $index;
 192 }
 193
 194 # ----------------------------------------------------------------------
 195 sub add_field {
 196
 197 =pod
 198
 199 =head2 add_field
 200
 201 Add an field to the table.  Returns the newly created
 202 C<SQL::Translator::Schema::Field> object.  The "name" parameter is
 203 required.  If you try to create a field with the same name as an
 204 existing field, you will get an error and the field will not be created.
 205
 206   my $f1    =  $table->add_field(
 207       name      => 'foo_id',
 208       data_type => 'integer',
 209       size      => 11,
 210   );
 211
 212   my $f2 =  SQL::Translator::Schema::Field->new(
 213       name   => 'name',
 214       table  => $table,
 215   );
 216   $f2    = $table->add_field( $field2 ) or die $table->error;
 217
 218 =cut
 219
 220     my $self        = shift;
 221     my $field_class = 'SQL::Translator::Schema::Field';
 222     my $field;
 223
 224     if ( UNIVERSAL::isa( $_[0], $field_class ) ) {
 225         $field = shift;
 226         $field->table( $self );
 227     }
 228     else {
 229         my %args = @_;
 230         $args{'table'} = $self;
 231         $field = $field_class->new( \%args ) or return
 232             $self->error( $field_class->error );
 233     }
 234
 235     $field->order( ++$FIELD_ORDER );
 236     my $field_name = $field->name or return $self->error('No name');
 237
 238     if ( exists $self->{'fields'}{ $field_name } ) {
 239         return $self->error(qq[Can't create field: "$field_name" exists]);
 240     }
 241     else {
 242         $self->{'fields'}{ $field_name } = $field;
 243     }
 244
 245     return $field;
 246 }
 247
 248 # ----------------------------------------------------------------------
 249 sub get_constraints {
 250
 251 =pod
 252
 253 =head2 get_constraints
 254
 255 Returns all the constraint objects as an array or array reference.
 256
 257   my @constraints = $table->get_constraints;
 258
 259 =cut
 260
 261     my $self = shift;
 262
 263     if ( ref $self->{'constraints'} ) {
 264         return wantarray
 265             ? @{ $self->{'constraints'} } : $self->{'constraints'};
 266     }
 267     else {
 268         $self->error('No constraints');
 269         return wantarray ? () : undef;
 270     }
 271 }
 272
 273 # ----------------------------------------------------------------------
 274 sub get_indices {
 275
 276 =pod
 277
 278 =head2 get_indices
 279
 280 Returns all the index objects as an array or array reference.
 281
 282   my @indices = $table->get_indices;
 283
 284 =cut
 285
 286     my $self = shift;
 287
 288     if ( ref $self->{'indices'} ) {
 289         return wantarray
 290             ? @{ $self->{'indices'} }
 291             : $self->{'indices'};
 292     }
 293     else {
 294         $self->error('No indices');
 295         return wantarray ? () : undef;
 296     }
 297 }
 298
 299 # ----------------------------------------------------------------------
 300 sub get_field {
 301
 302 =pod
 303
 304 =head2 get_field
 305
 306 Returns a field by the name provided.
 307
 308   my $field = $table->get_field('foo');
 309
 310 =cut
 311
 312     my $self       = shift;
 313     my $field_name = shift or return $self->error('No field name');
 314     return $self->error( qq[Field "$field_name" does not exist] ) unless
 315         exists $self->{'fields'}{ $field_name };
 316     return $self->{'fields'}{ $field_name };
 317 }
 318
 319 # ----------------------------------------------------------------------
 320 sub get_fields {
 321
 322 =pod
 323
 324 =head2 get_fields
 325
 326 Returns all the field objects as an array or array reference.
 327
 328   my @fields = $table->get_fields;
 329
 330 =cut
 331
 332     my $self = shift;
 333     my @fields =
 334         map  { $_->[1] }
 335         sort { $a->[0] <=> $b->[0] }
 336         map  { [ $_->order, $_ ] }
 337         values %{ $self->{'fields'} || {} };
 338
 339     if ( @fields ) {
 340         return wantarray ? @fields : \@fields;
 341     }
 342     else {
 343         $self->error('No fields');
 344         return wantarray ? () : undef;
 345     }
 346 }
 347
 348 # ----------------------------------------------------------------------
 349 sub is_valid {
 350
 351 =pod
 352
 353 =head2 is_valid
 354
 355 Determine whether the view is valid or not.
 356
 357   my $ok = $view->is_valid;
 358
 359 =cut
 360
 361     my $self = shift;
 362     return $self->error('No name')   unless $self->name;
 363     return $self->error('No fields') unless $self->get_fields;
 364
 365     for my $object (
 366         $self->get_fields, $self->get_indices, $self->get_constraints
 367     ) {
 368         return $object->error unless $object->is_valid;
 369     }
 370
 371     return 1;
 372 }
 373
 374 # ----------------------------------------------------------------------
 375 sub name {
 376
 377 =pod
 378
 379 =head2 name
 380
 381 Get or set the table's name.
 382
 383 If provided an argument, checks the schema object for a table of
 384 that name and disallows the change if one exists.
 385
 386   my $table_name = $table->name('foo');
 387
 388 =cut
 389
 390     my $self = shift;
 391
 392     if ( my $arg = shift ) {
 393         if ( my $schema = $self->schema ) {
 394             return $self->error( qq[Can't use table name "$arg": table exists] )
 395                 if $schema->get_table( $arg );
 396         }
 397         $self->{'name'} = $arg;
 398     }
 399
 400     return $self->{'name'} || '';
 401 }
 402
 403 # ----------------------------------------------------------------------
 404 sub schema {
 405
 406 =pod
 407
 408 =head2 schema
 409
 410 Get or set the table's schema object.
 411
 412   my $schema = $table->schema;
 413
 414 =cut
 415
 416     my $self = shift;
 417     if ( my $arg = shift ) {
 418         return $self->error('Not a schema object') unless
 419             UNIVERSAL::isa( $arg, 'SQL::Translator::Schema' );
 420         $self->{'schema'} = $arg;
 421     }
 422
 423     return $self->{'schema'};
 424 }
 425
 426 # ----------------------------------------------------------------------
 427 sub primary_key {
 428
 429 =pod
 430
 431 =head2 options
 432
 433 Gets or sets the table's primary key(s).  Takes one or more field
 434 names (as a string, list or array[ref]) as an argument.  If the field
 435 names are present, it will create a new PK if none exists, or it will
 436 add to the fields of an existing PK (and will unique the field names).
 437 Returns the C<SQL::Translator::Schema::Constraint> object representing
 438 the primary key.
 439
 440 These are eqivalent:
 441
 442   $table->primary_key('id');
 443   $table->primary_key(['name']);
 444   $table->primary_key('id','name']);
 445   $table->primary_key(['id','name']);
 446   $table->primary_key('id,name');
 447   $table->primary_key(qw[ id name ]);
 448
 449   my $pk = $table->primary_key;
 450
 451 =cut
 452
 453     my $self   = shift;
 454     my $fields = parse_list_arg( @_ );
 455
 456     my $constraint;
 457     if ( @$fields ) {
 458         for my $f ( @$fields ) {
 459             return $self->error(qq[Invalid field "$f"]) unless
 460                 $self->get_field($f);
 461         }
 462
 463         my $has_pk;
 464         for my $c ( $self->get_constraints ) {
 465             if ( $c->type eq PRIMARY_KEY ) {
 466                 $has_pk = 1;
 467                 $c->fields( @{ $c->fields }, @$fields );
 468                 $constraint = $c;
 469             }
 470         }
 471
 472         unless ( $has_pk ) {
 473             $constraint = $self->add_constraint(
 474                 type   => PRIMARY_KEY,
 475                 fields => $fields,
 476             );
 477         }
 478     }
 479
 480     if ( $constraint ) {
 481         return $constraint;
 482     }
 483     else {
 484         for my $c ( $self->get_constraints ) {
 485             return $c if $c->type eq PRIMARY_KEY;
 486         }
 487     }
 488
 489     return;
 490 }
 491
 492 # ----------------------------------------------------------------------
 493 sub options {
 494
 495 =pod
 496
 497 =head2 options
 498
 499 Get or set the table's options (e.g., table types for MySQL).  Returns
 500 an array or array reference.
 501
 502   my @options = $table->options;
 503
 504 =cut
 505
 506     my $self    = shift;
 507     my $options = parse_list_arg( @_ );
 508
 509     push @{ $self->{'options'} }, @$options;
 510
 511     if ( ref $self->{'options'} ) {
 512         return wantarray ? @{ $self->{'options'} || [] } : $self->{'options'};
 513     }
 514     else {
 515         return wantarray ? () : [];
 516     }
 517 }
 518
 519 # ----------------------------------------------------------------------
 520 sub order {
 521
 522 =pod
 523
 524 =head2 order
 525
 526 Get or set the table's order.
 527
 528   my $order = $table->order(3);
 529
 530 =cut
 531
 532     my ( $self, $arg ) = @_;
 533
 534     if ( defined $arg && $arg =~ /^\d+$/ ) {
 535         $self->{'order'} = $arg;
 536     }
 537
 538     return $self->{'order'} || 0;
 539 }
 540
 541 # ----------------------------------------------------------------------
 542 sub DESTROY {
 543     my $self = shift;
 544     undef $self->{'schema'}; # destroy cyclical reference
 545     undef $_ for @{ $self->{'constraints'} };
 546     undef $_ for @{ $self->{'indices'} };
 547     undef $_ for values %{ $self->{'fields'} };
 548 }
 549
 550 1;
 551
 552 # ----------------------------------------------------------------------
 553
 554 =pod
 555
 556 =head1 AUTHOR
 557
 558 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>
 559
 560 =cut