1 package SQL::Abstract; # see doc at end of file
3 # LDNOTE : this code is heavy refactoring from original SQLA.
4 # Several design decisions will need discussion during
5 # the test / diffusion / acceptance phase; those are marked with flag
6 # 'LDNOTE' (note by laurent.dami AT free.fr)
14 #======================================================================
16 #======================================================================
18 our $VERSION = '1.74';
20 # This would confuse some packagers
21 $VERSION = eval $VERSION if $VERSION =~ /_/; # numify for warning-free dev releases
25 # special operators (-in, -between). May be extended/overridden by user.
26 # See section WHERE: BUILTIN SPECIAL OPERATORS below for implementation
27 my @BUILTIN_SPECIAL_OPS = (
28 {regex => qr/^ (?: not \s )? between $/ix, handler => '_where_field_BETWEEN'},
29 {regex => qr/^ (?: not \s )? in $/ix, handler => '_where_field_IN'},
30 {regex => qr/^ ident $/ix, handler => '_where_op_IDENT'},
31 {regex => qr/^ value $/ix, handler => '_where_op_VALUE'},
34 # unaryish operators - key maps to handler
35 my @BUILTIN_UNARY_OPS = (
36 # the digits are backcompat stuff
37 { regex => qr/^ and (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
38 { regex => qr/^ or (?: [_\s]? \d+ )? $/xi, handler => '_where_op_ANDOR' },
39 { regex => qr/^ nest (?: [_\s]? \d+ )? $/xi, handler => '_where_op_NEST' },
40 { regex => qr/^ (?: not \s )? bool $/xi, handler => '_where_op_BOOL' },
41 { regex => qr/^ ident $/xi, handler => '_where_op_IDENT' },
42 { regex => qr/^ value $/ix, handler => '_where_op_VALUE' },
45 #======================================================================
46 # DEBUGGING AND ERROR REPORTING
47 #======================================================================
50 return unless $_[0]->{debug}; shift; # a little faster
51 my $func = (caller(1))[3];
52 warn "[$func] ", @_, "\n";
56 my($func) = (caller(1))[3];
57 Carp::carp "[$func] Warning: ", @_;
61 my($func) = (caller(1))[3];
62 Carp::croak "[$func] Fatal: ", @_;
66 #======================================================================
68 #======================================================================
72 my $class = ref($self) || $self;
73 my %opt = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
75 # choose our case by keeping an option around
76 delete $opt{case} if $opt{case} && $opt{case} ne 'lower';
78 # default logic for interpreting arrayrefs
79 $opt{logic} = $opt{logic} ? uc $opt{logic} : 'OR';
81 # how to return bind vars
82 # LDNOTE: changed nwiger code : why this 'delete' ??
83 # $opt{bindtype} ||= delete($opt{bind_type}) || 'normal';
84 $opt{bindtype} ||= 'normal';
86 # default comparison is "=", but can be overridden
89 # try to recognize which are the 'equality' and 'inequality' ops
90 # (temporary quickfix, should go through a more seasoned API)
91 $opt{equality_op} = qr/^(\Q$opt{cmp}\E|is|(is\s+)?like)$/i;
92 $opt{inequality_op} = qr/^(!=|<>|(is\s+)?not(\s+like)?)$/i;
95 $opt{sqltrue} ||= '1=1';
96 $opt{sqlfalse} ||= '0=1';
99 $opt{special_ops} ||= [];
100 # regexes are applied in order, thus push after user-defines
101 push @{$opt{special_ops}}, @BUILTIN_SPECIAL_OPS;
104 $opt{unary_ops} ||= [];
105 push @{$opt{unary_ops}}, @BUILTIN_UNARY_OPS;
107 # rudimentary sanity-check for user supplied bits treated as functions/operators
108 # If a purported function matches this regular expression, an exception is thrown.
109 # Literal SQL is *NOT* subject to this check, only functions (and column names
110 # when quoting is not in effect)
113 # need to guard against ()'s in column names too, but this will break tons of
114 # hacks... ideas anyone?
115 $opt{injection_guard} ||= qr/
121 return bless \%opt, $class;
125 sub _assert_pass_injection_guard {
126 if ($_[1] =~ $_[0]->{injection_guard}) {
127 my $class = ref $_[0];
128 puke "Possible SQL injection attempt '$_[1]'. If this is indeed a part of the "
129 . "desired SQL use literal SQL ( \'...' or \[ '...' ] ) or supply your own "
130 . "{injection_guard} attribute to ${class}->new()"
135 #======================================================================
137 #======================================================================
141 my $table = $self->_table(shift);
142 my $data = shift || return;
145 my $method = $self->_METHOD_FOR_refkind("_insert", $data);
146 my ($sql, @bind) = $self->$method($data);
147 $sql = join " ", $self->_sqlcase('insert into'), $table, $sql;
149 if ($options->{returning}) {
150 my ($s, @b) = $self->_insert_returning ($options);
155 return wantarray ? ($sql, @bind) : $sql;
158 sub _insert_returning {
159 my ($self, $options) = @_;
161 my $f = $options->{returning};
163 my $fieldlist = $self->_SWITCH_refkind($f, {
164 ARRAYREF => sub {join ', ', map { $self->_quote($_) } @$f;},
165 SCALAR => sub {$self->_quote($f)},
166 SCALARREF => sub {$$f},
168 return $self->_sqlcase(' returning ') . $fieldlist;
171 sub _insert_HASHREF { # explicit list of fields and then values
172 my ($self, $data) = @_;
174 my @fields = sort keys %$data;
176 my ($sql, @bind) = $self->_insert_values($data);
179 $_ = $self->_quote($_) foreach @fields;
180 $sql = "( ".join(", ", @fields).") ".$sql;
182 return ($sql, @bind);
185 sub _insert_ARRAYREF { # just generate values(?,?) part (no list of fields)
186 my ($self, $data) = @_;
188 # no names (arrayref) so can't generate bindtype
189 $self->{bindtype} ne 'columns'
190 or belch "can't do 'columns' bindtype when called with arrayref";
192 # fold the list of values into a hash of column name - value pairs
193 # (where the column names are artificially generated, and their
194 # lexicographical ordering keep the ordering of the original list)
195 my $i = "a"; # incremented values will be in lexicographical order
196 my $data_in_hash = { map { ($i++ => $_) } @$data };
198 return $self->_insert_values($data_in_hash);
201 sub _insert_ARRAYREFREF { # literal SQL with bind
202 my ($self, $data) = @_;
204 my ($sql, @bind) = @${$data};
205 $self->_assert_bindval_matches_bindtype(@bind);
207 return ($sql, @bind);
211 sub _insert_SCALARREF { # literal SQL without bind
212 my ($self, $data) = @_;
218 my ($self, $data) = @_;
220 my (@values, @all_bind);
221 foreach my $column (sort keys %$data) {
222 my $v = $data->{$column};
224 $self->_SWITCH_refkind($v, {
227 if ($self->{array_datatypes}) { # if array datatype are activated
229 push @all_bind, $self->_bindtype($column, $v);
231 else { # else literal SQL with bind
232 my ($sql, @bind) = @$v;
233 $self->_assert_bindval_matches_bindtype(@bind);
235 push @all_bind, @bind;
239 ARRAYREFREF => sub { # literal SQL with bind
240 my ($sql, @bind) = @${$v};
241 $self->_assert_bindval_matches_bindtype(@bind);
243 push @all_bind, @bind;
246 # THINK : anything useful to do with a HASHREF ?
247 HASHREF => sub { # (nothing, but old SQLA passed it through)
248 #TODO in SQLA >= 2.0 it will die instead
249 belch "HASH ref as bind value in insert is not supported";
251 push @all_bind, $self->_bindtype($column, $v);
254 SCALARREF => sub { # literal SQL without bind
258 SCALAR_or_UNDEF => sub {
260 push @all_bind, $self->_bindtype($column, $v);
267 my $sql = $self->_sqlcase('values')." ( ".join(", ", @values)." )";
268 return ($sql, @all_bind);
273 #======================================================================
275 #======================================================================
280 my $table = $self->_table(shift);
281 my $data = shift || return;
284 # first build the 'SET' part of the sql statement
285 my (@set, @all_bind);
286 puke "Unsupported data type specified to \$sql->update"
287 unless ref $data eq 'HASH';
289 for my $k (sort keys %$data) {
292 my $label = $self->_quote($k);
294 $self->_SWITCH_refkind($v, {
296 if ($self->{array_datatypes}) { # array datatype
297 push @set, "$label = ?";
298 push @all_bind, $self->_bindtype($k, $v);
300 else { # literal SQL with bind
301 my ($sql, @bind) = @$v;
302 $self->_assert_bindval_matches_bindtype(@bind);
303 push @set, "$label = $sql";
304 push @all_bind, @bind;
307 ARRAYREFREF => sub { # literal SQL with bind
308 my ($sql, @bind) = @${$v};
309 $self->_assert_bindval_matches_bindtype(@bind);
310 push @set, "$label = $sql";
311 push @all_bind, @bind;
313 SCALARREF => sub { # literal SQL without bind
314 push @set, "$label = $$v";
317 my ($op, $arg, @rest) = %$v;
319 puke 'Operator calls in update must be in the form { -op => $arg }'
320 if (@rest or not $op =~ /^\-(.+)/);
322 local $self->{_nested_func_lhs} = $k;
323 my ($sql, @bind) = $self->_where_unary_op ($1, $arg);
325 push @set, "$label = $sql";
326 push @all_bind, @bind;
328 SCALAR_or_UNDEF => sub {
329 push @set, "$label = ?";
330 push @all_bind, $self->_bindtype($k, $v);
336 my $sql = $self->_sqlcase('update') . " $table " . $self->_sqlcase('set ')
340 my($where_sql, @where_bind) = $self->where($where);
342 push @all_bind, @where_bind;
345 return wantarray ? ($sql, @all_bind) : $sql;
351 #======================================================================
353 #======================================================================
358 my $table = $self->_table(shift);
359 my $fields = shift || '*';
363 my($where_sql, @bind) = $self->where($where, $order);
365 my $f = (ref $fields eq 'ARRAY') ? join ', ', map { $self->_quote($_) } @$fields
367 my $sql = join(' ', $self->_sqlcase('select'), $f,
368 $self->_sqlcase('from'), $table)
371 return wantarray ? ($sql, @bind) : $sql;
374 #======================================================================
376 #======================================================================
381 my $table = $self->_table(shift);
385 my($where_sql, @bind) = $self->where($where);
386 my $sql = $self->_sqlcase('delete from') . " $table" . $where_sql;
388 return wantarray ? ($sql, @bind) : $sql;
392 #======================================================================
394 #======================================================================
398 # Finally, a separate routine just to handle WHERE clauses
400 my ($self, $where, $order) = @_;
403 my ($sql, @bind) = $self->_recurse_where($where);
404 $sql = $sql ? $self->_sqlcase(' where ') . "( $sql )" : '';
408 $sql .= $self->_order_by($order);
411 return wantarray ? ($sql, @bind) : $sql;
416 my ($self, $where, $logic) = @_;
418 # dispatch on appropriate method according to refkind of $where
419 my $method = $self->_METHOD_FOR_refkind("_where", $where);
421 my ($sql, @bind) = $self->$method($where, $logic);
423 # DBIx::Class directly calls _recurse_where in scalar context, so
424 # we must implement it, even if not in the official API
425 return wantarray ? ($sql, @bind) : $sql;
430 #======================================================================
431 # WHERE: top-level ARRAYREF
432 #======================================================================
435 sub _where_ARRAYREF {
436 my ($self, $where, $logic) = @_;
438 $logic = uc($logic || $self->{logic});
439 $logic eq 'AND' or $logic eq 'OR' or puke "unknown logic: $logic";
441 my @clauses = @$where;
443 my (@sql_clauses, @all_bind);
444 # need to use while() so can shift() for pairs
445 while (my $el = shift @clauses) {
447 # switch according to kind of $el and get corresponding ($sql, @bind)
448 my ($sql, @bind) = $self->_SWITCH_refkind($el, {
450 # skip empty elements, otherwise get invalid trailing AND stuff
451 ARRAYREF => sub {$self->_recurse_where($el) if @$el},
455 $self->_assert_bindval_matches_bindtype(@b);
459 HASHREF => sub {$self->_recurse_where($el, 'and') if %$el},
460 # LDNOTE : previous SQLA code for hashrefs was creating a dirty
461 # side-effect: the first hashref within an array would change
462 # the global logic to 'AND'. So [ {cond1, cond2}, [cond3, cond4] ]
463 # was interpreted as "(cond1 AND cond2) OR (cond3 AND cond4)",
464 # whereas it should be "(cond1 AND cond2) OR (cond3 OR cond4)".
466 SCALARREF => sub { ($$el); },
468 SCALAR => sub {# top-level arrayref with scalars, recurse in pairs
469 $self->_recurse_where({$el => shift(@clauses)})},
471 UNDEF => sub {puke "not supported : UNDEF in arrayref" },
475 push @sql_clauses, $sql;
476 push @all_bind, @bind;
480 return $self->_join_sql_clauses($logic, \@sql_clauses, \@all_bind);
483 #======================================================================
484 # WHERE: top-level ARRAYREFREF
485 #======================================================================
487 sub _where_ARRAYREFREF {
488 my ($self, $where) = @_;
489 my ($sql, @bind) = @$$where;
490 $self->_assert_bindval_matches_bindtype(@bind);
491 return ($sql, @bind);
494 #======================================================================
495 # WHERE: top-level HASHREF
496 #======================================================================
499 my ($self, $where) = @_;
500 my (@sql_clauses, @all_bind);
502 for my $k (sort keys %$where) {
503 my $v = $where->{$k};
505 # ($k => $v) is either a special unary op or a regular hashpair
506 my ($sql, @bind) = do {
508 # put the operator in canonical form
510 $op = substr $op, 1; # remove initial dash
511 $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
512 $op =~ s/\s+/ /g; # compress whitespace
514 # so that -not_foo works correctly
515 $op =~ s/^not_/NOT /i;
517 $self->_debug("Unary OP(-$op) within hashref, recursing...");
518 my ($s, @b) = $self->_where_unary_op ($op, $v);
520 # top level vs nested
521 # we assume that handled unary ops will take care of their ()s
523 List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}
525 defined($self->{_nested_func_lhs}) && ($self->{_nested_func_lhs} eq $k)
530 my $method = $self->_METHOD_FOR_refkind("_where_hashpair", $v);
531 $self->$method($k, $v);
535 push @sql_clauses, $sql;
536 push @all_bind, @bind;
539 return $self->_join_sql_clauses('and', \@sql_clauses, \@all_bind);
542 sub _where_unary_op {
543 my ($self, $op, $rhs) = @_;
545 if (my $op_entry = List::Util::first {$op =~ $_->{regex}} @{$self->{unary_ops}}) {
546 my $handler = $op_entry->{handler};
548 if (not ref $handler) {
549 if ($op =~ s/ [_\s]? \d+ $//x ) {
550 belch 'Use of [and|or|nest]_N modifiers is deprecated and will be removed in SQLA v2.0. '
551 . "You probably wanted ...-and => [ -$op => COND1, -$op => COND2 ... ]";
553 return $self->$handler ($op, $rhs);
555 elsif (ref $handler eq 'CODE') {
556 return $handler->($self, $op, $rhs);
559 puke "Illegal handler for operator $op - expecting a method name or a coderef";
563 $self->_debug("Generic unary OP: $op - recursing as function");
565 $self->_assert_pass_injection_guard($op);
567 my ($sql, @bind) = $self->_SWITCH_refkind ($rhs, {
569 puke "Illegal use of top-level '$op'"
570 unless $self->{_nested_func_lhs};
573 $self->_convert('?'),
574 $self->_bindtype($self->{_nested_func_lhs}, $rhs)
578 $self->_recurse_where ($rhs)
582 $sql = sprintf ('%s %s',
583 $self->_sqlcase($op),
587 return ($sql, @bind);
590 sub _where_op_ANDOR {
591 my ($self, $op, $v) = @_;
593 $self->_SWITCH_refkind($v, {
595 return $self->_where_ARRAYREF($v, $op);
599 return ( $op =~ /^or/i )
600 ? $self->_where_ARRAYREF( [ map { $_ => $v->{$_} } ( sort keys %$v ) ], $op )
601 : $self->_where_HASHREF($v);
605 puke "-$op => \\\$scalar makes little sense, use " .
607 ? '[ \$scalar, \%rest_of_conditions ] instead'
608 : '-and => [ \$scalar, \%rest_of_conditions ] instead'
613 puke "-$op => \\[...] makes little sense, use " .
615 ? '[ \[...], \%rest_of_conditions ] instead'
616 : '-and => [ \[...], \%rest_of_conditions ] instead'
620 SCALAR => sub { # permissively interpreted as SQL
621 puke "-$op => \$value makes little sense, use -bool => \$value instead";
625 puke "-$op => undef not supported";
631 my ($self, $op, $v) = @_;
633 $self->_SWITCH_refkind($v, {
635 SCALAR => sub { # permissively interpreted as SQL
636 belch "literal SQL should be -nest => \\'scalar' "
637 . "instead of -nest => 'scalar' ";
642 puke "-$op => undef not supported";
646 $self->_recurse_where ($v);
654 my ($self, $op, $v) = @_;
656 my ($s, @b) = $self->_SWITCH_refkind($v, {
657 SCALAR => sub { # interpreted as SQL column
658 $self->_convert($self->_quote($v));
662 puke "-$op => undef not supported";
666 $self->_recurse_where ($v);
670 $s = "(NOT $s)" if $op =~ /^not/i;
675 sub _where_op_IDENT {
677 my ($op, $rhs) = splice @_, -2;
679 puke "-$op takes a single scalar argument (a quotable identifier)";
682 # in case we are called as a top level special op (no '=')
685 $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
693 sub _where_op_VALUE {
695 my ($op, $rhs) = splice @_, -2;
697 # in case we are called as a top level special op (no '=')
702 ($lhs || $self->{_nested_func_lhs}),
709 $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
713 $self->_convert('?'),
719 sub _where_hashpair_ARRAYREF {
720 my ($self, $k, $v) = @_;
723 my @v = @$v; # need copy because of shift below
724 $self->_debug("ARRAY($k) means distribute over elements");
726 # put apart first element if it is an operator (-and, -or)
728 (defined $v[0] && $v[0] =~ /^ - (?: AND|OR ) $/ix)
732 my @distributed = map { {$k => $_} } @v;
735 $self->_debug("OP($op) reinjected into the distributed array");
736 unshift @distributed, $op;
739 my $logic = $op ? substr($op, 1) : '';
741 return $self->_recurse_where(\@distributed, $logic);
744 # LDNOTE : not sure of this one. What does "distribute over nothing" mean?
745 $self->_debug("empty ARRAY($k) means 0=1");
746 return ($self->{sqlfalse});
750 sub _where_hashpair_HASHREF {
751 my ($self, $k, $v, $logic) = @_;
754 local $self->{_nested_func_lhs} = $self->{_nested_func_lhs};
756 my ($all_sql, @all_bind);
758 for my $orig_op (sort keys %$v) {
759 my $val = $v->{$orig_op};
761 # put the operator in canonical form
764 # FIXME - we need to phase out dash-less ops
765 $op =~ s/^-//; # remove possible initial dash
766 $op =~ s/^\s+|\s+$//g;# remove leading/trailing space
767 $op =~ s/\s+/ /g; # compress whitespace
769 $self->_assert_pass_injection_guard($op);
771 # so that -not_foo works correctly
772 $op =~ s/^not_/NOT /i;
776 # CASE: col-value logic modifiers
777 if ( $orig_op =~ /^ \- (and|or) $/xi ) {
778 ($sql, @bind) = $self->_where_hashpair_HASHREF($k, $val, $1);
780 # CASE: special operators like -in or -between
781 elsif ( my $special_op = List::Util::first {$op =~ $_->{regex}} @{$self->{special_ops}} ) {
782 my $handler = $special_op->{handler};
784 puke "No handler supplied for special operator $orig_op";
786 elsif (not ref $handler) {
787 ($sql, @bind) = $self->$handler ($k, $op, $val);
789 elsif (ref $handler eq 'CODE') {
790 ($sql, @bind) = $handler->($self, $k, $op, $val);
793 puke "Illegal handler for special operator $orig_op - expecting a method name or a coderef";
797 $self->_SWITCH_refkind($val, {
799 ARRAYREF => sub { # CASE: col => {op => \@vals}
800 ($sql, @bind) = $self->_where_field_op_ARRAYREF($k, $op, $val);
803 ARRAYREFREF => sub { # CASE: col => {op => \[$sql, @bind]} (literal SQL with bind)
804 my ($sub_sql, @sub_bind) = @$$val;
805 $self->_assert_bindval_matches_bindtype(@sub_bind);
806 $sql = join ' ', $self->_convert($self->_quote($k)),
807 $self->_sqlcase($op),
812 UNDEF => sub { # CASE: col => {op => undef} : sql "IS (NOT)? NULL"
813 my $is = ($op =~ $self->{equality_op}) ? 'is' :
814 ($op =~ $self->{inequality_op}) ? 'is not' :
815 puke "unexpected operator '$orig_op' with undef operand";
816 $sql = $self->_quote($k) . $self->_sqlcase(" $is null");
819 FALLBACK => sub { # CASE: col => {op/func => $stuff}
821 # retain for proper column type bind
822 $self->{_nested_func_lhs} ||= $k;
824 ($sql, @bind) = $self->_where_unary_op ($op, $val);
827 $self->_convert($self->_quote($k)),
828 $self->{_nested_func_lhs} eq $k ? $sql : "($sql)", # top level vs nested
834 ($all_sql) = (defined $all_sql and $all_sql) ? $self->_join_sql_clauses($logic, [$all_sql, $sql], []) : $sql;
835 push @all_bind, @bind;
837 return ($all_sql, @all_bind);
842 sub _where_field_op_ARRAYREF {
843 my ($self, $k, $op, $vals) = @_;
845 my @vals = @$vals; #always work on a copy
848 $self->_debug(sprintf '%s means multiple elements: [ %s ]',
850 join (', ', map { defined $_ ? "'$_'" : 'NULL' } @vals ),
853 # see if the first element is an -and/-or op
855 if (defined $vals[0] && $vals[0] =~ /^ - ( AND|OR ) $/ix) {
860 # distribute $op over each remaining member of @vals, append logic if exists
861 return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
863 # LDNOTE : had planned to change the distribution logic when
864 # $op =~ $self->{inequality_op}, because of Morgan laws :
865 # with {field => {'!=' => [22, 33]}}, it would be ridiculous to generate
866 # WHERE field != 22 OR field != 33 : the user probably means
867 # WHERE field != 22 AND field != 33.
868 # To do this, replace the above to roughly :
869 # my $logic = ($op =~ $self->{inequality_op}) ? 'AND' : 'OR';
870 # return $self->_recurse_where([map { {$k => {$op, $_}} } @vals], $logic);
874 # try to DWIM on equality operators
875 # LDNOTE : not 100% sure this is the correct thing to do ...
876 return ($self->{sqlfalse}) if $op =~ $self->{equality_op};
877 return ($self->{sqltrue}) if $op =~ $self->{inequality_op};
880 puke "operator '$op' applied on an empty array (field '$k')";
885 sub _where_hashpair_SCALARREF {
886 my ($self, $k, $v) = @_;
887 $self->_debug("SCALAR($k) means literal SQL: $$v");
888 my $sql = $self->_quote($k) . " " . $$v;
892 # literal SQL with bind
893 sub _where_hashpair_ARRAYREFREF {
894 my ($self, $k, $v) = @_;
895 $self->_debug("REF($k) means literal SQL: @${$v}");
896 my ($sql, @bind) = @$$v;
897 $self->_assert_bindval_matches_bindtype(@bind);
898 $sql = $self->_quote($k) . " " . $sql;
899 return ($sql, @bind );
902 # literal SQL without bind
903 sub _where_hashpair_SCALAR {
904 my ($self, $k, $v) = @_;
905 $self->_debug("NOREF($k) means simple key=val: $k $self->{cmp} $v");
906 my $sql = join ' ', $self->_convert($self->_quote($k)),
907 $self->_sqlcase($self->{cmp}),
908 $self->_convert('?');
909 my @bind = $self->_bindtype($k, $v);
910 return ( $sql, @bind);
914 sub _where_hashpair_UNDEF {
915 my ($self, $k, $v) = @_;
916 $self->_debug("UNDEF($k) means IS NULL");
917 my $sql = $self->_quote($k) . $self->_sqlcase(' is null');
921 #======================================================================
922 # WHERE: TOP-LEVEL OTHERS (SCALARREF, SCALAR, UNDEF)
923 #======================================================================
926 sub _where_SCALARREF {
927 my ($self, $where) = @_;
930 $self->_debug("SCALAR(*top) means literal SQL: $$where");
936 my ($self, $where) = @_;
939 $self->_debug("NOREF(*top) means literal SQL: $where");
950 #======================================================================
951 # WHERE: BUILTIN SPECIAL OPERATORS (-in, -between)
952 #======================================================================
955 sub _where_field_BETWEEN {
956 my ($self, $k, $op, $vals) = @_;
958 my ($label, $and, $placeholder);
959 $label = $self->_convert($self->_quote($k));
960 $and = ' ' . $self->_sqlcase('and') . ' ';
961 $placeholder = $self->_convert('?');
962 $op = $self->_sqlcase($op);
964 my $invalid_args = "Operator '$op' requires either an arrayref with two defined values or expressions, or a single literal scalarref/arrayref-ref";
966 my ($clause, @bind) = $self->_SWITCH_refkind($vals, {
968 my ($s, @b) = @$$vals;
969 $self->_assert_bindval_matches_bindtype(@b);
976 puke $invalid_args if @$vals != 2;
978 my (@all_sql, @all_bind);
979 foreach my $val (@$vals) {
980 my ($sql, @bind) = $self->_SWITCH_refkind($val, {
982 return ($placeholder, $self->_bindtype($k, $val) );
988 my ($sql, @bind) = @$$val;
989 $self->_assert_bindval_matches_bindtype(@bind);
990 return ($sql, @bind);
993 my ($func, $arg, @rest) = %$val;
994 puke ("Only simple { -func => arg } functions accepted as sub-arguments to BETWEEN")
995 if (@rest or $func !~ /^ \- (.+)/x);
996 local $self->{_nested_func_lhs} = $k;
997 $self->_where_unary_op ($1 => $arg);
1003 push @all_sql, $sql;
1004 push @all_bind, @bind;
1008 (join $and, @all_sql),
1017 my $sql = "( $label $op $clause )";
1018 return ($sql, @bind)
1022 sub _where_field_IN {
1023 my ($self, $k, $op, $vals) = @_;
1025 # backwards compatibility : if scalar, force into an arrayref
1026 $vals = [$vals] if defined $vals && ! ref $vals;
1028 my ($label) = $self->_convert($self->_quote($k));
1029 my ($placeholder) = $self->_convert('?');
1030 $op = $self->_sqlcase($op);
1032 my ($sql, @bind) = $self->_SWITCH_refkind($vals, {
1033 ARRAYREF => sub { # list of choices
1034 if (@$vals) { # nonempty list
1035 my (@all_sql, @all_bind);
1037 for my $val (@$vals) {
1038 my ($sql, @bind) = $self->_SWITCH_refkind($val, {
1040 return ($placeholder, $val);
1045 ARRAYREFREF => sub {
1046 my ($sql, @bind) = @$$val;
1047 $self->_assert_bindval_matches_bindtype(@bind);
1048 return ($sql, @bind);
1051 my ($func, $arg, @rest) = %$val;
1052 puke ("Only simple { -func => arg } functions accepted as sub-arguments to IN")
1053 if (@rest or $func !~ /^ \- (.+)/x);
1054 local $self->{_nested_func_lhs} = $k;
1055 $self->_where_unary_op ($1 => $arg);
1059 'SQL::Abstract before v1.75 used to generate incorrect SQL when the '
1060 . "-$op operator was given an undef-containing list: !!!AUDIT YOUR CODE "
1061 . 'AND DATA!!! (the upcoming Data::Query-based version of SQL::Abstract '
1062 . 'will emit the logically correct SQL instead of raising this exception)'
1066 push @all_sql, $sql;
1067 push @all_bind, @bind;
1071 sprintf ('%s %s ( %s )',
1074 join (', ', @all_sql)
1076 $self->_bindtype($k, @all_bind),
1079 else { # empty list : some databases won't understand "IN ()", so DWIM
1080 my $sql = ($op =~ /\bnot\b/i) ? $self->{sqltrue} : $self->{sqlfalse};
1085 SCALARREF => sub { # literal SQL
1086 my $sql = $self->_open_outer_paren ($$vals);
1087 return ("$label $op ( $sql )");
1089 ARRAYREFREF => sub { # literal SQL with bind
1090 my ($sql, @bind) = @$$vals;
1091 $self->_assert_bindval_matches_bindtype(@bind);
1092 $sql = $self->_open_outer_paren ($sql);
1093 return ("$label $op ( $sql )", @bind);
1097 puke "Argument passed to the '$op' operator can not be undefined";
1101 puke "special op $op requires an arrayref (or scalarref/arrayref-ref)";
1105 return ($sql, @bind);
1108 # Some databases (SQLite) treat col IN (1, 2) different from
1109 # col IN ( (1, 2) ). Use this to strip all outer parens while
1110 # adding them back in the corresponding method
1111 sub _open_outer_paren {
1112 my ($self, $sql) = @_;
1113 $sql = $1 while $sql =~ /^ \s* \( (.*) \) \s* $/xs;
1118 #======================================================================
1120 #======================================================================
1123 my ($self, $arg) = @_;
1126 for my $c ($self->_order_by_chunks ($arg) ) {
1127 $self->_SWITCH_refkind ($c, {
1128 SCALAR => sub { push @sql, $c },
1129 ARRAYREF => sub { push @sql, shift @$c; push @bind, @$c },
1135 $self->_sqlcase(' order by'),
1141 return wantarray ? ($sql, @bind) : $sql;
1144 sub _order_by_chunks {
1145 my ($self, $arg) = @_;
1147 return $self->_SWITCH_refkind($arg, {
1150 map { $self->_order_by_chunks ($_ ) } @$arg;
1153 ARRAYREFREF => sub {
1154 my ($s, @b) = @$$arg;
1155 $self->_assert_bindval_matches_bindtype(@b);
1159 SCALAR => sub {$self->_quote($arg)},
1161 UNDEF => sub {return () },
1163 SCALARREF => sub {$$arg}, # literal SQL, no quoting
1166 # get first pair in hash
1167 my ($key, $val, @rest) = %$arg;
1169 return () unless $key;
1171 if ( @rest or not $key =~ /^-(desc|asc)/i ) {
1172 puke "hash passed to _order_by must have exactly one key (-desc or -asc)";
1178 for my $c ($self->_order_by_chunks ($val)) {
1181 $self->_SWITCH_refkind ($c, {
1186 ($sql, @bind) = @$c;
1190 $sql = $sql . ' ' . $self->_sqlcase($direction);
1192 push @ret, [ $sql, @bind];
1201 #======================================================================
1202 # DATASOURCE (FOR NOW, JUST PLAIN TABLE OR LIST OF TABLES)
1203 #======================================================================
1208 $self->_SWITCH_refkind($from, {
1209 ARRAYREF => sub {join ', ', map { $self->_quote($_) } @$from;},
1210 SCALAR => sub {$self->_quote($from)},
1211 SCALARREF => sub {$$from},
1216 #======================================================================
1218 #======================================================================
1220 # highly optimized, as it's called way too often
1222 # my ($self, $label) = @_;
1224 return '' unless defined $_[1];
1225 return ${$_[1]} if ref($_[1]) eq 'SCALAR';
1227 unless ($_[0]->{quote_char}) {
1228 $_[0]->_assert_pass_injection_guard($_[1]);
1232 my $qref = ref $_[0]->{quote_char};
1235 ($l, $r) = ( $_[0]->{quote_char}, $_[0]->{quote_char} );
1237 elsif ($qref eq 'ARRAY') {
1238 ($l, $r) = @{$_[0]->{quote_char}};
1241 puke "Unsupported quote_char format: $_[0]->{quote_char}";
1244 # parts containing * are naturally unquoted
1245 return join( $_[0]->{name_sep}||'', map
1246 { $_ eq '*' ? $_ : $l . $_ . $r }
1247 ( $_[0]->{name_sep} ? split (/\Q$_[0]->{name_sep}\E/, $_[1] ) : $_[1] )
1252 # Conversion, if applicable
1254 #my ($self, $arg) = @_;
1256 # LDNOTE : modified the previous implementation below because
1257 # it was not consistent : the first "return" is always an array,
1258 # the second "return" is context-dependent. Anyway, _convert
1259 # seems always used with just a single argument, so make it a
1261 # return @_ unless $self->{convert};
1262 # my $conv = $self->_sqlcase($self->{convert});
1263 # my @ret = map { $conv.'('.$_.')' } @_;
1264 # return wantarray ? @ret : $ret[0];
1265 if ($_[0]->{convert}) {
1266 return $_[0]->_sqlcase($_[0]->{convert}) .'(' . $_[1] . ')';
1273 #my ($self, $col, @vals) = @_;
1275 #LDNOTE : changed original implementation below because it did not make
1276 # sense when bindtype eq 'columns' and @vals > 1.
1277 # return $self->{bindtype} eq 'columns' ? [ $col, @vals ] : @vals;
1279 # called often - tighten code
1280 return $_[0]->{bindtype} eq 'columns'
1281 ? map {[$_[1], $_]} @_[2 .. $#_]
1286 # Dies if any element of @bind is not in [colname => value] format
1287 # if bindtype is 'columns'.
1288 sub _assert_bindval_matches_bindtype {
1289 # my ($self, @bind) = @_;
1291 if ($self->{bindtype} eq 'columns') {
1293 if (!defined $_ || ref($_) ne 'ARRAY' || @$_ != 2) {
1294 puke "bindtype 'columns' selected, you need to pass: [column_name => bind_value]"
1300 sub _join_sql_clauses {
1301 my ($self, $logic, $clauses_aref, $bind_aref) = @_;
1303 if (@$clauses_aref > 1) {
1304 my $join = " " . $self->_sqlcase($logic) . " ";
1305 my $sql = '( ' . join($join, @$clauses_aref) . ' )';
1306 return ($sql, @$bind_aref);
1308 elsif (@$clauses_aref) {
1309 return ($clauses_aref->[0], @$bind_aref); # no parentheses
1312 return (); # if no SQL, ignore @$bind_aref
1317 # Fix SQL case, if so requested
1319 # LDNOTE: if $self->{case} is true, then it contains 'lower', so we
1320 # don't touch the argument ... crooked logic, but let's not change it!
1321 return $_[0]->{case} ? $_[1] : uc($_[1]);
1325 #======================================================================
1326 # DISPATCHING FROM REFKIND
1327 #======================================================================
1330 my ($self, $data) = @_;
1332 return 'UNDEF' unless defined $data;
1334 # blessed objects are treated like scalars
1335 my $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1337 return 'SCALAR' unless $ref;
1340 while ($ref eq 'REF') {
1342 $ref = (Scalar::Util::blessed $data) ? '' : ref $data;
1346 return ($ref||'SCALAR') . ('REF' x $n_steps);
1350 my ($self, $data) = @_;
1351 my @try = ($self->_refkind($data));
1352 push @try, 'SCALAR_or_UNDEF' if $try[0] eq 'SCALAR' || $try[0] eq 'UNDEF';
1353 push @try, 'FALLBACK';
1357 sub _METHOD_FOR_refkind {
1358 my ($self, $meth_prefix, $data) = @_;
1361 for (@{$self->_try_refkind($data)}) {
1362 $method = $self->can($meth_prefix."_".$_)
1366 return $method || puke "cannot dispatch on '$meth_prefix' for ".$self->_refkind($data);
1370 sub _SWITCH_refkind {
1371 my ($self, $data, $dispatch_table) = @_;
1374 for (@{$self->_try_refkind($data)}) {
1375 $coderef = $dispatch_table->{$_}
1379 puke "no dispatch entry for ".$self->_refkind($data)
1388 #======================================================================
1389 # VALUES, GENERATE, AUTOLOAD
1390 #======================================================================
1392 # LDNOTE: original code from nwiger, didn't touch code in that section
1393 # I feel the AUTOLOAD stuff should not be the default, it should
1394 # only be activated on explicit demand by user.
1398 my $data = shift || return;
1399 puke "Argument to ", __PACKAGE__, "->values must be a \\%hash"
1400 unless ref $data eq 'HASH';
1403 foreach my $k ( sort keys %$data ) {
1404 my $v = $data->{$k};
1405 $self->_SWITCH_refkind($v, {
1407 if ($self->{array_datatypes}) { # array datatype
1408 push @all_bind, $self->_bindtype($k, $v);
1410 else { # literal SQL with bind
1411 my ($sql, @bind) = @$v;
1412 $self->_assert_bindval_matches_bindtype(@bind);
1413 push @all_bind, @bind;
1416 ARRAYREFREF => sub { # literal SQL with bind
1417 my ($sql, @bind) = @${$v};
1418 $self->_assert_bindval_matches_bindtype(@bind);
1419 push @all_bind, @bind;
1421 SCALARREF => sub { # literal SQL without bind
1423 SCALAR_or_UNDEF => sub {
1424 push @all_bind, $self->_bindtype($k, $v);
1435 my(@sql, @sqlq, @sqlv);
1439 if ($ref eq 'HASH') {
1440 for my $k (sort keys %$_) {
1443 my $label = $self->_quote($k);
1444 if ($r eq 'ARRAY') {
1445 # literal SQL with bind
1446 my ($sql, @bind) = @$v;
1447 $self->_assert_bindval_matches_bindtype(@bind);
1448 push @sqlq, "$label = $sql";
1450 } elsif ($r eq 'SCALAR') {
1451 # literal SQL without bind
1452 push @sqlq, "$label = $$v";
1454 push @sqlq, "$label = ?";
1455 push @sqlv, $self->_bindtype($k, $v);
1458 push @sql, $self->_sqlcase('set'), join ', ', @sqlq;
1459 } elsif ($ref eq 'ARRAY') {
1460 # unlike insert(), assume these are ONLY the column names, i.e. for SQL
1463 if ($r eq 'ARRAY') { # literal SQL with bind
1464 my ($sql, @bind) = @$v;
1465 $self->_assert_bindval_matches_bindtype(@bind);
1468 } elsif ($r eq 'SCALAR') { # literal SQL without bind
1469 # embedded literal SQL
1476 push @sql, '(' . join(', ', @sqlq) . ')';
1477 } elsif ($ref eq 'SCALAR') {
1481 # strings get case twiddled
1482 push @sql, $self->_sqlcase($_);
1486 my $sql = join ' ', @sql;
1488 # this is pretty tricky
1489 # if ask for an array, return ($stmt, @bind)
1490 # otherwise, s/?/shift @sqlv/ to put it inline
1492 return ($sql, @sqlv);
1494 1 while $sql =~ s/\?/my $d = shift(@sqlv);
1495 ref $d ? $d->[1] : $d/e;
1504 # This allows us to check for a local, then _form, attr
1506 my($name) = $AUTOLOAD =~ /.*::(.+)/;
1507 return $self->generate($name, @_);
1518 SQL::Abstract - Generate SQL from Perl data structures
1524 my $sql = SQL::Abstract->new;
1526 my($stmt, @bind) = $sql->select($source, \@fields, \%where, \@order);
1528 my($stmt, @bind) = $sql->insert($table, \%fieldvals || \@values);
1530 my($stmt, @bind) = $sql->update($table, \%fieldvals, \%where);
1532 my($stmt, @bind) = $sql->delete($table, \%where);
1534 # Then, use these in your DBI statements
1535 my $sth = $dbh->prepare($stmt);
1536 $sth->execute(@bind);
1538 # Just generate the WHERE clause
1539 my($stmt, @bind) = $sql->where(\%where, \@order);
1541 # Return values in the same order, for hashed queries
1542 # See PERFORMANCE section for more details
1543 my @bind = $sql->values(\%fieldvals);
1547 This module was inspired by the excellent L<DBIx::Abstract>.
1548 However, in using that module I found that what I really wanted
1549 to do was generate SQL, but still retain complete control over my
1550 statement handles and use the DBI interface. So, I set out to
1551 create an abstract SQL generation module.
1553 While based on the concepts used by L<DBIx::Abstract>, there are
1554 several important differences, especially when it comes to WHERE
1555 clauses. I have modified the concepts used to make the SQL easier
1556 to generate from Perl data structures and, IMO, more intuitive.
1557 The underlying idea is for this module to do what you mean, based
1558 on the data structures you provide it. The big advantage is that
1559 you don't have to modify your code every time your data changes,
1560 as this module figures it out.
1562 To begin with, an SQL INSERT is as easy as just specifying a hash
1563 of C<key=value> pairs:
1566 name => 'Jimbo Bobson',
1567 phone => '123-456-7890',
1568 address => '42 Sister Lane',
1569 city => 'St. Louis',
1570 state => 'Louisiana',
1573 The SQL can then be generated with this:
1575 my($stmt, @bind) = $sql->insert('people', \%data);
1577 Which would give you something like this:
1579 $stmt = "INSERT INTO people
1580 (address, city, name, phone, state)
1581 VALUES (?, ?, ?, ?, ?)";
1582 @bind = ('42 Sister Lane', 'St. Louis', 'Jimbo Bobson',
1583 '123-456-7890', 'Louisiana');
1585 These are then used directly in your DBI code:
1587 my $sth = $dbh->prepare($stmt);
1588 $sth->execute(@bind);
1590 =head2 Inserting and Updating Arrays
1592 If your database has array types (like for example Postgres),
1593 activate the special option C<< array_datatypes => 1 >>
1594 when creating the C<SQL::Abstract> object.
1595 Then you may use an arrayref to insert and update database array types:
1597 my $sql = SQL::Abstract->new(array_datatypes => 1);
1599 planets => [qw/Mercury Venus Earth Mars/]
1602 my($stmt, @bind) = $sql->insert('solar_system', \%data);
1606 $stmt = "INSERT INTO solar_system (planets) VALUES (?)"
1608 @bind = (['Mercury', 'Venus', 'Earth', 'Mars']);
1611 =head2 Inserting and Updating SQL
1613 In order to apply SQL functions to elements of your C<%data> you may
1614 specify a reference to an arrayref for the given hash value. For example,
1615 if you need to execute the Oracle C<to_date> function on a value, you can
1616 say something like this:
1620 date_entered => \["to_date(?,'MM/DD/YYYY')", "03/02/2003"],
1623 The first value in the array is the actual SQL. Any other values are
1624 optional and would be included in the bind values array. This gives
1627 my($stmt, @bind) = $sql->insert('people', \%data);
1629 $stmt = "INSERT INTO people (name, date_entered)
1630 VALUES (?, to_date(?,'MM/DD/YYYY'))";
1631 @bind = ('Bill', '03/02/2003');
1633 An UPDATE is just as easy, all you change is the name of the function:
1635 my($stmt, @bind) = $sql->update('people', \%data);
1637 Notice that your C<%data> isn't touched; the module will generate
1638 the appropriately quirky SQL for you automatically. Usually you'll
1639 want to specify a WHERE clause for your UPDATE, though, which is
1640 where handling C<%where> hashes comes in handy...
1642 =head2 Complex where statements
1644 This module can generate pretty complicated WHERE statements
1645 easily. For example, simple C<key=value> pairs are taken to mean
1646 equality, and if you want to see if a field is within a set
1647 of values, you can use an arrayref. Let's say we wanted to
1648 SELECT some data based on this criteria:
1651 requestor => 'inna',
1652 worker => ['nwiger', 'rcwe', 'sfz'],
1653 status => { '!=', 'completed' }
1656 my($stmt, @bind) = $sql->select('tickets', '*', \%where);
1658 The above would give you something like this:
1660 $stmt = "SELECT * FROM tickets WHERE
1661 ( requestor = ? ) AND ( status != ? )
1662 AND ( worker = ? OR worker = ? OR worker = ? )";
1663 @bind = ('inna', 'completed', 'nwiger', 'rcwe', 'sfz');
1665 Which you could then use in DBI code like so:
1667 my $sth = $dbh->prepare($stmt);
1668 $sth->execute(@bind);
1674 The functions are simple. There's one for each major SQL operation,
1675 and a constructor you use first. The arguments are specified in a
1676 similar order to each function (table, then fields, then a where
1677 clause) to try and simplify things.
1682 =head2 new(option => 'value')
1684 The C<new()> function takes a list of options and values, and returns
1685 a new B<SQL::Abstract> object which can then be used to generate SQL
1686 through the methods below. The options accepted are:
1692 If set to 'lower', then SQL will be generated in all lowercase. By
1693 default SQL is generated in "textbook" case meaning something like:
1695 SELECT a_field FROM a_table WHERE some_field LIKE '%someval%'
1697 Any setting other than 'lower' is ignored.
1701 This determines what the default comparison operator is. By default
1702 it is C<=>, meaning that a hash like this:
1704 %where = (name => 'nwiger', email => 'nate@wiger.org');
1706 Will generate SQL like this:
1708 WHERE name = 'nwiger' AND email = 'nate@wiger.org'
1710 However, you may want loose comparisons by default, so if you set
1711 C<cmp> to C<like> you would get SQL such as:
1713 WHERE name like 'nwiger' AND email like 'nate@wiger.org'
1715 You can also override the comparison on an individual basis - see
1716 the huge section on L</"WHERE CLAUSES"> at the bottom.
1718 =item sqltrue, sqlfalse
1720 Expressions for inserting boolean values within SQL statements.
1721 By default these are C<1=1> and C<1=0>. They are used
1722 by the special operators C<-in> and C<-not_in> for generating
1723 correct SQL even when the argument is an empty array (see below).
1727 This determines the default logical operator for multiple WHERE
1728 statements in arrays or hashes. If absent, the default logic is "or"
1729 for arrays, and "and" for hashes. This means that a WHERE
1733 event_date => {'>=', '2/13/99'},
1734 event_date => {'<=', '4/24/03'},
1737 will generate SQL like this:
1739 WHERE event_date >= '2/13/99' OR event_date <= '4/24/03'
1741 This is probably not what you want given this query, though (look
1742 at the dates). To change the "OR" to an "AND", simply specify:
1744 my $sql = SQL::Abstract->new(logic => 'and');
1746 Which will change the above C<WHERE> to:
1748 WHERE event_date >= '2/13/99' AND event_date <= '4/24/03'
1750 The logic can also be changed locally by inserting
1751 a modifier in front of an arrayref :
1753 @where = (-and => [event_date => {'>=', '2/13/99'},
1754 event_date => {'<=', '4/24/03'} ]);
1756 See the L</"WHERE CLAUSES"> section for explanations.
1760 This will automatically convert comparisons using the specified SQL
1761 function for both column and value. This is mostly used with an argument
1762 of C<upper> or C<lower>, so that the SQL will have the effect of
1763 case-insensitive "searches". For example, this:
1765 $sql = SQL::Abstract->new(convert => 'upper');
1766 %where = (keywords => 'MaKe iT CAse inSeNSItive');
1768 Will turn out the following SQL:
1770 WHERE upper(keywords) like upper('MaKe iT CAse inSeNSItive')
1772 The conversion can be C<upper()>, C<lower()>, or any other SQL function
1773 that can be applied symmetrically to fields (actually B<SQL::Abstract> does
1774 not validate this option; it will just pass through what you specify verbatim).
1778 This is a kludge because many databases suck. For example, you can't
1779 just bind values using DBI's C<execute()> for Oracle C<CLOB> or C<BLOB> fields.
1780 Instead, you have to use C<bind_param()>:
1782 $sth->bind_param(1, 'reg data');
1783 $sth->bind_param(2, $lots, {ora_type => ORA_CLOB});
1785 The problem is, B<SQL::Abstract> will normally just return a C<@bind> array,
1786 which loses track of which field each slot refers to. Fear not.
1788 If you specify C<bindtype> in new, you can determine how C<@bind> is returned.
1789 Currently, you can specify either C<normal> (default) or C<columns>. If you
1790 specify C<columns>, you will get an array that looks like this:
1792 my $sql = SQL::Abstract->new(bindtype => 'columns');
1793 my($stmt, @bind) = $sql->insert(...);
1796 [ 'column1', 'value1' ],
1797 [ 'column2', 'value2' ],
1798 [ 'column3', 'value3' ],
1801 You can then iterate through this manually, using DBI's C<bind_param()>.
1803 $sth->prepare($stmt);
1806 my($col, $data) = @$_;
1807 if ($col eq 'details' || $col eq 'comments') {
1808 $sth->bind_param($i, $data, {ora_type => ORA_CLOB});
1809 } elsif ($col eq 'image') {
1810 $sth->bind_param($i, $data, {ora_type => ORA_BLOB});
1812 $sth->bind_param($i, $data);
1816 $sth->execute; # execute without @bind now
1818 Now, why would you still use B<SQL::Abstract> if you have to do this crap?
1819 Basically, the advantage is still that you don't have to care which fields
1820 are or are not included. You could wrap that above C<for> loop in a simple
1821 sub called C<bind_fields()> or something and reuse it repeatedly. You still
1822 get a layer of abstraction over manual SQL specification.
1824 Note that if you set L</bindtype> to C<columns>, the C<\[$sql, @bind]>
1825 construct (see L</Literal SQL with placeholders and bind values (subqueries)>)
1826 will expect the bind values in this format.
1830 This is the character that a table or column name will be quoted
1831 with. By default this is an empty string, but you could set it to
1832 the character C<`>, to generate SQL like this:
1834 SELECT `a_field` FROM `a_table` WHERE `some_field` LIKE '%someval%'
1836 Alternatively, you can supply an array ref of two items, the first being the left
1837 hand quote character, and the second the right hand quote character. For
1838 example, you could supply C<['[',']']> for SQL Server 2000 compliant quotes
1839 that generates SQL like this:
1841 SELECT [a_field] FROM [a_table] WHERE [some_field] LIKE '%someval%'
1843 Quoting is useful if you have tables or columns names that are reserved
1844 words in your database's SQL dialect.
1848 This is the character that separates a table and column name. It is
1849 necessary to specify this when the C<quote_char> option is selected,
1850 so that tables and column names can be individually quoted like this:
1852 SELECT `table`.`one_field` FROM `table` WHERE `table`.`other_field` = 1
1854 =item injection_guard
1856 A regular expression C<qr/.../> that is applied to any C<-function> and unquoted
1857 column name specified in a query structure. This is a safety mechanism to avoid
1858 injection attacks when mishandling user input e.g.:
1860 my %condition_as_column_value_pairs = get_values_from_user();
1861 $sqla->select( ... , \%condition_as_column_value_pairs );
1863 If the expression matches an exception is thrown. Note that literal SQL
1864 supplied via C<\'...'> or C<\['...']> is B<not> checked in any way.
1866 Defaults to checking for C<;> and the C<GO> keyword (TransactSQL)
1868 =item array_datatypes
1870 When this option is true, arrayrefs in INSERT or UPDATE are
1871 interpreted as array datatypes and are passed directly
1873 When this option is false, arrayrefs are interpreted
1874 as literal SQL, just like refs to arrayrefs
1875 (but this behavior is for backwards compatibility; when writing
1876 new queries, use the "reference to arrayref" syntax
1882 Takes a reference to a list of "special operators"
1883 to extend the syntax understood by L<SQL::Abstract>.
1884 See section L</"SPECIAL OPERATORS"> for details.
1888 Takes a reference to a list of "unary operators"
1889 to extend the syntax understood by L<SQL::Abstract>.
1890 See section L</"UNARY OPERATORS"> for details.
1896 =head2 insert($table, \@values || \%fieldvals, \%options)
1898 This is the simplest function. You simply give it a table name
1899 and either an arrayref of values or hashref of field/value pairs.
1900 It returns an SQL INSERT statement and a list of bind values.
1901 See the sections on L</"Inserting and Updating Arrays"> and
1902 L</"Inserting and Updating SQL"> for information on how to insert
1903 with those data types.
1905 The optional C<\%options> hash reference may contain additional
1906 options to generate the insert SQL. Currently supported options
1913 Takes either a scalar of raw SQL fields, or an array reference of
1914 field names, and adds on an SQL C<RETURNING> statement at the end.
1915 This allows you to return data generated by the insert statement
1916 (such as row IDs) without performing another C<SELECT> statement.
1917 Note, however, this is not part of the SQL standard and may not
1918 be supported by all database engines.
1922 =head2 update($table, \%fieldvals, \%where)
1924 This takes a table, hashref of field/value pairs, and an optional
1925 hashref L<WHERE clause|/WHERE CLAUSES>. It returns an SQL UPDATE function and a list
1927 See the sections on L</"Inserting and Updating Arrays"> and
1928 L</"Inserting and Updating SQL"> for information on how to insert
1929 with those data types.
1931 =head2 select($source, $fields, $where, $order)
1933 This returns a SQL SELECT statement and associated list of bind values, as
1934 specified by the arguments :
1940 Specification of the 'FROM' part of the statement.
1941 The argument can be either a plain scalar (interpreted as a table
1942 name, will be quoted), or an arrayref (interpreted as a list
1943 of table names, joined by commas, quoted), or a scalarref
1944 (literal table name, not quoted), or a ref to an arrayref
1945 (list of literal table names, joined by commas, not quoted).
1949 Specification of the list of fields to retrieve from
1951 The argument can be either an arrayref (interpreted as a list
1952 of field names, will be joined by commas and quoted), or a
1953 plain scalar (literal SQL, not quoted).
1954 Please observe that this API is not as flexible as that of
1955 the first argument C<$source>, for backwards compatibility reasons.
1959 Optional argument to specify the WHERE part of the query.
1960 The argument is most often a hashref, but can also be
1961 an arrayref or plain scalar --
1962 see section L<WHERE clause|/"WHERE CLAUSES"> for details.
1966 Optional argument to specify the ORDER BY part of the query.
1967 The argument can be a scalar, a hashref or an arrayref
1968 -- see section L<ORDER BY clause|/"ORDER BY CLAUSES">
1974 =head2 delete($table, \%where)
1976 This takes a table name and optional hashref L<WHERE clause|/WHERE CLAUSES>.
1977 It returns an SQL DELETE statement and list of bind values.
1979 =head2 where(\%where, \@order)
1981 This is used to generate just the WHERE clause. For example,
1982 if you have an arbitrary data structure and know what the
1983 rest of your SQL is going to look like, but want an easy way
1984 to produce a WHERE clause, use this. It returns an SQL WHERE
1985 clause and list of bind values.
1988 =head2 values(\%data)
1990 This just returns the values from the hash C<%data>, in the same
1991 order that would be returned from any of the other above queries.
1992 Using this allows you to markedly speed up your queries if you
1993 are affecting lots of rows. See below under the L</"PERFORMANCE"> section.
1995 =head2 generate($any, 'number', $of, \@data, $struct, \%types)
1997 Warning: This is an experimental method and subject to change.
1999 This returns arbitrarily generated SQL. It's a really basic shortcut.
2000 It will return two different things, depending on return context:
2002 my($stmt, @bind) = $sql->generate('create table', \$table, \@fields);
2003 my $stmt_and_val = $sql->generate('create table', \$table, \@fields);
2005 These would return the following:
2007 # First calling form
2008 $stmt = "CREATE TABLE test (?, ?)";
2009 @bind = (field1, field2);
2011 # Second calling form
2012 $stmt_and_val = "CREATE TABLE test (field1, field2)";
2014 Depending on what you're trying to do, it's up to you to choose the correct
2015 format. In this example, the second form is what you would want.
2019 $sql->generate('alter session', { nls_date_format => 'MM/YY' });
2023 ALTER SESSION SET nls_date_format = 'MM/YY'
2025 You get the idea. Strings get their case twiddled, but everything
2026 else remains verbatim.
2028 =head1 WHERE CLAUSES
2032 This module uses a variation on the idea from L<DBIx::Abstract>. It
2033 is B<NOT>, repeat I<not> 100% compatible. B<The main logic of this
2034 module is that things in arrays are OR'ed, and things in hashes
2037 The easiest way to explain is to show lots of examples. After
2038 each C<%where> hash shown, it is assumed you used:
2040 my($stmt, @bind) = $sql->where(\%where);
2042 However, note that the C<%where> hash can be used directly in any
2043 of the other functions as well, as described above.
2045 =head2 Key-value pairs
2047 So, let's get started. To begin, a simple hash:
2051 status => 'completed'
2054 Is converted to SQL C<key = val> statements:
2056 $stmt = "WHERE user = ? AND status = ?";
2057 @bind = ('nwiger', 'completed');
2059 One common thing I end up doing is having a list of values that
2060 a field can be in. To do this, simply specify a list inside of
2065 status => ['assigned', 'in-progress', 'pending'];
2068 This simple code will create the following:
2070 $stmt = "WHERE user = ? AND ( status = ? OR status = ? OR status = ? )";
2071 @bind = ('nwiger', 'assigned', 'in-progress', 'pending');
2073 A field associated to an empty arrayref will be considered a
2074 logical false and will generate 0=1.
2076 =head2 Tests for NULL values
2078 If the value part is C<undef> then this is converted to SQL <IS NULL>
2087 $stmt = "WHERE user = ? AND status IS NULL";
2090 To test if a column IS NOT NULL:
2094 status => { '!=', undef },
2097 =head2 Specific comparison operators
2099 If you want to specify a different type of operator for your comparison,
2100 you can use a hashref for a given column:
2104 status => { '!=', 'completed' }
2107 Which would generate:
2109 $stmt = "WHERE user = ? AND status != ?";
2110 @bind = ('nwiger', 'completed');
2112 To test against multiple values, just enclose the values in an arrayref:
2114 status => { '=', ['assigned', 'in-progress', 'pending'] };
2116 Which would give you:
2118 "WHERE status = ? OR status = ? OR status = ?"
2121 The hashref can also contain multiple pairs, in which case it is expanded
2122 into an C<AND> of its elements:
2126 status => { '!=', 'completed', -not_like => 'pending%' }
2129 # Or more dynamically, like from a form
2130 $where{user} = 'nwiger';
2131 $where{status}{'!='} = 'completed';
2132 $where{status}{'-not_like'} = 'pending%';
2134 # Both generate this
2135 $stmt = "WHERE user = ? AND status != ? AND status NOT LIKE ?";
2136 @bind = ('nwiger', 'completed', 'pending%');
2139 To get an OR instead, you can combine it with the arrayref idea:
2143 priority => [ { '=', 2 }, { '>', 5 } ]
2146 Which would generate:
2148 $stmt = "WHERE ( priority = ? OR priority > ? ) AND user = ?";
2149 @bind = ('2', '5', 'nwiger');
2151 If you want to include literal SQL (with or without bind values), just use a
2152 scalar reference or array reference as the value:
2155 date_entered => { '>' => \["to_date(?, 'MM/DD/YYYY')", "11/26/2008"] },
2156 date_expires => { '<' => \"now()" }
2159 Which would generate:
2161 $stmt = "WHERE date_entered > "to_date(?, 'MM/DD/YYYY') AND date_expires < now()";
2162 @bind = ('11/26/2008');
2165 =head2 Logic and nesting operators
2167 In the example above,
2168 there is a subtle trap if you want to say something like
2169 this (notice the C<AND>):
2171 WHERE priority != ? AND priority != ?
2173 Because, in Perl you I<can't> do this:
2175 priority => { '!=', 2, '!=', 1 }
2177 As the second C<!=> key will obliterate the first. The solution
2178 is to use the special C<-modifier> form inside an arrayref:
2180 priority => [ -and => {'!=', 2},
2184 Normally, these would be joined by C<OR>, but the modifier tells it
2185 to use C<AND> instead. (Hint: You can use this in conjunction with the
2186 C<logic> option to C<new()> in order to change the way your queries
2187 work by default.) B<Important:> Note that the C<-modifier> goes
2188 B<INSIDE> the arrayref, as an extra first element. This will
2189 B<NOT> do what you think it might:
2191 priority => -and => [{'!=', 2}, {'!=', 1}] # WRONG!
2193 Here is a quick list of equivalencies, since there is some overlap:
2196 status => {'!=', 'completed', 'not like', 'pending%' }
2197 status => [ -and => {'!=', 'completed'}, {'not like', 'pending%'}]
2200 status => {'=', ['assigned', 'in-progress']}
2201 status => [ -or => {'=', 'assigned'}, {'=', 'in-progress'}]
2202 status => [ {'=', 'assigned'}, {'=', 'in-progress'} ]
2206 =head2 Special operators : IN, BETWEEN, etc.
2208 You can also use the hashref format to compare a list of fields using the
2209 C<IN> comparison operator, by specifying the list as an arrayref:
2212 status => 'completed',
2213 reportid => { -in => [567, 2335, 2] }
2216 Which would generate:
2218 $stmt = "WHERE status = ? AND reportid IN (?,?,?)";
2219 @bind = ('completed', '567', '2335', '2');
2221 The reverse operator C<-not_in> generates SQL C<NOT IN> and is used in
2224 If the argument to C<-in> is an empty array, 'sqlfalse' is generated
2225 (by default : C<1=0>). Similarly, C<< -not_in => [] >> generates
2226 'sqltrue' (by default : C<1=1>).
2228 In addition to the array you can supply a chunk of literal sql or
2229 literal sql with bind:
2232 customer => { -in => \[
2233 'SELECT cust_id FROM cust WHERE balance > ?',
2236 status => { -in => \'SELECT status_codes FROM states' },
2242 customer IN ( SELECT cust_id FROM cust WHERE balance > ? )
2243 AND status IN ( SELECT status_codes FROM states )
2247 Finally, if the argument to C<-in> is not a reference, it will be
2248 treated as a single-element array.
2250 Another pair of operators is C<-between> and C<-not_between>,
2251 used with an arrayref of two values:
2255 completion_date => {
2256 -not_between => ['2002-10-01', '2003-02-06']
2262 WHERE user = ? AND completion_date NOT BETWEEN ( ? AND ? )
2264 Just like with C<-in> all plausible combinations of literal SQL
2268 start0 => { -between => [ 1, 2 ] },
2269 start1 => { -between => \["? AND ?", 1, 2] },
2270 start2 => { -between => \"lower(x) AND upper(y)" },
2271 start3 => { -between => [
2273 \["upper(?)", 'stuff' ],
2280 ( start0 BETWEEN ? AND ? )
2281 AND ( start1 BETWEEN ? AND ? )
2282 AND ( start2 BETWEEN lower(x) AND upper(y) )
2283 AND ( start3 BETWEEN lower(x) AND upper(?) )
2285 @bind = (1, 2, 1, 2, 'stuff');
2288 These are the two builtin "special operators"; but the
2289 list can be expanded : see section L</"SPECIAL OPERATORS"> below.
2291 =head2 Unary operators: bool
2293 If you wish to test against boolean columns or functions within your
2294 database you can use the C<-bool> and C<-not_bool> operators. For
2295 example to test the column C<is_user> being true and the column
2296 C<is_enabled> being false you would use:-
2300 -not_bool => 'is_enabled',
2305 WHERE is_user AND NOT is_enabled
2307 If a more complex combination is required, testing more conditions,
2308 then you should use the and/or operators:-
2315 -not_bool => 'four',
2321 WHERE one AND two AND three AND NOT four
2324 =head2 Nested conditions, -and/-or prefixes
2326 So far, we've seen how multiple conditions are joined with a top-level
2327 C<AND>. We can change this by putting the different conditions we want in
2328 hashes and then putting those hashes in an array. For example:
2333 status => { -like => ['pending%', 'dispatched'] },
2337 status => 'unassigned',
2341 This data structure would create the following:
2343 $stmt = "WHERE ( user = ? AND ( status LIKE ? OR status LIKE ? ) )
2344 OR ( user = ? AND status = ? ) )";
2345 @bind = ('nwiger', 'pending', 'dispatched', 'robot', 'unassigned');
2348 Clauses in hashrefs or arrayrefs can be prefixed with an C<-and> or C<-or>
2349 to change the logic inside :
2355 -and => [ workhrs => {'>', 20}, geo => 'ASIA' ],
2356 -or => { workhrs => {'<', 50}, geo => 'EURO' },
2363 WHERE ( user = ? AND (
2364 ( workhrs > ? AND geo = ? )
2365 OR ( workhrs < ? OR geo = ? )
2368 =head3 Algebraic inconsistency, for historical reasons
2370 C<Important note>: when connecting several conditions, the C<-and->|C<-or>
2371 operator goes C<outside> of the nested structure; whereas when connecting
2372 several constraints on one column, the C<-and> operator goes
2373 C<inside> the arrayref. Here is an example combining both features :
2376 -and => [a => 1, b => 2],
2377 -or => [c => 3, d => 4],
2378 e => [-and => {-like => 'foo%'}, {-like => '%bar'} ]
2383 WHERE ( ( ( a = ? AND b = ? )
2384 OR ( c = ? OR d = ? )
2385 OR ( e LIKE ? AND e LIKE ? ) ) )
2387 This difference in syntax is unfortunate but must be preserved for
2388 historical reasons. So be careful : the two examples below would
2389 seem algebraically equivalent, but they are not
2391 {col => [-and => {-like => 'foo%'}, {-like => '%bar'}]}
2392 # yields : WHERE ( ( col LIKE ? AND col LIKE ? ) )
2394 [-and => {col => {-like => 'foo%'}, {col => {-like => '%bar'}}]]
2395 # yields : WHERE ( ( col LIKE ? OR col LIKE ? ) )
2398 =head2 Literal SQL and value type operators
2400 The basic premise of SQL::Abstract is that in WHERE specifications the "left
2401 side" is a column name and the "right side" is a value (normally rendered as
2402 a placeholder). This holds true for both hashrefs and arrayref pairs as you
2403 see in the L</WHERE CLAUSES> examples above. Sometimes it is necessary to
2404 alter this behavior. There are several ways of doing so.
2408 This is a virtual operator that signals the string to its right side is an
2409 identifier (a column name) and not a value. For example to compare two
2410 columns you would write:
2413 priority => { '<', 2 },
2414 requestor => { -ident => 'submitter' },
2419 $stmt = "WHERE priority < ? AND requestor = submitter";
2422 If you are maintaining legacy code you may see a different construct as
2423 described in L</Deprecated usage of Literal SQL>, please use C<-ident> in new
2428 This is a virtual operator that signals that the construct to its right side
2429 is a value to be passed to DBI. This is for example necessary when you want
2430 to write a where clause against an array (for RDBMS that support such
2431 datatypes). For example:
2434 array => { -value => [1, 2, 3] }
2439 $stmt = 'WHERE array = ?';
2440 @bind = ([1, 2, 3]);
2442 Note that if you were to simply say:
2448 the result would probably not be what you wanted:
2450 $stmt = 'WHERE array = ? OR array = ? OR array = ?';
2455 Finally, sometimes only literal SQL will do. To include a random snippet
2456 of SQL verbatim, you specify it as a scalar reference. Consider this only
2457 as a last resort. Usually there is a better way. For example:
2460 priority => { '<', 2 },
2461 requestor => { -in => \'(SELECT name FROM hitmen)' },
2466 $stmt = "WHERE priority < ? AND requestor IN (SELECT name FROM hitmen)"
2469 Note that in this example, you only get one bind parameter back, since
2470 the verbatim SQL is passed as part of the statement.
2474 Never use untrusted input as a literal SQL argument - this is a massive
2475 security risk (there is no way to check literal snippets for SQL
2476 injections and other nastyness). If you need to deal with untrusted input
2477 use literal SQL with placeholders as described next.
2479 =head3 Literal SQL with placeholders and bind values (subqueries)
2481 If the literal SQL to be inserted has placeholders and bind values,
2482 use a reference to an arrayref (yes this is a double reference --
2483 not so common, but perfectly legal Perl). For example, to find a date
2484 in Postgres you can use something like this:
2487 date_column => \[q/= date '2008-09-30' - ?::integer/, 10/]
2492 $stmt = "WHERE ( date_column = date '2008-09-30' - ?::integer )"
2495 Note that you must pass the bind values in the same format as they are returned
2496 by L</where>. That means that if you set L</bindtype> to C<columns>, you must
2497 provide the bind values in the C<< [ column_meta => value ] >> format, where
2498 C<column_meta> is an opaque scalar value; most commonly the column name, but
2499 you can use any scalar value (including references and blessed references),
2500 L<SQL::Abstract> will simply pass it through intact. So if C<bindtype> is set
2501 to C<columns> the above example will look like:
2504 date_column => \[q/= date '2008-09-30' - ?::integer/, [ dummy => 10 ]/]
2507 Literal SQL is especially useful for nesting parenthesized clauses in the
2508 main SQL query. Here is a first example :
2510 my ($sub_stmt, @sub_bind) = ("SELECT c1 FROM t1 WHERE c2 < ? AND c3 LIKE ?",
2514 bar => \["IN ($sub_stmt)" => @sub_bind],
2519 $stmt = "WHERE (foo = ? AND bar IN (SELECT c1 FROM t1
2520 WHERE c2 < ? AND c3 LIKE ?))";
2521 @bind = (1234, 100, "foo%");
2523 Other subquery operators, like for example C<"E<gt> ALL"> or C<"NOT IN">,
2524 are expressed in the same way. Of course the C<$sub_stmt> and
2525 its associated bind values can be generated through a former call
2528 my ($sub_stmt, @sub_bind)
2529 = $sql->select("t1", "c1", {c2 => {"<" => 100},
2530 c3 => {-like => "foo%"}});
2533 bar => \["> ALL ($sub_stmt)" => @sub_bind],
2536 In the examples above, the subquery was used as an operator on a column;
2537 but the same principle also applies for a clause within the main C<%where>
2538 hash, like an EXISTS subquery :
2540 my ($sub_stmt, @sub_bind)
2541 = $sql->select("t1", "*", {c1 => 1, c2 => \"> t0.c0"});
2542 my %where = ( -and => [
2544 \["EXISTS ($sub_stmt)" => @sub_bind],
2549 $stmt = "WHERE (foo = ? AND EXISTS (SELECT * FROM t1
2550 WHERE c1 = ? AND c2 > t0.c0))";
2554 Observe that the condition on C<c2> in the subquery refers to
2555 column C<t0.c0> of the main query : this is I<not> a bind
2556 value, so we have to express it through a scalar ref.
2557 Writing C<< c2 => {">" => "t0.c0"} >> would have generated
2558 C<< c2 > ? >> with bind value C<"t0.c0"> ... not exactly
2559 what we wanted here.
2561 Finally, here is an example where a subquery is used
2562 for expressing unary negation:
2564 my ($sub_stmt, @sub_bind)
2565 = $sql->where({age => [{"<" => 10}, {">" => 20}]});
2566 $sub_stmt =~ s/^ where //i; # don't want "WHERE" in the subclause
2568 lname => {like => '%son%'},
2569 \["NOT ($sub_stmt)" => @sub_bind],
2574 $stmt = "lname LIKE ? AND NOT ( age < ? OR age > ? )"
2575 @bind = ('%son%', 10, 20)
2577 =head3 Deprecated usage of Literal SQL
2579 Below are some examples of archaic use of literal SQL. It is shown only as
2580 reference for those who deal with legacy code. Each example has a much
2581 better, cleaner and safer alternative that users should opt for in new code.
2587 my %where = ( requestor => \'IS NOT NULL' )
2589 $stmt = "WHERE requestor IS NOT NULL"
2591 This used to be the way of generating NULL comparisons, before the handling
2592 of C<undef> got formalized. For new code please use the superior syntax as
2593 described in L</Tests for NULL values>.
2597 my %where = ( requestor => \'= submitter' )
2599 $stmt = "WHERE requestor = submitter"
2601 This used to be the only way to compare columns. Use the superior L</-ident>
2602 method for all new code. For example an identifier declared in such a way
2603 will be properly quoted if L</quote_char> is properly set, while the legacy
2604 form will remain as supplied.
2608 my %where = ( is_ready => \"", completed => { '>', '2012-12-21' } )
2610 $stmt = "WHERE completed > ? AND is_ready"
2611 @bind = ('2012-12-21')
2613 Using an empty string literal used to be the only way to express a boolean.
2614 For all new code please use the much more readable
2615 L<-bool|/Unary operators: bool> operator.
2621 These pages could go on for a while, since the nesting of the data
2622 structures this module can handle are pretty much unlimited (the
2623 module implements the C<WHERE> expansion as a recursive function
2624 internally). Your best bet is to "play around" with the module a
2625 little to see how the data structures behave, and choose the best
2626 format for your data based on that.
2628 And of course, all the values above will probably be replaced with
2629 variables gotten from forms or the command line. After all, if you
2630 knew everything ahead of time, you wouldn't have to worry about
2631 dynamically-generating SQL and could just hardwire it into your
2634 =head1 ORDER BY CLAUSES
2636 Some functions take an order by clause. This can either be a scalar (just a
2637 column name,) a hash of C<< { -desc => 'col' } >> or C<< { -asc => 'col' } >>,
2638 or an array of either of the two previous forms. Examples:
2640 Given | Will Generate
2641 ----------------------------------------------------------
2643 \'colA DESC' | ORDER BY colA DESC
2645 'colA' | ORDER BY colA
2647 [qw/colA colB/] | ORDER BY colA, colB
2649 {-asc => 'colA'} | ORDER BY colA ASC
2651 {-desc => 'colB'} | ORDER BY colB DESC
2653 ['colA', {-asc => 'colB'}] | ORDER BY colA, colB ASC
2655 { -asc => [qw/colA colB/] } | ORDER BY colA ASC, colB ASC
2658 { -asc => 'colA' }, | ORDER BY colA ASC, colB DESC,
2659 { -desc => [qw/colB/], | colC ASC, colD ASC
2660 { -asc => [qw/colC colD/],|
2662 ===========================================================
2666 =head1 SPECIAL OPERATORS
2668 my $sqlmaker = SQL::Abstract->new(special_ops => [
2672 my ($self, $field, $op, $arg) = @_;
2678 handler => 'method_name',
2682 A "special operator" is a SQL syntactic clause that can be
2683 applied to a field, instead of a usual binary operator.
2686 WHERE field IN (?, ?, ?)
2687 WHERE field BETWEEN ? AND ?
2688 WHERE MATCH(field) AGAINST (?, ?)
2690 Special operators IN and BETWEEN are fairly standard and therefore
2691 are builtin within C<SQL::Abstract> (as the overridable methods
2692 C<_where_field_IN> and C<_where_field_BETWEEN>). For other operators,
2693 like the MATCH .. AGAINST example above which is specific to MySQL,
2694 you can write your own operator handlers - supply a C<special_ops>
2695 argument to the C<new> method. That argument takes an arrayref of
2696 operator definitions; each operator definition is a hashref with two
2703 the regular expression to match the operator
2707 Either a coderef or a plain scalar method name. In both cases
2708 the expected return is C<< ($sql, @bind) >>.
2710 When supplied with a method name, it is simply called on the
2711 L<SQL::Abstract/> object as:
2713 $self->$method_name ($field, $op, $arg)
2717 $op is the part that matched the handler regex
2718 $field is the LHS of the operator
2721 When supplied with a coderef, it is called as:
2723 $coderef->($self, $field, $op, $arg)
2728 For example, here is an implementation
2729 of the MATCH .. AGAINST syntax for MySQL
2731 my $sqlmaker = SQL::Abstract->new(special_ops => [
2733 # special op for MySql MATCH (field) AGAINST(word1, word2, ...)
2734 {regex => qr/^match$/i,
2736 my ($self, $field, $op, $arg) = @_;
2737 $arg = [$arg] if not ref $arg;
2738 my $label = $self->_quote($field);
2739 my ($placeholder) = $self->_convert('?');
2740 my $placeholders = join ", ", (($placeholder) x @$arg);
2741 my $sql = $self->_sqlcase('match') . " ($label) "
2742 . $self->_sqlcase('against') . " ($placeholders) ";
2743 my @bind = $self->_bindtype($field, @$arg);
2744 return ($sql, @bind);
2751 =head1 UNARY OPERATORS
2753 my $sqlmaker = SQL::Abstract->new(unary_ops => [
2757 my ($self, $op, $arg) = @_;
2763 handler => 'method_name',
2767 A "unary operator" is a SQL syntactic clause that can be
2768 applied to a field - the operator goes before the field
2770 You can write your own operator handlers - supply a C<unary_ops>
2771 argument to the C<new> method. That argument takes an arrayref of
2772 operator definitions; each operator definition is a hashref with two
2779 the regular expression to match the operator
2783 Either a coderef or a plain scalar method name. In both cases
2784 the expected return is C<< $sql >>.
2786 When supplied with a method name, it is simply called on the
2787 L<SQL::Abstract/> object as:
2789 $self->$method_name ($op, $arg)
2793 $op is the part that matched the handler regex
2794 $arg is the RHS or argument of the operator
2796 When supplied with a coderef, it is called as:
2798 $coderef->($self, $op, $arg)
2806 Thanks to some benchmarking by Mark Stosberg, it turns out that
2807 this module is many orders of magnitude faster than using C<DBIx::Abstract>.
2808 I must admit this wasn't an intentional design issue, but it's a
2809 byproduct of the fact that you get to control your C<DBI> handles
2812 To maximize performance, use a code snippet like the following:
2814 # prepare a statement handle using the first row
2815 # and then reuse it for the rest of the rows
2817 for my $href (@array_of_hashrefs) {
2818 $stmt ||= $sql->insert('table', $href);
2819 $sth ||= $dbh->prepare($stmt);
2820 $sth->execute($sql->values($href));
2823 The reason this works is because the keys in your C<$href> are sorted
2824 internally by B<SQL::Abstract>. Thus, as long as your data retains
2825 the same structure, you only have to generate the SQL the first time
2826 around. On subsequent queries, simply use the C<values> function provided
2827 by this module to return your values in the correct order.
2829 However this depends on the values having the same type - if, for
2830 example, the values of a where clause may either have values
2831 (resulting in sql of the form C<column = ?> with a single bind
2832 value), or alternatively the values might be C<undef> (resulting in
2833 sql of the form C<column IS NULL> with no bind value) then the
2834 caching technique suggested will not work.
2838 If you use my C<CGI::FormBuilder> module at all, you'll hopefully
2839 really like this part (I do, at least). Building up a complex query
2840 can be as simple as the following:
2844 use CGI::FormBuilder;
2847 my $form = CGI::FormBuilder->new(...);
2848 my $sql = SQL::Abstract->new;
2850 if ($form->submitted) {
2851 my $field = $form->field;
2852 my $id = delete $field->{id};
2853 my($stmt, @bind) = $sql->update('table', $field, {id => $id});
2856 Of course, you would still have to connect using C<DBI> to run the
2857 query, but the point is that if you make your form look like your
2858 table, the actual query script can be extremely simplistic.
2860 If you're B<REALLY> lazy (I am), check out C<HTML::QuickTable> for
2861 a fast interface to returning and formatting data. I frequently
2862 use these three modules together to write complex database query
2863 apps in under 50 lines.
2869 =item * gitweb: L<http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/SQL-Abstract.git>
2871 =item * git: L<git://git.shadowcat.co.uk/dbsrgits/SQL-Abstract.git>
2877 Version 1.50 was a major internal refactoring of C<SQL::Abstract>.
2878 Great care has been taken to preserve the I<published> behavior
2879 documented in previous versions in the 1.* family; however,
2880 some features that were previously undocumented, or behaved
2881 differently from the documentation, had to be changed in order
2882 to clarify the semantics. Hence, client code that was relying
2883 on some dark areas of C<SQL::Abstract> v1.*
2884 B<might behave differently> in v1.50.
2886 The main changes are :
2892 support for literal SQL through the C<< \ [$sql, bind] >> syntax.
2896 support for the { operator => \"..." } construct (to embed literal SQL)
2900 support for the { operator => \["...", @bind] } construct (to embed literal SQL with bind values)
2904 optional support for L<array datatypes|/"Inserting and Updating Arrays">
2908 defensive programming : check arguments
2912 fixed bug with global logic, which was previously implemented
2913 through global variables yielding side-effects. Prior versions would
2914 interpret C<< [ {cond1, cond2}, [cond3, cond4] ] >>
2915 as C<< "(cond1 AND cond2) OR (cond3 AND cond4)" >>.
2916 Now this is interpreted
2917 as C<< "(cond1 AND cond2) OR (cond3 OR cond4)" >>.
2922 fixed semantics of _bindtype on array args
2926 dropped the C<_anoncopy> of the %where tree. No longer necessary,
2927 we just avoid shifting arrays within that tree.
2931 dropped the C<_modlogic> function
2935 =head1 ACKNOWLEDGEMENTS
2937 There are a number of individuals that have really helped out with
2938 this module. Unfortunately, most of them submitted bugs via CPAN
2939 so I have no idea who they are! But the people I do know are:
2941 Ash Berlin (order_by hash term support)
2942 Matt Trout (DBIx::Class support)
2943 Mark Stosberg (benchmarking)
2944 Chas Owens (initial "IN" operator support)
2945 Philip Collins (per-field SQL functions)
2946 Eric Kolve (hashref "AND" support)
2947 Mike Fragassi (enhancements to "BETWEEN" and "LIKE")
2948 Dan Kubb (support for "quote_char" and "name_sep")
2949 Guillermo Roditi (patch to cleanup "IN" and "BETWEEN", fix and tests for _order_by)
2950 Laurent Dami (internal refactoring, extensible list of special operators, literal SQL)
2951 Norbert Buchmuller (support for literal SQL in hashpair, misc. fixes & tests)
2952 Peter Rabbitson (rewrite of SQLA::Test, misc. fixes & tests)
2953 Oliver Charles (support for "RETURNING" after "INSERT")
2959 L<DBIx::Class>, L<DBIx::Abstract>, L<CGI::FormBuilder>, L<HTML::QuickTable>.
2963 Copyright (c) 2001-2007 Nathan Wiger <nwiger@cpan.org>. All Rights Reserved.
2965 This module is actively maintained by Matt Trout <mst@shadowcatsystems.co.uk>
2967 For support, your best bet is to try the C<DBIx::Class> users mailing list.
2968 While not an official support venue, C<DBIx::Class> makes heavy use of
2969 C<SQL::Abstract>, and as such list members there are very familiar with
2970 how to create queries.
2974 This module is free software; you may copy this under the same
2975 terms as perl itself (either the GNU General Public License or
2976 the Artistic License)