lib/SQL/Abstract.pm

   1 package SQL::Abstract; # see doc at end of file
   2
   3 # LDNOTE : this code is heavy refactoring from original SQLA.
   4 # Several design decisions will need discussion during
   5 # the test / diffusion / acceptance phase; those are marked with flag
   6 # 'LDNOTE' (note by laurent.dami AT free.fr)
   7
   8 use Carp;
   9 use strict;
  10 use warnings;
  11 use List::Util ();
  12 use Scalar::Util ();
  13
  14 #======================================================================
  15 # GLOBALS
  16 #======================================================================
  17
  18 our $VERSION  = '1.61';
  19
  20 # This would confuse some packagers
  21 #$VERSION      = eval $VERSION; # numify for warning-free dev releases
  22
  23 our $AUTOLOAD;
  24
  25 # special operators (-in, -between). May be extended/overridden by user.
  26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
  27 my @BUILTIN_SPECIAL_OPS = (
  28   {regex => qr/^(not )?between$/i, handler => '_where_field_BETWEEN'},
  29   {regex => qr/^(not )?in$/i,      handler => '_where_field_IN'},
  30 );
  31
  32 # unaryish operators - key maps to handler
  33 my @BUILTIN_UNARY_OPS = (
  34   # the digits are backcompat stuff
  35   { regex => qr/^and  (?: \s? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  36   { regex => qr/^or   (?: \s? \d+ )? $/xi, handler => '_where_op_ANDOR' },
  37   { regex => qr/^nest (?: \s? \d+ )? $/xi, handler => '_where_op_NEST' },
  38   { regex => qr/^ (?: not \s )? bool $/xi, handler => '_where_op_BOOL' },
  39 );
  40
  41 #======================================================================
  42 # DEBUGGING AND ERROR REPORTING
  43 #======================================================================
  44
  45 sub _debug {
  46   return unless $_[0]->{debug}; shift; # a little faster
  47   my $func = (caller(1))[3];
  48   warn "[$func] ", @_, "\n";
  49 }
  50
  51 sub belch (@) {
  52   my($func) = (caller(1))[3];
  53   carp "[$func] Warning: ", @_;
  54 }
  55
  56 sub puke (@) {
  57   my($func) = (caller(1))[3];
  58   croak "[$func] Fatal: ", @_;
  59 }
  60
  61
  62 #======================================================================
  63 # NEW
  64 #======================================================================
  65
  66 sub new {
  67   my $self = shift;
  68   my $class = ref($self) || $self;
  69   my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
  70
  71   # choose our case by keeping an option around
  72   delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
  73
  74   # default logic for interpreting arrayrefs
  75   $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
  76
  77   # how to return bind vars
  78   # LDNOTE: changed nwiger code : why this 'delete' ??
  79   # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
  80   $opt{bindtype} ||= 'normal';
  81
  82   # default comparison is "=", but can be overridden
  83   $opt{cmp} ||= '=';
  84
  85   # generic SQL comparison operators
  86   my $anchored_cmp_ops = join ('|', map { '^' . $_ . '$' } (
  87     '(?:is \s+)? (?:not \s+)? like',
  88     'is',
  89     (map { quotemeta($_) } (qw/ < > != <> = <= >= /) ),
  90   ));
  91   $opt{cmp_ops} = qr/$anchored_cmp_ops/ix;
  92
  93   # try to recognize which are the 'equality' and 'unequality' ops
  94   # (temporary quickfix, should go through a more seasoned API)
  95   $opt{equality_op}   = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
  96   $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
  97
  98   # SQL booleans
  99   $opt{sqltrue}  ||= '1=1';
 100   $opt{sqlfalse} ||= '0=1';
 101
 102   # special operators
 103   $opt{special_ops} ||= [];
 104   push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
 105
 106   # unary operators
 107   $opt{unary_ops} ||= [];
 108   push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
 109
 110   return bless \%opt, $class;
 111 }
 112
 113
 114
 115 #======================================================================
 116 # INSERT methods
 117 #======================================================================
 118
 119 sub insert {
 120   my $self    = shift;
 121   my $table   = $self->_table(shift);
 122   my $data    = shift || return;
 123   my $options = shift;
 124
 125   my $method       = $self->_METHOD_FOR_refkind("_insert", $data);
 126   my ($sql, @bind) = $self->$method($data);
 127   $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
 128
 129   if (my $ret = $options->{returning}) {
 130     $sql .= $self->_insert_returning ($ret);
 131   }
 132
 133   return wantarray ? ($sql, @bind) : $sql;
 134 }
 135
 136 sub _insert_returning {
 137   my ($self, $fields) = @_;
 138
 139   my $f = $self->_SWITCH_refkind($fields, {
 140     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$fields;},
 141     SCALAR       => sub {$self->_quote($fields)},
 142     SCALARREF    => sub {$$fields},
 143   });
 144   return join (' ', $self->_sqlcase(' returning'), $f);
 145 }
 146
 147 sub _insert_HASHREF { # explicit list of fields and then values
 148   my ($self, $data) = @_;
 149
 150   my @fields = sort keys %$data;
 151
 152   my ($sql, @bind) = $self->_insert_values($data);
 153
 154   # assemble SQL
 155   $_ = $self->_quote($_) foreach @fields;
 156   $sql = "( ".join(", ", @fields).") ".$sql;
 157
 158   return ($sql, @bind);
 159 }
 160
 161 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
 162   my ($self, $data) = @_;
 163
 164   # no names (arrayref) so can't generate bindtype
 165   $self->{bindtype} ne 'columns'
 166     or belch "can't do 'columns' bindtype when called with arrayref";
 167
 168   # fold the list of values into a hash of column name - value pairs
 169   # (where the column names are artificially generated, and their
 170   # lexicographical ordering keep the ordering of the original list)
 171   my $i = "a";  # incremented values will be in lexicographical order
 172   my $data_in_hash = { map { ($i++ => $_) } @$data };
 173
 174   return $self->_insert_values($data_in_hash);
 175 }
 176
 177 sub _insert_ARRAYREFREF { # literal SQL with bind
 178   my ($self, $data) = @_;
 179
 180   my ($sql, @bind) = @${$data};
 181   $self->_assert_bindval_matches_bindtype(@bind);
 182
 183   return ($sql, @bind);
 184 }
 185
 186
 187 sub _insert_SCALARREF { # literal SQL without bind
 188   my ($self, $data) = @_;
 189
 190   return ($$data);
 191 }
 192
 193 sub _insert_values {
 194   my ($self, $data) = @_;
 195
 196   my (@values, @all_bind);
 197   foreach my $column (sort keys %$data) {
 198     my $v = $data->{$column};
 199
 200     $self->_SWITCH_refkind($v, {
 201
 202       ARRAYREF => sub {
 203         if ($self->{array_datatypes}) { # if array datatype are activated
 204           push @values, '?';
 205           push @all_bind, $self->_bindtype($column, $v);
 206         }
 207         else {                          # else literal SQL with bind
 208           my ($sql, @bind) = @$v;
 209           $self->_assert_bindval_matches_bindtype(@bind);
 210           push @values, $sql;
 211           push @all_bind, @bind;
 212         }
 213       },
 214
 215       ARRAYREFREF => sub { # literal SQL with bind
 216         my ($sql, @bind) = @${$v};
 217         $self->_assert_bindval_matches_bindtype(@bind);
 218         push @values, $sql;
 219         push @all_bind, @bind;
 220       },
 221
 222       # THINK : anything useful to do with a HASHREF ?
 223       HASHREF => sub {  # (nothing, but old SQLA passed it through)
 224         #TODO in SQLA >= 2.0 it will die instead
 225         belch "HASH ref as bind value in insert is not supported";
 226         push @values, '?';
 227         push @all_bind, $self->_bindtype($column, $v);
 228       },
 229
 230       SCALARREF => sub {  # literal SQL without bind
 231         push @values, $$v;
 232       },
 233
 234       SCALAR_or_UNDEF => sub {
 235         push @values, '?';
 236         push @all_bind, $self->_bindtype($column, $v);
 237       },
 238
 239      });
 240
 241   }
 242
 243   my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
 244   return ($sql, @all_bind);
 245 }
 246
 247
 248
 249 #======================================================================
 250 # UPDATE methods
 251 #======================================================================
 252
 253
 254 sub update {
 255   my $self  = shift;
 256   my $table = $self->_table(shift);
 257   my $data  = shift || return;
 258   my $where = shift;
 259
 260   # first build the 'SET' part of the sql statement
 261   my (@set, @all_bind);
 262   puke "Unsupported data type specified to \$sql->update"
 263     unless ref $data eq 'HASH';
 264
 265   for my $k (sort keys %$data) {
 266     my $v = $data->{$k};
 267     my $r = ref $v;
 268     my $label = $self->_quote($k);
 269
 270     $self->_SWITCH_refkind($v, {
 271       ARRAYREF => sub {
 272         if ($self->{array_datatypes}) { # array datatype
 273           push @set, "$label = ?";
 274           push @all_bind, $self->_bindtype($k, $v);
 275         }
 276         else {                          # literal SQL with bind
 277           my ($sql, @bind) = @$v;
 278           $self->_assert_bindval_matches_bindtype(@bind);
 279           push @set, "$label = $sql";
 280           push @all_bind, @bind;
 281         }
 282       },
 283       ARRAYREFREF => sub { # literal SQL with bind
 284         my ($sql, @bind) = @${$v};
 285         $self->_assert_bindval_matches_bindtype(@bind);
 286         push @set, "$label = $sql";
 287         push @all_bind, @bind;
 288       },
 289       SCALARREF => sub {  # literal SQL without bind
 290         push @set, "$label = $$v";
 291        },
 292       SCALAR_or_UNDEF => sub {
 293         push @set, "$label = ?";
 294         push @all_bind, $self->_bindtype($k, $v);
 295       },
 296     });
 297   }
 298
 299   # generate sql
 300   my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
 301           . join ', ', @set;
 302
 303   if ($where) {
 304     my($where_sql, @where_bind) = $self->where($where);
 305     $sql .= $where_sql;
 306     push @all_bind, @where_bind;
 307   }
 308
 309   return wantarray ? ($sql, @all_bind) : $sql;
 310 }
 311
 312
 313
 314
 315 #======================================================================
 316 # SELECT
 317 #======================================================================
 318
 319
 320 sub select {
 321   my $self   = shift;
 322   my $table  = $self->_table(shift);
 323   my $fields = shift || '*';
 324   my $where  = shift;
 325   my $order  = shift;
 326
 327   my($where_sql, @bind) = $self->where($where, $order);
 328
 329   my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
 330                                    : $fields;
 331   my $sql = join(' ', $self->_sqlcase('select'), $f,
 332                       $self->_sqlcase('from'),   $table)
 333           . $where_sql;
 334
 335   return wantarray ? ($sql, @bind) : $sql;
 336 }
 337
 338 #======================================================================
 339 # DELETE
 340 #======================================================================
 341
 342
 343 sub delete {
 344   my $self  = shift;
 345   my $table = $self->_table(shift);
 346   my $where = shift;
 347
 348
 349   my($where_sql, @bind) = $self->where($where);
 350   my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
 351
 352   return wantarray ? ($sql, @bind) : $sql;
 353 }
 354
 355
 356 #======================================================================
 357 # WHERE: entry point
 358 #======================================================================
 359
 360
 361
 362 # Finally, a separate routine just to handle WHERE clauses
 363 sub where {
 364   my ($self, $where, $order) = @_;
 365
 366   # where ?
 367   my ($sql, @bind) = $self->_recurse_where($where);
 368   $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
 369
 370   # order by?
 371   if ($order) {
 372     $sql .= $self->_order_by($order);
 373   }
 374
 375   return wantarray ? ($sql, @bind) : $sql;
 376 }
 377
 378
 379 sub _recurse_where {
 380   my ($self, $where, $logic) = @_;
 381
 382   # dispatch on appropriate method according to refkind of $where
 383   my $method = $self->_METHOD_FOR_refkind("_where", $where);
 384
 385
 386   my ($sql, @bind) =  $self->$method($where, $logic);
 387
 388   # DBIx::Class directly calls _recurse_where in scalar context, so
 389   # we must implement it, even if not in the official API
 390   return wantarray ? ($sql, @bind) : $sql;
 391 }
 392
 393
 394
 395 #======================================================================
 396 # WHERE: top-level ARRAYREF
 397 #======================================================================
 398
 399
 400 sub _where_ARRAYREF {
 401   my ($self, $where, $logic) = @_;
 402
 403   $logic = uc($logic || $self->{logic});
 404   $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
 405
 406   my @clauses = @$where;
 407
 408   my (@sql_clauses, @all_bind);
 409   # need to use while() so can shift() for pairs
 410   while (my $el = shift @clauses) {
 411
 412     # switch according to kind of $el and get corresponding ($sql, @bind)
 413     my ($sql, @bind) = $self->_SWITCH_refkind($el, {
 414
 415       # skip empty elements, otherwise get invalid trailing AND stuff
 416       ARRAYREF  => sub {$self->_recurse_where($el)        if @$el},
 417
 418       ARRAYREFREF => sub { @{${$el}}                 if @{${$el}}},
 419
 420       HASHREF   => sub {$self->_recurse_where($el, 'and') if %$el},
 421            # LDNOTE : previous SQLA code for hashrefs was creating a dirty
 422            # side-effect: the first hashref within an array would change
 423            # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
 424            # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
 425            # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
 426
 427       SCALARREF => sub { ($$el);                                 },
 428
 429       SCALAR    => sub {# top-level arrayref with scalars, recurse in pairs
 430                         $self->_recurse_where({$el => shift(@clauses)})},
 431
 432       UNDEF     => sub {puke "not supported : UNDEF in arrayref" },
 433     });
 434
 435     if ($sql) {
 436       push @sql_clauses, $sql;
 437       push @all_bind, @bind;
 438     }
 439   }
 440
 441   return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
 442 }
 443
 444 #======================================================================
 445 # WHERE: top-level ARRAYREFREF
 446 #======================================================================
 447
 448 sub _where_ARRAYREFREF {
 449     my ($self, $where) = @_;
 450     my ($sql, @bind) = @{${$where}};
 451
 452     return ($sql, @bind);
 453 }
 454
 455 #======================================================================
 456 # WHERE: top-level HASHREF
 457 #======================================================================
 458
 459 sub _where_HASHREF {
 460   my ($self, $where) = @_;
 461   my (@sql_clauses, @all_bind);
 462
 463   for my $k (sort keys %$where) {
 464     my $v = $where->{$k};
 465
 466     # ($k => $v) is either a special unary op or a regular hashpair
 467     my ($sql, @bind) = do {
 468       if ($k =~ /^-./) {
 469         # put the operator in canonical form
 470         my $op = $k;
 471         $op =~ s/^-//;        # remove initial dash
 472         $op =~ s/[_\t ]+/ /g; # underscores and whitespace become single spaces
 473         $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 474
 475         $self->_debug("Unary OP(-$op) within hashref, recursing...");
 476
 477         my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}};
 478         if (my $handler = $op_entry->{handler}) {
 479           if (not ref $handler) {
 480             if ($op =~ s/\s?\d+$//) {
 481               belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
 482                   . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
 483               }
 484             $self->$handler ($op, $v);
 485           }
 486           elsif (ref $handler eq 'CODE') {
 487             $handler->($self, $op, $v);
 488           }
 489           else {
 490             puke "Illegal handler for operator $k - expecting a method name or a coderef";
 491           }
 492         }
 493         else {
 494           $self->debug("Generic unary OP: $k - recursing as function");
 495           $self->_where_func_generic ($op, $v);
 496         }
 497       }
 498       else {
 499         my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
 500         $self->$method($k, $v);
 501       }
 502     };
 503
 504     push @sql_clauses, $sql;
 505     push @all_bind, @bind;
 506   }
 507
 508   return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
 509 }
 510
 511 sub _where_func_generic {
 512   my ($self, $op, $rhs) = @_;
 513
 514   my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
 515     SCALAR =>   sub {
 516       puke "Illegal use of top-level '$op'"
 517         unless $self->{_nested_func_lhs};
 518
 519       return (
 520         $self->_convert('?'),
 521         $self->_bindtype($self->{_nested_func_lhs}, $rhs)
 522       );
 523     },
 524     FALLBACK => sub {
 525       $self->_recurse_where ($rhs)
 526     },
 527   });
 528
 529   $sql = sprintf ('%s%s',
 530     $self->_sqlcase($op),
 531     ($op =~ $self->{cmp_ops}) ? " $sql" : "( $sql )",
 532   );
 533
 534   return ($sql, @bind);
 535 }
 536
 537 sub _where_op_ANDOR {
 538   my ($self, $op, $v) = @_;
 539
 540   $self->_SWITCH_refkind($v, {
 541     ARRAYREF => sub {
 542       return $self->_where_ARRAYREF($v, $op);
 543     },
 544
 545     HASHREF => sub {
 546       return ( $op =~ /^or/i )
 547         ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
 548         : $self->_where_HASHREF($v);
 549     },
 550
 551     SCALARREF  => sub {
 552       puke "-$op => \\\$scalar not supported, use -nest => ...";
 553     },
 554
 555     ARRAYREFREF => sub {
 556       puke "-$op => \\[..] not supported, use -nest => ...";
 557     },
 558
 559     SCALAR => sub { # permissively interpreted as SQL
 560       puke "-$op => 'scalar' not supported, use -nest => \\'scalar'";
 561     },
 562
 563     UNDEF => sub {
 564       puke "-$op => undef not supported";
 565     },
 566    });
 567 }
 568
 569 sub _where_op_NEST {
 570   my ($self, $op, $v) = @_;
 571
 572   $self->_SWITCH_refkind($v, {
 573
 574     SCALAR => sub { # permissively interpreted as SQL
 575       belch "literal SQL should be -nest => \\'scalar' "
 576           . "instead of -nest => 'scalar' ";
 577       return ($v);
 578     },
 579
 580     UNDEF => sub {
 581       puke "-$op => undef not supported";
 582     },
 583
 584     FALLBACK => sub {
 585       $self->_recurse_where ($v);
 586     },
 587
 588    });
 589 }
 590
 591
 592 sub _where_op_BOOL {
 593   my ($self, $op, $v) = @_;
 594
 595   my ( $prefix, $suffix ) = ( $op =~ /\bnot\b/i )
 596     ? ( '(NOT ', ')' )
 597     : ( '', '' );
 598
 599   my ($sql, @bind) = do {
 600     $self->_SWITCH_refkind($v, {
 601       SCALAR => sub { # interpreted as SQL column
 602         $self->_convert($self->_quote($v));
 603       },
 604
 605       UNDEF => sub {
 606         puke "-$op => undef not supported";
 607       },
 608
 609       FALLBACK => sub {
 610         $self->_recurse_where ($v);
 611       },
 612     });
 613   };
 614
 615   return (
 616     join ('', $prefix, $sql, $suffix),
 617     @bind,
 618   );
 619 }
 620
 621
 622 sub _where_hashpair_ARRAYREF {
 623   my ($self, $k, $v) = @_;
 624
 625   if( @$v ) {
 626     my @v = @$v; # need copy because of shift below
 627     $self->_debug("ARRAY($k) means distribute over elements");
 628
 629     # put apart first element if it is an operator (-and, -or)
 630     my $op = (
 631        (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
 632          ? shift @v
 633          : ''
 634     );
 635     my @distributed = map { {$k =>  $_} } @v;
 636
 637     if ($op) {
 638       $self->_debug("OP($op) reinjected into the distributed array");
 639       unshift @distributed, $op;
 640     }
 641
 642     my $logic = $op ? substr($op, 1) : '';
 643
 644     return $self->_recurse_where(\@distributed, $logic);
 645   }
 646   else {
 647     # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
 648     $self->_debug("empty ARRAY($k) means 0=1");
 649     return ($self->{sqlfalse});
 650   }
 651 }
 652
 653 sub _where_hashpair_HASHREF {
 654   my ($self, $k, $v, $logic) = @_;
 655   $logic ||= 'and';
 656
 657   local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
 658   $self->{_nested_func_lhs} ||= $k;
 659
 660   my ($all_sql, @all_bind);
 661
 662   for my $orig_op (sort keys %$v) {
 663     my $val = $v->{$orig_op};
 664
 665     # put the operator in canonical form
 666     my $op = $orig_op;
 667     $op =~ s/^-//;        # remove initial dash
 668     $op =~ s/[_\t ]+/ /g; # underscores and whitespace become single spaces
 669     $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
 670
 671     my ($sql, @bind);
 672
 673     # CASE: col-value logic modifiers
 674     if ( $orig_op =~ /^ \- (and|or) $/xi ) {
 675       ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
 676     }
 677     # CASE: special operators like -in or -between
 678     elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
 679       my $handler = $special_op->{handler};
 680       if (! $handler) {
 681         puke "No handler supplied for special operator $orig_op";
 682       }
 683       elsif (not ref $handler) {
 684         ($sql, @bind) = $self->$handler ($k, $op, $val);
 685       }
 686       elsif (ref $handler eq 'CODE') {
 687         ($sql, @bind) = $handler->($self, $k, $op, $val);
 688       }
 689       else {
 690         puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
 691       }
 692     }
 693     else {
 694       $self->_SWITCH_refkind($val, {
 695
 696         ARRAYREF => sub {       # CASE: col => {op => \@vals}
 697           ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
 698         },
 699
 700         ARRAYREFREF => sub {    # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
 701           my ($sub_sql, @sub_bind) = @$$val;
 702           $self->_assert_bindval_matches_bindtype(@sub_bind);
 703           $sql  = join ' ', $self->_convert($self->_quote($k)),
 704                             $self->_sqlcase($op),
 705                             $sub_sql;
 706           @bind = @sub_bind;
 707         },
 708
 709         UNDEF => sub {          # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
 710           my $is = ($op =~ $self->{equality_op})   ? 'is'     :
 711                    ($op =~ $self->{inequality_op}) ? 'is not' :
 712                puke "unexpected operator '$orig_op' with undef operand";
 713           $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
 714         },
 715
 716         FALLBACK => sub {       # CASE: col => {op/func => $stuff}
 717           ($sql, @bind) = $self->_where_func_generic ($op, $val);
 718           $sql = join ' ', $self->_convert($self->_quote($k)), $sql;
 719         },
 720       });
 721     }
 722
 723     ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
 724     push @all_bind, @bind;
 725   }
 726   return ($all_sql, @all_bind);
 727 }
 728
 729
 730
 731 sub _where_field_op_ARRAYREF {
 732   my ($self, $k, $op, $vals) = @_;
 733
 734   my @vals = @$vals;  #always work on a copy
 735
 736   if(@vals) {
 737     $self->_debug(sprintf '%s means multiple elements: [ %s ]',
 738       $vals,
 739       join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
 740     );
 741
 742     # see if the first element is an -and/-or op
 743     my $logic;
 744     if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
 745       $logic = uc $1;
 746       shift @vals;
 747     }
 748
 749     # distribute $op over each remaining member of @vals, append logic if exists
 750     return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 751
 752     # LDNOTE : had planned to change the distribution logic when
 753     # $op =~ $self->{inequality_op}, because of Morgan laws :
 754     # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
 755     # WHERE field != 22 OR  field != 33 : the user probably means
 756     # WHERE field != 22 AND field != 33.
 757     # To do this, replace the above to roughly :
 758     # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
 759     # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
 760
 761   }
 762   else {
 763     # try to DWIM on equality operators
 764     # LDNOTE : not 100% sure this is the correct thing to do ...
 765     return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
 766     return ($self->{sqltrue})  if $op =~ $self->{inequality_op};
 767
 768     # otherwise
 769     puke "operator '$op' applied on an empty array (field '$k')";
 770   }
 771 }
 772
 773
 774 sub _where_hashpair_SCALARREF {
 775   my ($self, $k, $v) = @_;
 776   $self->_debug("SCALAR($k) means literal SQL: $$v");
 777   my $sql = $self->_quote($k) . " " . $$v;
 778   return ($sql);
 779 }
 780
 781 # literal SQL with bind
 782 sub _where_hashpair_ARRAYREFREF {
 783   my ($self, $k, $v) = @_;
 784   $self->_debug("REF($k) means literal SQL: @${$v}");
 785   my ($sql, @bind) = @${$v};
 786   $self->_assert_bindval_matches_bindtype(@bind);
 787   $sql  = $self->_quote($k) . " " . $sql;
 788   return ($sql, @bind );
 789 }
 790
 791 # literal SQL without bind
 792 sub _where_hashpair_SCALAR {
 793   my ($self, $k, $v) = @_;
 794   $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
 795   my $sql = join ' ', $self->_convert($self->_quote($k)),
 796                       $self->_sqlcase($self->{cmp}),
 797                       $self->_convert('?');
 798   my @bind =  $self->_bindtype($k, $v);
 799   return ( $sql, @bind);
 800 }
 801
 802
 803 sub _where_hashpair_UNDEF {
 804   my ($self, $k, $v) = @_;
 805   $self->_debug("UNDEF($k) means IS NULL");
 806   my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
 807   return ($sql);
 808 }
 809
 810 #======================================================================
 811 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
 812 #======================================================================
 813
 814
 815 sub _where_SCALARREF {
 816   my ($self, $where) = @_;
 817
 818   # literal sql
 819   $self->_debug("SCALAR(*top) means literal SQL: $$where");
 820   return ($$where);
 821 }
 822
 823
 824 sub _where_SCALAR {
 825   my ($self, $where) = @_;
 826
 827   # literal sql
 828   $self->_debug("NOREF(*top) means literal SQL: $where");
 829   return ($where);
 830 }
 831
 832
 833 sub _where_UNDEF {
 834   my ($self) = @_;
 835   return ();
 836 }
 837
 838
 839 #======================================================================
 840 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
 841 #======================================================================
 842
 843
 844 sub _where_field_BETWEEN {
 845   my ($self, $k, $op, $vals) = @_;
 846
 847   my ($label, $and, $placeholder);
 848   $label       = $self->_convert($self->_quote($k));
 849   $and         = ' ' . $self->_sqlcase('and') . ' ';
 850   $placeholder = $self->_convert('?');
 851   $op               = $self->_sqlcase($op);
 852
 853   my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
 854     ARRAYREFREF => sub {
 855       return @$$vals;
 856     },
 857     SCALARREF => sub {
 858       return $$vals;
 859     },
 860     ARRAYREF => sub {
 861       puke "special op 'between' accepts an arrayref with exactly two values"
 862         if @$vals != 2;
 863
 864       my (@all_sql, @all_bind);
 865       foreach my $val (@$vals) {
 866         my ($sql, @bind) = $self->_SWITCH_refkind($val, {
 867            SCALAR => sub {
 868              return ($placeholder, ($val));
 869            },
 870            SCALARREF => sub {
 871              return ($self->_convert($$val), ());
 872            },
 873            ARRAYREFREF => sub {
 874              my ($sql, @bind) = @$$val;
 875              return ($self->_convert($sql), @bind);
 876            },
 877         });
 878         push @all_sql, $sql;
 879         push @all_bind, @bind;
 880       }
 881
 882       return (
 883         (join $and, @all_sql),
 884         $self->_bindtype($k, @all_bind),
 885       );
 886     },
 887     FALLBACK => sub {
 888       puke "special op 'between' accepts an arrayref with two values, or a single literal scalarref/arrayref-ref";
 889     },
 890   });
 891
 892   my $sql = "( $label $op $clause )";
 893   return ($sql, @bind)
 894 }
 895
 896
 897 sub _where_field_IN {
 898   my ($self, $k, $op, $vals) = @_;
 899
 900   # backwards compatibility : if scalar, force into an arrayref
 901   $vals = [$vals] if defined $vals && ! ref $vals;
 902
 903   my ($label)       = $self->_convert($self->_quote($k));
 904   my ($placeholder) = $self->_convert('?');
 905   $op               = $self->_sqlcase($op);
 906
 907   my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
 908     ARRAYREF => sub {     # list of choices
 909       if (@$vals) { # nonempty list
 910         my $placeholders  = join ", ", (($placeholder) x @$vals);
 911         my $sql           = "$label $op ( $placeholders )";
 912         my @bind = $self->_bindtype($k, @$vals);
 913
 914         return ($sql, @bind);
 915       }
 916       else { # empty list : some databases won't understand "IN ()", so DWIM
 917         my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
 918         return ($sql);
 919       }
 920     },
 921
 922     SCALARREF => sub {  # literal SQL
 923       my $sql = $self->_open_outer_paren ($$vals);
 924       return ("$label $op ( $sql )");
 925     },
 926     ARRAYREFREF => sub {  # literal SQL with bind
 927       my ($sql, @bind) = @$$vals;
 928       $self->_assert_bindval_matches_bindtype(@bind);
 929       $sql = $self->_open_outer_paren ($sql);
 930       return ("$label $op ( $sql )", @bind);
 931     },
 932
 933     FALLBACK => sub {
 934       puke "special op 'in' requires an arrayref (or scalarref/arrayref-ref)";
 935     },
 936   });
 937
 938   return ($sql, @bind);
 939 }
 940
 941 # Some databases (SQLite) treat col IN (1, 2) different from
 942 # col IN ( (1, 2) ). Use this to strip all outer parens while
 943 # adding them back in the corresponding method
 944 sub _open_outer_paren {
 945   my ($self, $sql) = @_;
 946   $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
 947   return $sql;
 948 }
 949
 950
 951 #======================================================================
 952 # ORDER BY
 953 #======================================================================
 954
 955 sub _order_by {
 956   my ($self, $arg) = @_;
 957
 958   my (@sql, @bind);
 959   for my $c ($self->_order_by_chunks ($arg) ) {
 960     $self->_SWITCH_refkind ($c, {
 961       SCALAR => sub { push @sql, $c },
 962       ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
 963     });
 964   }
 965
 966   my $sql = @sql
 967     ? sprintf ('%s %s',
 968         $self->_sqlcase(' order by'),
 969         join (', ', @sql)
 970       )
 971     : ''
 972   ;
 973
 974   return wantarray ? ($sql, @bind) : $sql;
 975 }
 976
 977 sub _order_by_chunks {
 978   my ($self, $arg) = @_;
 979
 980   return $self->_SWITCH_refkind($arg, {
 981
 982     ARRAYREF => sub {
 983       map { $self->_order_by_chunks ($_ ) } @$arg;
 984     },
 985
 986     ARRAYREFREF => sub { [ @$$arg ] },
 987
 988     SCALAR    => sub {$self->_quote($arg)},
 989
 990     UNDEF     => sub {return () },
 991
 992     SCALARREF => sub {$$arg}, # literal SQL, no quoting
 993
 994     HASHREF   => sub {
 995       # get first pair in hash
 996       my ($key, $val) = each %$arg;
 997
 998       return () unless $key;
 999
1000       if ( (keys %$arg) > 1 or not $key =~ /^-(desc|asc)/i ) {
1001         puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
1002       }
1003
1004       my $direction = $1;
1005
1006       my @ret;
1007       for my $c ($self->_order_by_chunks ($val)) {
1008         my ($sql, @bind);
1009
1010         $self->_SWITCH_refkind ($c, {
1011           SCALAR => sub {
1012             $sql = $c;
1013           },
1014           ARRAYREF => sub {
1015             ($sql, @bind) = @$c;
1016           },
1017         });
1018
1019         $sql = $sql . ' ' . $self->_sqlcase($direction);
1020
1021         push @ret, [ $sql, @bind];
1022       }
1023
1024       return @ret;
1025     },
1026   });
1027 }
1028
1029
1030 #======================================================================
1031 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1032 #======================================================================
1033
1034 sub _table  {
1035   my $self = shift;
1036   my $from = shift;
1037   $self->_SWITCH_refkind($from, {
1038     ARRAYREF     => sub {join ', ', map { $self->_quote($_) } @$from;},
1039     SCALAR       => sub {$self->_quote($from)},
1040     SCALARREF    => sub {$$from},
1041     ARRAYREFREF  => sub {join ', ', @$from;},
1042   });
1043 }
1044
1045
1046 #======================================================================
1047 # UTILITY FUNCTIONS
1048 #======================================================================
1049
1050 sub _quote {
1051   my $self  = shift;
1052   my $label = shift;
1053
1054   $label or puke "can't quote an empty label";
1055
1056   # left and right quote characters
1057   my ($ql, $qr, @other) = $self->_SWITCH_refkind($self->{quote_char}, {
1058     SCALAR   => sub {($self->{quote_char}, $self->{quote_char})},
1059     ARRAYREF => sub {@{$self->{quote_char}}},
1060     UNDEF    => sub {()},
1061    });
1062   not @other
1063       or puke "quote_char must be an arrayref of 2 values";
1064
1065   # no quoting if no quoting chars
1066   $ql or return $label;
1067
1068   # no quoting for literal SQL
1069   return $$label if ref($label) eq 'SCALAR';
1070
1071   # separate table / column (if applicable)
1072   my $sep = $self->{name_sep} || '';
1073   my @to_quote = $sep ? split /\Q$sep\E/, $label : ($label);
1074
1075   # do the quoting, except for "*" or for `table`.*
1076   my @quoted = map { $_ eq '*' ? $_: $ql.$_.$qr} @to_quote;
1077
1078   # reassemble and return.
1079   return join $sep, @quoted;
1080 }
1081
1082
1083 # Conversion, if applicable
1084 sub _convert ($) {
1085   my ($self, $arg) = @_;
1086
1087 # LDNOTE : modified the previous implementation below because
1088 # it was not consistent : the first "return" is always an array,
1089 # the second "return" is context-dependent. Anyway, _convert
1090 # seems always used with just a single argument, so make it a
1091 # scalar function.
1092 #     return @_ unless $self->{convert};
1093 #     my $conv = $self->_sqlcase($self->{convert});
1094 #     my @ret = map { $conv.'('.$_.')' } @_;
1095 #     return wantarray ? @ret : $ret[0];
1096   if ($self->{convert}) {
1097     my $conv = $self->_sqlcase($self->{convert});
1098     $arg = $conv.'('.$arg.')';
1099   }
1100   return $arg;
1101 }
1102
1103 # And bindtype
1104 sub _bindtype (@) {
1105   my $self = shift;
1106   my($col, @vals) = @_;
1107
1108   #LDNOTE : changed original implementation below because it did not make
1109   # sense when bindtype eq 'columns' and @vals > 1.
1110 #  return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1111
1112   return $self->{bindtype} eq 'columns' ? map {[$col, $_]} @vals : @vals;
1113 }
1114
1115 # Dies if any element of @bind is not in [colname => value] format
1116 # if bindtype is 'columns'.
1117 sub _assert_bindval_matches_bindtype {
1118   my ($self, @bind) = @_;
1119
1120   if ($self->{bindtype} eq 'columns') {
1121     foreach my $val (@bind) {
1122       if (!defined $val || ref($val) ne 'ARRAY' || @$val != 2) {
1123         die "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1124       }
1125     }
1126   }
1127 }
1128
1129 sub _join_sql_clauses {
1130   my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1131
1132   if (@$clauses_aref > 1) {
1133     my $join  = " " . $self->_sqlcase($logic) . " ";
1134     my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1135     return ($sql, @$bind_aref);
1136   }
1137   elsif (@$clauses_aref) {
1138     return ($clauses_aref->[0], @$bind_aref); # no parentheses
1139   }
1140   else {
1141     return (); # if no SQL, ignore @$bind_aref
1142   }
1143 }
1144
1145
1146 # Fix SQL case, if so requested
1147 sub _sqlcase {
1148   my $self = shift;
1149
1150   # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1151   # don't touch the argument ... crooked logic, but let's not change it!
1152   return $self->{case} ? $_[0] : uc($_[0]);
1153 }
1154
1155
1156 #======================================================================
1157 # DISPATCHING FROM REFKIND
1158 #======================================================================
1159
1160 sub _refkind {
1161   my ($self, $data) = @_;
1162   my $suffix = '';
1163   my $ref;
1164   my $n_steps = 0;
1165
1166   while (1) {
1167     # blessed objects are treated like scalars
1168     $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1169     $n_steps += 1 if $ref;
1170     last          if $ref ne 'REF';
1171     $data = $$data;
1172   }
1173
1174   my $base = $ref || (defined $data ? 'SCALAR' : 'UNDEF');
1175
1176   return $base . ('REF' x $n_steps);
1177 }
1178
1179
1180
1181 sub _try_refkind {
1182   my ($self, $data) = @_;
1183   my @try = ($self->_refkind($data));
1184   push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1185   push @try, 'FALLBACK';
1186   return @try;
1187 }
1188
1189 sub _METHOD_FOR_refkind {
1190   my ($self, $meth_prefix, $data) = @_;
1191   my $method = List::Util::first {$_} map {$self->can($meth_prefix."_".$_)}
1192                               $self->_try_refkind($data)
1193     or puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1194   return $method;
1195 }
1196
1197
1198 sub _SWITCH_refkind {
1199   my ($self, $data, $dispatch_table) = @_;
1200
1201   my $coderef = List::Util::first {$_} map {$dispatch_table->{$_}}
1202                                $self->_try_refkind($data)
1203     or puke "no dispatch entry for ".$self->_refkind($data);
1204   $coderef->();
1205 }
1206
1207
1208
1209
1210 #======================================================================
1211 # VALUES, GENERATE, AUTOLOAD
1212 #======================================================================
1213
1214 # LDNOTE: original code from nwiger, didn't touch code in that section
1215 # I feel the AUTOLOAD stuff should not be the default, it should
1216 # only be activated on explicit demand by user.
1217
1218 sub values {
1219     my $self = shift;
1220     my $data = shift || return;
1221     puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1222         unless ref $data eq 'HASH';
1223
1224     my @all_bind;
1225     foreach my $k ( sort keys %$data ) {
1226         my $v = $data->{$k};
1227         $self->_SWITCH_refkind($v, {
1228           ARRAYREF => sub {
1229             if ($self->{array_datatypes}) { # array datatype
1230               push @all_bind, $self->_bindtype($k, $v);
1231             }
1232             else {                          # literal SQL with bind
1233               my ($sql, @bind) = @$v;
1234               $self->_assert_bindval_matches_bindtype(@bind);
1235               push @all_bind, @bind;
1236             }
1237           },
1238           ARRAYREFREF => sub { # literal SQL with bind
1239             my ($sql, @bind) = @${$v};
1240             $self->_assert_bindval_matches_bindtype(@bind);
1241             push @all_bind, @bind;
1242           },
1243           SCALARREF => sub {  # literal SQL without bind
1244           },
1245           SCALAR_or_UNDEF => sub {
1246             push @all_bind, $self->_bindtype($k, $v);
1247           },
1248         });
1249     }
1250
1251     return @all_bind;
1252 }
1253
1254 sub generate {
1255     my $self  = shift;
1256
1257     my(@sql, @sqlq, @sqlv);
1258
1259     for (@_) {
1260         my $ref = ref $_;
1261         if ($ref eq 'HASH') {
1262             for my $k (sort keys %$_) {
1263                 my $v = $_->{$k};
1264                 my $r = ref $v;
1265                 my $label = $self->_quote($k);
1266                 if ($r eq 'ARRAY') {
1267                     # literal SQL with bind
1268                     my ($sql, @bind) = @$v;
1269                     $self->_assert_bindval_matches_bindtype(@bind);
1270                     push @sqlq, "$label = $sql";
1271                     push @sqlv, @bind;
1272                 } elsif ($r eq 'SCALAR') {
1273                     # literal SQL without bind
1274                     push @sqlq, "$label = $$v";
1275                 } else {
1276                     push @sqlq, "$label = ?";
1277                     push @sqlv, $self->_bindtype($k, $v);
1278                 }
1279             }
1280             push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1281         } elsif ($ref eq 'ARRAY') {
1282             # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1283             for my $v (@$_) {
1284                 my $r = ref $v;
1285                 if ($r eq 'ARRAY') {   # literal SQL with bind
1286                     my ($sql, @bind) = @$v;
1287                     $self->_assert_bindval_matches_bindtype(@bind);
1288                     push @sqlq, $sql;
1289                     push @sqlv, @bind;
1290                 } elsif ($r eq 'SCALAR') {  # literal SQL without bind
1291                     # embedded literal SQL
1292                     push @sqlq, $$v;
1293                 } else {
1294                     push @sqlq, '?';
1295                     push @sqlv, $v;
1296                 }
1297             }
1298             push @sql, '(' . join(', ', @sqlq) . ')';
1299         } elsif ($ref eq 'SCALAR') {
1300             # literal SQL
1301             push @sql, $$_;
1302         } else {
1303             # strings get case twiddled
1304             push @sql, $self->_sqlcase($_);
1305         }
1306     }
1307
1308     my $sql = join ' ', @sql;
1309
1310     # this is pretty tricky
1311     # if ask for an array, return ($stmt, @bind)
1312     # otherwise, s/?/shift @sqlv/ to put it inline
1313     if (wantarray) {
1314         return ($sql, @sqlv);
1315     } else {
1316         1 while $sql =~ s/\?/my $d = shift(@sqlv);
1317                              ref $d ? $d->[1] : $d/e;
1318         return $sql;
1319     }
1320 }
1321
1322
1323 sub DESTROY { 1 }
1324
1325 sub AUTOLOAD {
1326     # This allows us to check for a local, then _form, attr
1327     my $self = shift;
1328     my($name) = $AUTOLOAD =~ /.*::(.+)/;
1329     return $self->generate($name, @_);
1330 }
1331
1332 1;
1333
1334
1335
1336 __END__
1337
1338 =head1 NAME
1339
1340 SQL::Abstract - Generate SQL from Perl data structures
1341
1342 =head1 SYNOPSIS
1343
1344     use SQL::Abstract;
1345
1346     my $sql = SQL::Abstract->new;
1347
1348     my($stmt, @bind) = $sql->select($table, \@fields, \%where, \@order);
1349
1350     my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1351
1352     my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1353
1354     my($stmt, @bind) = $sql->delete($table, \%where);
1355
1356     # Then, use these in your DBI statements
1357     my $sth = $dbh->prepare($stmt);
1358     $sth->execute(@bind);
1359
1360     # Just generate the WHERE clause
1361     my($stmt, @bind) = $sql->where(\%where, \@order);
1362
1363     # Return values in the same order, for hashed queries
1364     # See PERFORMANCE section for more details
1365     my @bind = $sql->values(\%fieldvals);
1366
1367 =head1 DESCRIPTION
1368
1369 This module was inspired by the excellent L<DBIx::Abstract>.
1370 However, in using that module I found that what I really wanted
1371 to do was generate SQL, but still retain complete control over my
1372 statement handles and use the DBI interface. So, I set out to
1373 create an abstract SQL generation module.
1374
1375 While based on the concepts used by L<DBIx::Abstract>, there are
1376 several important differences, especially when it comes to WHERE
1377 clauses. I have modified the concepts used to make the SQL easier
1378 to generate from Perl data structures and, IMO, more intuitive.
1379 The underlying idea is for this module to do what you mean, based
1380 on the data structures you provide it. The big advantage is that
1381 you don't have to modify your code every time your data changes,
1382 as this module figures it out.
1383
1384 To begin with, an SQL INSERT is as easy as just specifying a hash
1385 of C<key=value> pairs:
1386
1387     my %data = (
1388         name => 'Jimbo Bobson',
1389         phone => '123-456-7890',
1390         address => '42 Sister Lane',
1391         city => 'St. Louis',
1392         state => 'Louisiana',
1393     );
1394
1395 The SQL can then be generated with this:
1396
1397     my($stmt, @bind) = $sql->insert('people', \%data);
1398
1399 Which would give you something like this:
1400
1401     $stmt = "INSERT INTO people
1402                     (address, city, name, phone, state)
1403                     VALUES (?, ?, ?, ?, ?)";
1404     @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1405              '123-456-7890', 'Louisiana');
1406
1407 These are then used directly in your DBI code:
1408
1409     my $sth = $dbh->prepare($stmt);
1410     $sth->execute(@bind);
1411
1412 =head2 Inserting and Updating Arrays
1413
1414 If your database has array types (like for example Postgres),
1415 activate the special option C<< array_datatypes => 1 >>
1416 when creating the C<SQL::Abstract> object.
1417 Then you may use an arrayref to insert and update database array types:
1418
1419     my $sql = SQL::Abstract->new(array_datatypes => 1);
1420     my %data = (
1421         planets => [qw/Mercury Venus Earth Mars/]
1422     );
1423
1424     my($stmt, @bind) = $sql->insert('solar_system', \%data);
1425
1426 This results in:
1427
1428     $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1429
1430     @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1431
1432
1433 =head2 Inserting and Updating SQL
1434
1435 In order to apply SQL functions to elements of your C<%data> you may
1436 specify a reference to an arrayref for the given hash value. For example,
1437 if you need to execute the Oracle C<to_date> function on a value, you can
1438 say something like this:
1439
1440     my %data = (
1441         name => 'Bill',
1442         date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1443     );
1444
1445 The first value in the array is the actual SQL. Any other values are
1446 optional and would be included in the bind values array. This gives
1447 you:
1448
1449     my($stmt, @bind) = $sql->insert('people', \%data);
1450
1451     $stmt = "INSERT INTO people (name, date_entered)
1452                 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1453     @bind = ('Bill', '03/02/2003');
1454
1455 An UPDATE is just as easy, all you change is the name of the function:
1456
1457     my($stmt, @bind) = $sql->update('people', \%data);
1458
1459 Notice that your C<%data> isn't touched; the module will generate
1460 the appropriately quirky SQL for you automatically. Usually you'll
1461 want to specify a WHERE clause for your UPDATE, though, which is
1462 where handling C<%where> hashes comes in handy...
1463
1464 =head2 Complex where statements
1465
1466 This module can generate pretty complicated WHERE statements
1467 easily. For example, simple C<key=value> pairs are taken to mean
1468 equality, and if you want to see if a field is within a set
1469 of values, you can use an arrayref. Let's say we wanted to
1470 SELECT some data based on this criteria:
1471
1472     my %where = (
1473        requestor => 'inna',
1474        worker => ['nwiger', 'rcwe', 'sfz'],
1475        status => { '!=', 'completed' }
1476     );
1477
1478     my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1479
1480 The above would give you something like this:
1481
1482     $stmt = "SELECT * FROM tickets WHERE
1483                 ( requestor = ? ) AND ( status != ? )
1484                 AND ( worker = ? OR worker = ? OR worker = ? )";
1485     @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1486
1487 Which you could then use in DBI code like so:
1488
1489     my $sth = $dbh->prepare($stmt);
1490     $sth->execute(@bind);
1491
1492 Easy, eh?
1493
1494 =head1 FUNCTIONS
1495
1496 The functions are simple. There's one for each major SQL operation,
1497 and a constructor you use first. The arguments are specified in a
1498 similar order to each function (table, then fields, then a where
1499 clause) to try and simplify things.
1500
1501
1502
1503
1504 =head2 new(option => 'value')
1505
1506 The C<new()> function takes a list of options and values, and returns
1507 a new B<SQL::Abstract> object which can then be used to generate SQL
1508 through the methods below. The options accepted are:
1509
1510 =over
1511
1512 =item case
1513
1514 If set to 'lower', then SQL will be generated in all lowercase. By
1515 default SQL is generated in "textbook" case meaning something like:
1516
1517     SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1518
1519 Any setting other than 'lower' is ignored.
1520
1521 =item cmp
1522
1523 This determines what the default comparison operator is. By default
1524 it is C<=>, meaning that a hash like this:
1525
1526     %where = (name => 'nwiger', email => 'nate@wiger.org');
1527
1528 Will generate SQL like this:
1529
1530     WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1531
1532 However, you may want loose comparisons by default, so if you set
1533 C<cmp> to C<like> you would get SQL such as:
1534
1535     WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1536
1537 You can also override the comparsion on an individual basis - see
1538 the huge section on L</"WHERE CLAUSES"> at the bottom.
1539
1540 =item sqltrue, sqlfalse
1541
1542 Expressions for inserting boolean values within SQL statements.
1543 By default these are C<1=1> and C<1=0>. They are used
1544 by the special operators C<-in> and C<-not_in> for generating
1545 correct SQL even when the argument is an empty array (see below).
1546
1547 =item logic
1548
1549 This determines the default logical operator for multiple WHERE
1550 statements in arrays or hashes. If absent, the default logic is "or"
1551 for arrays, and "and" for hashes. This means that a WHERE
1552 array of the form:
1553
1554     @where = (
1555         event_date => {'>=', '2/13/99'},
1556         event_date => {'<=', '4/24/03'},
1557     );
1558
1559 will generate SQL like this:
1560
1561     WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1562
1563 This is probably not what you want given this query, though (look
1564 at the dates). To change the "OR" to an "AND", simply specify:
1565
1566     my $sql = SQL::Abstract->new(logic => 'and');
1567
1568 Which will change the above C<WHERE> to:
1569
1570     WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1571
1572 The logic can also be changed locally by inserting
1573 a modifier in front of an arrayref :
1574
1575     @where = (-and => [event_date => {'>=', '2/13/99'},
1576                        event_date => {'<=', '4/24/03'} ]);
1577
1578 See the L</"WHERE CLAUSES"> section for explanations.
1579
1580 =item convert
1581
1582 This will automatically convert comparisons using the specified SQL
1583 function for both column and value. This is mostly used with an argument
1584 of C<upper> or C<lower>, so that the SQL will have the effect of
1585 case-insensitive "searches". For example, this:
1586
1587     $sql = SQL::Abstract->new(convert => 'upper');
1588     %where = (keywords => 'MaKe iT CAse inSeNSItive');
1589
1590 Will turn out the following SQL:
1591
1592     WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1593
1594 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1595 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1596 not validate this option; it will just pass through what you specify verbatim).
1597
1598 =item bindtype
1599
1600 This is a kludge because many databases suck. For example, you can't
1601 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1602 Instead, you have to use C<bind_param()>:
1603
1604     $sth->bind_param(1, 'reg data');
1605     $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1606
1607 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1608 which loses track of which field each slot refers to. Fear not.
1609
1610 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1611 Currently, you can specify either C<normal> (default) or C<columns>. If you
1612 specify C<columns>, you will get an array that looks like this:
1613
1614     my $sql = SQL::Abstract->new(bindtype => 'columns');
1615     my($stmt, @bind) = $sql->insert(...);
1616
1617     @bind = (
1618         [ 'column1', 'value1' ],
1619         [ 'column2', 'value2' ],
1620         [ 'column3', 'value3' ],
1621     );
1622
1623 You can then iterate through this manually, using DBI's C<bind_param()>.
1624
1625     $sth->prepare($stmt);
1626     my $i = 1;
1627     for (@bind) {
1628         my($col, $data) = @$_;
1629         if ($col eq 'details' || $col eq 'comments') {
1630             $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1631         } elsif ($col eq 'image') {
1632             $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1633         } else {
1634             $sth->bind_param($i, $data);
1635         }
1636         $i++;
1637     }
1638     $sth->execute;      # execute without @bind now
1639
1640 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1641 Basically, the advantage is still that you don't have to care which fields
1642 are or are not included. You could wrap that above C<for> loop in a simple
1643 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1644 get a layer of abstraction over manual SQL specification.
1645
1646 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1647 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1648 will expect the bind values in this format.
1649
1650 =item quote_char
1651
1652 This is the character that a table or column name will be quoted
1653 with.  By default this is an empty string, but you could set it to
1654 the character C<`>, to generate SQL like this:
1655
1656   SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1657
1658 Alternatively, you can supply an array ref of two items, the first being the left
1659 hand quote character, and the second the right hand quote character. For
1660 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1661 that generates SQL like this:
1662
1663   SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1664
1665 Quoting is useful if you have tables or columns names that are reserved
1666 words in your database's SQL dialect.
1667
1668 =item name_sep
1669
1670 This is the character that separates a table and column name.  It is
1671 necessary to specify this when the C<quote_char> option is selected,
1672 so that tables and column names can be individually quoted like this:
1673
1674   SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1675
1676 =item array_datatypes
1677
1678 When this option is true, arrayrefs in INSERT or UPDATE are
1679 interpreted as array datatypes and are passed directly
1680 to the DBI layer.
1681 When this option is false, arrayrefs are interpreted
1682 as literal SQL, just like refs to arrayrefs
1683 (but this behavior is for backwards compatibility; when writing
1684 new queries, use the "reference to arrayref" syntax
1685 for literal SQL).
1686
1687
1688 =item special_ops
1689
1690 Takes a reference to a list of "special operators"
1691 to extend the syntax understood by L<SQL::Abstract>.
1692 See section L</"SPECIAL OPERATORS"> for details.
1693
1694 =item unary_ops
1695
1696 Takes a reference to a list of "unary operators"
1697 to extend the syntax understood by L<SQL::Abstract>.
1698 See section L</"UNARY OPERATORS"> for details.
1699
1700
1701
1702 =back
1703
1704 =head2 insert($table, \@values || \%fieldvals, \%options)
1705
1706 This is the simplest function. You simply give it a table name
1707 and either an arrayref of values or hashref of field/value pairs.
1708 It returns an SQL INSERT statement and a list of bind values.
1709 See the sections on L</"Inserting and Updating Arrays"> and
1710 L</"Inserting and Updating SQL"> for information on how to insert
1711 with those data types.
1712
1713 The optional C<\%options> hash reference may contain additional
1714 options to generate the insert SQL. Currently supported options
1715 are:
1716
1717 =over 4
1718
1719 =item returning
1720
1721 Takes either a scalar of raw SQL fields, or an array reference of
1722 field names, and adds on an SQL C<RETURNING> statement at the end.
1723 This allows you to return data generated by the insert statement
1724 (such as row IDs) without performing another C<SELECT> statement.
1725 Note, however, this is not part of the SQL standard and may not
1726 be supported by all database engines.
1727
1728 =back
1729
1730 =head2 update($table, \%fieldvals, \%where)
1731
1732 This takes a table, hashref of field/value pairs, and an optional
1733 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1734 of bind values.
1735 See the sections on L</"Inserting and Updating Arrays"> and
1736 L</"Inserting and Updating SQL"> for information on how to insert
1737 with those data types.
1738
1739 =head2 select($source, $fields, $where, $order)
1740
1741 This returns a SQL SELECT statement and associated list of bind values, as
1742 specified by the arguments  :
1743
1744 =over
1745
1746 =item $source
1747
1748 Specification of the 'FROM' part of the statement.
1749 The argument can be either a plain scalar (interpreted as a table
1750 name, will be quoted), or an arrayref (interpreted as a list
1751 of table names, joined by commas, quoted), or a scalarref
1752 (literal table name, not quoted), or a ref to an arrayref
1753 (list of literal table names, joined by commas, not quoted).
1754
1755 =item $fields
1756
1757 Specification of the list of fields to retrieve from
1758 the source.
1759 The argument can be either an arrayref (interpreted as a list
1760 of field names, will be joined by commas and quoted), or a
1761 plain scalar (literal SQL, not quoted).
1762 Please observe that this API is not as flexible as for
1763 the first argument C<$table>, for backwards compatibility reasons.
1764
1765 =item $where
1766
1767 Optional argument to specify the WHERE part of the query.
1768 The argument is most often a hashref, but can also be
1769 an arrayref or plain scalar --
1770 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1771
1772 =item $order
1773
1774 Optional argument to specify the ORDER BY part of the query.
1775 The argument can be a scalar, a hashref or an arrayref
1776 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1777 for details.
1778
1779 =back
1780
1781
1782 =head2 delete($table, \%where)
1783
1784 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1785 It returns an SQL DELETE statement and list of bind values.
1786
1787 =head2 where(\%where, \@order)
1788
1789 This is used to generate just the WHERE clause. For example,
1790 if you have an arbitrary data structure and know what the
1791 rest of your SQL is going to look like, but want an easy way
1792 to produce a WHERE clause, use this. It returns an SQL WHERE
1793 clause and list of bind values.
1794
1795
1796 =head2 values(\%data)
1797
1798 This just returns the values from the hash C<%data>, in the same
1799 order that would be returned from any of the other above queries.
1800 Using this allows you to markedly speed up your queries if you
1801 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1802
1803 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1804
1805 Warning: This is an experimental method and subject to change.
1806
1807 This returns arbitrarily generated SQL. It's a really basic shortcut.
1808 It will return two different things, depending on return context:
1809
1810     my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
1811     my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
1812
1813 These would return the following:
1814
1815     # First calling form
1816     $stmt = "CREATE TABLE test (?, ?)";
1817     @bind = (field1, field2);
1818
1819     # Second calling form
1820     $stmt_and_val = "CREATE TABLE test (field1, field2)";
1821
1822 Depending on what you're trying to do, it's up to you to choose the correct
1823 format. In this example, the second form is what you would want.
1824
1825 By the same token:
1826
1827     $sql->generate('alter session', { nls_date_format => 'MM/YY' });
1828
1829 Might give you:
1830
1831     ALTER SESSION SET nls_date_format = 'MM/YY'
1832
1833 You get the idea. Strings get their case twiddled, but everything
1834 else remains verbatim.
1835
1836
1837
1838
1839 =head1 WHERE CLAUSES
1840
1841 =head2 Introduction
1842
1843 This module uses a variation on the idea from L<DBIx::Abstract>. It
1844 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
1845 module is that things in arrays are OR'ed, and things in hashes
1846 are AND'ed.>
1847
1848 The easiest way to explain is to show lots of examples. After
1849 each C<%where> hash shown, it is assumed you used:
1850
1851     my($stmt, @bind) = $sql->where(\%where);
1852
1853 However, note that the C<%where> hash can be used directly in any
1854 of the other functions as well, as described above.
1855
1856 =head2 Key-value pairs
1857
1858 So, let's get started. To begin, a simple hash:
1859
1860     my %where  = (
1861         user   => 'nwiger',
1862         status => 'completed'
1863     );
1864
1865 Is converted to SQL C<key = val> statements:
1866
1867     $stmt = "WHERE user = ? AND status = ?";
1868     @bind = ('nwiger', 'completed');
1869
1870 One common thing I end up doing is having a list of values that
1871 a field can be in. To do this, simply specify a list inside of
1872 an arrayref:
1873
1874     my %where  = (
1875         user   => 'nwiger',
1876         status => ['assigned', 'in-progress', 'pending'];
1877     );
1878
1879 This simple code will create the following:
1880
1881     $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
1882     @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
1883
1884 A field associated to an empty arrayref will be considered a
1885 logical false and will generate 0=1.
1886
1887 =head2 Specific comparison operators
1888
1889 If you want to specify a different type of operator for your comparison,
1890 you can use a hashref for a given column:
1891
1892     my %where  = (
1893         user   => 'nwiger',
1894         status => { '!=', 'completed' }
1895     );
1896
1897 Which would generate:
1898
1899     $stmt = "WHERE user = ? AND status != ?";
1900     @bind = ('nwiger', 'completed');
1901
1902 To test against multiple values, just enclose the values in an arrayref:
1903
1904     status => { '=', ['assigned', 'in-progress', 'pending'] };
1905
1906 Which would give you:
1907
1908     "WHERE status = ? OR status = ? OR status = ?"
1909
1910
1911 The hashref can also contain multiple pairs, in which case it is expanded
1912 into an C<AND> of its elements:
1913
1914     my %where  = (
1915         user   => 'nwiger',
1916         status => { '!=', 'completed', -not_like => 'pending%' }
1917     );
1918
1919     # Or more dynamically, like from a form
1920     $where{user} = 'nwiger';
1921     $where{status}{'!='} = 'completed';
1922     $where{status}{'-not_like'} = 'pending%';
1923
1924     # Both generate this
1925     $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
1926     @bind = ('nwiger', 'completed', 'pending%');
1927
1928
1929 To get an OR instead, you can combine it with the arrayref idea:
1930
1931     my %where => (
1932          user => 'nwiger',
1933          priority => [ {'=', 2}, {'!=', 1} ]
1934     );
1935
1936 Which would generate:
1937
1938     $stmt = "WHERE user = ? AND priority = ? OR priority != ?";
1939     @bind = ('nwiger', '2', '1');
1940
1941 If you want to include literal SQL (with or without bind values), just use a
1942 scalar reference or array reference as the value:
1943
1944     my %where  = (
1945         date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
1946         date_expires => { '<' => \"now()" }
1947     );
1948
1949 Which would generate:
1950
1951     $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
1952     @bind = ('11/26/2008');
1953
1954
1955 =head2 Logic and nesting operators
1956
1957 In the example above,
1958 there is a subtle trap if you want to say something like
1959 this (notice the C<AND>):
1960
1961     WHERE priority != ? AND priority != ?
1962
1963 Because, in Perl you I<can't> do this:
1964
1965     priority => { '!=', 2, '!=', 1 }
1966
1967 As the second C<!=> key will obliterate the first. The solution
1968 is to use the special C<-modifier> form inside an arrayref:
1969
1970     priority => [ -and => {'!=', 2},
1971                           {'!=', 1} ]
1972
1973
1974 Normally, these would be joined by C<OR>, but the modifier tells it
1975 to use C<AND> instead. (Hint: You can use this in conjunction with the
1976 C<logic> option to C<new()> in order to change the way your queries
1977 work by default.) B<Important:> Note that the C<-modifier> goes
1978 B<INSIDE> the arrayref, as an extra first element. This will
1979 B<NOT> do what you think it might:
1980
1981     priority => -and => [{'!=', 2}, {'!=', 1}]   # WRONG!
1982
1983 Here is a quick list of equivalencies, since there is some overlap:
1984
1985     # Same
1986     status => {'!=', 'completed', 'not like', 'pending%' }
1987     status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
1988
1989     # Same
1990     status => {'=', ['assigned', 'in-progress']}
1991     status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
1992     status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
1993
1994
1995
1996 =head2 Special operators : IN, BETWEEN, etc.
1997
1998 You can also use the hashref format to compare a list of fields using the
1999 C<IN> comparison operator, by specifying the list as an arrayref:
2000
2001     my %where  = (
2002         status   => 'completed',
2003         reportid => { -in => [567, 2335, 2] }
2004     );
2005
2006 Which would generate:
2007
2008     $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2009     @bind = ('completed', '567', '2335', '2');
2010
2011 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2012 the same way.
2013
2014 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2015 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2016 'sqltrue' (by default : C<1=1>).
2017
2018 In addition to the array you can supply a chunk of literal sql or
2019 literal sql with bind:
2020
2021     my %where = {
2022       customer => { -in => \[
2023         'SELECT cust_id FROM cust WHERE balance > ?',
2024         2000,
2025       ],
2026       status => { -in => \'SELECT status_codes FROM states' },
2027     };
2028
2029 would generate:
2030
2031     $stmt = "WHERE (
2032           customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2033       AND status IN ( SELECT status_codes FROM states )
2034     )";
2035     @bind = ('2000');
2036
2037
2038
2039 Another pair of operators is C<-between> and C<-not_between>,
2040 used with an arrayref of two values:
2041
2042     my %where  = (
2043         user   => 'nwiger',
2044         completion_date => {
2045            -not_between => ['2002-10-01', '2003-02-06']
2046         }
2047     );
2048
2049 Would give you:
2050
2051     WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2052
2053 Just like with C<-in> all plausible combinations of literal SQL
2054 are possible:
2055
2056     my %where = {
2057       start0 => { -between => [ 1, 2 ] },
2058       start1 => { -between => \["? AND ?", 1, 2] },
2059       start2 => { -between => \"lower(x) AND upper(y)" },
2060       start3 => { -between => [
2061         \"lower(x)",
2062         \["upper(?)", 'stuff' ],
2063       ] },
2064     };
2065
2066 Would give you:
2067
2068     $stmt = "WHERE (
2069           ( start0 BETWEEN ? AND ?                )
2070       AND ( start1 BETWEEN ? AND ?                )
2071       AND ( start2 BETWEEN lower(x) AND upper(y)  )
2072       AND ( start3 BETWEEN lower(x) AND upper(?)  )
2073     )";
2074     @bind = (1, 2, 1, 2, 'stuff');
2075
2076
2077 These are the two builtin "special operators"; but the
2078 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2079
2080 =head2 Unary operators: bool
2081
2082 If you wish to test against boolean columns or functions within your
2083 database you can use the C<-bool> and C<-not_bool> operators. For
2084 example to test the column C<is_user> being true and the column
2085 <is_enabled> being false you would use:-
2086
2087     my %where  = (
2088         -bool       => 'is_user',
2089         -not_bool   => 'is_enabled',
2090     );
2091
2092 Would give you:
2093
2094     WHERE is_user AND NOT is_enabled
2095
2096 If a more complex combination is required, testing more conditions,
2097 then you should use the and/or operators:-
2098
2099     my %where  = (
2100         -and           => [
2101             -bool      => 'one',
2102             -bool      => 'two',
2103             -bool      => 'three',
2104             -not_bool  => 'four',
2105         ],
2106     );
2107
2108 Would give you:
2109
2110     WHERE one AND two AND three AND NOT four
2111
2112
2113 =head2 Nested conditions, -and/-or prefixes
2114
2115 So far, we've seen how multiple conditions are joined with a top-level
2116 C<AND>.  We can change this by putting the different conditions we want in
2117 hashes and then putting those hashes in an array. For example:
2118
2119     my @where = (
2120         {
2121             user   => 'nwiger',
2122             status => { -like => ['pending%', 'dispatched'] },
2123         },
2124         {
2125             user   => 'robot',
2126             status => 'unassigned',
2127         }
2128     );
2129
2130 This data structure would create the following:
2131
2132     $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2133                 OR ( user = ? AND status = ? ) )";
2134     @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2135
2136
2137 There is also a special C<-nest>
2138 operator which adds an additional set of parens, to create a subquery.
2139 For example, to get something like this:
2140
2141     $stmt = "WHERE user = ? AND ( workhrs > ? OR geo = ? )";
2142     @bind = ('nwiger', '20', 'ASIA');
2143
2144 You would do:
2145
2146     my %where = (
2147          user => 'nwiger',
2148         -nest => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2149     );
2150
2151
2152 Finally, clauses in hashrefs or arrayrefs can be
2153 prefixed with an C<-and> or C<-or> to change the logic
2154 inside :
2155
2156     my @where = (
2157          -and => [
2158             user => 'nwiger',
2159             -nest => [
2160                 -and => [workhrs => {'>', 20}, geo => 'ASIA' ],
2161                 -and => [workhrs => {'<', 50}, geo => 'EURO' ]
2162             ],
2163         ],
2164     );
2165
2166 That would yield:
2167
2168     WHERE ( user = ? AND
2169           ( ( workhrs > ? AND geo = ? )
2170          OR ( workhrs < ? AND geo = ? ) ) )
2171
2172
2173 =head2 Algebraic inconsistency, for historical reasons
2174
2175 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2176 operator goes C<outside> of the nested structure; whereas when connecting
2177 several constraints on one column, the C<-and> operator goes
2178 C<inside> the arrayref. Here is an example combining both features :
2179
2180    my @where = (
2181      -and => [a => 1, b => 2],
2182      -or  => [c => 3, d => 4],
2183       e   => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2184    )
2185
2186 yielding
2187
2188   WHERE ( (    ( a = ? AND b = ? )
2189             OR ( c = ? OR d = ? )
2190             OR ( e LIKE ? AND e LIKE ? ) ) )
2191
2192 This difference in syntax is unfortunate but must be preserved for
2193 historical reasons. So be careful : the two examples below would
2194 seem algebraically equivalent, but they are not
2195
2196   {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2197   # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2198
2199   [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2200   # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2201
2202
2203 =head2 Literal SQL
2204
2205 Finally, sometimes only literal SQL will do. If you want to include
2206 literal SQL verbatim, you can specify it as a scalar reference, namely:
2207
2208     my $inn = 'is Not Null';
2209     my %where = (
2210         priority => { '<', 2 },
2211         requestor => \$inn
2212     );
2213
2214 This would create:
2215
2216     $stmt = "WHERE priority < ? AND requestor is Not Null";
2217     @bind = ('2');
2218
2219 Note that in this example, you only get one bind parameter back, since
2220 the verbatim SQL is passed as part of the statement.
2221
2222 Of course, just to prove a point, the above can also be accomplished
2223 with this:
2224
2225     my %where = (
2226         priority  => { '<', 2 },
2227         requestor => { '!=', undef },
2228     );
2229
2230
2231 TMTOWTDI
2232
2233 Conditions on boolean columns can be expressed in the same way, passing
2234 a reference to an empty string, however using liternal SQL in this way
2235 is deprecated - the preferred method is to use the boolean operators -
2236 see L</"Unary operators: bool"> :
2237
2238     my %where = (
2239         priority  => { '<', 2 },
2240         is_ready  => \"";
2241     );
2242
2243 which yields
2244
2245     $stmt = "WHERE priority < ? AND is_ready";
2246     @bind = ('2');
2247
2248
2249 =head2 Literal SQL with placeholders and bind values (subqueries)
2250
2251 If the literal SQL to be inserted has placeholders and bind values,
2252 use a reference to an arrayref (yes this is a double reference --
2253 not so common, but perfectly legal Perl). For example, to find a date
2254 in Postgres you can use something like this:
2255
2256     my %where = (
2257        date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2258     )
2259
2260 This would create:
2261
2262     $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2263     @bind = ('10');
2264
2265 Note that you must pass the bind values in the same format as they are returned
2266 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2267 provide the bind values in the C<< [ column_meta => value ] >> format, where
2268 C<column_meta> is an opaque scalar value; most commonly the column name, but
2269 you can use any scalar value (including references and blessed references),
2270 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2271 to C<columns> the above example will look like:
2272
2273     my %where = (
2274        date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2275     )
2276
2277 Literal SQL is especially useful for nesting parenthesized clauses in the
2278 main SQL query. Here is a first example :
2279
2280   my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2281                                100, "foo%");
2282   my %where = (
2283     foo => 1234,
2284     bar => \["IN ($sub_stmt)" => @sub_bind],
2285   );
2286
2287 This yields :
2288
2289   $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2290                                              WHERE c2 < ? AND c3 LIKE ?))";
2291   @bind = (1234, 100, "foo%");
2292
2293 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2294 are expressed in the same way. Of course the C<$sub_stmt> and
2295 its associated bind values can be generated through a former call
2296 to C<select()> :
2297
2298   my ($sub_stmt, @sub_bind)
2299      = $sql->select("t1", "c1", {c2 => {"<" => 100},
2300                                  c3 => {-like => "foo%"}});
2301   my %where = (
2302     foo => 1234,
2303     bar => \["> ALL ($sub_stmt)" => @sub_bind],
2304   );
2305
2306 In the examples above, the subquery was used as an operator on a column;
2307 but the same principle also applies for a clause within the main C<%where>
2308 hash, like an EXISTS subquery :
2309
2310   my ($sub_stmt, @sub_bind)
2311      = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2312   my %where = (
2313     foo   => 1234,
2314     -nest => \["EXISTS ($sub_stmt)" => @sub_bind],
2315   );
2316
2317 which yields
2318
2319   $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2320                                         WHERE c1 = ? AND c2 > t0.c0))";
2321   @bind = (1234, 1);
2322
2323
2324 Observe that the condition on C<c2> in the subquery refers to
2325 column C<t0.c0> of the main query : this is I<not> a bind
2326 value, so we have to express it through a scalar ref.
2327 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2328 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2329 what we wanted here.
2330
2331 Another use of the subquery technique is when some SQL clauses need
2332 parentheses, as it often occurs with some proprietary SQL extensions
2333 like for example fulltext expressions, geospatial expressions,
2334 NATIVE clauses, etc. Here is an example of a fulltext query in MySQL :
2335
2336   my %where = (
2337     -nest => \["MATCH (col1, col2) AGAINST (?)" => qw/apples/]
2338   );
2339
2340 Finally, here is an example where a subquery is used
2341 for expressing unary negation:
2342
2343   my ($sub_stmt, @sub_bind)
2344      = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2345   $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2346   my %where = (
2347         lname  => {like => '%son%'},
2348         -nest  => \["NOT ($sub_stmt)" => @sub_bind],
2349     );
2350
2351 This yields
2352
2353   $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2354   @bind = ('%son%', 10, 20)
2355
2356
2357
2358 =head2 Conclusion
2359
2360 These pages could go on for a while, since the nesting of the data
2361 structures this module can handle are pretty much unlimited (the
2362 module implements the C<WHERE> expansion as a recursive function
2363 internally). Your best bet is to "play around" with the module a
2364 little to see how the data structures behave, and choose the best
2365 format for your data based on that.
2366
2367 And of course, all the values above will probably be replaced with
2368 variables gotten from forms or the command line. After all, if you
2369 knew everything ahead of time, you wouldn't have to worry about
2370 dynamically-generating SQL and could just hardwire it into your
2371 script.
2372
2373
2374
2375
2376 =head1 ORDER BY CLAUSES
2377
2378 Some functions take an order by clause. This can either be a scalar (just a
2379 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2380 or an array of either of the two previous forms. Examples:
2381
2382                Given            |         Will Generate
2383     ----------------------------------------------------------
2384                                 |
2385     \'colA DESC'                | ORDER BY colA DESC
2386                                 |
2387     'colA'                      | ORDER BY colA
2388                                 |
2389     [qw/colA colB/]             | ORDER BY colA, colB
2390                                 |
2391     {-asc  => 'colA'}           | ORDER BY colA ASC
2392                                 |
2393     {-desc => 'colB'}           | ORDER BY colB DESC
2394                                 |
2395     ['colA', {-asc => 'colB'}]  | ORDER BY colA, colB ASC
2396                                 |
2397     { -asc => [qw/colA colB] }  | ORDER BY colA ASC, colB ASC
2398                                 |
2399     [                           |
2400       { -asc => 'colA' },       | ORDER BY colA ASC, colB DESC,
2401       { -desc => [qw/colB/],    |          colC ASC, colD ASC
2402       { -asc => [qw/colC colD/],|
2403     ]                           |
2404     ===========================================================
2405
2406
2407
2408 =head1 SPECIAL OPERATORS
2409
2410   my $sqlmaker = SQL::Abstract->new(special_ops => [
2411      {
2412       regex => qr/.../,
2413       handler => sub {
2414         my ($self, $field, $op, $arg) = @_;
2415         ...
2416       },
2417      },
2418      {
2419       regex => qr/.../,
2420       handler => 'method_name',
2421      },
2422    ]);
2423
2424 A "special operator" is a SQL syntactic clause that can be
2425 applied to a field, instead of a usual binary operator.
2426 For example :
2427
2428    WHERE field IN (?, ?, ?)
2429    WHERE field BETWEEN ? AND ?
2430    WHERE MATCH(field) AGAINST (?, ?)
2431
2432 Special operators IN and BETWEEN are fairly standard and therefore
2433 are builtin within C<SQL::Abstract> (as the overridable methods
2434 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2435 like the MATCH .. AGAINST example above which is specific to MySQL,
2436 you can write your own operator handlers - supply a C<special_ops>
2437 argument to the C<new> method. That argument takes an arrayref of
2438 operator definitions; each operator definition is a hashref with two
2439 entries:
2440
2441 =over
2442
2443 =item regex
2444
2445 the regular expression to match the operator
2446
2447 =item handler
2448
2449 Either a coderef or a plain scalar method name. In both cases
2450 the expected return is C<< ($sql, @bind) >>.
2451
2452 When supplied with a method name, it is simply called on the
2453 L<SQL::Abstract/> object as:
2454
2455  $self->$method_name ($field, $op, $arg)
2456
2457  Where:
2458
2459   $op is the part that matched the handler regex
2460   $field is the LHS of the operator
2461   $arg is the RHS
2462
2463 When supplied with a coderef, it is called as:
2464
2465  $coderef->($self, $field, $op, $arg)
2466
2467
2468 =back
2469
2470 For example, here is an implementation
2471 of the MATCH .. AGAINST syntax for MySQL
2472
2473   my $sqlmaker = SQL::Abstract->new(special_ops => [
2474
2475     # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2476     {regex => qr/^match$/i,
2477      handler => sub {
2478        my ($self, $field, $op, $arg) = @_;
2479        $arg = [$arg] if not ref $arg;
2480        my $label         = $self->_quote($field);
2481        my ($placeholder) = $self->_convert('?');
2482        my $placeholders  = join ", ", (($placeholder) x @$arg);
2483        my $sql           = $self->_sqlcase('match') . " ($label) "
2484                          . $self->_sqlcase('against') . " ($placeholders) ";
2485        my @bind = $self->_bindtype($field, @$arg);
2486        return ($sql, @bind);
2487        }
2488      },
2489
2490   ]);
2491
2492
2493 =head1 UNARY OPERATORS
2494
2495   my $sqlmaker = SQL::Abstract->new(unary_ops => [
2496      {
2497       regex => qr/.../,
2498       handler => sub {
2499         my ($self, $op, $arg) = @_;
2500         ...
2501       },
2502      },
2503      {
2504       regex => qr/.../,
2505       handler => 'method_name',
2506      },
2507    ]);
2508
2509 A "unary operator" is a SQL syntactic clause that can be
2510 applied to a field - the operator goes before the field
2511
2512 You can write your own operator handlers - supply a C<unary_ops>
2513 argument to the C<new> method. That argument takes an arrayref of
2514 operator definitions; each operator definition is a hashref with two
2515 entries:
2516
2517 =over
2518
2519 =item regex
2520
2521 the regular expression to match the operator
2522
2523 =item handler
2524
2525 Either a coderef or a plain scalar method name. In both cases
2526 the expected return is C<< $sql >>.
2527
2528 When supplied with a method name, it is simply called on the
2529 L<SQL::Abstract/> object as:
2530
2531  $self->$method_name ($op, $arg)
2532
2533  Where:
2534
2535   $op is the part that matched the handler regex
2536   $arg is the RHS or argument of the operator
2537
2538 When supplied with a coderef, it is called as:
2539
2540  $coderef->($self, $op, $arg)
2541
2542
2543 =back
2544
2545
2546 =head1 PERFORMANCE
2547
2548 Thanks to some benchmarking by Mark Stosberg, it turns out that
2549 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2550 I must admit this wasn't an intentional design issue, but it's a
2551 byproduct of the fact that you get to control your C<DBI> handles
2552 yourself.
2553
2554 To maximize performance, use a code snippet like the following:
2555
2556     # prepare a statement handle using the first row
2557     # and then reuse it for the rest of the rows
2558     my($sth, $stmt);
2559     for my $href (@array_of_hashrefs) {
2560         $stmt ||= $sql->insert('table', $href);
2561         $sth  ||= $dbh->prepare($stmt);
2562         $sth->execute($sql->values($href));
2563     }
2564
2565 The reason this works is because the keys in your C<$href> are sorted
2566 internally by B<SQL::Abstract>. Thus, as long as your data retains
2567 the same structure, you only have to generate the SQL the first time
2568 around. On subsequent queries, simply use the C<values> function provided
2569 by this module to return your values in the correct order.
2570
2571
2572 =head1 FORMBUILDER
2573
2574 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2575 really like this part (I do, at least). Building up a complex query
2576 can be as simple as the following:
2577
2578     #!/usr/bin/perl
2579
2580     use CGI::FormBuilder;
2581     use SQL::Abstract;
2582
2583     my $form = CGI::FormBuilder->new(...);
2584     my $sql  = SQL::Abstract->new;
2585
2586     if ($form->submitted) {
2587         my $field = $form->field;
2588         my $id = delete $field->{id};
2589         my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2590     }
2591
2592 Of course, you would still have to connect using C<DBI> to run the
2593 query, but the point is that if you make your form look like your
2594 table, the actual query script can be extremely simplistic.
2595
2596 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2597 a fast interface to returning and formatting data. I frequently
2598 use these three modules together to write complex database query
2599 apps in under 50 lines.
2600
2601
2602 =head1 CHANGES
2603
2604 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2605 Great care has been taken to preserve the I<published> behavior
2606 documented in previous versions in the 1.* family; however,
2607 some features that were previously undocumented, or behaved
2608 differently from the documentation, had to be changed in order
2609 to clarify the semantics. Hence, client code that was relying
2610 on some dark areas of C<SQL::Abstract> v1.*
2611 B<might behave differently> in v1.50.
2612
2613 The main changes are :
2614
2615 =over
2616
2617 =item *
2618
2619 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2620
2621 =item *
2622
2623 support for the { operator => \"..." } construct (to embed literal SQL)
2624
2625 =item *
2626
2627 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2628
2629 =item *
2630
2631 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2632
2633 =item *
2634
2635 defensive programming : check arguments
2636
2637 =item *
2638
2639 fixed bug with global logic, which was previously implemented
2640 through global variables yielding side-effects. Prior versions would
2641 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2642 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2643 Now this is interpreted
2644 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2645
2646
2647 =item *
2648
2649 fixed semantics of  _bindtype on array args
2650
2651 =item *
2652
2653 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2654 we just avoid shifting arrays within that tree.
2655
2656 =item *
2657
2658 dropped the C<_modlogic> function
2659
2660 =back
2661
2662
2663
2664 =head1 ACKNOWLEDGEMENTS
2665
2666 There are a number of individuals that have really helped out with
2667 this module. Unfortunately, most of them submitted bugs via CPAN
2668 so I have no idea who they are! But the people I do know are:
2669
2670     Ash Berlin (order_by hash term support)
2671     Matt Trout (DBIx::Class support)
2672     Mark Stosberg (benchmarking)
2673     Chas Owens (initial "IN" operator support)
2674     Philip Collins (per-field SQL functions)
2675     Eric Kolve (hashref "AND" support)
2676     Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2677     Dan Kubb (support for "quote_char" and "name_sep")
2678     Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2679     Laurent Dami (internal refactoring, multiple -nest, extensible list of special operators, literal SQL)
2680     Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2681     Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2682     Oliver Charles (support for "RETURNING" after "INSERT")
2683
2684 Thanks!
2685
2686 =head1 SEE ALSO
2687
2688 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2689
2690 =head1 AUTHOR
2691
2692 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2693
2694 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2695
2696 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2697 While not an official support venue, C<DBIx::Class> makes heavy use of
2698 C<SQL::Abstract>, and as such list members there are very familiar with
2699 how to create queries.
2700
2701 =head1 LICENSE
2702
2703 This module is free software; you may copy this under the same
2704 terms as perl itself (either the GNU General Public License or
2705 the Artistic License)
2706
2707 =cut
2708